add 40

40/paper.pdf

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:af0ab0d5bc0ac7aa3bfaff2d3526d4c13baa20f05d3afa3f01a936d169d5f483
+size 651096

40/replication_package/EmpiricalAnalysis/dofiles/4_1_Allocation_Attention.do

@@ -0,0 +1,147 @@
+/* Do file creates Tables and Figures for first part of Section 4.1 of the paper and tables and figures referenced therein*/
+
+log using `"${PATH_OUT}/4_1_Allocation_Attention.log"', replace
+
+use "${PATH_IN_DATA}/formatted_data_replication.dta", clear
+
+
+********* Descriptive Figues Attention Allocation
+
+*Individual Decision level
+cdfplot Attention if Treatment_Environment==1 ,by(Treatment_Incentives) opt1(lwidth(medthick medthick medthick medthick) lc(gs0 gs7 gs11 gs13) ///
+    xtitle("attention (in sec.)")    ///
+    legend(label(1 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-10") ///
+           label(2 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-20")  ///
+           label(3 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-40") ///
+           label(4 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-A`=ustrunescape("\u1D0D")'`=ustrunescape("\u1D18")'`=ustrunescape("\u029F")'`=ustrunescape("\u1D07")'") ))  ///
+    ytitle("Cumulative Frequency", margin(medium) height(3) size(medium)) xtitle("Attention (in sec.)", margin(medium) height(3) size(medium))
+graph export `"${PATH_OUT}/figure2.png"', as(png) replace
+
+* Individual average level
+cdfplot attention_mean if Treatment_Environment==1 ,by(Treatment_Incentives) opt1(lwidth(medthick medthick medthick medthick) lc(gs0 gs7 gs11 gs13) ///
+    xtitle("Attention (in sec.)")    ///
+    legend(label(1 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-10") ///
+    label(2 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-20")  ///
+    label(3 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-40") ///
+    label(4 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-A`=ustrunescape("\u1D0D")'`=ustrunescape("\u1D18")'`=ustrunescape("\u029F")'`=ustrunescape("\u1D07")'") ))  ///
+    ytitle("Cumulative Frequency", margin(medium) height(3) size(medium)) xtitle("Attention (in sec.)", margin(medium) height(3) size(medium))
+graph export `"${PATH_OUT}/figureO_1.png"', as(png) replace
+
+*Individual Decision level; Low Raven Score
+cdfplot Attention if Treatment_Environment==1 & raven_score_median==1,by(Treatment_Incentives) opt1(lwidth(medthick medthick medthick medthick) lc(gs0 gs7 gs11 gs13) ///
+    xtitle("Attention (in sec.)")    ///
+    legend(label(1 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-10") ///
+    label(2 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-20")  ///
+    label(3 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-40") ///
+    label(4 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-A`=ustrunescape("\u1D0D")'`=ustrunescape("\u1D18")'`=ustrunescape("\u029F")'`=ustrunescape("\u1D07")'") ))  ///
+    ytitle("Cumulative Frequency", margin(medium) height(3) size(medlarge)) xtitle("Attention (in sec.)", margin(medium) height(3) size(medlarge))
+graph export `"${PATH_OUT}/figureB_1a.png"', as(png) replace
+
+*Individual Decision level; High Raven Score
+cdfplot Attention if Treatment_Environment==1 & raven_score_median==2,by(Treatment_Incentives) opt1(lwidth(medthick medthick medthick medthick) lc(gs0 gs7 gs11 gs13) ///
+    xtitle("Attention (in sec.)")    ///
+    legend(label(1 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-10") ///
+    label(2 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-20")  ///
+    label(3 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-40") ///
+    label(4 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-A`=ustrunescape("\u1D0D")'`=ustrunescape("\u1D18")'`=ustrunescape("\u029F")'`=ustrunescape("\u1D07")'") ))  ///
+    ytitle("Cumulative Frequency", margin(medium) height(3) size(medlarge)) xtitle("Attention (in sec.)", margin(medium) height(3) size(medlarge))
+graph export `"${PATH_OUT}/figureB_1b.png"', as(png) replace
+
+
+
+* Summary statistics and non-parametric tests for numbers reported in the text
+tabstat Attention if Treatment_Environment ==1 , by(Treatment_Incentives) stats(mean n)
+
+ksmirnov Attention if Treatment_Environment==1 & Treatment_Incentives==1 | Treatment_Incentives==4, by(Treatment_Incentives)
+
+spearman attention_mean Treatment_Incentives if round==1 & Treatment_Environment==1
+
+tabstat no_attention if Treatment_Environment ==1  , by(Treatment_Incentives) stats(mean n)
+
+spearman  attention_positive_mean Treatment_Incentives if round==1 & Treatment_Environment==1
+
+
+************Regression Table Average Attention, Extensive Margin + Choice Quality
+reg Attention i.Treatment_Incentives_Baseline_sc if Treatment_Environment==1  , cluster(subject_id) robust
+test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_3 = r(p)
+test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_4 = r(p)
+test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_3_4 = r(p)
+eststo plain_attention
+
+
+reg Attention i.Treatment_Incentives_Baseline_sc ${Wave_control} ${Ability_control} ${Controls} if Treatment_Environment==1  , cluster(subject_id) robust
+test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_3 = r(p)
+test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_4 = r(p)
+test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_3_4 = r(p)
+eststo all_control_attention
+
+reg  no_attention i.Treatment_Incentives_Baseline_sc if Treatment_Environment==1  , cluster(subject_id) robust
+test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_3 = r(p)
+test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_4 = r(p)
+test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_3_4 = r(p)
+eststo plain_attention_pos
+
+reg  no_attention i.Treatment_Incentives_Baseline_sc ${Wave_control} ${Ability_control} ${Controls} if Treatment_Environment==1  , cluster(subject_id) robust
+test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_3 = r(p)
+test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_4 = r(p)
+test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_3_4 = r(p)
+eststo all_control_attention_pos
+
+
+*Regressions Decision Quality
+reg summation_correct i.Treatment_Incentives_Baseline_sc if Treatment_Environment==1  , cluster(subject_id) robust
+test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_3 = r(p)
+test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_4 = r(p)
+test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_3_4 = r(p)
+eststo plain_sum
+
+reg summation_correct i.Treatment_Incentives_Baseline_sc ${Wave_control} ${Ability_control} ${Controls} if Treatment_Environment==1  , cluster(subject_id) robust
+test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_3 = r(p)
+test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_4 = r(p)
+test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_3_4 = r(p)
+eststo all_control_sum
+
+
+esttab plain_attention  all_control_attention ///
+    plain_attention_pos  all_control_attention_pos     ///
+    plain_sum  all_control_sum ///
+    using `"${PATH_OUT}/tableB_1.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order() ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    noomit nobase ///
+    nomtitles ///
+    mgroups("Avg. Attention" "Attention\,$=$\,0"  "Choice Quality", ///
+    pattern(1 0 1 0 1 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2 p_2_3 p_2_4 p_3_4, fmt(%18.0g %18.0g %5.3f %5.3f) labels(`"N"' "No. Subjects" "\(R^2\)" "\textsc{Baseline-20}=\textsc{Baseline-40}" "\textsc{Baseline-20}=\textsc{Baseline-A.}" "\textsc{Baseline-40}=\textsc{Baseline-A.}")) ///
+    indicate("Controls = *original* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat*")
+
+
+
+* Summary statistics and non-parametric tests for reported in the text
+
+tabstat summation_correct_mean if Treatment_Environment ==1  , by(Treatment_Incentives) stats(mean n)
+
+spearman  summation_correct_mean Treatment_Incentives_Baseline_sc if round==1 & Treatment_Environment==1
+
+
+log close

40/replication_package/EmpiricalAnalysis/dofiles/4_1_Passive_Behavior.do

@@ -0,0 +1,183 @@
+/* Do file creates Tables and Figures for second part of Section 4.2 of the paper and tables and figures referenced therein*/
+
+
+log using `"${PATH_OUT}/4_1_Passive_Behavior.log"', replace
+
+use "${PATH_IN_DATA}/formatted_data_replication.dta", clear
+
+
+
+
+tabstat default_followed if Treatment_Environment==1, by(Treatment_Incentives) stats(N mean)
+
+spearman default_followed_mean Treatment_Incentives if round==1 & Treatment_Environment==1
+
+
+
+* Overall Barchart Figure 3 (a)
+forvalues i=1(1)4{
+    reg default_followed i.Treatment_Incentives if Treatment_Environment==1  , cluster(subject_id) robust
+    margins i.Treatment_Incentives if Treatment_Incentives==`i', post
+    eststo plain_att_`i'
+}
+
+coefplot (plain_att_1, bcolor(gs0)) (plain_att_2, bcolor(gs7))  (plain_att_3, bcolor(gs11))  (plain_att_4, bcolor(gs13)) , vertical recast(bar) noci ///
+    xlabel(1 "Baseline-10" 2 "Baseline-20" 3 "Baseline-40" 4 "Baseline- A.", labgap(3) labsize(medlarge)) ytitle("Default Adherence", margin(medium) height(3) size(medlarge)) ylabel(0(0.1)1,glcolor(gs13)) ///
+    barwidth(0.75) graphregion(color(white)) bgcolor(white)   ///
+    offset(0) ///
+    coeflabels(,nolabels notick) ///
+        legend(label(1 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-10") ///
+           label(2 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-20")  ///
+           label(3 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-40") ///
+           label(4 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-A`=ustrunescape("\u1D0D")'`=ustrunescape("\u1D18")'`=ustrunescape("\u029F")'`=ustrunescape("\u1D07")'") )  ///
+    groups(*Treatment_Incentives* = `"Default incorrect"', labcolor(white) labsize(medlarge))
+
+graph export `"${PATH_OUT}/figure3a.png"', as(png) replace
+
+
+* By Default correct Barchart Figure 3 (b)
+forvalues j=1(1)4{
+    forvalues i=0(1)1{
+        reg default_followed i.Treatment_Incentives#i.default_correct_choice  if Treatment_Environment==1  , cluster(subject_id) robust
+        margins i.Treatment_Incentives#i.default_correct_choice if default_correct_choice==`i' & Treatment_Incentives==`j', post
+        eststo plain_att_`i'_`j'
+    }
+}
+
+coefplot (plain_att_0_1, bcolor(gs0)) (plain_att_0_2, bcolor(gs7))  (plain_att_0_3, bcolor(gs11))  (plain_att_0_4, bcolor(gs13))   ///
+         (plain_att_1_1, bcolor(gs0)) (plain_att_1_2, bcolor(gs7))  (plain_att_1_3, bcolor(gs11))  (plain_att_1_4, bcolor(gs13))   ///
+          , offset(0) vertical recast(bar) noci ///
+    coeflabels(,nolabels notick) ///
+    ytitle("Default Adherence", margin(medium) height(3) size(medlarge)) ylabel(0(0.1)1,glcolor(gs13)) ///
+    barwidth(0.75) graphregion(color(white)) bgcolor(white)   ///
+        legend(order(1 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-10" ///
+           2 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-20"  ///
+           3 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-40" ///
+           4 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'-A`=ustrunescape("\u1D0D")'`=ustrunescape("\u1D18")'`=ustrunescape("\u029F")'`=ustrunescape("\u1D07")'"))  ///
+        nooffset groups(*0.default_correct_choice* = `"Default incorrect"' *1.default_correct_choice*  = "Default correct", labsize(medlarge))
+
+graph export `"${PATH_OUT}/figure3b.png"', as(png) replace
+
+
+
+
+*********************************************
+*By default correct
+*********************************************
+tabstat default_followed if Treatment_Environment==1 & default_correct_choice==0, by(Treatment_Incentives) stats(N mean)
+tabstat default_followed if Treatment_Environment==1 & default_correct_choice==1, by(Treatment_Incentives) stats(N mean)
+
+
+*Default_followed_correct_mean is calculated using "bysort subject_id default_correct_choice:"; Round 1 Default is correct and therefore use mean from that round
+spearman default_followed_correct_mean Treatment_Incentives if round==1 & Treatment_Environment==1
+*Explanation see above, round 2 default happens to be false.
+spearman default_followed_correct_mean Treatment_Incentives if round==2 & Treatment_Environment==1
+
+
+******************************************************************************************
+*By Raven
+******************************************************************************************
+tabstat default_followed if Treatment_Environment==1 & raven_score_median==1, by(Treatment_Incentives) stats(N mean)
+tabstat default_followed if Treatment_Environment==1 & raven_score_median==2, by(Treatment_Incentives) stats(N mean)
+
+spearman default_followed_mean Treatment_Incentives if round==1 &raven_score_median==1 & Treatment_Environment==1
+spearman default_followed_mean Treatment_Incentives if round==1 &raven_score_median==2 & Treatment_Environment==1
+spearman default_followed_mean Treatment_Incentives if round==1 &raven_score_quartiles==4 & Treatment_Environment==1
+
+
+
+
+
+
+
+
+
+
+
+
+
+*Regression Table
+reg default_followed i.Treatment_Incentives_Baseline_sc if Treatment_Environment==1  , cluster(subject_id) robust
+test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_3 = r(p)
+test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_4 = r(p)
+test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_3_4 = r(p)
+eststo plain_default
+
+reg default_followed i.Treatment_Incentives_Baseline_sc ${Wave_control} ${Ability_control} ${Controls} if Treatment_Environment==1 , cluster(subject_id) robust
+test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_3 = r(p)
+test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_2_4 = r(p)
+test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+estadd scalar p_3_4 = r(p)
+eststo all_control_default
+
+forvalues i=0(1)1{
+
+    reg default_followed i.Treatment_Incentives_Baseline_sc if Treatment_Environment==1  & default_correct_choice==`i', cluster(subject_id) robust
+    test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+    estadd scalar p_2_3 = r(p)
+    test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+    estadd scalar p_2_4 = r(p)
+    test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+    estadd scalar p_3_4 = r(p)
+    eststo plain_default_`i'
+
+    reg default_followed i.Treatment_Incentives_Baseline_sc ${Wave_control} ${Ability_control} ${Controls} if Treatment_Environment==1 & default_correct_choice==`i' , cluster(subject_id) robust
+    test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+    estadd scalar p_2_3 = r(p)
+    test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+    estadd scalar p_2_4 = r(p)
+    test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+    estadd scalar p_3_4 = r(p)
+    eststo all_control_default_`i'
+}
+
+
+************Raven
+forvalues i=1(1)2 {
+    reg default_followed i.b1.raven_score_median i.b1.Treatment_Incentives_Baseline_sc if Treatment_Environment==1 & raven_score_median==`i'  , cluster(subject_id) robust
+    test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+    estadd scalar p_2_3 = r(p)
+    test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+    estadd scalar p_2_4 = r(p)
+    test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+    estadd scalar p_3_4 = r(p)
+    eststo raven_plain_default_`i'
+
+    reg default_followed i.b1.raven_score_median i.b1.Treatment_Incentives_Baseline_sc ${Wave_control} ${Ability_control} ${Controls} if Treatment_Environment==1 & raven_score_median==`i' , cluster(subject_id) robust
+    test 2.Treatment_Incentives_Baseline_sc=3.Treatment_Incentives_Baseline_sc
+    estadd scalar p_2_3 = r(p)
+    test 2.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+    estadd scalar p_2_4 = r(p)
+    test 3.Treatment_Incentives_Baseline_sc=4.Treatment_Incentives_Baseline_sc
+    estadd scalar p_3_4 = r(p)
+    eststo raven_all_control_default_`i'
+
+}
+
+
+esttab plain_default all_control_default ///
+    plain_default_0 all_control_default_0 ///
+    plain_default_1 all_control_default_1 ///
+    raven_plain_default_1 raven_all_control_default_1 ///
+    raven_plain_default_2 raven_all_control_default_2 ///
+    using `"${PATH_OUT}/tableB_2.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order() star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes noomit nobase nomtitles ///
+    mgroups("Overall" "Default incorrect" "Default correct" "Raven Low" "Raven High", ///
+    pattern(1 0 1 0 1 0 1 0 1 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2 p_2_3 p_2_4 p_3_4, fmt(%18.0g %18.0g %5.3f %5.3f) labels("N" "No. Subjects" "\(R^2\)" "\textsc{Baseline-20}=\textsc{Baseline-40}" "\textsc{Baseline-20}=\textsc{Baseline-A.}" "\textsc{Baseline-40}=\textsc{Baseline-A.}")) ///
+    indicate("Controls = *original* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat*")
+
+
+
+
+
+
+
+log close

40/replication_package/EmpiricalAnalysis/dofiles/4_2_Cognitive_Spillover.do

@@ -0,0 +1,246 @@
+/*
+*/
+
+log using `"${PATH_OUT}/4_2_Cognitive_Spillover.log"', replace
+
+
+*************** FIRST ESTIMATION RESULTS FORM ONLINE EXPEIRMENT! ******************
+use "${PATH_IN_DATA}/formatted_data_long_mturk.dta", clear
+
+eststo clear
+foreach var of varlist math_time math_task_correct passive_choice memory payoff_share {
+
+    reg `var' i.Treatment_intervention, cluster(subject_id)
+    eststo p_`var'
+
+    reg `var' i.Treatment_intervention  window_height1 window_width1 age i.gender, cluster(subject_id)
+    eststo c_`var'
+}
+
+
+esttab * ///
+    using `"${PATH_OUT}/tableO_10.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase ///
+    nomtitles ///
+    mgroups("Avg. Attention" "\shortstack{Choice Quality \\ (Decision Task)}" "Default Adherence" "\shortstack{Choice Quality \\ (Background Task)}"  "Payoff Share" , ///
+    pattern(1 0 1 0 1 0 1 0 1 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2, fmt(%18.0g %18.0g %9.2g) labels("N" "No. Subjects" "\(R^2\)")) ///
+    indicate("Controls = *age* *gender* *window*")
+
+
+
+cdfplot math_time ,by(Treatment_intervention) opt1(lwidth(medthick))  ///
+    legend(label(1 "Baseline") label(2 "Intervention"))  ///
+    ytitle("Cumulative Frequency", margin(medium) height(3) size(medium)) ///
+    xtitle("Attention (in sec.)", margin(medium) height(3) size(medium)) ///
+    legend(order(1 "B`=ustrunescape("\u1D00")'`=ustrunescape("\uA731")'`=ustrunescape("\u1D07")'`=ustrunescape("\u029F")'`=ustrunescape("\u026A")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D07")'" ///
+                2 "`=ustrunescape("\u0049")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D1B")'`=ustrunescape("\u1D07")'`=ustrunescape("\u0280")'`=ustrunescape("\u1D20")'`=ustrunescape("\u1D07")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D1B")'`=ustrunescape("\u026A")'`=ustrunescape("\u1D0F")'`=ustrunescape("\u0274")'"))
+
+graph export `"${PATH_OUT}/figureO_3.png"', as(png) replace
+
+
+eststo clear
+
+
+* Generate Estimation results for Table 3 in the main text
+reg memory i.Treatment_intervention, cluster(subject_id)
+eststo p_memory
+
+reg memory i.Treatment_intervention window_height1 window_width1 age i.gender, cluster(subject_id)
+eststo c_memory
+
+
+
+*************** MAIN LAB EXPEIRMENT **************
+use "${PATH_IN_DATA}/formatted_data_replication.dta", clear
+
+* Drop Ample Observations, which are not analyzed in this section.
+drop if Treatment_Incentives==4
+
+tabstat load_correct , by(Treatment_intervention)
+tabstat load_correct , by(Treatment_Environment)
+
+************************************************************************************
+************ Background Task Quality
+************************************************************************
+
+reg load_correct i.Treatment_intervention , robust cluster(subject_id)
+eststo force_plain
+reg load_correct i.Treatment_intervention ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} , robust cluster(subject_id)
+eststo force_all_controls_ability
+
+reg load_correct i.Treatment_Environment , robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo plain
+
+reg load_correct i.Treatment_Environment ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} , robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo all_controls_ability
+
+
+esttab force_plain  force_all_controls_ability ///
+    plain all_controls_ability ///
+    p_memory c_memory ///
+    using `"${PATH_OUT}/table3.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase ///
+    nomtitles ///
+    mgroups("Lab Experiment" "Online Experiment" , ///
+    pattern(1 0 0 0 1 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2 p_treatments, fmt(%18.0g %18.0g %5.3f %5.3f) labels(`"N"' "No. Subjects"  "\(R^2\)" "\textsc{Directed}=\textsc{Forced}")) ///
+    indicate("Controls = *original* *Incentives* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat* *age* *gender* *window* ")
+
+
+
+
+
+
+
+
+************************************************************************************
+************ Background Task Quality: HETEROGENEITIES
+************************************************************************
+
+***************************
+******** RAVEN ************
+ ***************************
+
+reg load_correct i.b0.Treatment_intervention#i.bn.raven_score_median i.bn.raven_score_median  ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust nocons
+eststo incentives_heterogeneity
+
+coefplot    (incentives_heterogeneity ,  fcolor(gs8) mcolor(gs8) lcolor(gs8)) , ///
+    vertical lwidth(*1) keep(*Treatment_intervention*) ///
+    ciopts(recast(rcap)lpattern(dash)lwidth(*.6) lcolor(gs0) ) citop ci(95) ///
+    xlabel(, labgap(3) labsize(medium)) ytitle ("Spillover", margin(medium) height(3) size(medium)) ylabel(-.1(0.05).1) ///
+    graphregion(color(white))  yline(0, lcolor(black)) xlabel(1 "Raven Score {&le} Median" 2 "Raven Score {&gt} Median " )
+
+graph export `"${PATH_OUT}/figure4.png"', as(png) replace
+
+
+reg load_correct i.raven_score_median i.Treatment_intervention i.Treatment_intervention#i.raven_score_median  , cluster(subject_id) robust
+eststo hetero_force_both_raw
+
+reg load_correct i.raven_score_median i.Treatment_intervention i.Treatment_intervention#i.raven_score_median   ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust
+eststo hetero_force_all
+
+reg load_correct i.raven_score_median i.Treatment_Environment i.Treatment_Environment#i.raven_score_median  , cluster(subject_id) robust
+eststo hetero_both_raw
+
+reg load_correct i.raven_score_median i.Treatment_Environment i.Treatment_Environment#i.raven_score_median   ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust
+eststo hetero_all
+
+esttab   hetero_force_both_raw hetero_force_all ///
+         hetero_both_raw hetero_all   ///
+    using `"${PATH_OUT}/tableO_4.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* 2.Treatment_Environment* 3.Treatment_Environment*) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase ///
+    nomtitles ///
+    mgroups("Spillover" , ///
+    pattern(1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+     stats(N N_clust r2, fmt(%18.0g %18.0g %5.3f) labels("N" "No. Subjects" "\(R^2\)")) ///
+    indicate("Controls = *original* *Incentives* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat* *age* *gender* ")
+
+
+
+***************************
+******** Task Difficulty **
+***************************
+
+reg load_correct i.b0.Treatment_intervention#i.bn.high_task_difficulty i.bn.high_task_difficulty  ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust nocons
+eststo incentives_heterogeneity
+
+coefplot    (incentives_heterogeneity ,  fcolor(gs8) mcolor(gs8) lcolor(gs8)) , ///
+    vertical lwidth(*1) keep(*Treatment_intervention*) ///
+    ciopts(recast(rcap)lpattern(dash)lwidth(*.6) lcolor(gs0) ) citop ci(95) ///
+    xlabel(, labgap(3) labsize(medium)) ytitle ("Spillover", margin(medium) height(3) size(medium)) ///
+    graphregion(color(white))  yline(0, lcolor(black)) xlabel(1 "Difficulty {&le} Median" 2 "Difficulty {&gt} Median" ) ylabel(-.1(0.05).1)
+graph export `"${PATH_OUT}/figure5.png"', as(png) replace
+
+
+
+reg load_correct i.high_task_difficulty i.Treatment_intervention i.Treatment_intervention#i.high_task_difficulty , cluster(subject_id) robust
+eststo hetero_force_both_raw
+
+reg load_correct i.high_task_difficulty i.Treatment_intervention i.Treatment_intervention#i.high_task_difficulty  ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust
+eststo hetero_force_all
+
+reg load_correct i.high_task_difficulty i.Treatment_Environment i.Treatment_Environment#i.high_task_difficulty , cluster(subject_id) robust
+eststo hetero_both_raw
+
+reg load_correct i.high_task_difficulty i.Treatment_Environment i.Treatment_Environment#i.high_task_difficulty  ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust
+eststo hetero_all
+
+esttab   hetero_force_both_raw hetero_force_all ///
+         hetero_both_raw hetero_all   ///
+    using `"${PATH_OUT}/tableO_5.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* 2.Treatment_Environment* 3.Treatment_Environment*) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase ///
+    nomtitles ///
+    mgroups("Spillover" , ///
+    pattern(1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+     stats(N N_clust r2, fmt(%18.0g %18.0g %5.3f) labels("N" "No. Subjects" "\(R^2\)")) ///
+    indicate("Controls = *original* *Incentives* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat* *age* *gender* ")
+
+
+***************************
+******** Incentives **
+***************************
+
+
+reg load_correct i.b0.Treatment_intervention#i.bn.Treatment_Incentives i.bn.Treatment_Incentives  ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust nocons
+eststo incentives_heterogeneity
+
+coefplot    (incentives_heterogeneity ,  fcolor(gs8) mcolor(gs8) lcolor(gs8)) , ///
+    vertical lwidth(*1) keep(*Treatment_intervention*) ///
+    ciopts(recast(rcap)lpattern(dash)lwidth(*.6) lcolor(gs0) ) citop ci(95) ///
+    xlabel(, labgap(3) labsize(medium)) ytitle ("Spillover", margin(medium) height(3) size(medium)) ///
+    graphregion(color(white))  yline(0, lcolor(black))    ///
+    xlabel( 1 " `=ustrunescape("\u0049")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D1B")'`=ustrunescape("\u1D07")'`=ustrunescape("\u0280")'`=ustrunescape("\u1D20")'`=ustrunescape("\u1D07")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D1B")'`=ustrunescape("\u026A")'`=ustrunescape("\u1D0F")'`=ustrunescape("\u0274")'-10" ///
+    2" `=ustrunescape("\u0049")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D1B")'`=ustrunescape("\u1D07")'`=ustrunescape("\u0280")'`=ustrunescape("\u1D20")'`=ustrunescape("\u1D07")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D1B")'`=ustrunescape("\u026A")'`=ustrunescape("\u1D0F")'`=ustrunescape("\u0274")'-20" ///
+    3" `=ustrunescape("\u0049")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D1B")'`=ustrunescape("\u1D07")'`=ustrunescape("\u0280")'`=ustrunescape("\u1D20")'`=ustrunescape("\u1D07")'`=ustrunescape("\u0274")'`=ustrunescape("\u1D1B")'`=ustrunescape("\u026A")'`=ustrunescape("\u1D0F")'`=ustrunescape("\u0274")'-40") ///
+    ylabel(-.1(0.05).1)
+graph export `"${PATH_OUT}/figure6.png"', as(png) replace
+
+
+reg load_correct i.Treatment_Incentives_Int_sc i.Treatment_intervention i.Treatment_intervention#i.Treatment_Incentives_Int_sc  , cluster(subject_id) robust
+eststo hetero_force_both_raw
+
+
+reg load_correct i.Treatment_Incentives_Int_sc i.Treatment_intervention i.Treatment_intervention#i.Treatment_Incentives_Int_sc   ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust
+eststo hetero_force_all
+
+reg load_correct i.Treatment_Incentives_Int_sc i.Treatment_Environment i.Treatment_Environment#i.Treatment_Incentives_Int_sc , cluster(subject_id) robust
+eststo hetero_both_raw
+
+reg load_correct i.Treatment_Incentives_Int_sc i.Treatment_Environment i.Treatment_Environment#i.Treatment_Incentives_Int_sc  ${Wave_control} ${Ability_control} ${Controls} , cluster(subject_id) robust
+eststo hetero_all
+
+esttab   hetero_force_both_raw  hetero_force_all ///
+         hetero_both_raw  hetero_all   ///
+    using `"${PATH_OUT}/tableO_6.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* 2.Treatment_Environment* 3.Treatment_Environment*) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase ///
+    nomtitles ///
+    mgroups("Spillover" , ///
+    pattern(1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+     stats(N N_clust r2, fmt(%18.0g %18.0g %5.3f) labels("N" "No. Subjects" "\(R^2\)")) ///
+    indicate("Controls = *original* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat* *age* *gender* ")
+
+
+log close

40/replication_package/EmpiricalAnalysis/dofiles/4_2_Interventions_targeted_domain.do

@@ -0,0 +1,237 @@
+/*
+*/
+
+log using `"${PATH_OUT}/4_2_Interventions_targeted_domain.log"', replace
+
+use "${PATH_IN_DATA}/formatted_data_replication.dta", clear
+
+
+
+
+
+tabstat summation_correct_mean if  Treatment_Incentives!=4, by(Treatment_Environment) stats(mean n)
+
+****************************************************************
+**** Table 2, Decision Task + Default Adherence
+****************************************************************
+
+reg summation_correct i.Treatment_intervention if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo force_plain
+reg summation_correct i.Treatment_intervention ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo force_all_controls_ability
+
+reg summation_correct i.Treatment_Environment if Treatment_Incentives!=4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo plain
+
+reg summation_correct i.Treatment_Environment ${Incentive_control}  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo all_controls_ability
+
+reg default_followed i.Treatment_intervention if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_force_plain
+reg default_followed i.Treatment_intervention ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_force_controls
+
+reg default_followed i.Treatment_Environment if Treatment_Incentives!=4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo passive_plain
+
+reg default_followed i.Treatment_Environment ${Incentive_control}  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo passive_controls
+
+esttab  force_plain  force_all_controls_ability ///
+    plain   all_controls_ability ///
+     passive_force_plain passive_force_controls ///
+     passive_plain  passive_controls ///
+    using `"${PATH_OUT}/table2.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* *Treatment_Environment*) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase ///
+    nomtitles ///
+    mgroups("Panel (a): Choice Quality" "Panel (b): Default Adherence" , ///
+    pattern(1 0 0 0 1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2 p_treatments, fmt(%18.0g %18.0g %5.3f %5.3f) labels(`"N"' "No. Subjects"  "\(R^2\)" "\textsc{Directed}=\textsc{Forced}")) ///
+    indicate("Controls = *original* *Incentives* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat*")
+
+
+
+
+
+
+****************************************************************
+****  Heterogenous Effects: Incentives
+****************************************************************
+
+reg summation_correct i.b1.Treatment_Incentives_Int_sc i.bn.Treatment_Incentives i.Treatment_intervention#i.Treatment_Incentives if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo force_plain
+
+reg summation_correct i.b1.Treatment_Incentives_Int_sc i.bn.Treatment_Incentives i.Treatment_intervention#i.Treatment_Incentives  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo force_all_controls_ability
+
+reg summation_correct i.b1.Treatment_Incentives_Int_sc i.bn.Treatment_Incentives i.Treatment_Environment#i.Treatment_Incentives if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo plain
+
+reg summation_correct i.b1.Treatment_Incentives_Int_sc i.bn.Treatment_Incentives i.Treatment_Environment#i.Treatment_Incentives   ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo all_controls_ability
+
+reg default_followed i.b1.Treatment_Incentives_Int_sc i.bn.Treatment_Incentives i.Treatment_intervention#i.Treatment_Incentives if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_force_plain
+reg default_followed i.b1.Treatment_Incentives_Int_sc i.bn.Treatment_Incentives i.Treatment_intervention#i.Treatment_Incentives  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_force_controls
+
+reg default_followed i.b1.Treatment_Incentives_Int_sc i.bn.Treatment_Incentives i.Treatment_Environment#i.Treatment_Incentives if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_plain
+
+reg default_followed i.b1.Treatment_Incentives_Int_sc i.bn.Treatment_Incentives i.Treatment_Environment#i.Treatment_Incentives   ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_controls
+
+esttab  force_plain  force_all_controls_ability ///
+    plain   all_controls_ability ///
+     passive_force_plain passive_force_controls ///
+     passive_plain  passive_controls ///
+    using `"${PATH_OUT}/tableO_2.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* *Treatment_Environment*) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase noomit ///
+    interaction("-") ///
+    nomtitles ///
+    mgroups("Panel (a): Choice Quality" "Panel (b): Default Adherence" , ///
+    pattern(1 0 0 0 1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2, fmt(%18.0g %18.0g %5.3f ) labels(`"N"' "No. Subjects"  "\(R^2\)")) ///
+    indicate("Controls = *original*  *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat*")
+
+
+
+
+****************************************************************
+* Heterogenous Effects: Raven Score
+****************************************************************
+
+reg summation_correct i.raven_score_median i.Treatment_intervention i.Treatment_intervention#i.raven_score_median   if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo force_plain
+
+reg summation_correct i.raven_score_median i.Treatment_intervention i.Treatment_intervention#i.raven_score_median   i.b3.Treatment_Incentives ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo force_all_controls_ability
+
+reg summation_correct i.raven_score_median i.Treatment_Environment i.Treatment_Environment#i.raven_score_median if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo plain
+
+reg summation_correct i.raven_score_median i.Treatment_Environment i.Treatment_Environment#i.raven_score_median ${Incentive_control}  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo all_controls_ability
+
+reg default_followed i.raven_score_median i.Treatment_intervention i.Treatment_intervention#i.raven_score_median   if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_force_plain
+
+reg default_followed i.raven_score_median i.Treatment_intervention i.Treatment_intervention#i.raven_score_median   ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_force_controls
+
+reg default_followed i.raven_score_median i.Treatment_Environment i.Treatment_Environment#i.raven_score_median if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_plain
+
+reg default_followed i.raven_score_median i.Treatment_Environment i.Treatment_Environment#i.raven_score_median ${Incentive_control}  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo passive_controls
+
+esttab  force_plain  force_all_controls_ability ///
+    plain   all_controls_ability ///
+     passive_force_plain passive_force_controls ///
+     passive_plain  passive_controls ///
+    using `"${PATH_OUT}/tableO_3.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* 2.Treatment_Environment* 3.Treatment_Environment*) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase noomit ///
+    nomtitles ///
+    mgroups("Panel (a): Choice Quality" "Panel (b): Default Adherence" , ///
+    pattern(1 0 0 0 1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2, fmt(%18.0g %18.0g %5.3f ) labels(`"N"' "No. Subjects"  "\(R^2\)")) ///
+    indicate("Controls = *original* *Incentives* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat*")
+
+
+
+****************************************************************
+**** AMPLE
+****************************************************************
+
+reg default_followed i.Treatment_intervention if Treatment_Incentives==4, robust cluster(subject_id)
+eststo def_force_plain
+reg default_followed i.Treatment_intervention ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives==4, robust cluster(subject_id)
+eststo def_force_all_controls
+reg default_followed i.Treatment_Environment if Treatment_Incentives==4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo def_plain
+reg default_followed i.Treatment_Environment ${Incentive_control}  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives==4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo def_all_controls
+
+
+reg summation_correct i.Treatment_intervention if Treatment_Incentives==4, robust cluster(subject_id)
+eststo sum_force_plain
+reg summation_correct i.Treatment_intervention ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives==4, robust cluster(subject_id)
+eststo sum_force_all_controls
+reg summation_correct i.Treatment_Environment if Treatment_Incentives==4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo sum_plain
+reg summation_correct i.Treatment_Environment ${Incentive_control}  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives==4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo sum_all_controls
+
+
+
+reg load_correct i.Treatment_intervention if  Treatment_Incentives==4, robust cluster(subject_id)
+eststo back_force_plain
+reg load_correct i.Treatment_intervention ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if  Treatment_Incentives==4, robust cluster(subject_id)
+eststo back_force_all_controls
+reg load_correct i.Treatment_Environment if  Treatment_Incentives==4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo back_plain
+reg load_correct i.Treatment_Environment ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if  Treatment_Incentives==4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo back_all_controls
+
+
+
+
+esttab ///
+    sum_force_plain sum_force_all_controls ///
+    sum_plain sum_all_controls ///
+    def_force_plain def_force_all_controls ///
+    def_plain def_all_controls ///
+    back_force_plain back_force_all_controls ///
+    back_plain back_all_controls ///
+    using `"${PATH_OUT}/tableO_7.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase ///
+    nomtitles ///
+    mgroups("Choice Quality (Decision Task)" "Default Adherence" "Choice Quality (Background Task)" , ///
+    pattern(1 0 0 0 1 0 0 0 1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2 p_treatments, fmt(%18.0g %18.0g %5.3f %5.3f) labels(`"N"' "No. Subjects"  "\(R^2\)" "\textsc{Directed}=\textsc{Forced}")) ///
+    indicate("Controls = *original* *Incentives* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat* *age* *gender*")
+
+
+
+
+
+
+
+
+
+log close

40/replication_package/EmpiricalAnalysis/dofiles/4_3_Payoffs_And_Efficiency.do

@@ -0,0 +1,224 @@
+log using `"${PATH_OUT}/4_3_Payoffs_And_Efficiency.log"', replace
+
+use "${PATH_IN_DATA}/formatted_data_replication.dta", clear
+
+
+
+reg payoff_share i.Treatment_intervention if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo force_plain
+
+reg payoff_share i.Treatment_intervention ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+eststo force_all_controls_ability
+
+
+reg payoff_share i.Treatment_Environment if Treatment_Incentives!=4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo plain
+
+reg payoff_share i.Treatment_Environment ${Incentive_control}  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4, robust cluster(subject_id)
+test 2.Treatment_Environment=3.Treatment_Environment
+estadd scalar p_treatments = r(p)
+eststo all_controls_ability
+
+esttab  force_plain  force_all_controls_ability  ///
+    plain   all_controls_ability ///
+    using `"${PATH_OUT}/table4.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* 2.Treatment_Environment* 3.Treatment_Environment*)  ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase ///
+    nomtitles ///
+    mgroups("Payoff Share" , ///
+    pattern(1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+    stats(N N_clust r2 p_treatments, fmt(%18.0g %18.0g %5.3f %5.3f) labels(`"N"' "No. Subjects"  "\(R^2\)" "\textsc{Directed}=\textsc{Forced}")) ///
+    indicate("Controls = *original* *Incentives* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat*")
+
+
+
+*** Tables heterogeneity:
+
+reg payoff_share i.b1.Treatment_Incentives_Int_sc i.b1.Treatment_Incentives i.Treatment_intervention i.Treatment_intervention#i.b1.Treatment_Incentives  if Treatment_Incentives!=4 , cluster(subject_id) robust
+eststo hetero_force_both_raw
+reg payoff_share i.b1.Treatment_Incentives_Int_sc i.b1.Treatment_Incentives i.Treatment_intervention i.Treatment_intervention#i.b1.Treatment_Incentives  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4 , cluster(subject_id) robust
+eststo hetero_force_all
+
+reg payoff_share i.b1.Treatment_Incentives_Int_sc i.b1.Treatment_Incentives i.Treatment_Environment i.Treatment_Environment#i.b1.Treatment_Incentives if Treatment_Incentives!=4 , cluster(subject_id) robust
+eststo hetero_both_raw
+reg payoff_share i.b1.Treatment_Incentives_Int_sc i.b1.Treatment_Incentives i.Treatment_Environment i.Treatment_Environment#i.b1.Treatment_Incentives  ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4 , cluster(subject_id) robust
+eststo hetero_all
+
+esttab   hetero_force_both_raw hetero_force_all ///
+         hetero_both_raw hetero_all   ///
+    using `"${PATH_OUT}/tableO_8.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* 2.Treatment_Environment* 3.Treatment_Environment*) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase noomit ///
+    nomtitles ///
+    mgroups("Payoff Share" , ///
+    pattern(1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+     stats(N N_clust r2, fmt(%18.0g %18.0g %5.3f) labels("N" "No. Subjects" "\(R^2\)")) ///
+    indicate("Controls = *original*  *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat*")
+
+
+
+****************************** Coefplots Heterogeneity ******************************
+
+
+reg payoff_share i.b0.Treatment_intervention#i.bn.raven_score_median i.bn.raven_score_median  ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if  Treatment_Incentives!=4, cluster(subject_id) nocons
+eststo incentives_heterogeneity
+
+coefplot    (incentives_heterogeneity ,  fcolor(gs8) mcolor(gs8) lcolor(gs8)) , ///
+    vertical lwidth(*1) keep(*Treatment_intervention*) ///
+    ciopts(recast(rcap)lpattern(dash)lwidth(*.6) lcolor(gs0) ) citop ci(95) ///
+    xlabel(, labgap(3) labsize(medlarge)) ytitle ("Payoff Share", margin(medium) height(3) size(medlarge)) ylabel(-.1(0.05).1) ///
+    graphregion(color(white))  yline(0, lcolor(black)) xlabel(1 "Raven Score {&le} Median" 2 "Raven Score {&gt} Median")
+
+graph export `"${PATH_OUT}/figure7.png"', as(png) replace
+
+reg payoff_share i.b0.Treatment_intervention#i.bn.raven_score_quartiles i.bn.raven_score_quartiles  ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if  Treatment_Incentives!=4, cluster(subject_id) nocons
+eststo incentives_heterogeneity
+
+coefplot    (incentives_heterogeneity ,  fcolor(gs8) mcolor(gs8) lcolor(gs8)) , ///
+    vertical lwidth(*1) keep(*Treatment_intervention*) ///
+    ciopts(recast(rcap)lpattern(dash)lwidth(*.6) lcolor(gs0) ) citop ci(95) ///
+    xlabel(, labgap(3) labsize(medlarge)) ytitle ("Payoff Share", margin(medium) height(3) size(medlarge)) ylabel(-.1(0.05).1) ///
+    graphregion(color(white))  yline(0, lcolor(black)) xlabel(1 `""Raven score" "1st Quartile""' 2 `""Raven score" "2nd Quartile"'  3 `""Raven score" "3rd Quartile""' 4 `""Raven score" "4th Quartile""')
+
+graph export `"${PATH_OUT}/figureO_2.png"', as(png) replace
+
+
+*** Tables heterogeneity:
+
+reg payoff_share i.raven_score_median i.Treatment_intervention i.Treatment_intervention#i.raven_score_median  if Treatment_Incentives!=4 , cluster(subject_id) robust
+eststo hetero_force_both_raw
+reg payoff_share i.raven_score_median i.Treatment_intervention i.Treatment_intervention#i.raven_score_median   ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4 , cluster(subject_id) robust
+eststo hetero_force_all
+
+reg payoff_share i.raven_score_median i.Treatment_Environment i.Treatment_Environment#i.raven_score_median if Treatment_Incentives!=4 , cluster(subject_id) robust
+eststo hetero_both_raw
+reg payoff_share i.raven_score_median i.Treatment_Environment i.Treatment_Environment#i.raven_score_median  ${Incentive_control} ${Wave_control} ${Ability_control} ${Controls} if Treatment_Incentives!=4 , cluster(subject_id) robust
+eststo hetero_all
+
+esttab   hetero_force_both_raw hetero_force_all ///
+         hetero_both_raw hetero_all   ///
+    using `"${PATH_OUT}/tableO_9.tex"', replace ///
+    b(%5.3f) se(%5.3f) ///
+    order(*Treatment_intervention* 2.Treatment_Environment* 3.Treatment_Environment*) ///
+    star(* .1 ** .05 *** .01) ///
+    label booktabs nonotes ///
+    nodepvars nobase noomit ///
+    nomtitles ///
+    mgroups("Payoff Share" , ///
+    pattern(1 0 0 0) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+     stats(N N_clust r2, fmt(%18.0g %18.0g %5.3f) labels("N" "No. Subjects" "\(R^2\)")) ///
+    indicate("Controls = *original* *Incentives* *ability* *age* *gender* *perc_multitasking* *subject_cat*  *q_abitur_grade_cat* *q_math_grade_cat*")
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+
+********** Calculate Hypothetical Payoffs for Table 5***************
+
+cap program drop convert
+program define convert, eclass
+    matrix list `1'
+    ereturn  scalar N=.
+    ereturn matrix mean `1'
+end
+
+
+use "${PATH_IN_DATA}/formatted_data_replication.dta", clear
+
+*Restrict dataset to Baseline-Scarce treatments
+drop if Treatment_Environment!=1
+drop if Treatment_Incentives==4
+drop if round!=1
+
+expand 3
+
+*Hypo. Treatment ID
+bysort subject_id: gen Treatment_Incentives_Hypo=_n
+label var Treatment_Incentives_Hypo "Hypothetical Incentives"
+label values Treatment_Incentives_Hypo Treatment_Incentives
+
+
+* Always got 40 cents for load task
+gen hypo_payoff_load_mean  = load_correct_mean * 0.4
+
+* Get hypo payoff for decision task using real behavior under one of three incentive schemes
+gen hypo_payoff_summation_mean  = .
+replace hypo_payoff_summation_mean  = summation_correct_mean * 0.1 if Treatment_Incentives_Hypo ==1
+replace hypo_payoff_summation_mean  = summation_correct_mean * 0.2 if Treatment_Incentives_Hypo ==2
+replace hypo_payoff_summation_mean  = summation_correct_mean * 0.4 if Treatment_Incentives_Hypo ==3
+
+** Hypothethical payoff + share
+gen hypo_payoff_mean = hypo_payoff_load_mean  + hypo_payoff_summation_mean
+gen hypo_payoff_share = .
+replace hypo_payoff_share  = hypo_payoff_mean / 0.5 if Treatment_Incentives_Hypo ==1
+replace hypo_payoff_share  = hypo_payoff_mean / 0.6 if Treatment_Incentives_Hypo ==2
+replace hypo_payoff_share  = hypo_payoff_mean / 0.8 if Treatment_Incentives_Hypo ==3
+
+gen hypo_payoff_share_table =hypo_payoff_share
+replace hypo_payoff_share_table =. if Treatment_Incentives == Treatment_Incentives_Hypo
+
+
+estpost tabstat hypo_payoff_share_table if Treatment_Incentives ==1 , by(Treatment_Incentives_Hypo) statistics(mean sd) columns(statistics) listwise nototal
+eststo one
+estpost tabstat hypo_payoff_share_table if Treatment_Incentives ==2 , by(Treatment_Incentives_Hypo) statistics(mean sd) columns(statistics) listwise nototal
+eststo two
+estpost tabstat hypo_payoff_share_table if Treatment_Incentives ==3 , by(Treatment_Incentives_Hypo) statistics(mean sd) columns(statistics) listwise nototal
+eststo three
+
+estpost tabstat payoff_share_mean if  Treatment_Incentives_Hypo==1 , by(Treatment_Incentives) statistics(mean sd) columns(statistics) listwise nototal
+eststo observed
+
+matrix diff=e(mean)
+matrix t=e(mean)
+estpost ttest hypo_payoff_share if Treatment_Incentives_Hypo ==1 &Treatment_Incentives !=3 , by(Treatment_Incentives )
+matrix help=e(b)
+matrix help2=e(p)
+matrix diff[1,1] = help[1,1]
+matrix t[1,1] = help2[1,1]
+estpost ttest hypo_payoff_share if Treatment_Incentives_Hypo ==2 &Treatment_Incentives !=3 , by(Treatment_Incentives )
+matrix help=e(b)
+matrix help2=e(p)
+matrix diff[1,2] = help[1,1]
+matrix t[1,2] = help2[1,1]
+estpost ttest hypo_payoff_share if Treatment_Incentives_Hypo ==3 &Treatment_Incentives !=1 , by(Treatment_Incentives )
+matrix help=e(b)
+matrix help2=e(p)
+matrix diff[1,3] = help[1,1]
+matrix t[1,3] = help2[1,1]
+
+convert diff
+eststo diff
+
+convert t
+eststo t
+
+
+* Data for Table 5
+esttab one two three observed diff t, ///
+     order(10 20 40) ///
+     main(mean %5.3f) aux(sd %5.3f) ///
+     nostar unstack  noobs nonote  nolabel nonumber ///
+     mtitles("\textsc{40/10}" "\textsc{40/20}" "\textsc{40/40}" "" "diff" "p-values") ///
+     mgroups("Hypothetical behavior in" "Observed" "Diff. to largest benchmark" , pattern(1 0 0 1 1 0) ) ///
+
+clear
+
+log close

40/replication_package/EmpiricalAnalysis/dofiles/Supplementary_Material_Randomization_Check_table.do

@@ -0,0 +1,143 @@
+log using `"${PATH_OUT}/Randomization_Check.log"', replace
+
+
+use "${PATH_IN_DATA}/formatted_data_replication.dta", clear
+keep if round==1
+
+
+set scheme s1color_black_gray
+
+**********************************
+* Little program to convert matrix
+**********************************
+
+cap program drop convert
+program define convert, eclass
+    matrix list `1'
+    ereturn  scalar N=.
+    ereturn matrix mean `1'
+    ereturn local estimates_title="p-values"
+end
+
+
+
+* Generate variables specifallcy needed for balancing table
+
+egen ability_load_std_1=std(ability_load) if original_lab==1
+egen ability_task_std_1=std(ability_task) if original_lab==1
+
+egen ability_load_std=std(ability_load) if original_lab==0
+egen ability_task_std=std(ability_task) if original_lab==0
+
+replace ability_load_std=ability_load_std_1 if original_lab==1
+replace ability_task_std=ability_task_std_1 if original_lab==1
+drop ability_load_std_1 ability_task_std_1
+
+label var ability_task_std "Ability Decision Task (std.)"
+label var ability_load_std "Ability Background Task (std.)"
+
+bysort Treatment_Environment Treatment_Incentives: gen obs=_N
+label var obs "N"
+
+
+cap drop treatment_id
+egen treatment_id=group(Treatment_Environment Treatment_Incentives )
+
+
+
+* Write Balancing table; Different parts are appended after creating results via tabstat
+
+qui file open table_out using `"${PATH_OUT}/tableO_1.tex"', write replace
+file write table_out "   \begin{tabular}{l*{13}{c}}" _n
+file write table_out "\toprule" _n
+file close table_out
+
+estimates clear
+
+bysort Treatment_Environment: eststo: estpost tabstat ability_load_std ability_task_std  q_age q_gender economist perc_multitasking_2 perc_multitasking_1, by(Treatment_Incentives) nototal   statistics(mean sd) columns(statistics) listwise
+
+* copy mean matrix such that p-values vector has the correct length etc.
+matrix p_values=e(mean)
+local i=0
+foreach var of varlist ability_load_std ability_task_std  q_age q_gender economist perc_multitasking_2 perc_multitasking_1 {
+    local i=1+`i'
+    kwallis `var' , by(treatment_id)
+    local p=chi2tail(`r(df)',`r(chi2_adj)')
+    matrix p_values[1,`i']=`p'
+}
+
+matrix p_values=p_values[1,1..7]
+matrix coleq p_values=p-value p-value p-value p-value p-value p-value
+
+* Convert p-values to estimation result and store it
+convert p_values
+eststo p_values
+
+esttab est*  p_values using `"${PATH_OUT}/tableO_1.tex"', ///
+    main(mean %5.2f) aux(sd %5.2f) nostar unstack ///
+    noobs nonote label append booktabs compress  ///
+    nonumber  nomtitles frag ///
+    mgroups("\textsc{Baseline}" "\textsc{Directed Attention}" "\textsc{Forced Choice}" "Kruskal-Wallis" , ///
+    pattern(1 1 1 1) prefix(\multicolumn{@span}{c}{) suffix(}) span erepeat(\cmidrule(lr){@span})) ///
+
+
+
+* As tabstat uses only observation with no missings, perform second part where only data from certain waves are available
+estimates clear
+bysort Treatment_Environment: eststo: estpost tabstat raven_score treatment_id, by(Treatment_Incentives) nototal   statistics(mean sd) columns(statistics) listwise
+
+* copy mean matrix such that p-values vector has the correct length etc.
+matrix p_values=e(mean)
+local i=0
+foreach var of varlist raven_score treatment_id{
+    local i=1+`i'
+    kwallis `var' , by(treatment_id)
+    local p=chi2tail(`r(df)',`r(chi2_adj)')
+    matrix p_values[1,`i']=`p'
+}
+
+matrix p_values=p_values[1,1..2]
+matrix coleq p_values=p-value p-value
+
+* Convert p-values to estimation result and store it
+convert p_values
+eststo p_values
+
+esttab est*  p_values using `"${PATH_OUT}/tableO_1.tex"', ///
+    append frag  ///
+    drop(treatment_id) /// refcat(raven_score "\emph{2nd Wave only}", nolabel) nobaselevels ///
+    main(mean %5.2f) aux(sd %5.2f) nostar unstack ///
+    eqlabels(none) nolines ///
+    noobs nonote label  booktabs compress  ///
+    nomtitles nodepvar nonumber
+
+estimates clear
+bysort Treatment_Environment: eststo: estpost tabstat  original_lab treatment_id, by(Treatment_Incentives) nototal   statistics(mean sd) columns(statistics) listwise
+esttab est*   using `"${PATH_OUT}/tableO_1.tex"', ///
+    append frag  drop(treatment_id) ///
+    main(mean %4.0g)  nostar unstack ///
+    eqlabels(none) ///
+    noobs nonote label  booktabs compress  ///
+    nomtitles nodepvar nonumber
+
+estimates clear
+bysort Treatment_Environment: eststo: estpost tabstat obs  treatment_id, by(Treatment_Incentives) nototal   statistics(mean sd) columns(statistics) listwise
+esttab est*   using `"${PATH_OUT}/tableO_1.tex"', ///
+    append frag  drop(treatment_id) ///
+    main(mean %5.0g)  nostar unstack ///
+    eqlabels(none) ///
+    noobs nonote label  booktabs compress  ///
+    nomtitles nodepvar nonumber
+
+qui file open table_out using `"${PATH_OUT}/tableO_1.tex"', write append
+file write table_out "\bottomrule" _n
+file write table_out "\end{tabular}" _n
+file close table_out
+
+
+
+log close
+
+
+
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/_/_eststo.ado

@@ -0,0 +1,28 @@
+*! version 1.0.4  09nov2007  Ben Jann
+
+program define _eststo, byable(onecall)
+    local caller : di _caller()
+    version 8.2
+    if "`_byvars'"!="" local by "by `_byvars'`_byrc0' : "
+    if inlist(`"`1'"',"clear","dir","drop") {
+        version `caller': `by'eststo `0'
+    }
+    else {
+        capt _on_colon_parse `0'
+        if !_rc {
+            local command `"`s(after)'"'
+            if `"`command'"'!="" {
+                local command `":`command'"'
+            }
+            local 0 `"`s(before)'"'
+        }
+        syntax [anything] [, Esample * ]
+        if `"`esample'"'=="" {
+            local options `"noesample `options'"'
+        }
+        if `"`options'"'!="" {
+            local options `", `options'"'
+        }
+        version `caller': `by'eststo `anything'`options' `command'
+    }
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/_/_eststo.hlp

@@ -0,0 +1 @@
+.h eststo

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/_/_gpp.ado

@@ -0,0 +1,24 @@
+*! 1.0.1 NJC 29 January 1999
+* 1.0.0 13 March 1998
+* computes (i - a)/(n - 2a + 1)
+program define _gpp
+        version 5.0
+        local varlist "req new max(1)"
+        local exp "req nopre"
+        local if "opt"
+        local in "opt"
+        local options "a(real 0.5) BY(string)"
+        parse "`*'"
+        tempvar value i touse
+        if "`by'" != "" { confirm variable `by' }
+        quietly {
+                mark `touse' `if' `in'
+                markout `touse' `exp'
+                gen `value' = `exp' if `touse'
+                sort `touse' `by' `value'
+                by `touse' `by' : gen long `i' = _n if `value' != .
+                by `touse' `by' : replace `varlist' = /*
+                 */ (`i' - `a') / (`i'[_N] - 2 * `a' + 1)
+                label var `varlist' "Fraction of the data"
+        }
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/_/_oaxaca.ado

@@ -0,0 +1,1505 @@
+*!version 1.0.7  Ben Jann  18nov2008
+
+program define _oaxaca, rclass sortpreserve
+    version 9.2
+    capt syntax [, Level(passthru) eform xb noLEgend ]
+    if _rc==0 {
+        Display `0'
+        exit
+    }
+    syntax anything ///
+        [if] [in] [fw aw pw iw] [,  ///
+        THREEfold THREEfold2(str)                   ///
+        Weights(numlist) Reference(name) split      ///
+        Adjust(passthru)                            ///
+        Detail Detail2(passthru)                    ///
+        CATegorical(string)                         ///
+        x1(passthru) x2(passthru)                   ///
+        FIXed FIXed2(string)                        ///
+        noSE                                        ///
+        SVY SVY2(str asis)                          ///
+        vce(str) CLuster(passthru)                  ///
+        NOSUEST SUEST                               ///
+        eform                                       ///
+        Level(passthru)                             ///
+        xb                                          ///
+        noLEgend                                    ///
+        NOIsily                                     ///
+        nodisplay                                   ///
+        depname(passthru) /// dependent variable name for returns/display
+        nlcom             /// undocumented: use nlcom to derive SE's (slow)
+    ]
+    _parse_elist `anything' // returns local elist
+    local se = "`se'"==""
+    if `"`fixed2'"'!="" local fixed
+    if `"`detail2'"'!="" local detail detail
+    if `"`weights'"'=="" & `"`reference'"'=="" local threefold threefold
+    if `"`threefold2'"'!="" {
+        if `"`threefold2'"'!=substr("reverse",1,max(1,strlen(`"`threefold2'"'))) {
+            di as err "invalid threefold() option"
+            exit 198
+        }
+        local threefold threefold
+        local threefold2 reverse
+    }
+    if (`"`weights'"'!="") + (`"`reference'"'!="") + ("`threefold'"!="")>1 {
+        di as err "only one of threefold, weight(), and reference() allowed"
+        exit 198
+    }
+    if "`nosuest'"!="" & "`suest'"!="" {
+        di as err "suest and nosuest not both allowed"
+        exit 198
+    }
+    if `"`svy2'"'!="" local svy "svy"
+    if "`svy'"!="" {
+        local i 0
+        foreach opt in vce cluster weight {
+            local optnm: word `++i' of "vce()" "cluster()" "weights"
+            if `"``opt''"'!="" {
+                di as err "`optnm' not allowed with svy"
+                exit 198
+            }
+        }
+    }
+    local qui = cond("`noisily'"=="","quietly","")
+
+// reference equal to one of the groups?
+    if "`reference'"!="" {
+        local tmp: list posof "`reference'" in elist
+        if `tmp' {
+            local weights = 2 - `tmp'
+            local reference
+        }
+    }
+
+// use suest?
+    local suest = cond("`suest'"!="",1,0)
+    if `"`reference'`svy'`cluster'"'!="" {
+        local suest 1
+    }
+    if `"`vce'"'!="" {
+        _vce_iscluster `vce'
+        if `vce_iscluster' local suest 1
+        local vce `"vce(`vce')"'
+    }
+    if `se'==0 | "`nosuest'"!="" {
+        local suest 0
+    }
+
+// get estimates
+    local robreg = (`suest'==0 & `se')
+    nobreak {
+    // preserve last estimates
+        tempname hcurrent
+        tempvar  touse1 touse2 subpop1 subpop2
+        _est hold `hcurrent', restore nullok estsystem
+        local g 0
+        foreach est in `elist' `reference' {
+            local ++g
+            qui estimates restore `est'
+        // determine esample (and subpop if svy)
+            if `g'<3 {
+                qui gen byte `touse`g'' = e(sample)==1
+                _marksubpop `e(subpop)', g(`subpop`g'')
+                qui replace `subpop`g'' = 0 if `touse`g''==0
+                if "`svy'"=="" {
+                    qui replace `touse`g'' = 0 if `subpop`g''==0
+                }
+                if "`e(cmd)'"=="heckman" | "`e(cmd)'"=="heckprob" {
+                    local tmp "`touse`g''"
+                    if "`svy'"!="" {
+                        local tmp "`subpop`g''"
+                    }
+                    local depvar: word 1 of `e(depvar)'
+                    qui replace `tmp' = 0 if `depvar'>=.
+                    local depvar_s: word 2 of `e(depvar)'
+                    if "`depvar_s'"!="" {
+                        qui replace `tmp' = 0 if `depvar_s'==0
+                    }
+                }
+            }
+        // if not suest: get coefficients (and variances if se)
+            if `suest'==0 {
+                tempname b`g'
+                mat `b`g'' = e(b)
+                local firsteq: coleq `b`g'', q
+                local firsteq: word 1 of `firsteq'
+                mat `b`g'' = `b`g''[1,"`firsteq':"]
+                local eqlab = "b`g'"
+                if `g'==3 local eqlab = "b_ref"
+                mat coleq `b`g'' = "`eqlab'"
+                if `se' {
+                    tempname V`g'
+                    mat `V`g'' = e(V)
+                    mat `V`g'' = `V`g''["`firsteq':","`firsteq':"]
+                    mat coleq `V`g'' = "`eqlab'"
+                    mat roweq `V`g'' = "`eqlab'"
+                    if "`e(vce)'"!="robust" local robreg 0
+                }
+            }
+        }
+    }
+    if `robreg' {
+        local e_vce     "robust"
+        local e_vcetype "Robust"
+    }
+
+// apply suest
+    tempname b V
+    if `suest' {
+        `qui' suest `elist' `reference', `svy' `vce' `cluster'
+        mat `b' = e(b)
+        mat `V' = e(V)
+        local e_vce     "`e(vce)'"
+        local e_vcetype "`e(vcetype)'"
+        ExtractFirstEqs "b1 b2 b_ref" `b' `V'
+    }
+    else {
+        mat `b' = `b1', `b2'
+        mat drop `b1' `b2'
+        if `se' {
+            mat `V' = `V1'
+            MatAppendDiag `V' `V2'
+            mat drop `V1' `V2'
+        }
+        if `g'==3 {
+            mat `b' = `b', `b3'
+            mat drop `b3'
+            if `se' {
+                MatAppendDiag `V' `V3'
+                mat drop `V3'
+            }
+        }
+    }
+
+// apply deviation contrast transform to categorical variables
+    if `"`categorical'"'!="" {
+        if `se' {
+            _devcon `b' `V', groups(`categorical')
+        }
+        else {
+            _decvon `b', groups(`categorical')
+        }
+    }
+
+// insert 0's for missing coefficients
+    mata: oaxaca_insertmissingcoefs()  // returns coefnames in local coef
+
+// compute means
+    marksample touse, novarlist zeroweight
+    qui replace `touse' = 0 if `touse1'==0 & `touse2'==0
+    tempname x Vx
+    if "`svy'"!="" {
+        capt _parsesvyopt `svy2'
+        if _rc {
+            di as err "invalid svy() option"
+            exit 198
+        }
+        capt _parsesvysubpop `svy_subpop'
+        if _rc {
+            di as err "invalid subpop() option"
+            exit 198
+        }
+        //=> svy `svy_type', subpop(`svy_subpop') `svy_opts': ...
+    }
+    local cons
+    if `: list posof "_cons" in coefs' {
+        local cons "_cons"
+    }
+    local xvars: list coefs - cons
+    if "`cons'"!="" {
+        tempname xcons
+        qui gen byte `xcons' = 1
+        local xvars: list xvars | xcons
+    }
+    if `suest' {
+        tempname grpvar
+        gen byte `grpvar'= 0
+        qui replace `grpvar' = 1 if `subpop1'
+        capt assert (`grpvar'==0) if `subpop2'
+        if _rc {
+            error "overlapping samples (groups not distinct)"
+            exit 498
+        }
+        qui replace `grpvar' = 2 if `subpop2'
+        if "`svy'"=="" {
+            `qui' mean `xvars' if `touse' [`weight'`exp'], ///
+                over(`grpvar') `vce' `cluster'
+            if e(N_clust)<. {
+                local e_N_clust = e(N_clust)
+                local e_clustvar "`e(clustvar)'"
+            }
+        }
+        else {
+            `qui' svy `svy_type', ///
+                subpop(`svy_subpop' & (`subpop1' | `subpop2')) `svy_opts' : ///
+                    mean `xvars' if `touse', over(`grpvar')
+            local e_prefix "`e(prefix)'"
+            local e_N_strata = e(N_strata)
+            local e_N_psu = e(N_psu)
+            local e_N_pop = e(N_pop)
+            local e_df_r = e(df_r)
+        }
+        if "`e(vce)'"!="analytic" {
+            local e_vce     "`e(vce)'"
+            local e_vcetype "`e(vcetype)'"
+        }
+        local e_wtype "`e(wtype)'"
+        local e_wexp `"`e(wexp)'"'
+        mat `x' = e(b)
+        mat `Vx' = e(V)
+        local N1 = el(e(_N),1,1)
+        local N2 = el(e(_N),1,2)
+        if "`cons'"!="" {
+            local coleq: coleq `x'
+            local coleq: subinstr local coleq "`xcons'" "_cons", word all
+            mat coleq `x' = `coleq'
+            mat coleq `Vx' = `coleq'
+            mat roweq `Vx' = `coleq'
+        }
+        mata: oaxaca_reorderxandVx()
+    }
+    else {
+        tempname xtmp Vxtmp
+        local tmp
+        forv i = 1/2 {
+            if "`svy'"=="" {
+                `qui' mean `xvars' if `touse' & `touse`i'' [`weight'`exp'], `vce' `cluster'
+            }
+            else {
+                `qui' svy `svy_type', subpop(`svy_subpop' & `subpop`i'') `svy_opts' : ///
+                    mean `xvars' if `touse' & `touse`i''
+            }
+            mat `x`tmp'' = e(b)
+            local N`i' = el(e(_N),1,1)
+            local e_wtype "`e(wtype)'"
+            local e_wexp `"`e(wexp)'"'
+            if "`cons'"!="" {
+                local coln: colnames `x`tmp''
+                local coln: subinstr local coln "`xcons'" "_cons", word
+                mat coln `x`tmp'' = `coln'
+            }
+            mat coleq `x`tmp'' = "x`i'"
+            if `se' {
+                mat `Vx`tmp'' = e(V)
+                if "`cons'"!="" {
+                    mat coln `Vx`tmp'' = `coln'
+                    mat rown `Vx`tmp'' = `coln'
+                }
+                mat coleq `Vx`tmp'' = "x`i'"
+                mat roweq `Vx`tmp'' = "x`i'"
+            }
+            local tmp tmp
+        }
+        mat `x' = `x', `xtmp'
+        mat drop `xtmp'
+        if `se' {
+            MatAppendDiag `Vx' `Vxtmp'
+            mat drop `Vxtmp'
+        }
+    }
+    if `"`x1'`x2'"'!="" {
+        _setXvals `x' `Vx', se(`se') `x1' `x2'
+    }
+    mat `b' = `b', `x'
+    mat drop `x'
+    if `se' {
+        if "`fixed'"!="" {
+            mat `Vx' = `Vx'*0
+        }
+        else if `"`fixed2'"'!=""{
+            local fixedx
+            foreach var of local fixed2 {
+                capt unab temp: `var'
+                if _rc {
+                    local temp "`var'"
+                }
+                local temp: list temp & coefs
+                if `"`temp'"'=="" {
+                    di as err `"`var' not found"'
+                    exit 111
+                }
+                local fixedx: list fixedx | temp
+            }
+            if `"`fixedx'"'!="" {
+                mata: oaxaca_setfixedXtozero(0)
+            }
+        }
+        MatAppendDiag `V' `Vx'
+        mat drop `Vx'
+    }
+
+// post b and V for use with nlcom
+    if `se' {
+        eret post `b' `V'
+        _eretpostcmd
+        tempname V0
+        mat `V0' = e(V)
+    }
+    else {
+        eret post `b'
+    }
+    tempname b0
+    mat `b0' = e(b)
+
+// parse adjust() => returns locals adjust and coefsadj
+    _parseadjust, `adjust' coefs(`coefs')
+
+// parse detail2() option => returns local cgroups
+    _parsedetail2, `detail2' coefs(`coefsadj')
+
+    if "`nlcom'"!="" {
+    // nlcom step 1: detailed decomposition
+        local terms1
+        local terms2
+        local terms3
+        if "`threefold'"!="" {
+            local 1 1
+            local 2 2
+            if "`threefold2'"!="" {
+                local 1 2
+                local 2 1
+            }
+            local i 0
+            foreach coef of local coefsadj {
+                local ++i
+                local term1`i' (E_`coef':([x1]_b[`coef']-[x2]_b[`coef'])*[b`2']_b[`coef'])
+                local terms1 `"`macval(terms1)' \`term1`i''"'
+                local term2`i' (C_`coef':[x`2']_b[`coef']*([b1]_b[`coef']-[b2]_b[`coef']))
+                local terms2 `"`macval(terms2)' \`term2`i''"'
+                local term3`i' (I_`coef':([x1]_b[`coef']-[x2]_b[`coef'])*([b`1']_b[`coef']-[b`2']_b[`coef']))
+                local terms3 `"`macval(terms3)' \`term3`i''"'
+            }
+            local eqnames "E_ C_ I_"
+        }
+        else {
+            if "`reference'"!="" {
+                local i 0
+                foreach coef of local coefsadj {
+                    local ++i
+                    local term1`i' (E_`coef':([x1]_b[`coef']-[x2]_b[`coef'])*[b_ref]_b[`coef'])
+                    local terms1 `"`macval(terms1)' \`term1`i''"'
+                    if "`split'"=="" {
+                        local term2`i' (U_`coef':[x1]_b[`coef']*([b1]_b[`coef']-[b_ref]_b[`coef']) ///
+                                    + [x2]_b[`coef']*([b_ref]_b[`coef']-[b2]_b[`coef']))
+                        local terms2 `"`macval(terms2)' \`term2`i''"'
+                    }
+                    else {
+                        local term2`i' (U1_`coef':[x1]_b[`coef']*([b1]_b[`coef']-[b_ref]_b[`coef']))
+                        local term3`i' (U2_`coef':[x2]_b[`coef']*([b_ref]_b[`coef']-[b2]_b[`coef']))
+                        local terms2 `"`macval(terms2)' \`term2`i''"'
+                        local terms3 `"`macval(terms3)' \`term3`i''"'
+                    }
+                }
+            }
+            else {  // => weights()
+                local i 0
+                local wgt
+                foreach coef of local coefsadj {
+                    if `"`wgt'"'=="" { // => recycle
+                        local wgt "`weights'"
+                    }
+                    gettoken w wgt : wgt
+                    local m = 1 - `w'
+                    local ++i
+                    local term1`i' (E_`coef':([x1]_b[`coef']-[x2]_b[`coef']) * ///
+                                (`w'*[b1]_b[`coef']+`m'*[b2]_b[`coef']))
+                    local terms1 `"`macval(terms1)' \`term1`i''"'
+                    if "`split'"=="" {
+                        local term2`i' (U_`coef':[x1]_b[`coef']*(`m'*[b1]_b[`coef']-`m'*[b2]_b[`coef']) ///
+                                        + [x2]_b[`coef']*(`w'*[b1]_b[`coef']-`w'*[b2]_b[`coef']))
+                        local terms2 `"`macval(terms2)' \`term2`i''"'
+                    }
+                    else {
+                        local term2`i' (U1_`coef':[x1]_b[`coef']*(`m'*[b1]_b[`coef']-`m'*[b2]_b[`coef']))
+                        local term3`i' (U2_`coef':[x2]_b[`coef']*(`w'*[b1]_b[`coef']-`w'*[b2]_b[`coef']))
+                        local terms2 `"`macval(terms2)' \`term2`i''"'
+                        local terms3 `"`macval(terms3)' \`term3`i''"'
+                    }
+                }
+            }
+            if "`split'"=="" {
+                local eqnames "E_ U_"
+            }
+            else {
+                local eqnames "E_ U1_ U2_"
+            }
+        }
+        local plus
+        local xb1
+        local xb2
+        foreach coef of local coefs {
+            local xb1 `xb1'`plus'[x1]_b[`coef']*[b1]_b[`coef']
+            local xb2 `xb2'`plus'[x2]_b[`coef']*[b2]_b[`coef']
+            local plus "+"
+        }
+        local xb1 (D_xb1:`xb1')
+        local xb2 (D_xb2:`xb2')
+        local plus
+        local adj
+        foreach coef of local adjust {
+            local adj `adj'`plus'[x1]_b[`coef']*[b1]_b[`coef']-[x2]_b[`coef']*[b2]_b[`coef']
+            local plus "+"
+        }
+        if `"`adj'"'!="" {
+            local adj (D_adj:`adj')
+        }
+        if `se' {
+            quietly nlcom `xb1' `xb2' `adj' `terms1' `terms2' `terms3', post
+        }
+        else {
+            nlcom_nose `xb1' `xb2' `adj' `terms1' `terms2' `terms3'
+            mat `b' = r(b)
+            eret post `b'
+        }
+
+    // nlcom step 2: totals
+        local terms1
+        local terms2
+        local terms3
+        local j 0
+        foreach eq of local eqnames {
+            local ++j
+            local i 0
+            local term`j'tot
+            local plus
+            foreach group of local cgroups {
+                local ++i
+                local term`j'`i'
+                local plusplus
+                gettoken gname gcoefs : group
+                if `"`gcoefs'"'=="" {
+                    local gcoefs `"`gname'"'
+                }
+                foreach coef of local gcoefs {
+                    local term`j'tot `term`j'tot'`plus'_b[`eq'`coef']
+                    local plus "+"
+                    if "`coef'"=="_cons" & inlist("`eq'","E_","I_") continue
+                    if "`detail'"!="" {
+                        local term`j'`i' `term`j'`i''`plusplus'_b[`eq'`coef']
+                        local plusplus "+"
+                    }
+                }
+                if `"`term`j'`i''"'!="" {
+                    local term`j'`i' (`eq'`gname':`term`j'`i'')
+                    local terms`j' `"`macval(terms`j')' \`term`j'`i''"'
+                }
+            }
+            if "`detail'"!="" {
+                local term`j'tot (`eq'Total:`term`j'tot')
+            }
+            else {
+                local term`j'tot (`eq':`term`j'tot')
+            }
+            local terms`j' `"`macval(terms`j')' \`term`j'tot'"'
+        }
+        if `"`adj'"'!="" {
+            local adj (D_Adjusted:_b[D_xb1]-_b[D_xb2]-_b[D_adj])
+        }
+        if `se' {
+            quietly nlcom (D_Prediction_1:_b[D_xb1]) (D_Prediction_2:_b[D_xb2]) ///
+                (D_Difference:_b[D_xb1]-_b[D_xb2]) `adj' ///
+                `terms1' `terms2' `terms3'
+            mat `b' = r(b)
+            mat `V' = r(V)
+        }
+        else {
+            nlcom_nose (D_Prediction_1:_b[D_xb1]) (D_Prediction_2:_b[D_xb2]) ///
+                (D_Difference:_b[D_xb1]-_b[D_xb2]) `adj' ///
+                `terms1' `terms2' `terms3'
+            mat `b' = r(b)
+        }
+    }
+    else {
+        mata: oaxaca_decomp()
+    }
+    if `se'==0 {
+        mat `V' = `b''*`b'*0
+    }
+
+// post results
+    local coln: coln `b'
+    local coln `" `coln'"'
+    local coln: subinstr local coln " D_" " Differential:", all
+    local eqcolon = cond("`detail'"!="",":","")
+    local eqname = cond("`detail'"!="","","Decomposition:")
+    if "`threefold'"!="" {
+        local coln: subinstr local coln " E_" " `eqname'Endowments`eqcolon'", all
+        local coln: subinstr local coln " C_" " `eqname'Coefficients`eqcolon'", all
+        local coln: subinstr local coln " I_" " `eqname'Interaction`eqcolon'", all
+    }
+    else {
+        local coln: subinstr local coln " E_" " `eqname'Explained`eqcolon'", all
+        if "`split'"=="" {
+            local coln: subinstr local coln " U_" " `eqname'Unexplained`eqcolon'", all
+        }
+        else {
+            local coln: subinstr local coln " U1_" " `eqname'Unexplained_1`eqcolon'", all
+            local coln: subinstr local coln " U2_" " `eqname'Unexplained_2`eqcolon'", all
+        }
+    }
+    mat coln `b' = `coln'
+    mat coln `V' = `coln'
+    mat rown `V' = `coln'
+    if "`threefold'"!="" local model threefold `threefold2'
+    else                 local model twofold `split'
+    if "`reference'"!="" local refcoefs "b_ref"
+    if `"`detail2'"'!="" {
+        local dlegend
+        local space
+        foreach cgroup of local cgroups {
+            if `:list sizeof cgroup'>1 {
+                gettoken name vars : cgroup
+                local dlegend `"`dlegend'`space'"`name':`vars'""'
+                local space " "
+            }
+        }
+    }
+    PostResults `b' `V', b0(`b0') v0(`V0') `depname' esample(`touse') ///
+        suest(`suest') model(`model') weights(`weights') ///
+        refcoefs(`refcoefs') detail(`detail') legend(`dlegend') ///
+        adjust(`adjust') fixed(`fixedx') ///
+        n1(`N1') n2(`N2') wtype(`e_wtype') wexp(`e_wexp') ///
+        vce(`e_vce') vcetype(`e_vcetype') n_clust(`e_N_clust') ///
+        clustvar(`e_clustvar') prefix(`e_prefix') n_strata(`e_N_strata') ///
+        n_psu(`e_N_psu') n_pop(`e_N_pop') df_r(`e_df_r')
+
+// display
+    if "`display'"=="" {
+        Display, `level' `eform' `xb' `legend'
+    }
+
+// cleanup
+    _est unhold `hcurrent', not
+end
+
+prog _parse_elist
+    syntax namelist(name=elist min=2 max=2)
+    if "`:word 1 of `elist''"=="`:word 2 of `elist''" {
+        di as err "namelist:  too few specified"
+        exit 102
+    }
+    c_local elist "`elist'"
+end
+
+prog Display, eclass
+    syntax [, level(passthru) eform xb noLEgend ]
+    if !inlist("`e(cmd)'","_oaxaca","oaxaca") {
+        error 301
+    }
+    if "`eform'"!="" {
+        local eform "eform(exp(b))"
+        tempname b
+        mat `b' = e(b)
+        local coln: colnames `b'
+        local newcoln: subinstr local coln "_cons" "__cons", word count(local cons)
+        if `cons' {
+            mat coln `b' = `newcoln'
+            ereturn repost b = `b', rename
+        }
+    }
+    _coef_table_header
+    eret display, `level' `eform'
+    if "`eform'"!="" {
+        if `cons' {
+            mat `b' = e(b)
+            mat coln `b' = `coln'
+            ereturn repost b = `b', rename
+        }
+    }
+    if "`legend'"=="" {
+        Display_legend
+    }
+    if `"`xb'"'!="" {
+        Display_b0, `level'
+    }
+end
+
+prog Display_legend
+    if `"`e(legend)'"'=="" exit
+    foreach line in `e(legend)' {
+        local i 0
+        local piece: piece `++i' 78 of `"`line'"'
+        di as txt `"`piece'"'
+        while (1) {
+            local piece: piece `++i' 76 of `"`line'"'
+            if `"`piece'"'=="" continue, break
+            di as txt `"  `piece'"'
+        }
+    }
+end
+
+prog Display_b0
+    syntax [, Level(passthru)]
+    tempname hcurrent b V
+    mat `b' = e(b0)
+    mat `V' = e(V0)
+    _est hold `hcurrent', restore estsystem
+    di _n "Coefficients (b) and means (x)"
+    eret post `b' `V'
+    eret display, `level'
+end
+
+prog _marksubpop
+    syntax [varname(default=none)] [if], g(name)
+    marksample touse
+    if "`varlist'"!="" {
+        qui replace `touse' = 0 if `varlist'==0
+    }
+    rename `touse' `g'
+end
+
+prog ExtractFirstEqs
+    args eqlab b V
+    local i 0
+    foreach nm in `e(names)' {
+        local ++i
+        local suffix: word 1 of `e(eqnames`i')'
+        if `"`suffix'"'!="_" {
+            local nm `"`nm'_`suffix'"'
+        }
+        local oldeqs `"`oldeqs'`space'`nm'"'
+        local neweqs `"`neweqs'`space'`:word `i' of `eqlab''"'
+        local space " "
+    }
+    mata: oaxaca_extracteqs()
+end
+
+prog MatAppendDiag
+    args A D
+    tempname B C
+    mat `B' = J(rowsof(`A'),colsof(`D'),0)
+    mat coln `B' = `:colfullnames `D''
+    mat `C' = J(rowsof(`D'),colsof(`A'),0)
+    mat rown `C' = `:rowfullnames `D''
+    mat `A' = (`A', `B') \ (`C', `D')
+end
+
+program _parsesvyopt
+    syntax [anything] [, SUBpop(str asis) * ]
+
+    c_local svy_type `"`anything'"'
+    c_local svy_opts    `"`options'"'
+    c_local svy_subpop  `"`subpop'"'
+end
+
+program _vce_iscluster
+    syntax [anything] [, * ]
+    local vce_type: word 1 of `anything'
+    local iscluster 0
+    if `"`vce_type'"'==substr("cluster",1,max(2,strlen(`"`vce_type'"'))) local iscluster 1
+    c_local vce_iscluster `iscluster'
+end
+
+program _parsesvysubpop
+    syntax [varname(default=none)] [if/]
+    if `"`if'"'!="" {
+        local iff `"(`if') & "'
+    }
+    c_local svy_subpop `"`varlist' if `iff'1"'
+end
+
+program define _devcon
+// based on devcon.ado from SSC, version 1.0.9 06dec2005, by Ben Jann
+    version 9.2
+    syntax anything, Groups(passthru)
+    gettoken b: anything
+
+    mat `b' = `b''
+    local eqs: roweq `b', quoted
+    local eqs: list uniq eqs
+    foreach eq of local eqs {
+        __devcon `anything', `groups' eq(`eq':) eqs(`eqs')
+    }
+    mat `b' = `b''
+end
+
+program define __devcon, eclass
+// based on devcon.ado from SSC, version 1.0.9 06dec2005, by Ben Jann
+    syntax anything, Groups(string) [ eq(str asis) eqs(str asis) ]
+    gettoken b V: anything
+    gettoken V : V
+    local hasV = (`"`V'"'!="")
+
+// get coef names
+    tempname btmp
+    mat `btmp' = `b'[`"`eq'"',1]
+    local vars: rownames `btmp'
+    mat drop `btmp'
+    local rest `vars'
+
+// parse groups
+    gettoken 1 groups : groups, parse(",")
+    while `"`1'"'!="" {
+        gettoken 1 cons : 1, parse("(")
+        if "`cons'"!="" {
+            unab cons: `cons'
+        }
+        if "`cons'"=="" local cons _cons
+        if !`:list cons in vars' {
+            di as error `"categorical(): `cons' not found"'
+            exit 111
+        }
+        unab 1: `1'
+        local keep `1'
+        local ref: list 1 - vars
+        if `:list sizeof ref'>1 {
+            di as txt "categorical(): several possible reference indicators: `ref'"
+            di as txt "using first indicator; this may cause problems"
+        }
+        local ref: word 1 of `ref'
+        if "`ref'"=="" {
+            di as error "categorical(): no reference indicator found"
+            exit 111
+        }
+        local 1: list vars & 1
+        if "`1'"=="" {
+            di as error "invalid categorical() option"
+            exit 198
+        }
+        if !`:list 1 in rest' {
+            di as error "categorical(): groups must be distinct"
+            exit 198
+        }
+        local rest: list rest - 1
+        local 1: list 1 | ref
+        local 1: list keep & 1
+        local gvars `"`gvars'"`1'" "'
+        if `:list ref in refs' {
+            di as error "categorical(): groups must be distinct"
+            exit 198
+        }
+        else local refs "`refs'`ref' "
+        local conss "`conss'`cons' "
+        gettoken 1 groups : groups, parse(",")
+        gettoken 1 groups : groups, parse(",")
+    }
+
+// determine order of coefficients
+    local var: word 1 of `vars'
+    while "`var'"!="" {
+        if `:list var in rest' {
+            local master `"`master'`"`eq'`var'"' "'
+            local vars: list vars - var
+        }
+        else {
+            foreach gvar of local gvars {
+                if `:list var in gvar' {
+                    foreach temp of local gvar {
+                        local master `"`master'`"`eq'`temp'"' "'
+                    }
+                    local vars: list vars - gvar
+                    continue, break
+                }
+            }
+        }
+        local var: word 1 of `vars'
+    }
+
+// normalize coefficients and compute (co-)variances
+    tempname I Icons Vtmp Z
+    local g 0
+    foreach vars of local gvars {
+        local ref: word `++g' of `refs'
+        local cons: word `g' of `conss'
+        local k: word count `vars'
+    // - prepare indicator vector
+        mat `I' = `b' * 0
+        foreach var of local vars {
+            if "`var'"!="`ref'" {
+                mat `I'[rownumb(`I',`"`eq'`var'"'),1] = 1
+            }
+        }
+        mat `Icons' = `I'
+        mat `Icons'[rownumb(`Icons',`"`eq'`cons'"'),1] = -1
+    // - transform coefficients vector
+        mat `btmp' = `I'' * `b' / `k'
+        mat rown `btmp' = `"`eq'`ref'"'
+        mat `b' = `b' - `Icons' * `btmp' \ -`btmp'
+        if `hasV' {
+        // - add ref cat to V
+            mat `Vtmp' = ( `I'' * `V' / `k' )
+            mat rown `Vtmp' = `"`eq'`ref'"'
+            mat `V' = ( `V' \ -`Vtmp' ) , ( ( -`Vtmp'' \ `Vtmp' * `I' / `k' ))
+        // - update indicator vectors and transform V
+            mat `I' = `I' \ `btmp'*0
+            mat `Icons' = `Icons' \ `btmp'*0
+            mat `Vtmp' = ( `I'' * `V' / `k' )
+            mat `V' = `V' - `Icons' * `Vtmp' - `Vtmp'' * `Icons'' ///
+            + `Vtmp' * `I' / `k' * `Icons' * `Icons''
+            mat drop `Vtmp'
+        }
+        mat drop `btmp'
+    }
+
+// reorder b and V
+    foreach eqi of local eqs {
+        if `"`eqi':"'==`"`eq'"' {
+            foreach var of local master {
+                mat `btmp' = nullmat(`btmp') \ `b'[`"`var'"',1]
+            }
+        }
+        else {
+            mat `btmp' = nullmat(`btmp') \ `b'[`"`eqi':"',1]
+        }
+    }
+    mat `b' = `btmp'
+    mat drop `btmp'
+    if `hasV' {
+        foreach eqi of local eqs {
+            if `"`eqi':"'==`"`eq'"' {
+                foreach var of local master {
+                    mat `Vtmp' = nullmat(`Vtmp') \ `V'[`"`var'"',1...]
+                }
+            }
+            else {
+                mat `Vtmp' = nullmat(`Vtmp') \ `V'[`"`eqi':"',1...]
+            }
+        }
+        mat `V' = `Vtmp'
+        mat drop `Vtmp'
+        foreach eqi of local eqs {
+            if `"`eqi':"'==`"`eq'"' {
+                foreach var of local master {
+                    mat `Vtmp' = nullmat(`Vtmp') , `V'[1...,`"`var'"']
+                }
+            }
+            else {
+                mat `Vtmp' = nullmat(`Vtmp') , `V'[1...,`"`eqi':"']
+            }
+        }
+        mat `V' = `Vtmp'
+        mat drop `Vtmp'
+    }
+end
+
+prog _setXvals
+    syntax anything, se(str) [ x1(str) x2(str) ]
+    gettoken x Vx : anything
+    gettoken Vx : Vx
+    tempname tmp
+    local fixedx
+    forv i = 1/2 {
+        if `"`x`i''"'=="" continue
+        mat `tmp' = `x'[1,"x`i':"]
+        local coefs: colnames `tmp'
+        while (1) {
+            if `"`x`i''"'=="" continue, break
+            gettoken var x`i' : x`i', parse(" =,")
+            if `"`var'"'=="," {
+                gettoken var x`i' : x`i', parse(" =")
+            }
+            gettoken val x`i' : x`i', parse(" =,")
+            if `"`val'"'=="=" {
+                gettoken val x`i' : x`i', parse(" ,")
+            }
+            capt confirm number `val'
+            if _rc | `"`var'"'=="" {
+                di as err "invalid x`i'() option"
+                exit 198
+            }
+            capt unab trash : `var'
+            if _rc {
+                local trash `"`var'"'
+            }
+            local vars: list coefs & trash
+            if `"`vars'"'=="" {
+                di as err `"x`i'(): `var' not found"'
+                exit 111
+            }
+            local coefs: list coefs - vars
+            foreach v of local vars {
+                mat `x'[1,colnumb(`x',`"x`i':`v'"')] = `val'
+                local fixedx `"`fixedx' `"x`i':`v'"'"'
+            }
+        }
+    }
+    if `se' {
+        mata: oaxaca_setfixedXtozero(1)
+    }
+end
+
+program _eretpostcmd, eclass
+    eret local cmd "_oaxaca"
+end
+
+program _parsedetail2
+    syntax [, Detail2(str) coefs(str) ]
+    local rest "`coefs'"
+    while (1) {
+        if `"`detail2'"'=="" continue, break
+        gettoken group detail2 : detail2, parse(",")
+        gettoken gname vars : group, parse("=:")
+        gettoken trash vars: vars, parse("=:")
+        if `"`gname'"'=="" | `"`vars'"'=="" {
+            di as err "invalid detail() option"
+            exit 198
+        }
+        local gvars
+        foreach var of local vars {
+            capt unab trash: `var'
+            if _rc local trash `"`var'"'
+            local svar: list rest & trash
+            if "`svar'"=="" {
+                di as err `"`var' not found"'
+                exit 111
+            }
+            else {
+                local rest: list rest - svar
+            }
+            local gvars: list gvars | svar
+        }
+        local groups `"`groups' "`gname' `gvars'""'
+        gettoken group detail2 : detail2, parse(",") // get rid of leading comma
+    }
+    local cgroups
+    while (1) {
+        if `"`coefs'"'=="" continue, break
+        gettoken coef coefs : coefs
+        if `:list coef in rest' {
+            local cgroups `"`cgroups' "`coef'""'
+        }
+        else {
+            foreach group in `groups' {
+                gettoken name vars : group
+                if `:list coef in vars' {
+                    local group `""`group'""'
+                    local cgroups `"`cgroups' `group'"'
+                    local groups: list groups - group
+                    local coefs: list coefs - vars
+                    continue, break
+                }
+            }
+        }
+    }
+    c_local cgroups `"`cgroups'"'
+end
+
+program _parseadjust
+    syntax [, adjust(str) coefs(str) ]
+    foreach var of local adjust {
+        capt unab trash: `var'
+        if _rc local trash `"`var'"'
+        local svar: list coefs & trash
+        if "`svar'"=="" {
+            di as err `"`var' not found"'
+            exit 111
+        }
+        else {
+            local coefs: list coefs - svar
+        }
+        local vars: list vars | svar
+    }
+    c_local adjust `"`vars'"'
+    c_local coefsadj  `"`coefs'"'
+end
+
+program nlcom_nose, rclass
+    gettoken term rest : 0, match(paren)
+    tempname b
+    while (1) {
+        if `"`term'"'=="" continue, break
+        gettoken name exp : term, parse(":")
+        gettoken trash exp : exp, parse(":")
+        mat `b' = nullmat(`b'), (`exp')
+        local coln `"`coln' `"`name'"'"'
+        gettoken term rest : rest, match(paren)
+    }
+    mat coln `b' = `coln'
+    ret mat b = `b'
+end
+
+program PostResults, eclass
+    syntax anything,  b0(str) esample(str) suest(str) [ ///
+        depname(str) model(str) weights(str) refcoefs(str) ///
+        detail(str) legend(str asis) adjust(str) fixed(str) ///
+        v0(str) n1(str) n2(str) ///
+        wtype(str) wexp(str asis) vce(str) vcetype(str) ///
+        n_clust(str) clustvar(str) prefix(str) n_strata(str) ///
+        n_psu(str) n_pop(str) df_r(str)  ]
+    qui count if `esample'
+    if `"`depname'"'!="" {
+        local depvar `"`depname'"'
+        local depname `"depname(`depname')"'
+    }
+    eret post `anything', esample(`esample') obs(`r(N)') `depname'
+    foreach opt in prefix clustvar vcetype vce wexp wtype  {
+        eret local `opt' `"``opt''"'
+    }
+    if `suest' eret local suest suest
+    foreach opt in fixed adjust legend detail refcoefs weights model depvar {
+        eret local `opt' `"``opt''"'
+    }
+    eret local title "Blinder-Oaxaca decomposition"
+    eret local cmd "_oaxaca"
+    if "`n1'`n2'"!="" {
+        eret scalar N_1 = `n1'
+        eret scalar N_2 = `n2'
+    }
+    foreach opt in N_clust N_strata N_psu N_pop df_r {
+        local optt = lower("`opt'")
+        if `"``optt''"'!="" {
+            eret scalar `opt' = ``optt''
+        }
+    }
+    eret mat b0 = `b0'
+    if "`v0'"!="" {
+        eret mat V0 = `v0'
+    }
+end
+
+version 9.2
+mata:
+
+void oaxaca_extracteqs()
+{
+    b = st_matrix(st_local("b"))
+    V = st_matrix(st_local("V"))
+    old = tokens(st_local("oldeqs"))
+    newi = tokens(st_local("neweqs"))
+    stripe = st_matrixcolstripe(st_local("b"))
+    r = 0
+    j = 1
+    match = 0
+    for (i=1; i<=rows(stripe); i++) {
+        if (stripe[i,1]==old[j]) {
+            r++
+            match = 1
+        }
+        else if (match) {
+            j++
+            i--
+            match = 0
+        }
+        if (j>length(old)) break
+    }
+    p = J(r,1,.)
+    r = 0
+    j = 1
+    for (i=1; i<=rows(stripe); i++) {
+        if (stripe[i,1]==old[j]) {
+            p[++r] = i
+            match = 1
+            stripe[i,1] = newi[j]
+        }
+        else if (match) {
+            j++
+            i--
+            match = 0
+        }
+        if (j>length(old)) break
+    }
+    b = b[,p]
+    V = V[p,p]
+    stripe = stripe[p,]
+    st_matrix(st_local("b"), b)
+    st_matrixcolstripe(st_local("b"), stripe)
+    st_matrix(st_local("V"), V)
+    st_matrixcolstripe(st_local("V"), stripe)
+    st_matrixrowstripe(st_local("V"), stripe)
+}
+
+void oaxaca_insertmissingcoefs()
+{
+    b = st_matrix(st_local("b"))
+    stripe = st_matrixcolstripe(st_local("b"))
+    coefs = select(stripe[,2],(stripe[,1]:=="b1"))
+    coefs2 = select(stripe[,2],(stripe[,1]:=="b2"))
+    r = 0
+    for (i=1; i<=length(coefs2); i++) {
+        if (anyof(coefs, coefs2[i])==0) r++
+    }
+    if (r>0) {
+        p = J(r,1,.)
+        r = 0
+        for (i=1; i<=length(coefs2); i++) {
+            if (anyof(coefs, coefs2[i])==0) p[++r] = i
+        }
+        coefs = coefs \ coefs2[p]
+    }
+    if (anyof(coefs,"_cons") & !allof(coefs,"_cons")) {
+        coefs = select(coefs,coefs:!="_cons") \ "_cons"
+    }
+    ncoef = length(coefs)
+    neq = 2 + (stripe[rows(stripe),1]=="b_ref")
+    r = 0
+    for (j=1; j<=neq; j++) {
+        eq = ("b1", "b2", "b_ref")[j]
+        for (i=1; i<=ncoef; i++) {
+            r = r + (length(oaxaca_which(stripe[,1]:==eq :& stripe[,2]:==coefs[i]))>0)
+        }
+    }
+    p = J(r,1,.)
+    r = 1
+    p0 = (1::neq*ncoef)
+    for (j=1; j<=neq; j++) {
+        eq = ("b1", "b2", "b_ref")[j]
+        for (i=1; i<=ncoef; i++) {
+            tmp = oaxaca_which(stripe[,1]:==eq :& stripe[,2]:==coefs[i])
+            if (length(tmp)>0) {
+                p[r++] = tmp[1]
+            }
+            else p0[(j-1)*ncoef+i] = .
+        }
+    }
+    p0 = select(p0, p0:!=.)
+    bnew = J(1,neq*ncoef,0)
+    bnew[p0] = b[p]
+    stripenew = (J(ncoef,1,"b1"),coefs) \ (J(ncoef,1,"b2"),coefs)
+    if (neq==3)  stripenew = (stripenew) \ (J(ncoef,1,"b_ref"),coefs)
+    st_matrix(st_local("b"), bnew)
+    st_matrixcolstripe(st_local("b"), stripenew)
+    st_local("coefs",oaxaca_invtokens(coefs))
+    if (st_local("se")=="1") {
+        V = st_matrix(st_local("V"))
+        Vnew = J(rows(V),neq*ncoef,0)
+        Vnew[,p0] = V[,p]
+        V = J(neq*ncoef,neq*ncoef,0)
+        V[p0,] = Vnew[p,]
+        st_matrix(st_local("V"), V)
+        st_matrixcolstripe(st_local("V"), stripenew)
+        st_matrixrowstripe(st_local("V"), stripenew)
+    }
+}
+
+void oaxaca_reorderxandVx()
+{
+    b = st_matrix(st_local("x"))
+    coefs = st_matrixcolstripe(st_local("x")) //tokens(st_local("coefs"))'
+    k = length(b)
+    p = range(1, k-1, 2) \ range(2, k, 2)
+    b = b[p]
+    stripe = ("x":+coefs[p,2]), coefs[p,1] //(J(length(coefs),1,"x1"),coefs) \ (J(length(coefs),1,"x2"),coefs)
+    st_matrix(st_local("x"), b)
+    st_matrixcolstripe(st_local("x"), stripe)
+    if (st_local("se")=="1") {
+        V = st_matrix(st_local("Vx"))
+        V = V[p,p]
+        st_matrix(st_local("Vx"), V)
+        st_matrixcolstripe(st_local("Vx"), stripe)
+        st_matrixrowstripe(st_local("Vx"), stripe)
+    }
+}
+
+void oaxaca_setfixedXtozero(real scalar eq)
+{
+    V = st_matrix(st_local("Vx"))
+    fixed = tokens(st_local("fixedx"))'
+    if (eq) {
+        stripe = st_matrixcolstripe(st_local("Vx"))
+        stripe = stripe[,1] :+ ":" :+ stripe[,2]
+    }
+    else stripe = st_matrixcolstripe(st_local("Vx"))[,2]
+    r = 0
+    for (i=1;i<=length(fixed);i++) {
+        r = r + length(oaxaca_which(stripe:==fixed[i]))
+    }
+    p = J(r,1,.)
+    r = 1
+    for (i=1;i<=length(fixed);i++) {
+        tmp = oaxaca_which(stripe:==fixed[i])
+        p[|r \ r+length(tmp)-1|] = tmp
+        r = r + length(tmp)
+    }
+    V[p,] = V[p,]*0
+    V[,p] = V[,p]*0
+    st_replacematrix(st_local("Vx"),V)
+}
+
+void oaxaca_decomp()
+{
+    se      = (st_local("se")=="1")
+    tf      = (st_local("threefold")!="")
+    tfr     = (st_local("threefold2")!="")
+    ref     = (st_local("reference")!="")
+    wgt     = strtoreal(tokens(st_local("weights")))
+    split   = (st_local("split")!="")
+    detail  = (st_local("detail")!="")
+    cgroups = tokens(st_local("cgroups"))
+    ngrp    = length(cgroups)
+    adjust  = tokens(st_local("adjust"))
+    adjyes  = length(adjust)>0
+    b       = st_matrix("e(b)")
+    stripe  = st_matrixcolstripe("e(b)")
+    if (se) V = st_matrix("e(V)")
+    ncoefs  = 0
+    for (i=1; i<=ngrp; i++) {
+        ncoefs  = ncoefs + max(((length(tokens(cgroups[i]))-1),1))
+    }
+    if (length(wgt)>0) { // expand wgt (recycle)
+        w = J(1,ncoefs,.)
+        for (i=1; i<=ncoefs; i=i+length(wgt)) {
+            r = i + length(wgt) - 1
+            if (r<=ncoefs)  w[|i \ r|] = wgt
+            else            w[|i \ ncoefs|] = wgt[|1 \ i-ncoefs+1|]
+        }
+        m = 1:-w
+    }
+    b1 = x1 = b2 = x2 = p = J(1,ncoefs,.)
+    G = J(ncoefs,ngrp,0)
+    grpnms  = J(1,ngrp,"")
+    k = 0
+    for (i=1; i<=ngrp; i++) {
+        grp = tokens(cgroups[i])
+        if (length(grp)==1) grp = grp, grp
+        grpnms[i] = grp[1]
+        for (j=2; j<=length(grp); j++) { // skip first
+            coef = grp[j]
+            k++
+            b1[k] = oaxaca_which(stripe[,1]:=="b1":&stripe[,2]:==coef)
+            x1[k] = oaxaca_which(stripe[,1]:=="x1":&stripe[,2]:==coef)
+            b2[k] = oaxaca_which(stripe[,1]:=="b2":&stripe[,2]:==coef)
+            x2[k] = oaxaca_which(stripe[,1]:=="x2":&stripe[,2]:==coef)
+            if (ref) p[k] = oaxaca_which(stripe[,1]:=="b_ref":&stripe[,2]:==coef)
+            G[k,i] = 1
+        }
+    }
+    coln = "D_Prediction_1", "D_Prediction_2", "D_Difference"
+    if (length(adjust)>0) {
+        b1a = x1a = b2a = x2a = J(1,length(adjust),.)
+        for (i=1; i<=length(adjust); i++) {
+            coef = adjust[i]
+            b1a[i] = oaxaca_which(stripe[,1]:=="b1":&stripe[,2]:==coef)
+            x1a[i] = oaxaca_which(stripe[,1]:=="x1":&stripe[,2]:==coef)
+            b2a[i] = oaxaca_which(stripe[,1]:=="b2":&stripe[,2]:==coef)
+            x2a[i] = oaxaca_which(stripe[,1]:=="x2":&stripe[,2]:==coef)
+        }
+        res =
+            b[(x1,x1a)]*b[(b1,b1a)]',
+            b[(x2,x2a)]*b[(b2,b2a)]',
+            b[(x1,x1a)]*b[(b1,b1a)]' - b[(x2,x2a)]*b[(b2,b2a)]',
+            b[x1]*b[b1]' - b[x2]*b[b2]'
+        coln = coln, "D_Adjusted"
+        if (se) {
+            D = J(4, length(b), 0)
+            D[1,(b1,b1a,x1,x1a)] = b[(x1,x1a,b1,b1a)]
+            D[2,(b2,b2a,x2,x2a)] = b[(x2,x2a,b2,b2a)]
+            D[3,(b1,b1a,x1,x1a,b2,b2a,x2,x2a)] = b[(x1,x1a,b1,b1a)], -b[(x2,x2a,b2,b2a)]
+            D[4,(b1,x1,b2,x2)] = b[(x1,b1)], -b[(x2,b2)]
+        }
+    }
+    else {
+        res =
+            b[x1]*b[b1]',
+            b[x2]*b[b2]',
+            b[x1]*b[b1]' - b[x2]*b[b2]'
+        if (se) {
+            D = J(3, length(b), 0)
+            D[1,(b1,x1)] = b[(x1,b1)]
+            D[2,(b2,x2)] = b[(x2,b2)]
+            D[3,(b1,x1,b2,x2)] = b[(x1,b1)], -b[(x2,b2)]
+        }
+    }
+    if (se) j = rows(D)
+    if (tfr) { // threefold reverse
+        if (detail) {
+            res = res,
+                ((b[x1]-b[x2]) :* b[b1]) * G,           (b[x1]-b[x2])*b[b1]',
+                (b[x1] :* (b[b1]-b[b2])) * G,           b[x1]*(b[b1]-b[b2])',
+                ((b[x1]-b[x2]) :* (b[b2]-b[b1])) * G,   (b[x1]-b[x2])*(b[b2]-b[b1])'
+            coln = coln, "E_":+grpnms, "E_Total", "C_":+grpnms, "C_Total",
+                "I_":+grpnms, "I_Total"
+            if (se) {
+                D = D \ J(3*(ngrp+1), length(b), 0)
+                D[++j::j+ngrp-1,(x1,x2,b1)] = G'*diag(b[b1]),G'*diag(-b[b1]),G'*diag(b[x1]-b[x2])
+                D[j=j+ngrp,(x1,x2,b1)] = b[b1], -b[b1], b[x1]-b[x2]
+                D[++j::j+ngrp-1,(x1,b1,b2)] = G'*diag(b[b1]-b[b2]), G'*diag(b[x1]), G'*diag(-b[x1])
+                D[j=j+ngrp,(x1,b1,b2)] = b[b1]-b[b2], b[x1], -b[x1]
+                D[++j::j+ngrp-1,(x1,x2,b1,b2)] = G'*diag(b[b2]-b[b1]), G'*diag(b[b1]-b[b2]),
+                    G'*diag(b[x2]-b[x1]), G'*diag(b[x1]-b[x2])
+                D[j=j+ngrp,(x1,x2,b1,b2)] = b[b2]-b[b1], b[b1]-b[b2], b[x2]-b[x1], b[x1]-b[x2]
+            }
+        }
+        else {
+            res = res,
+                (b[x1]-b[x2])*b[b1]',
+                b[x1]*(b[b1]-b[b2])',
+                (b[x1]-b[x2])*(b[b2]-b[b1])'
+            coln = coln, "E_", "C_", "I_"
+            if (se) {
+                D = D \ J(3, length(b), 0)
+                D[++j,(x1,x2,b1)] = b[b1], -b[b1], b[x1]-b[x2]
+                D[++j,(x1,b1,b2)] = b[b1]-b[b2], b[x1], -b[x1]
+                D[++j,(x1,x2,b1,b2)] = b[b2]-b[b1], b[b1]-b[b2], b[x2]-b[x1], b[x1]-b[x2]
+            }
+        }
+    }
+    else if (tf) { // threefold
+        if (detail) {
+            res = res,
+                ((b[x1]-b[x2]) :* b[b2]) * G,           (b[x1]-b[x2])*b[b2]',
+                (b[x2] :* (b[b1]-b[b2])) * G,           b[x2]*(b[b1]-b[b2])',
+                ((b[x1]-b[x2]) :* (b[b1]-b[b2])) * G,   (b[x1]-b[x2])*(b[b1]-b[b2])'
+            coln = coln, "E_":+grpnms, "E_Total", "C_":+grpnms, "C_Total",
+                "I_":+grpnms, "I_Total"
+            if (se) {
+                D = D \ J(3*(ngrp+1), length(b), 0)
+                D[++j::j+ngrp-1,(x1,x2,b2)] = G'*diag(b[b2]),G'*diag(-b[b2]),G'*diag(b[x1]-b[x2])
+                D[j=j+ngrp,(x1,x2,b2)] = b[b2], -b[b2], b[x1]-b[x2]
+                D[++j::j+ngrp-1,(x2,b1,b2)] = G'*diag(b[b1]-b[b2]), G'*diag(b[x2]), G'*diag(-b[x2])
+                D[j=j+ngrp,(x2,b1,b2)] = b[b1]-b[b2], b[x2], -b[x2]
+                D[++j::j+ngrp-1,(x1,x2,b1,b2)] = G'*diag(b[b1]-b[b2]), G'*diag(b[b2]-b[b1]),
+                    G'*diag(b[x1]-b[x2]), G'*diag(b[x2]-b[x1])
+                D[j=j+ngrp,(x1,x2,b1,b2)] = b[b1]-b[b2], b[b2]-b[b1], b[x1]-b[x2], b[x2]-b[x1]
+            }
+        }
+        else {
+            res = res,
+                (b[x1]-b[x2])*b[b2]',
+                b[x2]*(b[b1]-b[b2])',
+                (b[x1]-b[x2])*(b[b1]-b[b2])'
+            coln = coln, "E_", "C_", "I_"
+            if (se) {
+                D = D \ J(3, length(b), 0)
+                D[++j,(x1,x2,b2)] = b[b2], -b[b2], b[x1]-b[x2]
+                D[++j,(x2,b1,b2)] = b[b1]-b[b2], b[x2], -b[x2]
+                D[++j,(x1,x2,b1,b2)] = b[b1]-b[b2], b[b2]-b[b1], b[x1]-b[x2], b[x2]-b[x1]
+            }
+        }
+    }
+    else if (ref) { // reference coefs
+        if (detail) {
+            res = res,
+                ((b[x1]-b[x2]) :* b[p]) * G, (b[x1]-b[x2])*b[p]',
+                (split ? (b[x1] :* (b[b1]-b[p])) * G, b[x1] * (b[b1]-b[p])',
+                         (b[x2] :* (b[p]-b[b2])) * G, b[x2] * (b[p]-b[b2])'
+                       : (b[x1] :* (b[b1]-b[p]) + b[x2] :* (b[p]-b[b2])) * G,
+                         b[x1] * (b[b1]-b[p])' + b[x2] * (b[p]-b[b2])'
+                       )
+            coln = coln, "E_":+grpnms, "E_Total", (split ?
+                ("U1_":+grpnms, "U1_Total", "U2_":+grpnms, "U2_Total")
+                : ("U_":+grpnms, "U_Total"))
+            if (se) {
+                D = D \ J((2+split)*(ngrp+1), length(b), 0)
+                D[++j::j+ngrp-1,(x1,x2,p)] = G'*diag(b[p]), G'*diag(-b[p]), G'*diag(b[x1]-b[x2])
+                D[j=j+ngrp,(x1,x2,p)] = b[p], -b[p], b[x1]-b[x2]
+                if (split) {
+                    D[++j::j+ngrp-1,(x1,b1,p)] = G'*diag(b[b1]-b[p]), G'*diag(b[x1]), G'*diag(-b[x1])
+                    D[j=j+ngrp,(x1,b1,p)] = b[b1]-b[p], b[x1], -b[x1]
+                    D[++j::j+ngrp-1,(x2,p,b2)] = G'*diag(b[p]-b[b2]), G'*diag(b[x2]), G'*diag(-b[x2])
+                    D[j=j+ngrp,(x2,p,b2)] = b[p]-b[b2], b[x2], -b[x2]
+                }
+                else {
+                    D[++j::j+ngrp-1,(x1,x2,b1,b2,p)] = G'*diag(b[b1]-b[p]), G'*diag(b[p]-b[b2]),
+                        G'*diag(b[x1]), G'*diag(-b[x2]), G'*diag(b[x2]-b[x1])
+                    D[j=j+ngrp,(x1,x2,b1,b2,p)] = b[b1]-b[p], b[p]-b[b2], b[x1], -b[x2], b[x2]-b[x1]
+                }
+            }
+        }
+        else {
+            res = res,
+                (b[x1]-b[x2])*b[p]',
+                (split ? b[x1] * (b[b1]-b[p])', b[x2] * (b[p]-b[b2])'
+                       : b[x1] * (b[b1]-b[p])' + b[x2] * (b[p]-b[b2])'
+                       )
+            coln = coln, "E_", (split ? ("U1_", "U2_") : "U_")
+            if (se) {
+                D = D \ J(2+split, length(b), 0)
+                D[++j,(x1,x2,p)] = b[p], -b[p], b[x1]-b[x2]
+                if (split) {
+                    D[++j,(x1,b1,p)] = b[b1]-b[p], b[x1], -b[x1]
+                    D[++j,(x2,p,b2)] = b[p]-b[b2], b[x2], -b[x2]
+                }
+                else {
+                    D[++j,(x1,x2,b1,b2,p)] = b[b1]-b[p], b[p]-b[b2], b[x1], -b[x2], b[x2]-b[x1]
+                }
+            }
+        }
+    }
+    else /*if length(wgt)>0*/ { // weights
+        if (detail) {
+            res = res,
+                ((b[x1]-b[x2]) :* (w:*b[b1]+m:*b[b2])) * G,
+                    (b[x1]-b[x2]) * (w:*b[b1]+m:*b[b2])',
+                (split ? (b[x1] :* (m:*b[b1]-m:*b[b2])) * G, b[x1] * (m:*b[b1]-m:*b[b2])',
+                         (b[x2] :* (w:*b[b1]-w:*b[b2])) * G, b[x2] * (w:*b[b1]-w:*b[b2])'
+                       : (b[x1] :* (m:*b[b1]-m:*b[b2]) + b[x2] :* (w:*b[b1]-w:*b[b2])) * G,
+                         b[x1] * (m:*b[b1]-m:*b[b2])' + b[x2] * (w:*b[b1]-w:*b[b2])'
+                       )
+            coln = coln, "E_":+grpnms, "E_Total", (split ?
+                ("U1_":+grpnms, "U1_Total", "U2_":+grpnms, "U2_Total")
+                : ("U_":+grpnms, "U_Total"))
+            if (se) {
+                D = D \ J((2+split)*(ngrp+1), length(b), 0)
+                D[++j::j+ngrp-1,(x1,x2,b1,b2)] =
+                    G'*diag(w:*b[b1]+m:*b[b2]), G'*diag(-w:*b[b1]-m:*b[b2]),
+                    G'*diag(w:*b[x1]-w:*b[x2]), G'*diag(m:*b[x1]-m:*b[x2])
+                D[j=j+ngrp,(x1,x2,b1,b2)] = w:*b[b1]+m:*b[b2], -w:*b[b1]-m:*b[b2],
+                    w:*b[x1]-w:*b[x2], m:*b[x1]-m:*b[x2]
+                if (split) {
+                    D[++j::j+ngrp-1,(x1,b1,b2)] = G'*diag(m:*b[b1]-m:*b[b2]), G'*diag(m:*b[x1]),
+                        G'*diag(-m:*b[x1])
+                    D[j=j+ngrp,(x1,b1,b2)] = m:*b[b1]-m:*b[b2], m:*b[x1], -m:*b[x1]
+                    D[++j::j+ngrp-1,(x2,b1,b2)] = G'*diag(w:*b[b1]-w:*b[b2]), G'*diag(w:*b[x2]),
+                        G'*diag(-w:*b[x2])
+                    D[j=j+ngrp,(x2,b1,b2)] = w:*b[b1]-w:*b[b2], w:*b[x2], -w:*b[x2]
+                }
+                else {
+                    D[++j::j+ngrp-1,(x1,x2,b1,b2)] =
+                        G'*diag(m:*b[b1]-m:*b[b2]), G'*diag(w:*b[b1]-w:*b[b2]),
+                        G'*diag(m:*b[x1]+w:*b[x2]), G'*diag(-m:*b[x1]-w:*b[x2])
+                    D[j=j+ngrp,(x1,x2,b1,b2)] = m:*b[b1]-m:*b[b2], w:*b[b1]-w:*b[b2],
+                        m:*b[x1]+w:*b[x2], -m:*b[x1]-w:*b[x2]
+                }
+            }
+        }
+        else {
+            res = res,
+                (b[x1]-b[x2]) * (w:*b[b1]+m:*b[b2])',
+                (split ? b[x1] * (m:*b[b1]-m:*b[b2])', b[x2] * (w:*b[b1]-w:*b[b2])'
+                       : b[x1] * (m:*b[b1]-m:*b[b2])' + b[x2] * (w:*b[b1]-w:*b[b2])'
+                       )
+            coln = coln, "E_", (split ? ("U1_", "U2_") : "U_")
+            if (se) {
+                D = D \ J(2+split, length(b), 0)
+                D[++j,(x1,x2,b1,b2)] = w:*b[b1]+m:*b[b2], -w:*b[b1]-m:*b[b2],
+                    w:*b[x1]-w:*b[x2], m:*b[x1]-m:*b[x2]
+                if (split) {
+                    D[++j,(x1,b1,b2)] = m:*b[b1]-m:*b[b2], m:*b[x1], -m:*b[x1]
+                    D[++j,(x2,b1,b2)] = w:*b[b1]-w:*b[b2], w:*b[x2], -w:*b[x2]
+                }
+                else {
+                    D[++j,(x1,x2,b1,b2)] = m:*b[b1]-m:*b[b2], w:*b[b1]-w:*b[b2],
+                        m:*b[x1]+w:*b[x2], -m:*b[x1]-w:*b[x2]
+                }
+            }
+        }
+    }
+    if (se) {
+        V = D*V*D'
+    }
+    stripe = J(length(coln),1,""), coln'
+    if (detail) {
+        notcons = (stripe[,2]:!="E__cons":&stripe[,2]:!="I__cons")
+        res = select(res, notcons')
+        stripe = select(stripe, notcons)
+    }
+    st_matrix(st_local("b"), res)
+    st_matrixcolstripe(st_local("b"), stripe)
+    if (se) {
+        if (detail) V = select(select(V, notcons'), notcons)
+        st_matrix(st_local("V"),V)
+        st_matrixrowstripe(st_local("V"),stripe)
+        st_matrixcolstripe(st_local("V"),stripe)
+    }
+}
+
+string scalar oaxaca_invtokens(string vector In)
+{
+    string scalar Out
+    real scalar i
+
+    Out = ""
+    for (i=1; i<=length(In); i++) {
+        Out = Out + (i>1 ? " " : "") + In[i]
+    }
+    return(Out)
+}
+
+real matrix oaxaca_which(real vector I)
+{
+        if (cols(I)!=1) return(select(1..cols(I), I))
+        else return(select(1::rows(I), I))
+}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/b/binscatter.ado

@@ -0,0 +1,1048 @@
+*! version 7.02  24nov2013  Michael Stepner, [email protected]
+
+/* CC0 license information:
+To the extent possible under law, the author has dedicated all copyright and related and neighboring rights
+to this software to the public domain worldwide. This software is distributed without any warranty.
+
+This code is licensed under the CC0 1.0 Universal license.  The full legal text as well as a
+human-readable summary can be accessed at http://creativecommons.org/publicdomain/zero/1.0/
+*/
+
+* Why did I include a formal license? Jeff Atwood gives good reasons: http://www.codinghorror.com/blog/2007/04/pick-a-license-any-license.html
+
+
+program define binscatter, eclass sortpreserve
+	version 12.1
+	
+	syntax varlist(min=2 numeric) [if] [in] [aweight fweight], [by(varname) ///
+		Nquantiles(integer 20) GENxq(name) discrete xq(varname numeric) MEDians ///
+		CONTROLs(varlist numeric ts fv) absorb(varname) noAddmean ///
+		LINEtype(string) rd(numlist ascending) reportreg ///
+		COLors(string) MColors(string) LColors(string) Msymbols(string) ///
+		savegraph(string) savedata(string) replace ///
+		nofastxtile randvar(varname numeric) randcut(real 1) randn(integer -1) ///
+		/* LEGACY OPTIONS */ nbins(integer 20) create_xq x_q(varname numeric) symbols(string) method(string) unique(string) ///
+		*]
+
+	set more off
+
+	* Create convenient weight local
+	if ("`weight'"!="") local wt [`weight'`exp']
+	
+	***** Begin legacy option compatibility code
+	
+	if (`nbins'!=20) {
+		if (`nquantiles'!=20) {
+			di as error "Cannot specify both nquantiles() and nbins(): both are the same option, nbins is supported only for backward compatibility."
+			exit
+		}
+		di as text "NOTE: legacy option nbins() has been renamed nquantiles(), and is supported only for backward compatibility."
+		local nquantiles=`nbins'
+	}
+	
+	if ("`create_xq'"!="") {
+		if ("`genxq'"!="") {
+			di as error "Cannot specify both genxq() and create_xq: both are the same option, create_xq is supported only for backward compatibility."
+			exit
+		}
+		di as text "NOTE: legacy option create_xq has been renamed genxq(), and is supported only for backward compatibility."
+		local genxq="q_"+word("`varlist'",-1)
+	}
+	
+	if ("`x_q'"!="") {
+		if ("`xq'"!="") {
+			di as error "Cannot specify both xq() and x_q(): both are the same option, x_q() is supported only for backward compatibility."
+			exit
+		}
+		di as text "NOTE: legacy option x_q() has been renamed xq(), and is supported only for backward compatibility."
+		local xq `x_q'
+	}
+	
+	if ("`symbols'"!="") {
+		if ("`msymbols'"!="") {
+			di as error "Cannot specify both msymbols() and symbols(): both are the same option, symbols() is supported only for backward compatibility."
+			exit
+		}
+		di as text "NOTE: legacy option symbols() has been renamed msymbols(), and is supported only for backward compatibility."
+		local msymbols `symbols'
+	}
+	
+	if ("`linetype'"=="noline") {
+		di as text "NOTE: legacy line type 'noline' has been renamed 'none', and is supported only for backward compatibility."
+		local linetype none
+	}
+	
+	if ("`method'"!="") {
+		di as text "NOTE: method() is no longer a recognized option, and will be ignored. binscatter now always uses the fastest method without a need for two instances"
+	}
+	
+	if ("`unique'"!="") {
+		di as text "NOTE: unique() is no longer a recognized option, and will be ignored. binscatter now considers the x-variable discrete if it has fewer unique values than nquantiles()"
+	}
+		
+	***** End legacy option capatibility code
+
+	*** Perform checks
+
+	* Set default linetype and check valid
+	if ("`linetype'"=="") local linetype lfit
+	else if !inlist("`linetype'","connect","lfit","qfit","none") {
+		di as error "linetype() must either be connect, lfit, qfit, or none"
+		exit
+	}
+	
+	* Check that nofastxtile isn't combined with fastxtile-only options
+	if "`fastxtile'"=="nofastxtile" & ("`randvar'"!="" | `randcut'!=1 | `randn'!=-1) {
+		di as error "Cannot combine randvar, randcut or randn with nofastxtile"
+		exit
+	}
+
+	* Misc checks
+	if ("`genxq'"!="" & ("`xq'"!="" | "`discrete'"!="")) | ("`xq'"!="" & "`discrete'"!="") {
+		di as error "Cannot specify more than one of genxq(), xq(), and discrete simultaneously."
+		exit
+	}
+	if ("`genxq'"!="") confirm new variable `genxq'
+	if ("`xq'"!="") {
+		capture assert `xq'==int(`xq') & `xq'>0
+		if _rc!=0 {
+			di as error "xq() must contain only positive integers."
+			exit
+		}
+		
+		if ("`controls'`absorb'"!="") di as text "warning: xq() is specified in combination with controls() or absorb(). note that binning takes places after residualization, so the xq variable should contain bins of the residuals."
+	}
+	if `nquantiles'!=20 & ("`xq'"!="" | "`discrete'"!="") {
+		di as error "Cannot specify nquantiles in combination with discrete or an xq variable."
+		exit
+	}
+	if "`reportreg'"!="" & !inlist("`linetype'","lfit","qfit") {
+		di as error "Cannot specify 'reportreg' when no fit line is being created."
+		exit
+	}
+	if "`replace'"=="" {
+		if `"`savegraph'"'!="" {
+			if regexm(`"`savegraph'"',"\.[a-zA-Z0-9]+$") confirm new file `"`savegraph'"'
+			else confirm new file `"`savegraph'.gph"'
+		}
+		if `"`savedata'"'!="" {
+			confirm new file `"`savedata'.csv"'
+			confirm new file `"`savedata'.do"'
+		}
+	}
+
+	* Mark sample (reflects the if/in conditions, and includes only nonmissing observations)
+	marksample touse
+	markout `touse' `by' `xq' `controls' `absorb', strok
+	qui count if `touse'
+	local samplesize=r(N)
+	local touse_first=_N-`samplesize'+1
+	local touse_last=_N
+
+	* Parse varlist into y-vars and x-var
+	local x_var=word("`varlist'",-1)
+	local y_vars=regexr("`varlist'"," `x_var'$","")
+	local ynum=wordcount("`y_vars'")
+
+	* Check number of unique byvals & create local storing byvals
+	if "`by'"!="" {
+		local byvarname `by'
+	
+		capture confirm numeric variable `by'
+		if _rc {
+			* by-variable is string => generate a numeric version
+			tempvar by
+			tempname bylabel
+			egen `by'=group(`byvarname'), lname(`bylabel')
+		}
+		
+		local bylabel `:value label `by'' /*catch value labels for numeric by-vars too*/ 
+		
+		tempname byvalmatrix
+		qui tab `by' if `touse', nofreq matrow(`byvalmatrix')
+		
+		local bynum=r(r)
+		forvalues i=1/`bynum' {
+			local byvals `byvals' `=`byvalmatrix'[`i',1]'
+		}
+	}
+	else local bynum=1
+	
+
+	****** Create residuals  ******
+	
+	if (`"`controls'`absorb'"'!="") quietly {
+	
+		* Parse absorb to define the type of regression to be used
+		if `"`absorb'"'!="" {
+			local regtype "areg"
+			local absorb "absorb(`absorb')"
+		}
+		else {
+			local regtype "reg"
+		}
+	
+		* Generate residuals
+		
+		local firstloop=1
+		foreach var of varlist `x_var' `y_vars' {
+			tempvar residvar
+			`regtype' `var' `controls' `wt' if `touse', `absorb'
+			predict `residvar' if e(sample), residuals
+			if ("`addmean'"!="noaddmean") {
+				summarize `var' `wt' if `touse', meanonly
+				replace `residvar'=`residvar'+r(mean)
+			}
+			
+			label variable `residvar' "`var'"
+			if `firstloop'==1 {
+				local x_r `residvar'
+				local firstloop=0
+			}
+			else local y_vars_r `y_vars_r' `residvar'
+		}
+		
+	}
+	else { 	/*absorb and controls both empty, no need for regression*/
+		local x_r `x_var'
+		local y_vars_r `y_vars'
+	}
+
+
+	****** Regressions for fit lines ******
+	
+	if ("`reportreg'"=="") local reg_verbosity "quietly"
+
+	if inlist("`linetype'","lfit","qfit") `reg_verbosity' {
+
+		* If doing a quadratic fit, generate a quadratic term in x
+		if "`linetype'"=="qfit" {
+			tempvar x_r2
+			gen `x_r2'=`x_r'^2
+		}
+		
+		* Create matrices to hold regression results
+		tempname e_b_temp
+		forvalues i=1/`ynum' {
+			tempname y`i'_coefs
+		}
+		
+		* LOOP over by-vars
+		local counter_by=1
+		if ("`by'"=="") local noby="noby"
+		foreach byval in `byvals' `noby' {
+		
+			* LOOP over rd intervals
+			tokenize  "`rd'"
+			local counter_rd=1	
+				
+			while ("`1'"!="" | `counter_rd'==1) {
+			
+				* display text headers
+				if "`reportreg'"!="" {
+					di "{txt}{hline}"
+					if ("`by'"!="") {
+						if ("`bylabel'"=="") di "-> `byvarname' = `byval'"
+						else {
+							di "-> `byvarname' = `: label `bylabel' `byval''"
+						}
+					}
+					if ("`rd'"!="") {
+						if (`counter_rd'==1) di "RD: `x_var'<=`1'"
+						else if ("`2'"!="") di "RD: `x_var'>`1' & `x_var'<=`2'"
+						else di "RD: `x_var'>`1'"
+					}
+				}
+				
+				* set conditions on reg
+				local conds `touse'
+				
+				if ("`by'"!="" ) local conds `conds' & `by'==`byval'
+				
+				if ("`rd'"!="") {
+					if (`counter_rd'==1) local conds `conds' & `x_r'<=`1'
+					else if ("`2'"!="") local conds `conds' & `x_r'>`1' & `x_r'<=`2'
+					else local conds `conds' & `x_r'>`1'
+				}
+
+				* LOOP over y-vars
+				local counter_depvar=1
+				foreach depvar of varlist `y_vars_r' {
+				
+					* display text headers
+					if (`ynum'>1) {
+						if ("`controls'`absorb'"!="") local depvar_name : var label `depvar'
+						else local depvar_name `depvar'
+						di as text "{bf:y_var = `depvar_name'}"
+					}
+					
+					* perform regression
+					if ("`reg_verbosity'"=="quietly") capture reg `depvar' `x_r2' `x_r' `wt' if `conds'
+					else capture noisily reg `depvar' `x_r2' `x_r' `wt' if `conds'
+					
+					* store results
+					if (_rc==0) matrix e_b_temp=e(b)
+					else if (_rc==2000) {
+						if ("`reg_verbosity'"=="quietly") di as error "no observations for one of the fit lines. add 'reportreg' for more info."
+						
+						if ("`linetype'"=="lfit") matrix e_b_temp=.,.
+						else /*("`linetype'"=="qfit")*/ matrix e_b_temp=.,.,.
+					}
+					else {
+						error _rc
+						exit _rc
+					}
+					
+					* relabel matrix row			
+					if ("`by'"!="") matrix roweq e_b_temp = "by`counter_by'"
+					if ("`rd'"!="") matrix rownames e_b_temp = "rd`counter_rd'"
+					else matrix rownames e_b_temp = "="
+					
+					* save to y_var matrix
+					if (`counter_by'==1 & `counter_rd'==1) matrix `y`counter_depvar'_coefs'=e_b_temp
+					else matrix `y`counter_depvar'_coefs'=`y`counter_depvar'_coefs' \ e_b_temp
+					
+					* increment depvar counter
+					local ++counter_depvar
+				}
+			
+				* increment rd counter
+				if (`counter_rd'!=1) mac shift
+				local ++counter_rd
+				
+			}
+			
+			* increment by counter
+			local ++counter_by
+			
+		}
+	
+		* relabel matrix column names
+		forvalues i=1/`ynum' {
+			if ("`linetype'"=="lfit") matrix colnames `y`i'_coefs' = "`x_var'" "_cons"
+			else if ("`linetype'"=="qfit") matrix colnames `y`i'_coefs' = "`x_var'^2" "`x_var'" "_cons"
+		}
+	
+	}
+
+	******* Define the bins *******
+	
+	* Specify and/or create the xq var, as necessary
+	if "`xq'"=="" {
+
+		if !(`touse_first'==1 & word("`:sortedby'",1)=="`x_r'") sort `touse' `x_r'
+	
+		if "`discrete'"=="" { /* xq() and discrete are not specified */
+			
+			* Check whether the number of unique values > nquantiles, or <= nquantiles
+			capture mata: characterize_unique_vals_sorted("`x_r'",`touse_first',`touse_last',`nquantiles')
+			
+			if (_rc==0) { /* number of unique values <= nquantiles, set to discrete */
+				local discrete discrete
+				if ("`genxq'"!="") di as text `"note: the x-variable has fewer unique values than the number of bins specified (`nquantiles').  It will therefore be treated as discrete, and genxq() will be ignored"'
+
+				local xq `x_r'
+				local nquantiles=r(r)
+				if ("`by'"=="") {
+					tempname xq_boundaries xq_values
+					matrix `xq_boundaries'=r(boundaries)		
+					matrix `xq_values'=r(values)
+				}
+			}
+			else if (_rc==134) { /* number of unique values > nquantiles, perform binning */
+				if ("`genxq'"!="") local xq `genxq'
+				else tempvar xq
+	
+				if ("`fastxtile'"!="nofastxtile") fastxtile `xq' = `x_r' `wt' in `touse_first'/`touse_last', nq(`nquantiles') randvar(`randvar') randcut(`randcut') randn(`randn')
+				else xtile `xq' = `x_r' `wt' in `touse_first'/`touse_last', nq(`nquantiles')
+
+				if ("`by'"=="") {
+					mata: characterize_unique_vals_sorted("`xq'",`touse_first',`touse_last',`nquantiles')
+
+					if (r(r)!=`nquantiles') {
+						di as text "warning: nquantiles(`nquantiles') was specified, but only `r(r)' were generated. see help file under nquantiles() for explanation."
+						local nquantiles=r(r)
+					}
+
+					tempname xq_boundaries xq_values
+					matrix `xq_boundaries'=r(boundaries)		
+					matrix `xq_values'=r(values)
+				}
+			}
+			else {
+				error _rc
+			}
+
+		}
+		
+		else { /* discrete is specified, xq() & genxq() are not */
+		
+			if ("`controls'`absorb'"!="") di as text "warning: discrete is specified in combination with controls() or absorb(). note that binning takes places after residualization, so the residualized x-variable may contain many more unique values."
+
+			capture mata: characterize_unique_vals_sorted("`x_r'",`touse_first',`touse_last',`=`samplesize'/2')
+		
+			if (_rc==0) {
+				local xq `x_r'
+				local nquantiles=r(r)
+				if ("`by'"=="") {
+					tempname xq_boundaries xq_values
+					matrix `xq_boundaries'=r(boundaries)		
+					matrix `xq_values'=r(values)
+				}
+			}
+			else if (_rc==134) {
+				di as error "discrete specified, but number of unique values is > (sample size/2)"
+				exit 134
+			}
+			else {
+				error _rc
+			}
+		}
+	}
+	else {
+
+		if !(`touse_first'==1 & word("`:sortedby'",1)=="`xq'") sort `touse' `xq'
+		
+		* set nquantiles & boundaries
+		mata: characterize_unique_vals_sorted("`xq'",`touse_first',`touse_last',`=`samplesize'/2')
+		
+		if (_rc==0) {
+			local nquantiles=r(r)
+			if ("`by'"=="") {
+				tempname xq_boundaries xq_values
+				matrix `xq_boundaries'=r(boundaries)		
+				matrix `xq_values'=r(values)
+			}
+		}
+		else if (_rc==134) {
+			di as error "discrete specified, but number of unique values is > (sample size/2)"
+			exit 134
+		}
+		else {
+			error _rc
+		}
+	}
+
+	********** Compute scatter points **********
+
+	if ("`by'"!="") {
+		sort `touse' `by' `xq'
+		tempname by_boundaries
+		mata: characterize_unique_vals_sorted("`by'",`touse_first',`touse_last',`bynum')
+		matrix `by_boundaries'=r(boundaries)
+	}
+
+	forvalues b=1/`bynum' {
+		if ("`by'"!="") {
+			mata: characterize_unique_vals_sorted("`xq'",`=`by_boundaries'[`b',1]',`=`by_boundaries'[`b',2]',`nquantiles')
+			tempname xq_boundaries xq_values
+			matrix `xq_boundaries'=r(boundaries)
+			matrix `xq_values'=r(values)
+		}
+		/* otherwise xq_boundaries and xq_values are defined above in the binning code block */
+
+		* Define x-means
+		tempname xbin_means
+		if ("`discrete'"=="discrete") {
+			matrix `xbin_means'=`xq_values'
+		}
+		else {
+			means_in_boundaries `x_r' `wt', bounds(`xq_boundaries') `medians'
+			matrix `xbin_means'=r(means)
+		}
+
+		* LOOP over y-vars to define y-means
+		local counter_depvar=0
+		foreach depvar of varlist `y_vars_r' {
+			local ++counter_depvar
+
+			means_in_boundaries `depvar' `wt', bounds(`xq_boundaries') `medians'
+
+			* store to matrix
+			if (`b'==1) {
+				tempname y`counter_depvar'_scatterpts
+				matrix `y`counter_depvar'_scatterpts' = `xbin_means',r(means)
+			}
+			else {
+				* make matrices conformable before right appending			
+				local rowdiff=rowsof(`y`counter_depvar'_scatterpts')-rowsof(`xbin_means')
+				if (`rowdiff'==0) matrix `y`counter_depvar'_scatterpts' = `y`counter_depvar'_scatterpts',`xbin_means',r(means)
+				else if (`rowdiff'>0)  matrix `y`counter_depvar'_scatterpts' = `y`counter_depvar'_scatterpts', ( (`xbin_means',r(means)) \ J(`rowdiff',2,.) )
+				else /*(`rowdiff'<0)*/ matrix `y`counter_depvar'_scatterpts' = ( `y`counter_depvar'_scatterpts' \ J(-`rowdiff',colsof(`y`counter_depvar'_scatterpts'),.) ) ,`xbin_means',r(means)
+			}
+		}
+	}
+
+	*********** Perform Graphing ***********
+
+	* If rd is specified, prepare xline parameters
+	if "`rd'"!="" {
+		foreach xval in "`rd'" {
+			local xlines `xlines' xline(`xval', lpattern(dash) lcolor(gs8))
+		}
+	}
+
+	* Fill colors if missing
+	if `"`colors'"'=="" local colors ///
+		navy maroon forest_green dkorange teal cranberry lavender ///
+		khaki sienna emidblue emerald brown erose gold bluishgray ///
+		/* lime magenta cyan pink blue */
+	if `"`mcolors'"'=="" {
+		if (`ynum'==1 & `bynum'==1 & "`linetype'"!="connect") local mcolors `: word 1 of `colors''
+		else local mcolors `colors'
+	}
+	if `"`lcolors'"'=="" {
+		if (`ynum'==1 & `bynum'==1 & "`linetype'"!="connect") local lcolors `: word 2 of `colors''
+		else local lcolors `colors'
+	}
+	local num_mcolor=wordcount(`"`mcolors'"')
+	local num_lcolor=wordcount(`"`lcolors'"')
+
+
+	* Prepare connect & msymbol options
+	if ("`linetype'"=="connect") local connect "c(l)"
+	if "`msymbols'"!="" {
+		local symbol_prefix "msymbol("
+		local symbol_suffix ")"
+	}
+	
+	*** Prepare scatters
+	
+	* c indexes which color is to be used
+	local c=0
+	
+	local counter_series=0
+	
+	* LOOP over by-vars
+	local counter_by=0
+	if ("`by'"=="") local noby="noby"
+	foreach byval in `byvals' `noby' {
+		local ++counter_by
+		
+		local xind=`counter_by'*2-1
+		local yind=`counter_by'*2
+
+		* LOOP over y-vars
+		local counter_depvar=0
+		foreach depvar of varlist `y_vars' {
+			local ++counter_depvar
+			local ++c
+			
+			* LOOP over rows (each row contains a coordinate pair)
+			local row=1
+			local xval=`y`counter_depvar'_scatterpts'[`row',`xind']
+			local yval=`y`counter_depvar'_scatterpts'[`row',`yind']
+			
+			if !missing(`xval',`yval') {
+				local ++counter_series
+				local scatters `scatters' (scatteri
+				if ("`savedata'"!="") {
+					if ("`by'"=="") local savedata_scatters `savedata_scatters' (scatter `depvar' `x_var'
+					else local savedata_scatters `savedata_scatters' (scatter `depvar'_by`counter_by' `x_var'_by`counter_by'
+				}
+			}
+			else {
+				* skip the rest of this loop iteration
+				continue
+			}
+			
+			while (`xval'!=. & `yval'!=.) {
+				local scatters `scatters' `yval' `xval'
+			
+				local ++row
+				local xval=`y`counter_depvar'_scatterpts'[`row',`xind']
+				local yval=`y`counter_depvar'_scatterpts'[`row',`yind']
+			}
+			
+			* Add options
+			local scatter_options `connect' mcolor(`: word `c' of `mcolors'') lcolor(`: word `c' of `lcolors'') `symbol_prefix'`: word `c' of `msymbols''`symbol_suffix'
+			local scatters `scatters', `scatter_options')
+			if ("`savedata'"!="") local savedata_scatters `savedata_scatters', `scatter_options')
+		
+
+			* Add legend
+			if "`by'"=="" {
+				if (`ynum'==1) local legend_labels off
+				else local legend_labels `legend_labels' lab(`counter_series' `depvar')
+			}
+			else {
+				if ("`bylabel'"=="") local byvalname=`byval'
+				else {
+					local byvalname `: label `bylabel' `byval''
+				}
+			
+				if (`ynum'==1) local legend_labels `legend_labels' lab(`counter_series' `byvarname'=`byvalname')
+				else local legend_labels `legend_labels' lab(`counter_series' `depvar': `byvarname'=`byvalname')
+			}
+			if ("`by'"!="" | `ynum'>1) local order `order' `counter_series'
+			
+		}
+		
+	}
+	
+	*** Fit lines
+		
+	if inlist(`"`linetype'"',"lfit","qfit") {
+	
+		* c indexes which color is to be used
+		local c=0
+		
+		local rdnum=wordcount("`rd'")+1
+		
+		tempname fitline_bounds
+		if ("`rd'"=="") matrix `fitline_bounds'=.,.
+		else matrix `fitline_bounds'=.,`=subinstr("`rd'"," ",",",.)',.
+
+		* LOOP over by-vars
+		local counter_by=0
+		if ("`by'"=="") local noby="noby"
+		foreach byval in `byvals' `noby' {
+			local ++counter_by
+			
+			** Set the column for the x-coords in the scatterpts matrix
+			local xind=`counter_by'*2-1
+			
+			* Set the row to start seeking from
+			*     note: each time we seek a coeff, it should be from row (rd_num)(counter_by-1)+counter_rd
+			local row0=( `rdnum' ) * (`counter_by' - 1)
+			
+			
+			* LOOP over y-vars
+			local counter_depvar=0
+			foreach depvar of varlist `y_vars_r' {
+				local ++counter_depvar
+				local ++c
+				
+				* Find lower and upper bounds for the fit line
+				matrix `fitline_bounds'[1,1]=`y`counter_depvar'_scatterpts'[1,`xind']
+				
+				local fitline_ub_rindex=`nquantiles'
+				local fitline_ub=.
+				while `fitline_ub'==. {
+					local fitline_ub=`y`counter_depvar'_scatterpts'[`fitline_ub_rindex',`xind']
+					local --fitline_ub_rindex
+				}
+				matrix `fitline_bounds'[1,`rdnum'+1]=`fitline_ub'
+		
+				* LOOP over rd intervals
+				forvalues counter_rd=1/`rdnum' {
+					
+					if (`"`linetype'"'=="lfit") {
+						local coef_quad=0
+						local coef_lin=`y`counter_depvar'_coefs'[`row0'+`counter_rd',1]
+						local coef_cons=`y`counter_depvar'_coefs'[`row0'+`counter_rd',2]
+					}
+					else if (`"`linetype'"'=="qfit") {
+						local coef_quad=`y`counter_depvar'_coefs'[`row0'+`counter_rd',1]
+						local coef_lin=`y`counter_depvar'_coefs'[`row0'+`counter_rd',2]
+						local coef_cons=`y`counter_depvar'_coefs'[`row0'+`counter_rd',3]
+					}
+					
+					if !missing(`coef_quad',`coef_lin',`coef_cons') {
+						local leftbound=`fitline_bounds'[1,`counter_rd']
+						local rightbound=`fitline_bounds'[1,`counter_rd'+1]
+					
+						local fits `fits' (function `coef_quad'*x^2+`coef_lin'*x+`coef_cons', range(`leftbound' `rightbound') lcolor(`: word `c' of `lcolors''))
+					}
+				}
+			}
+		}
+	}
+	
+	* Prepare y-axis title
+	if (`ynum'==1) local ytitle `y_vars'
+	else if (`ynum'==2) local ytitle : subinstr local y_vars " " " and "
+	else local ytitle : subinstr local y_vars " " "; ", all
+
+	* Display graph
+	local graphcmd twoway `scatters' `fits', graphregion(fcolor(white)) `xlines' xtitle(`x_var') ytitle(`ytitle') legend(`legend_labels' order(`order')) `options'
+	if ("`savedata'"!="") local savedata_graphcmd twoway `savedata_scatters' `fits', graphregion(fcolor(white)) `xlines' xtitle(`x_var') ytitle(`ytitle') legend(`legend_labels' order(`order')) `options'
+	`graphcmd'
+	
+	****** Save results ******
+	
+	* Save graph
+	if `"`savegraph'"'!="" {
+		* check file extension using a regular expression
+		if regexm(`"`savegraph'"',"\.[a-zA-Z0-9]+$") local graphextension=regexs(0)
+		
+		if inlist(`"`graphextension'"',".gph","") graph save `"`savegraph'"', `replace'
+		else graph export `"`savegraph'"', `replace'
+	}
+
+	* Save data
+	if ("`savedata'"!="") {
+	
+		*** Save a CSV containing the scatter points
+		tempname savedatafile
+		file open `savedatafile' using `"`savedata'.csv"', write text `replace'
+		
+		* LOOP over rows
+		forvalues row=0/`nquantiles' {
+		
+			*** Put the x-variable at the left
+			* LOOP over by-vals
+			forvalues counter_by=1/`bynum' {
+			
+				if (`row'==0) { /* write variable names */
+					if "`by'"!="" local bynlabel _by`counter_by'
+					file write `savedatafile' "`x_var'`bynlabel',"
+				}
+				else { /* write data values */
+					if (`row'<=`=rowsof(`y1_scatterpts')') file write `savedatafile' (`y1_scatterpts'[`row',`counter_by'*2-1]) ","
+					else file write `savedatafile' ".,"
+				}
+			}
+			
+			*** Now y-variables at the right
+			
+			* LOOP over y-vars
+			local counter_depvar=0
+			foreach depvar of varlist `y_vars' {
+				local ++counter_depvar
+
+				* LOOP over by-vals
+				forvalues counter_by=1/`bynum' {
+				
+				
+					if (`row'==0) { /* write variable names */
+						if "`by'"!="" local bynlabel _by`counter_by'
+						file write `savedatafile' "`depvar'`bynlabel'"
+					}
+					else { /* write data values */
+						if (`row'<=`=rowsof(`y`counter_depvar'_scatterpts')') file write `savedatafile' (`y`counter_depvar'_scatterpts'[`row',`counter_by'*2])
+						else file write `savedatafile' "."
+					}
+					
+					* unless this is the last variable in the dataset, add a comma
+					if !(`counter_depvar'==`ynum' & `counter_by'==`bynum') file write `savedatafile' ","
+					
+				} /* end by-val loop */
+				
+			} /* end y-var loop */
+			
+			file write `savedatafile' _n
+			
+		} /* end row loop */
+
+		file close `savedatafile'
+		di as text `"(file `savedata'.csv written containing saved data)"'
+		
+		
+		
+		*** Save a do-file with the commands to generate a nicely labeled dataset and re-create the binscatter graph
+		
+		file open `savedatafile' using `"`savedata'.do"', write text `replace'
+		
+		file write `savedatafile' `"insheet using `savedata'.csv"' _n _n
+		
+		if "`by'"!="" {
+			foreach var of varlist `x_var' `y_vars' {
+				local counter_by=0
+				foreach byval in `byvals' {
+					local ++counter_by
+					if ("`bylabel'"=="") local byvalname=`byval'
+					else {
+						local byvalname `: label `bylabel' `byval''
+					}
+					file write `savedatafile' `"label variable `var'_by`counter_by' "`var'; `byvarname'==`byvalname'""' _n
+				}
+			}
+			file write `savedatafile' _n
+		}
+		
+		file write `savedatafile' `"`savedata_graphcmd'"' _n
+		
+		file close `savedatafile'
+		di as text `"(file `savedata'.do written containing commands to process saved data)"'
+		
+	}
+
+	*** Return items
+	ereturn post, esample(`touse')
+	
+	ereturn scalar N = `samplesize'
+	
+	ereturn local graphcmd `"`graphcmd'"'
+	if inlist("`linetype'","lfit","qfit") {
+		forvalues yi=`ynum'(-1)1 {
+			ereturn matrix y`yi'_coefs=`y`yi'_coefs'
+		}
+	}
+	
+	if ("`rd'"!="") {
+		tempname rdintervals
+		matrix `rdintervals' = (. \ `=subinstr("`rd'"," ","\",.)' ) , ( `=subinstr("`rd'"," ","\",.)' \ .)
+
+		forvalues i=1/`=rowsof(`rdintervals')' {
+			local rdintervals_labels `rdintervals_labels' rd`i'
+		}
+		matrix rownames `rdintervals' = `rdintervals_labels'
+		matrix colnames `rdintervals' = gt lt_eq
+		ereturn matrix rdintervals=`rdintervals'
+	}
+	
+	if ("`by'"!="" & "`by'"=="`byvarname'") { /* if a numeric by-variable was specified */
+		forvalues i=1/`=rowsof(`byvalmatrix')' {
+			local byvalmatrix_labels `byvalmatrix_labels' by`i'
+		}
+		matrix rownames `byvalmatrix' = `byvalmatrix_labels'
+		matrix colnames `byvalmatrix' = `by'
+		ereturn matrix byvalues=`byvalmatrix'
+	}
+	
+end
+
+
+**********************************
+
+* Helper programs
+
+program define means_in_boundaries, rclass
+	version 12.1
+
+	syntax varname(numeric) [aweight fweight], BOUNDsmat(name) [MEDians]
+	
+	* Create convenient weight local
+	if ("`weight'"!="") local wt [`weight'`exp']
+	
+	local r=rowsof(`boundsmat')
+	matrix means=J(`r',1,.)
+	
+	if ("`medians'"!="medians") {
+		forvalues i=1/`r' {
+			sum `varlist' in `=`boundsmat'[`i',1]'/`=`boundsmat'[`i',2]' `wt', meanonly
+			matrix means[`i',1]=r(mean)
+		}
+	}
+	else {
+		forvalues i=1/`r' {
+			_pctile `varlist' in `=`boundsmat'[`i',1]'/`=`boundsmat'[`i',2]' `wt', percentiles(50)
+			matrix means[`i',1]=r(r1)
+		}
+	}
+	
+	return clear
+	return matrix means=means
+
+end
+
+*** copy of: version 1.21  8oct2013  Michael Stepner, [email protected]
+program define fastxtile, rclass
+	version 11
+
+	* Parse weights, if any
+	_parsewt "aweight fweight pweight" `0' 
+	local 0  "`s(newcmd)'" /* command minus weight statement */
+	local wt "`s(weight)'"  /* contains [weight=exp] or nothing */
+
+	* Extract parameters
+	syntax newvarname=/exp [if] [in] [,Nquantiles(integer 2) Cutpoints(varname numeric) ALTdef ///
+		CUTValues(numlist ascending) randvar(varname numeric) randcut(real 1) randn(integer -1)]
+
+	* Mark observations which will be placed in quantiles
+	marksample touse, novarlist
+	markout `touse' `exp'
+	qui count if `touse'
+	local popsize=r(N)
+
+	if "`cutpoints'"=="" & "`cutvalues'"=="" { /***** NQUANTILES *****/
+		if `"`wt'"'!="" & "`altdef'"!="" {
+			di as error "altdef option cannot be used with weights"
+			exit 198
+		}
+		
+		if `randn'!=-1 {
+			if `randcut'!=1 {
+				di as error "cannot specify both randcut() and randn()"
+				exit 198
+			}
+			else if `randn'<1 {
+				di as error "randn() must be a positive integer"
+				exit 198
+			}
+			else if `randn'>`popsize' {
+				di as text "randn() is larger than the population. using the full population."
+				local randvar=""
+			}
+			else {
+				local randcut=`randn'/`popsize'
+				
+				if "`randvar'"!="" {
+					qui sum `randvar', meanonly
+					if r(min)<0 | r(max)>1 {
+						di as error "with randn(), the randvar specified must be in [0,1] and ought to be uniformly distributed"
+						exit 198
+					}
+				}
+			}
+		}
+
+		* Check if need to gen a temporary uniform random var
+		if "`randvar'"=="" {
+			if (`randcut'<1 & `randcut'>0) { 
+				tempvar randvar
+				gen `randvar'=runiform()
+			}
+			* randcut sanity check
+			else if `randcut'!=1 {
+				di as error "if randcut() is specified without randvar(), a uniform r.v. will be generated and randcut() must be in (0,1)"
+				exit 198
+			}
+		}
+
+		* Mark observations used to calculate quantile boundaries
+		if ("`randvar'"!="") {
+			tempvar randsample
+			mark `randsample' `wt' if `touse' & `randvar'<=`randcut'
+		}
+		else {
+			local randsample `touse'
+		}
+
+		* Error checks
+		qui count if `randsample'
+		local samplesize=r(N)
+		if (`nquantiles' > r(N) + 1) {
+			if ("`randvar'"=="") di as error "nquantiles() must be less than or equal to the number of observations [`r(N)'] plus one"
+			else di as error "nquantiles() must be less than or equal to the number of sampled observations [`r(N)'] plus one"
+			exit 198
+		}
+		else if (`nquantiles' < 2) {
+			di as error "nquantiles() must be greater than or equal to 2"
+			exit 198
+		}
+
+		* Compute quantile boundaries
+		_pctile `exp' if `randsample' `wt', nq(`nquantiles') `altdef'
+
+		* Store quantile boundaries in list
+		forvalues i=1/`=`nquantiles'-1' {
+			local cutvallist `cutvallist' r(r`i')
+		}
+	}
+	else if "`cutpoints'"!="" { /***** CUTPOINTS *****/
+	
+		* Parameter checks
+		if "`cutvalues'"!="" {
+			di as error "cannot specify both cutpoints() and cutvalues()"
+			exit 198
+		}		
+		if "`wt'"!="" | "`randvar'"!="" | "`ALTdef'"!="" | `randcut'!=1 | `nquantiles'!=2 | `randn'!=-1 {
+			di as error "cutpoints() cannot be used with nquantiles(), altdef, randvar(), randcut(), randn() or weights"
+			exit 198
+		}
+
+		tempname cutvals
+		qui tab `cutpoints', matrow(`cutvals')
+		
+		if r(r)==0 {
+			di as error "cutpoints() all missing"
+			exit 2000
+		}
+		else {
+			local nquantiles = r(r) + 1
+			
+			forvalues i=1/`r(r)' {
+				local cutvallist `cutvallist' `cutvals'[`i',1]
+			}
+		}
+	}
+	else { /***** CUTVALUES *****/
+		if "`wt'"!="" | "`randvar'"!="" | "`ALTdef'"!="" | `randcut'!=1 | `nquantiles'!=2 | `randn'!=-1 {
+			di as error "cutvalues() cannot be used with nquantiles(), altdef, randvar(), randcut(), randn() or weights"
+			exit 198
+		}
+		
+		* parse numlist
+		numlist "`cutvalues'"
+		local cutvallist `"`r(numlist)'"'
+		local nquantiles=wordcount(`"`r(numlist)'"')+1
+	}
+
+	* Pick data type for quantile variable
+	if (`nquantiles'<=100) local qtype byte
+	else if (`nquantiles'<=32,740) local qtype int
+	else local qtype long
+
+	* Create quantile variable
+	local cutvalcommalist : subinstr local cutvallist " " ",", all
+	qui gen `qtype' `varlist'=1+irecode(`exp',`cutvalcommalist') if `touse'
+	label var `varlist' "`nquantiles' quantiles of `exp'"
+	
+	* Return values
+	if ("`samplesize'"!="") return scalar n = `samplesize'
+	else return scalar n = .
+	
+	return scalar N = `popsize'
+	
+	tokenize `"`cutvallist'"'
+	forvalues i=`=`nquantiles'-1'(-1)1 {
+		return scalar r`i' = ``i''
+	}
+
+end
+
+
+version 12.1
+set matastrict on
+
+mata:
+
+void characterize_unique_vals_sorted(string scalar var, real scalar first, real scalar last, real scalar maxuq) {
+	// Inputs: a numeric variable, a starting & ending obs #, and a maximum number of unique values
+	// Requires: the data to be sorted on the specified variable within the observation boundaries given
+	//				(no check is made that this requirement is satisfied)
+	// Returns: the number of unique values found
+	//			the unique values found
+	//			the observation boundaries of each unique value in the dataset
+	
+	
+	// initialize returned results
+	real scalar Nunique
+	Nunique=0
+
+	real matrix values
+	values=J(maxuq,1,.)
+	
+	real matrix boundaries
+	boundaries=J(maxuq,2,.)
+
+	// initialize computations
+	real scalar var_index
+	var_index=st_varindex(var)
+	
+	real scalar curvalue
+	real scalar prevvalue
+	
+	// perform computations
+	real scalar obs
+	for (obs=first; obs<=last; obs++) {
+		curvalue=_st_data(obs,var_index)
+		
+		if (curvalue!=prevvalue) {
+			Nunique++
+			if (Nunique<=maxuq) {
+				prevvalue=curvalue
+				values[Nunique,1]=curvalue
+				boundaries[Nunique,1]=obs
+				if (Nunique>1) boundaries[Nunique-1,2]=obs-1
+			}
+			else {
+				exit(error(134))
+			}
+			
+		}
+	}
+	boundaries[Nunique,2]=last
+	
+	// return results
+	stata("return clear")
+	
+	st_numscalar("r(r)",Nunique)
+	st_matrix("r(values)",values[1..Nunique,.])
+	st_matrix("r(boundaries)",boundaries[1..Nunique,.])
+
+}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/b/binscatter.sthlp

@@ -0,0 +1,332 @@
+{smcl}
+{* *! version 7.02  24nov2013}{...}
+{viewerjumpto "Syntax" "binscatter##syntax"}{...}
+{viewerjumpto "Description" "binscatter##description"}{...}
+{viewerjumpto "Options" "binscatter##options"}{...}
+{viewerjumpto "Examples" "binscatter##examples"}{...}
+{viewerjumpto "Saved results" "binscatter##saved_results"}{...}
+{viewerjumpto "Author" "binscatter##author"}{...}
+{viewerjumpto "Acknowledgements" "binscatter##acknowledgements"}{...}
+{title:Title}
+
+{p2colset 5 19 21 2}{...}
+{p2col :{hi:binscatter} {hline 2}}Binned scatterplots{p_end}
+{p2colreset}{...}
+
+
+{marker syntax}{title:Syntax}
+
+{p 8 15 2}
+{cmd:binscatter}
+{varlist} {ifin}
+{weight}
+[{cmd:,} {it:options}]
+
+
+{pstd}
+where {it:varlist} is 
+{p_end}
+		{it:y_1} [{it:y_2} [...]] {it:x}
+
+{synoptset 26 tabbed}{...}
+{synopthdr :options}
+{synoptline}
+{syntab :Main}
+{synopt :{opth by(varname)}}plot separate series for each group (see {help binscatter##by_notes:important notes below}){p_end}
+{synopt :{opt med:ians}}plot within-bin medians instead of means{p_end}
+
+{syntab :Bins}
+{synopt :{opth n:quantiles(#)}}number of equal-sized bins to be created; default is {bf:20}{p_end}
+{synopt :{opth gen:xq(varname)}}generate quantile variable containing the bins{p_end}
+{synopt :{opt discrete}}each x-value to be used as a separate bin{p_end}
+{synopt :{opth xq(varname)}}variable which already contains bins; bins therefore not recomputed{p_end}
+
+{syntab :Controls}
+{synopt :{opth control:s(varlist)}}residualize the x & y variables on controls before plotting{p_end}
+{synopt :{opth absorb(varname)}}residualize the x & y variables on a categorical variable{p_end}
+{synopt :{opt noa:ddmean}}do not add the mean of each variable back to its residuals{p_end}
+
+{syntab :Fit Line}
+{synopt :{opth line:type(binscatter##linetype:linetype)}}type of fit line; default is {bf:lfit}, may also be {bf:qfit}, {bf:connect}, or {bf:none}{p_end}
+{synopt :{opth rd(numlist)}}create regression discontinuity at x-values{p_end}
+{synopt :{opt reportreg}}display the regressions used to estimate the fit lines{p_end}
+
+{syntab :Graph Style}
+{synopt :{cmdab:col:ors(}{it:{help colorstyle}list}{cmd:)}}ordered list of colors{p_end}
+{synopt :{cmdab:mc:olors(}{it:{help colorstyle}list}{cmd:)}}overriding ordered list of colors for the markers{p_end}
+{synopt :{cmdab:lc:olors(}{it:{help colorstyle}list}{cmd:)}}overriding ordered list of colors for the lines{p_end}
+{synopt :{cmdab:m:symbols(}{it:{help symbolstyle}list}{cmd:)}}ordered list of symbols{p_end}
+{synopt :{it:{help twoway_options}}}{help title options:titles}, {help legend option:legends}, {help axis options:axes}, added {help added line options:lines} and {help added text options:text},
+	{help region options:regions}, {help name option:name}, {help aspect option:aspect ratio}, etc.{p_end}
+
+{syntab :Save Output}
+{synopt :{opt savegraph(filename)}}save graph to file; format automatically detected from extension [ex: .gph .jpg .png]{p_end}
+{synopt :{opt savedata(filename)}}save {it:filename}.csv containg scatterpoint data, and {it:filename}.do to process data into graph{p_end}
+{synopt :{opt replace}}overwrite existing files{p_end}
+
+{syntab :fastxtile options}
+{synopt :{opt nofastxtile}}use xtile instead of fastxtile{p_end}
+{synopt :{opth randvar(varname)}}use {it:varname} to sample observations when computing quantile boundaries{p_end}
+{synopt :{opt randcut(#)}}upper bound on {cmd:randvar()} used to cut the sample; default is {cmd:randcut(1)}{p_end}
+{synopt :{opt randn(#)}}number of observations to sample when computing quantile boundaries{p_end}
+{synoptline}
+{p 4 6 2}
+{opt aweight}s and {opt fweight}s are allowed;
+see {help weight}.
+{p_end}
+
+
+{marker description}{...}
+{title:Description}
+
+{pstd}
+{opt binscatter} generates binned scatterplots, and is optimized for speed in large datasets.
+
+{pstd}
+Binned scatterplots provide a non-parametric way of visualizing the relationship between two variables.
+With a large number of observations, a scatterplot that plots every data point would become too crowded
+to interpret visually.  {cmd:binscatter} groups the x-axis variable into equal-sized bins, computes the
+mean of the x-axis and y-axis variables within each bin, then creates a scatterplot of these data points.
+The result is a non-parametric visualization of the conditional expectation function.
+
+{pstd}
+{opt binscatter} provides built-in options to control for covariates before plotting the relationship
+(see {help binscatter##controls:Controls}).  Additionally, {cmd:binscatter} will plot fit lines based
+on the underlying data, and can automatically handle regression discontinuities (see {help binscatter##fit_line:Fit Line}).
+
+
+{marker options}{...}
+{title:Options}
+
+{dlgtab:Main}
+
+{marker by_notes}{...}
+{phang}{opth by(varname)} plots a separate series for each by-value.  Both numeric and string by-variables
+are supported, but numeric by-variables will have faster run times.
+
+{pmore}Users should be aware of the two ways in which {cmd:binscatter} does not condition on by-values:
+
+{phang3}1) When combined with {opt controls()} or {opt absorb()}, the program residualizes using the restricted model in which each covariate
+has the same coefficient in each by-value sample.  It does not run separate regressions for each by-value.  If you wish to control for 
+covariates using a different model, you can residualize your x- and y-variables beforehand using your desired model then run {cmd:binscatter}
+on the residuals you constructed.
+
+{phang3}2) When not combined with {opt discrete} or {opt xq()}, the program constructs a single set of bins
+using the unconditional quantiles of the x-variable.  It does not bin the x-variable separately for each by-value.
+If you wish to use a different binning procedure (such as constructing equal-sized bins separately for each
+by-value), you can construct a variable containing your desired bins beforehand, then run {cmd:binscatter} with {opt xq()}.
+
+{phang}{opt med:ians} creates the binned scatterplot using the median x- and y-value within each bin, rather than the mean.
+This option only affects the scatter points; it does not, for instance, cause {opt linetype(lfit)}
+to use quantile regression instead of OLS when drawing a fit line.
+
+{dlgtab:Bins}
+
+{phang}{opth n:quantiles(#)} specifies the number of equal-sized bins to be created.  This is equivalent to the number of
+points in each series.  The default is {bf:20}. If the x-variable has fewer
+unique values than the number of bins specified, then {opt discrete} will be automatically invoked, and no
+binning will be performed.
+This option cannot be combined with {opt discrete} or {opt xq()}.
+
+{pmore}
+Binning is performed after residualization when combined with {opt controls()} or {opt absorb()}.
+Note that the binning procedure is equivalent to running xtile, which in certain cases will generate
+fewer quantile categories than specified. (e.g. {stata sysuse auto}; {stata xtile temp=mpg, nq(20)}; {stata tab temp})
+  
+{phang}{opth gen:xq(varname)} creates a categorical variable containing the computed bins.
+This option cannot be combined with {opt discrete} or {opt xq()}.
+
+{phang}{opt discrete} specifies that the x-variable is discrete and that each x-value is to be treated as
+a separate bin. {cmd:binscatter} will therefore plot the mean y-value associated with each x-value.
+This option cannot be combined with {opt nquantiles()}, {opt genxq()} or {opt xq()}.
+
+{pmore}
+In most cases, {opt discrete} should not be combined with {opt controls()} or {opt absorb()}, since residualization occurs before binning,
+and in general the residual of a discrete variable will not be discrete.
+
+{phang}{opth xq(varname)} specifies a categorical variable that contains the bins to be used, instead of {cmd:binscatter} generating them.
+This option is typically used to avoid recomputing the bins needlessly when {cmd:binscatter} is being run repeatedly on the same sample
+and with the same x-variable.
+It may be convenient to use {opt genxq(binvar)} in the first iteration, and specify {opt xq(binvar)} in subsequent iterations.
+Computing quantiles is computationally intensive in large datasets, so avoiding repetition can reduce run times considerably.
+This option cannot be combined with {opt nquantiles()}, {opt genxq()} or {opt discrete}.
+
+{pmore}
+Care should be taken when combining {opt xq()} with {opt controls()} or {opt absorb()}.  Binning takes place after residualization,
+so if the sample changes or the control variables change, the bins ought to be recomputed as well.
+
+{marker controls}{...}
+{dlgtab:Controls}
+
+{phang}{opth control:s(varlist)} residualizes the x-variable and y-variables on the specified controls before binning and plotting.
+To do so, {cmd:binscatter} runs a regression of each variable on the controls, generates the residuals, and adds the sample mean of
+each variable back to its residuals.
+
+{phang}{opth absorb(varname)} absorbs fixed effects in the categorical variable from the x-variable and y-variables before binning and plotting,
+To do so, {cmd:binscatter} runs an {helpb areg} of each variable with {it:absorb(varname)} and any {opt controls()} specified.  It then generates the
+residuals and adds the sample mean of each variable back to its residuals.
+
+{phang}{opt noa:ddmean} prevents the sample mean of each variable from being added back to its residuals, when combined with {opt controls()} or {opt absorb()}.
+
+{marker fit_line}{...}
+{dlgtab:Fit Line}
+
+{marker linetype}{...}
+{phang}{opth line:type(binscatter##linetype:linetype)} specifies the type of line plotted on each series.
+The default is {bf:lfit}, which plots a linear fit line.  Other options are {bf:qfit} for a quadratic fit line,
+{bf:connect} for connected points, and {bf:none} for no line.
+
+{pmore}Linear or quadratic fit lines are estimated using the underlying data, not the binned scatter points. When combined with
+{opt controls()} or {opt absorb()}, the fit line is estimated after the variables have been residualized.
+
+{phang}{opth rd(numlist)} draws a dashed vertical line at the specified x-values and generates regression discontinuities when combined with {opt line(lfit|qfit)}.
+Separate fit lines will be estimated below and above each discontinuity.  These estimations are performed using the underlying data, not the binned scatter points.
+
+{pmore}The regression discontinuities do not affect the binned scatter points in any way.
+Specifically, a bin may contain a discontinuity within its range, and therefore include data from both sides of the discontinuity.
+
+{phang}{opt reportreg} displays the regressions used to estimate the fit lines in the results window.
+
+{dlgtab:Graph Style}
+
+{phang}{cmdab:col:ors(}{it:{help colorstyle}list}{cmd:)} specifies an ordered list of colors for each series
+
+{phang}{cmdab:mc:olors(}{it:{help colorstyle}list}{cmd:)} specifies an ordered list of colors for the markers of each series, which overrides any list provided in {opt colors()}
+
+{phang}{cmdab:lc:olors(}{it:{help colorstyle}list}{cmd:)} specifies an ordered list of colors for the line of each series, which overrides any list provided in {opt colors()}
+
+{phang}{cmdab:m:symbols(}{it:{help symbolstyle}list}{cmd:)} specifies an ordered list of symbols for each series
+
+{phang}{it:{help twoway_options}}:
+
+{pmore}Any unrecognized options added to {cmd:binscatter} are appended to the end of the twoway command which generates the
+binned scatter plot.
+
+{pmore}These can be used to control the graph {help title options:titles},
+{help legend option:legends}, {help axis options:axes}, added {help added line options:lines} and {help added text options:text},
+{help region options:regions}, {help name option:name}, {help aspect option:aspect ratio}, etc.
+
+{dlgtab:Save Output}
+
+{phang}{opt savegraph(filename)} saves the graph to a file.  The format is automatically detected from the extension specified [ex: {bf:.gph .jpg .png}],
+and either {cmd:graph save} or {cmd:graph export} is run.  If no file extension is specified {bf:.gph} is assumed.
+
+{phang}{opt savedata(filename)} saves {it:filename}{bf:.csv} containing the binned scatterpoint data, and {it:filename}{bf:.do} which
+loads the scatterpoint data, labels the variables, and plots the binscatter graph.
+
+{pmore}Note that the saved result {bf:e(cmd)} provides an alternative way of capturing the binscatter graph and editing it.
+
+{phang}{opt replace} specifies that files be overwritten if they alredy exist
+
+{dlgtab:fastxtile options}
+
+{phang}{opt nofastxtile} forces the use of {cmd:xtile} instead of {cmd:fastxtile} to compute bins.  There is no situation where this should
+be necessary or useful.  The {cmd:fastxile} program generates identical results to {cmd:xtile}, but runs faster on large datasets, and has
+additional options for random sampling which may be useful to increase speed.
+
+{pmore}{cmd:fastxtile} is built into the {cmd:binscatter} code, but may also be installed
+separately from SSC ({stata ssc install fastxtile:click here to install}) for use outside of {cmd:binscatter}.
+
+{phang}{opth randvar(varname)} requests that {it:varname} be used to select a
+sample of observations when computing the quantile boundaries.  Sampling increases
+the speed of the binning procedure, but generates bins which are only approximately equal-sized
+due to sampling error.  It is possible to omit this option and still perform random sampling from U[0,1]
+as described below in {opt randcut()} and {opt randn()}.
+
+{phang}{opt randcut(#)} specifies the upper bound on the variable contained
+in {opt randvar(varname)}. Quantile boundaries are approximated using observations for which
+{opt randvar()} <= #.  If no variable is specified in {opt randvar()},
+a standard uniform random variable is generated. The default is {cmd:randcut(1)}.
+This option cannot be combined with {opt randn()}.
+
+{phang}{opt randn(#)} specifies an approximate number of observations to sample when
+computing the quantile boundaries. Quantile boundaries are approximated using observations
+for which a uniform random variable is <= #/N. The exact number of observations
+sampled may therefore differ from #, but it equals # in expectation. When this option is
+combined with {opth randvar(varname)}, {it:varname} ought to be distributed U[0,1].
+Otherwise, a standard uniform random variable is generated. This option cannot be combined
+with {opt randcut()}.
+
+
+{marker examples}{...}
+{title:Examples}
+
+{pstd}Load the 1988 extract of the National Longitudinal Survey of Young Women and Mature Women.{p_end}
+{phang2}. {stata sysuse nlsw88}{p_end}
+{phang2}. {stata keep if inrange(age,35,44) & inrange(race,1,2)}{p_end}
+
+{pstd}What is the relationship between job tenure and wages?{p_end}
+{phang2}. {stata scatter wage tenure}{p_end}
+{phang2}. {stata binscatter wage tenure}{p_end}
+
+{pstd}The scatter was too crowded to be easily interpetable. The binscatter is cleaner, but a linear fit looks unreasonable.{p_end}
+
+{pstd}Try a quadratic fit.{p_end}
+{phang2}. {stata binscatter wage tenure, line(qfit)}{p_end}
+
+{pstd}We can also plot a linear regression discontinuity.{p_end}
+{phang2}. {stata binscatter wage tenure, rd(2.5)}{p_end}
+
+{pstd} What is the relationship between age and wages?{p_end}
+{phang2}. {stata scatter wage age}{p_end}
+{phang2}. {stata binscatter wage age}{p_end}
+
+{pstd} The binscatter is again much easier to interpret. (Note that {cmd:binscatter} automatically
+used each age as a discrete bin, since there are fewer than 20 unique values.){p_end}
+
+{pstd}How does the relationship vary by race?{p_end}
+{phang2}. {stata binscatter wage age, by(race)}{p_end}
+
+{pstd} The relationship between age and wages is very different for whites and blacks. But what if we control for occupation?{p_end}
+{phang2}. {stata binscatter wage age, by(race) absorb(occupation)}{p_end}
+
+{pstd} A very different picture emerges.  Let's label this graph nicely.{p_end}
+{phang2}. {stata binscatter wage age, by(race) absorb(occupation) msymbols(O T) xtitle(Age) ytitle(Hourly Wage) legend(lab(1 White) lab(2 Black))}{p_end}
+
+
+{marker saved_results}{...}
+{title:Saved Results}
+
+{pstd}
+{cmd:binscatter} saves the following in {cmd:e()}:
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Scalars}{p_end}
+{synopt:{cmd:e(N)}}number of observations{p_end}
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Macros}{p_end}
+{synopt:{cmd:e(graphcmd)}}twoway command used to generate graph, which does not depend on loaded data{p_end}
+{p 30 30 2}Note: it is often important to reference this result using `"`{bf:e(graphcmd)}'"'
+rather than {bf:e(graphcmd)} in order to avoid truncation due to Stata's character limit for strings.
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Matrices}{p_end}
+{synopt:{cmd:e(byvalues)}}ordered list of by-values {it:(if numeric by-variable specified)}{p_end}
+{synopt:{cmd:e(rdintervals)}}ordered list of rd intervals {it:(if rd specified)}{p_end}
+{synopt:{cmd:e(y#_coefs)}}fit line coefficients for #th y-variable {it:(if lfit or qfit specified)}{p_end}
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Functions}{p_end}
+{synopt:{cmd:e(sample)}}marks sample{p_end}
+{p2colreset}{...}
+
+
+{marker author}{...}
+{title:Author}
+
+{pstd}Michael Stepner{p_end}
+{pstd}[email protected]{p_end}
+
+
+{marker acknowledgements}{...}
+{title:Acknowledgements}
+
+{pstd}The present version of {cmd:binscatter} is based on a program first written by Jessica Laird.
+
+{pstd}This program was developed under the guidance and direction of Raj Chetty and John
+Friedman.  Laszlo Sandor provided suggestions which improved the program considerably, and offered abundant help
+testing it.
+
+{pstd}Thank you also to the users of early versions of the program who devoted time to reporting
+the bugs that they encountered.

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/backup.trk

@@ -0,0 +1,447 @@
+* 00000021
+*! version 1.0.0
+* Do not erase or edit this file
+* It is used by Stata to track the ado and help
+* files you have installed.
+
+S http://fmwww.bc.edu/repec/bocode/l
+N listtab.pkg
+D 12 Feb 2014
+U 1
+d 'LISTTAB': module to list variables as rows of a TeX, HTML or word processor table
+d 
+d   listtab outputs a list of variables to the Stata log or to a
+d file as TeX, HTML or word processor table rows, which can then be
+d inserted into a TeX, HTML or word processor table by cutting and
+d pasting and/or file linking and/or embedding (eg using the TeX
+d \input command). listtab produces the table rows, but may also
+d produce a set of header lines before the table rows and/or footer
+d lines after the table rows, containing preambles and/or table
+d definitions and/or table headers and/or table footers, as
+d specified by the user.
+d 
+d KW: output
+d KW: LaTeX
+d KW: HTML
+d KW: RTF
+d 
+d Requires: Stata version 11.0
+d 
+d Distribution-Date: 20121105
+d 
+d Author: Roger Newson, National Heart and Lung Institute at Imperial College London
+d Support: email r.newson@@imperial.ac.uk
+d 
+f l/listtab.ado
+f l/listtab.sthlp
+f l/listtab_rstyle.ado
+f l/listtab_rstyle.sthlp
+f l/listtab_vars.ado
+f l/listtab_vars.sthlp
+e
+S http://fmwww.bc.edu/repec/bocode/e
+N estout.pkg
+D 13 Feb 2015
+U 4
+d 'ESTOUT': module to make regression tables
+d 
+d  estout produces a table of regression results from one or
+d several models for use with spreadsheets, LaTeX, HTML, or a
+d word-processor table. eststo stores a quick copy of the active
+d estimation results for later tabulation. esttab is a wrapper for
+d estout. It displays a pretty looking publication-style regression
+d table without much typing. estadd adds additional results to the
+d e()-returns for one or several models previously fitted and
+d stored. This package subsumes the previously circulated esto,
+d esta, estadd,  and estadd_plus. An earlier version of estout is
+d available  as estout1.
+d 
+d KW: estimates
+d KW: LaTeX
+d KW: HTML
+d KW: word processor
+d KW: output
+d 
+d Requires: Stata version 8.2
+d 
+d Distribution-Date: 20140604
+d 
+d Author: Ben Jann, University of Bern
+d Support: email jann@@soz.unibe.ch
+d 
+f _/_eststo.ado
+f _/_eststo.hlp
+f e/estadd.ado
+f e/estadd.hlp
+f e/estout.ado
+f e/estout.hlp
+f e/eststo.ado
+f e/eststo.hlp
+f e/estpost.ado
+f e/estpost.hlp
+f e/esttab.ado
+f e/esttab.hlp
+e
+S http://fmwww.bc.edu/repec/bocode/t
+N tabout.pkg
+D 13 Feb 2015
+U 5
+d 'TABOUT': module to export publication quality cross-tabulations
+d 
+d  tabout is a table building program for oneway and twoway
+d tables of frequencies and percentages, and for summary tables. It
+d produces publication quality tables for export to a text file.
+d These tables can then be used with spreadsheets, word processors,
+d web browsers or compilers like LaTeX. The tables produced by
+d tabout allow multiple panels so that a number of variables can be
+d included in the one table. tabout also provides standard errors
+d and confidence intervals, as well as a range of table statistics
+d (chi2 etc). The output from tabout matches Stata's tabulate, most
+d of tabstat and some of table.
+d 
+d KW: tables
+d KW: latex
+d KW: html
+d KW: delimited text
+d 
+d Requires: Stata version 9.2
+d 
+d Distribution-Date: 20150112
+d 
+d Author: Ian Watson , Macquarie University, Australia
+d Support: email mail@@ianwatson.com.au
+d 
+f t/tabout.ado
+f t/tabstatout.ado
+f t/tabout.hlp
+f f/figout.ado
+f f/figout.hlp
+e
+S http://www.econ.hit-u.ac.jp/~kan/research/ztree2stata
+N ztree2stata.pkg
+D 12 Jun 2015
+U 6
+d ztree2stata.  Imports a z-Tree data file and converts it into Stata format.
+d Program by Kan Takeuchi.
+d Instruction manual in PDF is also available at my website.
+d ({browse "http://www.econ.hit-u.ac.jp/~kan/research/ztree2stata/ztree2stata.pdf":http://www.econ.hit-u.ac.jp/~kan/research/ztree2stata/ztree2stata.pdf}).
+f z/ztree2stata.ado
+f z/ztree2stata.hlp
+e
+S http://fmwww.bc.edu/RePEc/bocode/s
+N strdist.pkg
+D 25 Apr 2016
+U 7
+d 'STRDIST': module to calculate the Levenshtein distance, or edit distance, between strings
+d 
+d  strdist calculates the Levenshtein distance, or edit distance,
+d between strings. It is implemented in Mata, and does not require
+d a C plugin.
+d 
+d KW: edit distance
+d KW: Levenshtein distance
+d KW: string comparison
+d KW: data management
+d 
+d Requires: Stata version 10
+d 
+d Distribution-Date: 20121111
+d 
+d Author: Michael Barker, Georgetown University
+d Support: email michael.barker96@@gmail.com
+d 
+f s/strdist.ado
+f s/strdist.sthlp
+e
+S http://www.stata-journal.com/software/sj15-1
+N st0381.pkg
+D 10 Jun 2016
+U 8
+d SJ15-1 st0381. Dunn's test of multiple...
+d Dunn's test of multiple comparisons using rank
+d   sums
+d by Alexis Dinno, School of Community Health,
+d      Portland State University, Portland, OR
+d Support:  alexis.dinno@@pdx.edu
+d After installation, type help ^dunntest^
+f d/dunntest.ado
+f d/dunntest.sthlp
+e
+S http://fmwww.bc.edu/RePEc/bocode/f
+N fmm.pkg
+D  5 Sep 2016
+U 9
+d 'FMM': module to estimate finite mixture models
+d 
+d  fmm fits a finite mixture regression model using maximum
+d likelihood estimation.  The model is a J-component finite mixture
+d of densities, with the density within a class  (j) allowed to
+d vary in location and scale.  Optionally, the mixing probabilities
+d may be  specified with covariates.  fmm currently fits mixtures
+d of the following distributions: Gamma, Normal (Gaussian),
+d Lognormal, Negative binomial 1 & 2 (mean and constant
+d dispersion), Poisson, Student-t (with fixed degrees of freedom)
+d 
+d KW: Finite mixture model
+d KW: maximum likelihood estimation
+d KW: mixture of densities
+d 
+d Requires: Stata version 9.2
+d 
+d Distribution-Date: 20120212
+d 
+d Author: Partha Deb, Hunter College
+d Support: email partha.deb@@hunter.cuny.edu
+d 
+f f/fmm.ado
+f f/fmm.hlp
+f f/fmm_postestimation.hlp
+f f/fmm_gamma_lf.ado
+f f/fmm_gamma_p.ado
+f f/fmm_lognormal_lf.ado
+f f/fmm_lognormal_p.ado
+f f/fmm_negbin1_lf.ado
+f f/fmm_negbin1_p.ado
+f f/fmm_negbin2_lf.ado
+f f/fmm_negbin2_p.ado
+f f/fmm_normal_lf.ado
+f f/fmm_normal_p.ado
+f f/fmm_poisson_lf.ado
+f f/fmm_poisson_p.ado
+f f/fmm_studentt_lf.ado
+f f/fmm_studentt_p.ado
+f g/gammareg_lf.ado
+f l/lognormalreg_lf.ado
+f n/normalreg_lf.ado
+f s/studenttreg_lf.ado
+e
+S http://www.stata-journal.com/software/sj7-2
+N gr0001_3.pkg
+D  9 Sep 2016
+U 10
+d SJ7-2 gr0001_3.  Update: Generalized Lorenz curves and...
+d Update:  Generalized Lorenz curves and related graphs
+d by Philippe Van Kerm, CEPS/INSEAD G.-D. Luxembourg,
+d    University of Namur, Belgium
+d    Stephen P. Jenkins, University of Essex, UK
+d Support:  philippe.vankerm@@ceps.lu, stephenj@@essex.ac.uk
+d After installation, type help ^glcurve^
+f g/glcurve.ado
+f g/glcurve.hlp
+e
+S http://fmwww.bc.edu/repec/bocode/c
+N coefplot.pkg
+D 15 Sep 2017
+U 12
+d 'COEFPLOT': module to plot regression coefficients and other results
+d 
+d   coefplot plots results from estimation commands or Stata
+d matrices. Results from multiple models or matrices can be
+d combined in a single graph. The default behavior of coefplot is
+d to draw markers for coefficients and horizontal spikes for
+d confidence intervals. However, coefplot can also produce various
+d other types of graphs.
+d 
+d KW: graphics
+d KW: coefficients
+d KW: estimation
+d 
+d Requires: Stata version 11
+d 
+d Distribution-Date: 20170216
+d 
+d Author: Ben Jann, University of Bern
+d Support: email jann@@soz.unibe.ch
+d 
+f c/coefplot.ado
+f c/coefplot.sthlp
+e
+S http://fmwww.bc.edu/repec/bocode/l
+N latab.pkg
+D  4 Oct 2017
+U 13
+d 'LATAB': module to generate LaTeX output from tabulate
+d 
+d latab tabulates the varlist (max of 2 variables) and produces a
+d display with LaTeX code embedded in the output. The user may then
+d copy from this display (or copy from a log file) and paste into a
+d LaTeX document. Companion program latabstat produces LaTeX output
+d from the tabstat command.
+d 
+d Distribution-Date: 20030119
+d 
+d Author: Ian Watson , ACIRRT, University of Sydney
+d Support: email iangwatson@@pnc.com.au
+d 
+f l/latab.ado
+f l/latab.hlp
+f l/latabstat.ado
+f l/latabstat.hlp
+e
+S http://fmwww.bc.edu/repec/bocode/b
+N binscatter.pkg
+D  4 Oct 2017
+U 14
+d 'BINSCATTER': module to generate binned scatterplots
+d 
+d  binscatter generates binned scatterplots, and is optimized for
+d speed in large  datasets.  Binned scatterplots provide a
+d non-parametric way of visualizing the relationship between two
+d variables.  With a large number of observations, a scatterplot
+d that plots every data point would become too crowded to interpret
+d visually.  binscatter groups the x-axis variable into equal-sized
+d bins, computes the mean of the x-axis and y-axis variables within
+d each bin, then creates a scatterplot of these data points.  It
+d provides built-in options to control for covariates before
+d plotting the relationship.  It will also plot fit lines based on
+d the underlying data, and can automatically handle regression
+d discontinuities.
+d 
+d KW: scatterplot
+d KW: data description
+d KW: regression discontinuity
+d 
+d Requires: Stata version 12.1
+d 
+d Distribution-Date: 20131124
+d 
+d Author: Michael Stepner
+d Support: email michaelstepner@@gmail.com
+d 
+f b/binscatter.ado
+f b/binscatter.sthlp
+e
+S http://fmwww.bc.edu/repec/bocode/c
+N center.pkg
+D 14 Nov 2017
+U 15
+d 'CENTER': module to center (or standardize) variables
+d 
+d  center centers variables to have zero sample mean  (and,
+d optionally, unit sample variance). center is byable and may also
+d be used for quasi-demeaning.
+d 
+d KW: centering
+d KW: demeaning
+d KW: z-score
+d 
+d Requires: Stata version 7.0
+d 
+d Distribution-Date: 20170413
+d 
+d Author: Ben Jann, University of Bern
+d Support: email jann@@soz.unibe.ch
+d 
+f c/center.ado
+f c/center.hlp
+e
+S http://www.stata.com/stb/stb61
+N gr42_1.pkg
+D 29 Nov 2017
+U 16
+d STB-61 gr42_1.  Quantile plots, generalized: update to Stata 7.0
+d STB insert by Nicholas J. Cox, University of Durham, UK
+d Support:  n.j.cox@@durham.ac.uk
+d After installation, see help ^quantil2^
+f _/_gpp.ado
+f q/quantil2.ado
+f q/quantil2.hlp
+e
+S http://fmwww.bc.edu/repec/bocode/c
+N cdfplot.pkg
+D  5 Dec 2017
+U 17
+d 'CDFPLOT': module to plot a cumulative distribution function
+d 
+d cdfplot plots the sample cumulative distribution function.
+d Distributions can be compared within subgroups defined by a
+d second variable. The best fitting  normal (Gaussian) model may be
+d superimposed over the sample c.d.f.
+d 
+d KW: graph
+d KW: CDF
+d KW: Gaussian
+d 
+d Requires: Stata version 9
+d 
+d Distribution-Date: 20080714
+d 
+d Author: Adrian Mander
+d Support: email Adrian.Mander@@mrc-hnr.cam.ac.uk
+d 
+f c/cdfplot.ado
+f c/cdfplot.hlp
+e
+S http://www.stata-journal.com/software/sj8-4
+N st0151.pkg
+D  9 Mar 2018
+U 18
+d SJ8-4 st0151.  The Blinder-Oaxaca decomposition for linear...
+d  The Blinder-Oaxaca decomposition for linear regression
+d    models
+d by Ben Jann, ETH Zurich
+d Support:  jannb@@ethz.ch
+d After installation, type help ^oaxaca^
+f o/oaxaca.ado
+f o/oaxaca.hlp
+f _/_oaxaca.ado
+e
+S http://www.stata.com/users/vwiggins
+N grc1leg.pkg
+D 30 Jul 2018
+U 19
+d grc1leg.  Combine graphs into one graph with a common legend.
+d Program by Vince Wiggins, StataCorp <vwiggins@@stata.com>.
+d Statalist distribution, 16 June 2003.
+d 
+d Exactly like -graph combine- but shows a single common legend for all
+d combined graphs.
+d 
+d Distribution-Date: 02jun2010
+f g/grc1leg.ado
+f g/grc1leg.hlp
+e
+S http://www.stata-journal.com/software/sj19-1
+N gr41_5.pkg
+D 18 Nov 2019
+U 20
+d SJ19-1 gr41_5. Update: Distribution function plots
+d Update: Distribution function plots
+d by Nicholas J. Cox, Durham University, UK
+d Support:  [email protected]
+d After installation, type help {cmd:displot}
+d DOI:  10.1177/1536867X19833285
+f d/distplot.ado
+f d/distplot.hlp
+e
+S http://fmwww.bc.edu/repec/bocode/d
+N distplot.pkg
+D 18 Nov 2019
+U 21
+d 'DISTPLOT': module to generate distribution function plot
+d 
+d distplot produces a plot of cumulative distribution function(s).
+d This shows the proportion (or if desired the frequency) of values
+d  less than or equal to each value. With the reverse option,
+d distplot produces a plot of the complementary function.  This
+d version is for Stata 8 or later.  Also included in this package
+d are distplot7 files, a clone of the  last version of this program
+d written for Stata 7.
+d 
+d KW: graphics
+d KW: frequency distributions
+d KW: cumulative distribution function
+d 
+d Requires: Stata version 8.0 (7.0 for distplot7)
+d 
+d 
+d Author: Nicholas J. Cox, University of Durham
+d Support: email N.J.Cox@@durham.ac.uk
+d 
+d Distribution-Date: 20170916
+d 
+f d/distplot.ado
+f d/distplot.sthlp
+f d/distplot7.ado
+f d/distplot7.hlp
+e

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/c/cdfplot.ado

@@ -0,0 +1,156 @@
+*! Date    : 10 July 2008
+*! Version : 1.04
+*! Author  : Adrian Mander
+*! Email   : [email protected]
+
+*! ADAPTED from version 1.0.1 David Clayton/Michael Hills Oct-95    STB-49 gr37
+
+/*
+29/03/07 version 1.03 - Remove a describe at the end of the program
+10/07/08 version 1.04 - Add an option to stop the cdf being plotted
+*/
+
+program define cdfplot
+version 9.0
+syntax varname [aweight fweight iweight pweight] [if] [in] [,BY(varname) opt1(string) opt2(string) NOCDF NORMal SAMEsd XLOG * ]
+local goptions `"`options'"'
+
+/* Check options */
+if "`nocdf'"~="" & "`normal'"=="" {
+  di "{err}WARNING the nocdf option can only be used when the normal option is specified"
+  exit(198)
+}
+
+preserve
+
+local yv "`varlist'"
+local yvlab : variable label `yv'
+
+/* Log-transformation -- need for change?*/
+tempvar yvar w touse
+if "`xlog'"=="" {
+  qui gen `yvar' = `yv'
+  lab var `yvar' "`yvlab'"
+}
+else {
+  qui gen `yvar' = log(`yv')
+  lab var `yvar' "Log `yvlab'"
+  local yvlab "Log `yvlab'"
+}
+
+/* All the weights required.. */
+if "`weight'"=="" qui gen `w' = 1
+else qui gen `w' `exp'
+
+/* The missing data steps */
+qui egen int `touse' = rmiss(`varlist' `w') `if' `in' 
+qui drop if `touse'>0 
+qui replace `touse'= 0
+qui replace `touse'=1 `if' `in'
+keep if `touse'
+keep `yv' `yvar' `w' `by'
+tempvar cw ccw grp sy ssy
+
+/* now calculations... */
+
+if "`by'"=="" {
+
+  /* cw is the cumulative probabilities  sy is the normalised version */
+
+  sort `yvar'
+  qui gen `cw' = sum(`w')
+  if "`normal'"~="" {
+    qui gen `sy' = sum(`w'*`yvar')
+    qui replace `sy' = `yvar' - `sy'[_N]/`cw'[_N]
+    qui gen `ssy' = sum(`w'*(`sy'^2))
+    if "`weight'"=="" | "`weight'"=="`fweight'" qui replace `sy' = `sy'/sqrt(`ssy'[_N]/(`cw'[_N]-1))
+    else qui replace `sy' = `sy'/sqrt(`ssy'[_N]/`cw'[_N])
+    qui replace `sy' = normprob(`sy')
+    qui replace `cw' = `cw'/`cw'[_N]
+
+    lab var `sy' "Normal c.d.f."
+    lab var `cw' "c.d.f."
+
+    local vlist "`cw'"
+    local nlist "`sy'"
+  }
+  else {
+    qui replace `cw' = `cw'/`cw'[_N]
+    local vlist "`cw'"
+  }
+
+}
+
+else {
+  qui levelsof `by'
+  local bylevs "`r(levels)'"
+
+  sort `by' `yvar'
+  qui by `by': gen `cw' = sum(`w')
+  qui by `by': gen `grp' = (_n==1)
+  qui replace `grp' = sum(`grp')
+
+  if "`normal'"~="" {
+    qui by `by': gen `sy' = sum(`w'*`yvar')
+    qui by `by': replace `sy' = `yvar' - `sy'[_N]/`cw'[_N]
+    if "`samesd'"=="" {
+      qui by `by': gen `ssy' = sum(`w'*(`sy'^2))
+	if "`weight'"=="`fweight'"|"`weight'"=="" qui by `by':replace `sy'=`sy'/sqrt(`ssy'[_N]/(`cw'[_N]-1))
+      else qui by `by':replace `sy'=`sy'/sqrt(`ssy'[_N]/`cw'[_N])
+    }
+    else {
+      qui gen `ccw' = sum(`w')
+      qui gen `ssy' = sum(`w'*(`sy'^2))
+      if "`weight'"=="`fweight'"|"`weight'"=="" qui replace `sy'=`sy'/sqrt(`ssy'[_N]/(`ccw'[_N]-`grp'[_N]))
+      else qui replace `sy'=`sy'/sqrt(`ssy'[_N]/`ccw'[_N])
+    }
+  }
+  qui by `by': replace `cw' = `cw'/`cw'[_N]
+	
+  /* now the loop by the different groups */
+
+  local group 1
+  while `group' <= `grp'[_N] {
+    tempvar gsc
+    qui gen `gsc' = `cw' if `group'==`grp'
+
+    /* Check whether the variable has a value label and then label accordingly */
+    local test: value label `by'
+    local bylevval: word `group' of `bylevs'
+    if "`test'"~="" local bylevname: label (`by') `bylevval'
+    else local bylevname `"`bylevval'"'    
+    lab var `gsc' "c.d.f. of  `bylevname' "
+
+    if "`normal'"=="" {		
+	local vlist "`vlist' `gsc'"
+	local group = `group'+1
+    }
+    else {
+	tempvar gsd 
+	qui gen `gsd' = normprob(`sy') if `group'==`grp'
+      lab var `gsd' "Normal c.d.f. for `bylevname' "
+	local vlist "`vlist' `gsc' "
+	local nlist "`nlist' `gsd' "
+	local group = `group'+1
+    }
+  }
+
+
+}
+qui replace `yv' = .  if _n<_N & `yvar'[_n]==`yvar'[_n+1]
+
+local n: list sizeof vlist
+local connect: di _dup(`n') "J "
+
+local plot1 `" (line `vlist' `yv', c(`connect') cmissing(y) `opt1') "'
+if "`normal'"~="" local plot2 "|| (line `nlist' `yv', `opt2')"
+
+if "`nocdf'"~="" & "`normal'"~="" cap twoway  `plot2', ylabel(, angle(0)) ytitle(Cumulative Probability) `goptions'
+else cap twoway `plot1' `plot2', ylabel(, angle(0)) ytitle(Cumulative Probability) `goptions'
+
+if _rc~=0 {
+  di as error "WARNING: problem with the twoway command "
+  twoway `plot1' `plot2', ylabel(, angle(0)) ytitle(Cumulative Probability) `goptions'
+}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/c/cdfplot.hlp

@@ -0,0 +1,139 @@
+{smcl}
+{* 9 July 2008}{...}
+{cmd:help cdfplot}
+{hline}
+
+{title:Title}
+
+  {hi:Plots the cumulative distribution function}
+
+{title:Syntax}
+
+{p 8 27 2}
+{cmdab:cdfplot} {help varname} [{help if}] [{help in}] [{help weight}] 
+[{cmd:,} {it:options}]
+
+{synoptset 20 tabbed}{...}
+{synopthdr}
+{synoptline}
+{syntab:Main}
+{synopt:{opt by}(varname)} specifies a separate c.d.f. to be drawn for each value of varname. {p_end}
+{synopt:{opt norm:al}} specifies that a Gaussian probability curve with the same mean and standard 
+deviation to be superimposed over the c.d.f. {p_end}
+{synopt:{opt same:sd}} specifies that the normal c.d.f.s use the same same standard deviation. {p_end}
+{synopt:{opt nocdf}} specifies that the empirical c.d.f. is not drawn. {p_end}
+{synopt:{opt opt1}(twoway_options)} specifies the additional graph options for the c.d.f. plot. {p_end}
+{synopt:{opt opt2}(twoway_options)} specifies the additional graph options for the Gaussian c.d.f. plots . {p_end}
+{synopt:{opt {help twoway_options}}} any twoway options are applied to the final graph. {p_end}
+{synoptline}
+{p2colreset}{...}
+
+
+{title:Description}
+
+{pstd}
+{hi:cdfplot} plots the sample cumulative distribution function. Distributions can
+be compared within subgroups defined by a second variable. The best fitting 
+normal (Gaussian) model may be superimposed over the sample c.d.f.
+
+{title:Updating this command using SSC}
+
+{pstd} 
+To obtain the latest version click the following to uninstall the old version
+
+{pstd}
+{stata ssc uninstall cdfplot}
+
+{pstd}
+And click here to install the new version
+
+{pstd}
+{stata ssc install cdfplot}
+
+{title:Options}
+
+{phang}
+{opt by}(varname) specifies a separate c.d.f. to be drawn for each value 
+of varname. These are plotted on the same graph for easier comparison.
+
+{phang}
+{opt norm:al} specifies that a normal probability curve with the same mean and standard 
+deviation to be superimposed over the c.d.f.
+
+{phang}
+{opt same:sd} is relevant only when {hi:by} and {hi:normal} options are used together.
+It specifies that the normal curves with different means have the same standard deviations. 
+This demonstrates the fit of the conventional Gaussian location shift model.
+
+{phang}
+{opt nocdf} specifies that the empirical c.d.f. is not drawn but this option will not work unless
+the normal option is specified, hence only the smoothed Gaussian c.d.f will be drawn. {p_end}
+
+{phang}
+{cmdab:opt1}{cmd:(}{it:twoway_options}{cmd:)} specifies additional graph options for the c.d.f. plots.
+
+{phang}
+{cmdab:opt2}{cmd:(}{it:twoway_options}{cmd:)} specifies additional graph options for the Gaussian c.d.f. plots.
+
+{phang}
+If the {hi:xlog} option is used, the {hi:normal} option causes log-normal distributions
+to be fitted.
+
+{title:Examples}
+
+{pstd}
+Using the variable {hi:length} from the {hi:auto} data (click on the following commands in order):
+
+{pstd}
+{hi: NOTE DATA will be lost when loading new data}
+
+{pstd}
+{stata sysuse auto,replace}{p_end}
+{pstd}
+{stata cdfplot length, normal}{p_end}
+{pstd}
+{stata cdfplot length, by(foreign)}{p_end}
+{pstd}
+{stata cdfplot length, by(foreign) norm saving(mygraph)}{p_end}
+{pstd}
+{stata cdfplot length [fw=rep78], by(foreign) norm saving(mygraph,replace)}{p_end}
+
+{pstd}
+Using the variable {hi:bp} from the {hi:bplong} data 
+
+{pstd}
+{stata sysuse bplong,replace}{p_end}
+{pstd}
+{stata cdfplot bp, norm}{p_end}
+{pstd}
+{stata cdfplot bp, by(agegrp)}{p_end}
+{pstd}
+{stata cdfplot bp, by(agegrp) norm}{p_end}
+
+{pstd}
+Now to show the use of the options in the individual graphs, {hi:opt1} alters the line colours
+for the c.d.f. graphs and {hi:opt2} alters the line pattern for the Gaussian c.d.f.
+
+{pstd}
+{stata cdfplot bp, by(agegrp) opt1( lc(red green olive) ) opt2( lp(dash dash dash) ) norm }
+
+{title:Author}
+
+{pstd}
+Adrian Mander, MRC Human Nutrition Research Unit, Cambridge, UK.
+
+{pstd}
+Email {browse "mailto:[email protected]":[email protected]}
+
+
+{title:Acknowledgement}
+
+{pstd}
+This command is nearly a direct port of the {hi:cdf} command that was written by
+{bf: David Clayton} and {bf:Michael Hills} in STB-49.
+
+{title:Also see}
+
+{pstd}
+{help cdf} (if installed)
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/c/coefplot.sthlp

@@ -0,0 +1,1751 @@
+{smcl}
+{* *! version 1.4.9  13feb2017 Ben Jann}{...}
+{vieweralsosee "[G-2] graph" "help graph"}{...}
+{vieweralsosee "[R] estimates" "help estimates"}{...}
+{vieweralsosee "[R] marginsplot" "help marginsplot"}{...}
+{vieweralsosee "[R] margins" "help margins"}{...}
+{viewerjumpto "Syntax" "coefplot##syntax"}{...}
+{viewerjumpto "Description" "coefplot##description"}{...}
+{viewerjumpto "Options" "coefplot##options"}{...}
+{viewerjumpto "Examples" "coefplot##examples"}{...}
+{viewerjumpto "Remarks" "coefplot##remarks"}{...}
+{viewerjumpto "Saved results" "coefplot##saved_results"}{...}
+{viewerjumpto "References" "coefplot##references"}{...}
+{viewerjumpto "Author" "coefplot##author"}{...}
+{viewerjumpto "History" "coefplot##history"}{...}
+{hi:help coefplot}{...}
+{right: Also see: {browse "http://repec.sowi.unibe.ch/stata/coefplot"}}
+{hline}
+
+{title:Title}
+
+{pstd}
+    {hi:coefplot} {hline 2} Plotting regression coefficients and other
+    results
+
+{marker syntax}{...}
+{title:Syntax}
+
+{p 8 15 2}
+    {cmd:coefplot} {it:subgraph} [ || {it:subgraph} || ... ]
+    [{cmd:,} {help coefplot##globalopts:{it:globalopts}} ]
+
+{pstd}
+    where {it:subgraph} is defined as
+
+{p 8 16 2}
+    {cmd:(}{it:plot}{cmd:)} [ {cmd:(}{it:plot}{cmd:)} ... ]
+    [, {help coefplot##subgropts:{it:subgropts}} ]
+
+{pstd}
+    and {it:plot} is either {cmd:_skip} (to skip a plot) or
+
+{p 8 16 2}
+    {it:model} [ \ {it:model} \ ... ]
+    [, {help coefplot##plotopts:{it:plotopts}} ]
+
+{pstd}
+    and {it:model} is
+
+{p 8 16 2}
+    {it:name} [{cmd:,} {help coefplot##modelopts:{it:modelopts}} ]
+
+{pstd}
+    where {it:name} is the name of a stored model
+    (see help {helpb estimates}; type {cmd:.} or leave blank to refer to
+    the active model). The {cmd:*} and {cmd:?} wildcards are allowed
+    in {it:name}; see
+    {help coefplot##wildcards:{it:Using wildcards in model names}}. Furthermore,
+    {it:model} may also be
+
+{p 8 16 2}
+    {helpb coefplot##matrix:{ul:m}atrix({it:mspec})} [{cmd:,} {help coefplot##modelopts:{it:modelopts}} ]
+
+{pstd}
+    to plot results from a matrix (see
+    {help coefplot##matrix:{it:Plotting results from matrices}} below).
+    Parentheses around {it:plot} can be omitted if {it:plot} does not contain
+    spaces.
+
+{synoptset 25 tabbed}{...}
+{marker modelopts}{synopthdr:modelopts}
+{synoptline}
+{syntab:Main}
+{synopt:{helpb coefplot##omitted:{ul:omit}ted}}include omitted
+    coefficients
+    {p_end}
+{synopt:{helpb coefplot##baselevels:{ul:base}levels}}include base levels
+    {p_end}
+{synopt:{helpb coefplot##b:b({it:mspec})}}specify source to be plotted; default is to
+    plot {cmd:e(b)}
+    {p_end}
+{synopt:{helpb coefplot##at:at{sf:[}({it:spec}){sf:]}}}get plot positions from
+    {cmd:e(at)}, or as specified by {it:spec}
+    {p_end}
+{synopt:{helpb coefplot##keep:keep({it:coeflist})}}keep specified coefficients
+    {p_end}
+{synopt:{helpb coefplot##drop:drop({it:coeflist})}}drop specified coefficients
+    {p_end}
+
+{syntab:Confidence intervals}
+{synopt:{helpb coefplot##noci:noci}}omit confidence intervals
+    {p_end}
+{synopt:{helpb coefplot##levels:{ul:l}evels({it:numlist})}}set level(s) for
+    conficence intervals
+    {p_end}
+{synopt:{helpb coefplot##ci:ci({it:spec})}}provide confidence intervals
+    {p_end}
+{synopt:{helpb coefplot##v:v({it:name})}}provide variances; default is to use
+    {cmd:e(V)}
+    {p_end}
+{synopt:{helpb coefplot##se:se({it:mspec})}}provide standard errors
+    {p_end}
+{synopt:{helpb coefplot##df:df({it:spec})}}provide degrees of freedom
+    {p_end}
+{synopt:{helpb coefplot##citype:citype(logit|{ul:norm}al)}}method to compute
+    confidence intervals; default is {cmd:citype(normal)}
+    {p_end}
+
+{syntab:Transform results}
+{synopt:{helpb coefplot##eform:eform{sf:[}({it:coeflist}){sf:]}}}plot
+    exponentiated point estimates and confidence intervals
+    {p_end}
+{synopt:{helpb coefplot##rescale:rescale({it:spec})}}rescale point estimates
+    and confidence intervals
+    {p_end}
+{synopt:{helpb coefplot##transform:{ul:trans}form({it:matchlist})}}transform
+    point estimates and confidence intervals
+    {p_end}
+
+{syntab:Names and labels}
+{synopt:{helpb coefplot##rename:rename({it:spec})}}rename coefficients
+    {p_end}
+{synopt:{helpb coefplot##eqrename:{ul:eqren}ame({it:spec})}}rename
+    equations
+    {p_end}
+{synopt:{helpb coefplot##asequation:{ul:aseq}uation{sf:[}({it:string}){sf:]}}}set equation
+    to model name or {it:string}
+    {p_end}
+{synopt:{helpb coefplot##swapnames:{ul:swap}names}}swap coefficient names and
+    equation names
+    {p_end}
+{synopt:{helpb coefplot##mlabels:mlabels({it:matchlist})}}specify marker labels
+    {p_end}
+
+{syntab:Auxiliary results}
+{synopt:{helpb coefplot##aux:aux({sf:{it:mspec} [{it:mspec} ...]})}}make
+    additional results available as {cmd:@aux1}, {cmd:@aux2}, etc.
+    {p_end}
+{synoptline}
+
+{synoptset 25 tabbed}{...}
+{marker plotopts}{synopthdr:plotopts}
+{synoptline}
+{syntab:Passthru}
+{synopt:{help coefplot##modelopts:{it:modelopts}}}plot-specific model options;
+    see {help coefplot##place:{it:Placement of options}}
+    {p_end}
+
+{syntab:Main}
+{synopt:{helpb coefplot##label:{ul:lab}el({it:string})}}label to be used for
+    the plot in the legend
+    {p_end}
+{synopt:{helpb coefplot##key:key{sf:[}(ci {sf:[}#{sf:]}){sf:]}}}key
+    symbol to be used for the plot in the legend
+    {p_end}
+{synopt:{helpb coefplot##nokey:nokey}}do not include the plot in the legend
+    {p_end}
+{synopt:{helpb coefplot##pstyle:{ul:psty}le({it:pstyle})}}overall
+    style of the plot
+    {p_end}
+{synopt:{helpb coefplot##axis:{ul:ax}is({it:#})}}choice of axis for the plot, {cmd:1} {ul:<} {it:#} {ul:<} {cmd:9}
+    {p_end}
+{synopt:{helpb coefplot##offset:offset({it:#})}}provide offset for plot
+    positions
+    {p_end}
+{synopt:{helpb coefplot##ifopt:if({it:exp})}}restrict the contents of the plot
+    {p_end}
+{synopt:{helpb coefplot##weight:{ul:w}eight({it:exp})}}scale size of markers
+    {p_end}
+
+{syntab:Markers}
+{synopt:{it:{help marker_options}}}change look of
+    markers (color, size, etc.)
+    {p_end}
+{synopt:{helpb coefplot##mlabel:{ul:ml}abel}}add coefficient values as marker
+    labels
+    {p_end}
+{synopt:{it:{help marker_label_options}}}change the look and position of marker
+    labels
+    {p_end}
+{synopt:{helpb coefplot##recast:recast({it:plottype})}}plot results using
+    {it:plottype}
+    {p_end}
+
+{syntab:Confidence spikes}
+{synopt:{helpb coefplot##cionly:cionly}}plot confidence spikes only
+    {p_end}
+{synopt:{helpb coefplot##citop:citop}}draw confidence spikes in front
+    of markers
+    {p_end}
+{synopt:{helpb coefplot##ciopts:{ul:ciop}ts({it:options})}}affect rendition
+    of confidence spikes
+    {p_end}
+{synopt:{helpb coefplot##cismooth:{ul:cis}mooth{sf:[}({it:options}){sf:]}}}add smoothed
+    confidence intervals
+    {p_end}
+{synoptline}
+
+{synoptset 25 tabbed}{...}
+{marker subgropts}{synopthdr:subgropts}
+{synoptline}
+{syntab:Passthru}
+{synopt:{help coefplot##modelopts:{it:modelopts}}}subgraph-specific model
+    options; see {help coefplot##place:{it:Placement of options}}
+    {p_end}
+{synopt:{help coefplot##plotopts:{it:plotopts}}}subgraph-specific plot
+    options; see {help coefplot##place:{it:Placement of options}}
+    {p_end}
+
+{syntab:Main}
+{synopt:{helpb coefplot##bylabel:{ul:bylab}el({it:string})}}label to be used
+    for the subgraph
+    {p_end}
+{synoptline}
+
+{synoptset 25 tabbed}{...}
+{marker globalopts}{synopthdr:globalopts}
+{synoptline}
+{syntab:Passthru}
+{synopt:{help coefplot##modelopts:{it:modelopts}}}global model options; see
+    {help coefplot##place:{it:Placement of options}}
+    {p_end}
+{synopt:{help coefplot##plotopts:{it:plotopts}}}global plot options; see
+    {help coefplot##place:{it:Placement of options}}
+    {p_end}
+{synopt:{help coefplot##subgropts:{it:subgropts}}}global subgraph options;
+    see {help coefplot##place:{it:Placement of options}}
+    {p_end}
+
+{syntab:Main}
+{synopt:{helpb coefplot##horizontal:{ul:hor}izontal}}coefficient values are
+    on x axis; general default
+    {p_end}
+{synopt:{helpb coefplot##vertical:{ul:vert}ical}}coefficient values are on y
+    axis; default with {cmd:at()}
+    {p_end}
+{synopt:{helpb coefplot##eqstrict:eqstrict}}be strict about equations
+    {p_end}
+{synopt:{helpb coefplot##order:order({it:coeflist})}}order coefficients
+    {p_end}
+{synopt:{helpb coefplot##orderby:orderby({it:spec})}}order coefficients by
+    specific model
+    {p_end}
+{synopt:{helpb coefplot##sort:sort{sf:[}({it:spec}){sf:]}}}sort coefficients
+    {p_end}
+{synopt:{helpb coefplot##relocate:{ul:reloc}ate({it:spec})}}assign
+    specific positions to coefficients
+    {p_end}
+{synopt:{helpb coefplot##bycoefs:{ul:byc}oefs}}arrange subgraphs by
+    coefficients
+    {p_end}
+{synopt:{helpb coefplot##norecycle:{ul:norec}ycle}}increment plot styles across
+    subgraphs
+    {p_end}
+{synopt:{helpb coefplot##nooffsets:{ul:nooff}sets}}do not offset plot
+    positions
+    {p_end}
+{synopt:{helpb coefplot##format:format({it:format})}}set the display format for
+    numeric labels
+    {p_end}
+{synopt:{helpb coefplot##pnum:p{it:#}({it:plotopts})}}options for {it:#}th plot
+    {p_end}
+
+{syntab:Labels and grid lines}
+{synopt:{helpb coefplot##nolabels:{ul:nolab}els}}use variable names instead of
+    labels
+    {p_end}
+{synopt:{helpb coefplot##coeflabels:{ul:coefl}abels({it:spec})}}specify
+    custom labels for coefficients
+    {p_end}
+{synopt:{helpb coefplot##noeqlabels:{ul:noeql}abels}}suppress equation labels
+    {p_end}
+{synopt:{helpb coefplot##eqlabels:{ul:eql}abels({it:spec})}}specify labels
+    for equations
+    {p_end}
+{synopt:{helpb coefplot##headings:{ul:head}ings({it:spec})}}add headings between
+    coefficients
+    {p_end}
+{synopt:{helpb coefplot##groups:groups({it:spec})}}add labels for groups of
+    coefficients
+    {p_end}
+{synopt:{helpb coefplot##plotlabels:{ul:plotl}abels({it:spec})}}(re)set plot
+    labels
+    {p_end}
+{synopt:{helpb coefplot##bylabels:bylabels({it:spec})}}(re)set subgraph
+    labels
+    {p_end}
+{synopt:{helpb coefplot##grid:grid({it:options})}}affect rendition of grid lines
+    {p_end}
+
+{syntab:Save results}
+{synopt:{helpb coefplot##generate:{ul:gen}erate{sf:[}({it:prefix}){sf:]}}}generate
+    variables containing the graph data
+    {p_end}
+{synopt:{helpb coefplot##replace:replace}}overwrite existing variables
+    {p_end}
+
+{syntab:Add plots}
+{synopt:{helpb addplot_option:addplot({it:plot})}}add other plots to the
+    graph
+    {p_end}
+{synopt:{helpb coefplot##nodrop:nodrop}}do not drop observations
+    {p_end}
+
+{syntab:Y axis, X axis, Titles, Legend, Overall, By}
+{synopt:{it:{help twoway_options}}}twoway options, other than {cmd:by()}
+    {p_end}
+{synopt:{cmdab:byop:ts(}{it:{help by_option:byopts}}{cmd:)}}how subgraphs
+    are combined
+    {p_end}
+{synoptline}
+
+
+{marker description}{...}
+{title:Description}
+
+{pstd}
+    {cmd:coefplot} plots results from estimation commands or Stata matrices.
+    Results from multiple models or matrices can be combined in a single
+    graph. The default behavior of {cmd:coefplot} is to draw markers for
+    coefficients and horizontal spikes for confidence intervals. However,
+    {cmd:coefplot} can also produce various other types of graphs.
+
+
+{marker options}{...}
+{title:Options}
+{dlgtab:Model options}
+
+{marker omitted}{...}
+{phang}
+    {cmd:omitted} includes omitted coefficients. This may be useful if a model
+    contains coefficients that have been dropped due to collinearity.
+
+{marker baselevels}{...}
+{phang}
+    {cmd:baselevels} includes base levels of factor variables.
+
+{marker b}{...}
+{phang}
+    {cmd:b(}{it:mspec}{cmd:)} specifies the source from which the point
+    estimates and coefficient names are to be collected. The default is to use
+    (the first row of) {cmd:e(b)} (or {cmd:e(b_mi)} if plotting results from
+    {helpb mi estimate}). {cmd:b()} is discarded in matrix mode (see
+    {help coefplot##matrix:{it:Plotting results from matrices}} below).
+    {it:mspec} may be:
+
+{p2colset 13 25 27 2}{...}
+{p2col:{it:name}}use first row of {cmd:e(}{it:name}{cmd:)}
+    {p_end}
+{p2col:{it:name}{cmd:[}#{cmd:,.]}}use #th row of
+    {cmd:e(}{it:name}{cmd:)}; may also type {it:name}{cmd:[}#{cmd:,]}
+    or {it:name}{cmd:[}#{cmd:]}
+    {p_end}
+{p2col:{it:name}{cmd:[.,}#{cmd:]}}use #th column of
+    {cmd:e(}{it:name}{cmd:)}; may also type {it:name}{cmd:[,}#{cmd:]}
+    {p_end}
+{p2colreset}{...}
+
+{marker at}{...}
+{phang}
+    {cmd:at}[{cmd:(}{it:spec}{cmd:)}] causes plot positions to be determined
+    by the values in {cmd:e(at)} (or matrix {cmd:at}) or as specified by
+    {it:spec}. The default is to create a categorical axis with coefficients
+    matched by their names. However, if {cmd:at} is specified, the axis is
+    treated as continuous. Note that labeling options
+    {cmd:coeflabels()}, {cmd:eqlabels()}, {cmd:headings()}, or {cmd:groups()}
+    are not allowed if {cmd:at} is specified. Also not allowed with {cmd:at}
+    are options {cmd:bycoefs}, {cmd:order()}, and {cmd:relocate()}.
+    Furthermore, note that {cmd:at} has to be specified for all models or
+    for none. {it:spec} is
+
+            [{it:atspec}] [{cmd:,} {opt t:ransform(exp)}]
+
+{pmore}
+    where {it:atspec} may be
+
+{p2colset 13 27 29 2}{...}
+{p2col:{it:mspec}}as above for {helpb coefplot##b:b()}
+    {p_end}
+{p2col:#}use #th at-dimension ({helpb margins}) or #th row/column of main matrix
+    {p_end}
+{p2col:{opt m:atrix(mspec)}}read from matrix instead of {cmd:e()}
+    {p_end}
+{p2col:{opt _coef}}use coefficient names as plot positions
+    {p_end}
+{p2col:{opt _eq}}use equation names as plot positions
+    {p_end}
+{p2colreset}{...}
+
+{pmore}
+    If {cmd:at} is specified without argument, the plot positions are taken from the first row
+    of {cmd:e(at)} (or matrix {cmd:at}). A special case are results from
+    {helpb margins} where recovering the plot positions is more
+    complicated. The default in this case is to use the first
+    at-dimension. Type, e.g., {cmd:at(2)} if multiple at-dimension were specified
+    with {helpb margins} and you want to use the second dimension. Furthermore,
+    in matrix mode (see
+    {help coefplot##matrix:{it:Plotting results from matrices}} below), {cmd:at(2)}
+    would read the plot positions from the 2nd row (or column) of the main matrix.
+
+{pmore}
+    When plotting results from {cmd:e()} it is sometimes convenient to
+    maintain an external matrix with the plot positions instead of
+    adding plot positions to each {cmd:e()}-set. In this case you can use
+    syntax {cmd:at(matrix(}{it:mspec}{cmd:))} to read the plot positions. Note
+    that the vector of plot positions must have the same length as the
+    coefficient vectors of the plotted models; elements are matched by position,
+    not by name.
+
+{pmore}
+    Furthermore, {cmd:at(_coef)} or {cmd:at(_eq)} will use the coefficient names or
+    the equation names as plot positions, respectively. This is useful only if
+    the coefficient names or the equation names are numeric. Note that you may
+    use {helpb coefplot##rename:rename()} and
+    {helpb coefplot##eqrename:eqrename()} to strip a non-numeric prefix or suffix
+    from coefficient names or equation names.
+
+{pmore}
+    Suboption {cmd:transform()} transforms the plot positions before creating
+    the graph. Within the transformation expression, use {cmd:@} as a
+    placeholder for the value to be transformed. For example, to take the
+    antilogarithm of the plot positions type {cmd:transform(exp(@))}.
+
+{marker keep}{...}
+{phang}
+    {cmd:keep(}{it:coeflist}{cmd:)} specifies the coefficients to be
+    plotted. The default is to include all coefficients from the
+    first (nonzero) equation of a model (and discard further equations).
+    {it:coeflist} is a space-separated list of
+    elements such as:
+
+{p2colset 13 25 27 2}{...}
+{p2col:{it:coef}}keep coefficient {it:coef}
+    {p_end}
+{p2col:{it:eq}{cmd::}}keep all coefficients from equation {it:eq}
+    {p_end}
+{p2col:{it:eq}{cmd::}{it:coef}}keep coefficient {it:coef} from equation {it:eq}
+    {p_end}
+{p2colreset}{...}
+
+{pmore}
+    where {it:eq} and {it:coef} may contain "{cmd:*}" (any string) and
+    "{cmd:?}" (any nonzero character) wildcards. For example, type {cmd:keep(*:)} or
+    {cmd:keep(*:*)} to plot all coefficients from all equations.
+
+{pmore}
+    If {it:eq} is specified, it is applied to all subsequent
+    names until a new {it:eq} is specified. For example,
+    {cmd:keep(3:mpg price 4:weight)} will plot coefficients "{cmd:mpg}" and
+    "{cmd:price}" from equation "{cmd:3}" and coefficient "{cmd:weight}" from
+    equation "{cmd:4}".
+
+{marker drop}{...}
+{phang}
+    {cmd:drop(}{it:coeflist}{cmd:)} drops the specified coefficients, where
+    {it:coeflist} is as above for {helpb coefplot##keep:keep()}.
+
+{marker noci}{...}
+{phang}
+    {cmd:noci} omits confidence intervals.
+
+{marker levels}{...}
+{phang}
+    {cmd:levels(}{it:{help numlist}}{cmd:)} sets the level(s), as percentages,
+    for confidence intervals. Specified values may be between 10.00 and 99.99
+    and can have at most two digits after the decimal point. The default is
+    {cmd:levels(95)} or as set by {helpb set level}. If multiple values are
+    specified, multiple confidence intervals are plotted. For example, type
+    {cmd:levels(99.9 99 95)} to plot the 99.9%, 99%, and 95% confidence
+    intervals. The default is to use (logarithmically) increasing line widths
+    for multiple confidence intervals. This behavior is disabled as soon as
+    {cmd:lwidth()} or {cmd:recast()} is specified within
+    {helpb coefplot##ciopts:ciopts()}.
+
+{marker ci}{...}
+{phang}
+    {cmd:ci(}{it:spec}{cmd:)} specifies the source from which to collect
+    confidence intervals. Default is to compute confidence intervals for the
+    levels specified in {cmd:levels()} using variances/standard errors (and,
+    possibly, degrees of freedom). The {cmd:ci()} option is useful to
+    plot confidence intervals that have been provided by the estimation
+    command (such as, e.g., {helpb bootstrap}). {it:spec} is
+
+            {it:cispec} [{it:cispec} ...]
+
+{pmore}
+    where {it:cispec} is {it:name} to get the lower and upper confidence limits
+    from rows 1 and 2 of {cmd:e(}{it:name}{cmd:)} (or matrix {it:name}),
+    respectively. Alternatively, {it:cispec} may be {cmd:(}{it:mspec}
+    {it:mspec}{cmd:)} to identify the lower and upper confidence limits, with
+    {it:mspec} as above for {helpb coefplot##b:b()}. For example, after
+    {helpb bootstrap}, {cmd:ci(ci_bc)} would get bias-corrected confidence intervals
+    from rows 1 and 2 of {cmd:e(ci_bc)}. The same could be achieved by
+    {cmd:ci((ci_bc[1] ci_bc[2]))}.
+
+{pmore}
+    {it:cispec} may also be # for a specific confidence level as in
+    {helpb coefplot##levels:levels()}. Hence, you may type, e.g.,
+    {cmd:ci(95 myci)} to plot the usual 95% confidence intervals along with
+    custom confidence intervals provided in {cmd:e(myci)}. Levels specified
+    in {cmd:ci()} take precedence over levels specified in {cmd:levels()}),
+    however, you may also type {cmd:""} within {cmd:ci()} to leave a
+    position blank an use the specified level from {cmd:levels()}.
+
+{pmore}
+    In matrix mode (see
+    {help coefplot##matrix:{it:Plotting results from matrices}} below),
+    {it:cispec} may also be {cmd:(}# #{cmd:)}. For example, {cmd:ci((2 3))} would
+    read the lower confidence limit from the 2nd row (or column) and
+    the upper confidence limit from the 3rd row (or column) of the main matrix.
+
+{marker v}{...}
+{phang}
+    {cmd:v(}{it:name}{cmd:)} specifies that the variances for confidence interval
+    computation are to be taken from the diagonal of {cmd:e(}{it:name}{cmd:)}
+    (or matrix {it:name}). Default is {cmd:e(V)} (or {cmd:e(V_mi)} if plotting
+    results from {helpb mi estimate}).
+
+{marker se}{...}
+{phang}
+    {cmd:se(}{it:mspec}{cmd:)} provides standard errors to be used for
+    computation of confidence intervals. Default is to compute confidence
+    intervals based on the variances in {cmd:e(V)}
+    (see {helpb coefplot##v:v()} above). {it:mspec} is as above for
+    {helpb coefplot##b:b()}.
+    In matrix mode (see
+    {help coefplot##matrix:{it:Plotting results from matrices}} below), you may
+    also specify {cmd:se(}#{cmd:)} to read the standard errors from the #th
+    row (or column) of the main matrix.
+
+{marker df}{...}
+{phang}
+    {cmd:df(}{it:spec}{cmd:)} specifies degrees of freedom (DF) to be taken into
+    account for confidence interval computation. Default is to obtain DF
+    from scalar {cmd:e(df_r)} if defined (as in, e.g., {helpb regress})
+    or, for results from {helpb mi estimate}, from matrix {cmd:e(df_mi)}. Otherwise,
+    no DF are taken into account. Specify {cmd:df(}{it:spec}{cmd:)} to provide
+    custom DF. {it:spec} may be:
+
+{p2colset 13 25 27 2}{...}
+{p2col:#}set DF for all coefficients to #
+    {p_end}
+{p2col:{it:mspec}}as above for {helpb coefplot##b:b()}
+    {p_end}
+{p2colreset}{...}
+
+{marker citype}{...}
+{phang}
+    {cmd:citype()} specifies the method to be used to compute the limits of
+    confidence intervals. {cmd:citype(normal)}, the default, computes confidence
+    limits based on untransformed coefficients and standard errors. Let {it:b} be
+    the point estimate, {it:se} the standard error, and {it:t} the (1-{it:a}/2)
+    quantile of the standard normal distribution or the t-distribution (if degrees
+    of freedom are available; see above), where {it:a} is 1 minus the
+    confidence level (e.g. {it:a}=5% for a 95% confidence interval). Then the
+    limits of the {cmd:citype(normal)} confidence interval are defined as
+
+            {it:b} +/- {it:t} * {it:se}
+
+{pmore}
+    {cmd:citype(logit)} uses the logit transformation to compute the limits
+    of confidence intervals. This is useful if the estimates to be plotted are
+    proportions and the confidence limits are supposed to lie between 0 and 1.
+    The limits of the {cmd:citype(logit)} confidence interval are computed as
+
+            invlogit(logit({it:b}) +/- {it:t} * {it:se} / ({it:b} * (1 - {it:b})))
+
+{pmore}
+    (see the "Methods and formulas" section in
+    {mansection R proportion:{bf:[R] proportion}}).
+
+{marker eform}{...}
+{phang}
+    {cmd:eform}[{cmd:(}{it:coeflist}{cmd:)}] causes point estimates and
+    confidence intervals to be exponentiated. This is useful
+    if you want to plot hazard ratios (HR), incidence-rate ratios (IRR),
+    odds ratios (OR), or relative-risk ratios (RRR). If {cmd:eform} is
+    specified without arguments, then all coefficients of the model are
+    exponentiated. To exponentiate only selected coefficients, specify
+    {it:coeflist} as above for {helpb coefplot##keep:keep()}.
+
+{marker rescale}{...}
+{phang}
+    {cmd:rescale(}{it:spec}{cmd:)} rescales point estimates and confidence
+    intervals. Type {cmd:rescale(}#{cmd:)} to rescale all coefficients
+    by a constant factor. For example, {cmd:rescale(100)} will multiply all
+    coefficients by 100. Alternatively, {it:spec} may be
+
+            {it:coeflist} {cmd:=} # [{it:coeflist} {cmd:=} # ...]
+
+{pmore}
+    with {it:coeflist} as above for {helpb coefplot##keep:keep()}.
+
+{marker transform}{...}
+{phang}
+    {cmd:transform(}{it:matchlist}{cmd:)} transforms point estimates and confidence
+    intervals. {it:machlist} is:
+
+            {it:coeflist} {cmd:= "}{it:{help exp}}{cmd:"}  [{it:coeflist} {cmd:= "}{it:{help exp}}{cmd:"} ...]
+
+{pmore}
+    with {it:coeflist} as above for {helpb coefplot##keep:keep()}. Within the
+    transformation expression, use {cmd:@} as a placeholder for
+    the value to be transformed. For example, to take the square root of all
+    coefficients type {cmd:transform(* = sqrt(@))}. In addition, internal
+    variables may be used as explained in
+    {help coefplot##tempvar:Accessing internal temporary variables}. The
+    transformation expression must be enclosed in double quotes if it contains
+    spaces. If specified, {cmd:eform()} and {cmd:rescale()} are applied before applying
+    {cmd:transform()}.
+
+{marker rename}{...}
+{phang}
+    {cmd:rename(}{it:spec}{cmd:)} renames coefficients. {it:spec} is:
+
+            {it:coeflist} {cmd:=} {it:newname} [{it:coeflist} {cmd:=} {it:newname} ...] [{cmd:,} {cmdab:r:egex}]
+
+{pmore}
+    with {it:coeflist} as above for {helpb coefplot##keep:keep()} except that
+    wildcards are only allowed in equation names, and coefficient names may
+    be specified as {it:prefix}{cmd:*} to replace a prefix or
+    {cmd:*}{it:suffix} to replace a suffix. For example,
+    {cmd:rename(*.foreign = .cartype)} will rename coefficients such as
+    {cmd:0.foreign} and {cmd:1.foreign} to {cmd:0.cartype} and
+    {cmd:1.cartype}. {it:newname} must be enclosed in double quotes if it
+    contains spaces. For labeling coefficients, also see
+    {helpb coefplot##coeflabels:coeflabels()}.
+
+{pmore}
+    Apply option {cmd:regex} to cause coefficient specifications (but not
+    equation specifications) to be interpreted as
+    {browse "https://en.wikipedia.org/wiki/Regular_expression":regular expressions}. In this
+    case, {it:newname} may contain {cmd:\1}, ..., {cmd:\9} to reference back to
+    matched subexpressions (and {cmd:\0} for the entire match). For example, type
+    {cmd:rename(^AA([0-9]+)BB$ = YY\1ZZ, regex)} to rename
+    coefficients such as {cmd:AA123BB}, {cmd:AA0BB}, or {cmd:AA99BB} to
+    {cmd:YY123ZZ}, {cmd:YY0ZZ}, or {cmd:YY99ZZ}. If the leading {cmd:^} or the
+    tailing {cmd:$} is omitted, only the matched part of a coefficient name is
+    subject to substitution; the rest of the name will remain unchanged. Include
+    the regular expressions in quotes or compound double quotes if they contain
+    funny characters (such as, e.g., quotes, equal signs, or commas).
+
+{marker eqrename}{...}
+{phang}
+    {cmd:eqrename(}{it:spec}{cmd:)} renames equations. {it:spec} is:
+
+            {it:eqlist} {cmd:=} {it:newname} [{it:eqlist} {cmd:=} {it:newname} ...] [{cmd:,} {cmdab:r:egex}]
+
+{pmore}
+    where {it:eqlist} is a space separated list of equation names. Equation
+    names may be {it:prefix}{cmd:*} to replace a prefix or
+    {cmd:*}{it:suffix} to replace a suffix. For example,
+    {cmd:eqrename(rep78* = reprec)} will rename equations such as
+    {cmd:rep78_3} and {cmd:rep78_4} to {cmd:reprec_3} and
+    {cmd:reprec_4}. {it:newname} must be enclosed in double quotes if it
+    contains spaces. For labeling equations, also see
+    {helpb coefplot##eqlabels:eqlabels()}.
+
+{pmore}
+    Apply option {cmd:regex} to cause equation specifications to be interpreted as
+    {browse "https://en.wikipedia.org/wiki/Regular_expression":regular expressions}. In this
+    case, {it:newname} may contain {cmd:\1}, ..., {cmd:\9} to reference back to
+    matched subexpressions (and {cmd:\0} for the entire match). For example, type
+    {cmd:eqrename(^eq([0-9])0$ = Outcome_\1, regex)} to rename
+    equations such as {cmd:eq20} or {cmd:eq90} to
+    {cmd:Outcome_1} or {cmd:Outcome_9}. If the leading {cmd:^} or the
+    tailing {cmd:$} is omitted, only the matched part of an equation name is
+    subject to substitution; the rest of the name will remain unchanged. Include the regular expressions in
+    quotes or compound double quotes if they contain funny characters (such as, e.g., quotes,
+    equal signs, or commas).
+
+{marker asequation}{...}
+{phang}
+    {cmd:asequation}[{cmd:(}{it:string}{cmd:)}] sets the equation name for all
+    included coefficients from the model to {it:string}. This is useful if you
+    want to assign an equation name to results that have been stored without
+    information on equations. If {cmd:asequation} is specified without
+    argument, the name of the model is used. If you apply the
+    {cmd:asequation()} option you may also want to specify
+    {helpb coefplot##eqstrict:eqstrict}.
+
+{marker swapnames}{...}
+{phang}
+    {cmd:swapnames} swaps coefficient names and equation names after collecting
+    the model's results. The names are swapped after applying model options
+    such as {cmd:keep()}, {cmd:drop()}, or {cmd:rename()} but
+    before applying global options such as {cmd:coeflabel()}, {cmd:order()},
+    or {cmd:eqlabels()}.
+
+{marker mlabels}{...}
+{phang}
+    {cmd:mlabels(}{it:matchlist}{cmd:)} specifies marker labels for
+    coefficients. {it:matchlist} is:
+
+            {it:coeflist} {cmd:=} # "{it:label}" [{it:coeflist} {cmd:=} # "{it:label}" ...]
+
+{pmore}
+    where {it:coeflist} is as above for {helpb coefplot##keep:keep()} and # is a
+    number 0--12 for the location of the marker label (see
+    {manhelpi clockposstyle G-4}). Not all of Stata's plot types
+    support marker labels. For example, if you use
+    {helpb coefplot##recast:recast(bar)} to change the plot type to
+    {helpb twoway_bar:bar}, no marker labels will be displayed.
+
+{marker aux}{...}
+{phang}
+    {cmd:aux(}{it:mspec} [{it:mspec} ...]{cmd:)} collects additional results
+    and makes them available as internal variables. {it:mspec} is as above for
+    {helpb coefplot##b:b()}. The internal variables
+    are named {cmd:@aux1}, {cmd:@aux2}, ..., and can be used within
+    {helpb coefplot##ifopt:if()},
+    {helpb coefplot##weight:weight()},
+    {helpb coefplot##transform:transform()},
+    {helpb marker_label_options:mlabel()},
+    {helpb marker_label_options:mlabvposition()}, and
+    {helpb addplot_option:addplot()} (see
+    {help coefplot##tempvar:Accessing internal temporary variables}
+    below). In matrix mode (see
+    {help coefplot##matrix:{it:Plotting results from matrices}} below), you may
+    also specify {cmd:aux(}# [# ...]{cmd:)} to read the from corresponding
+    rows (or column) of the main matrix.
+
+{dlgtab:Plot options}
+
+{marker label}{...}
+{phang}
+    {cmd:label(}{it:string}{cmd:)} provides a label for the plot to be used
+    in the legend. Use double quotes to create multiline labels. For example,
+    {cmd:label("This is a" "long label")} would create a two-line label. For
+    text effects (bold, italics, greek letters, etc.) use SMCL tags as
+    described in {it:{help graph_text}}.
+
+{marker key}{...}
+{phang}
+    {cmd:key}[{cmd:(ci} [{cmd:#}]{cmd:)}] determines the key symbol
+    to be used for the plot in the legend. {cmd:key} without argument uses
+    the plot's marker symbol; this is the default. {cmd:key(ci)} determines
+    the key symbol from the (first) confidence interval. {cmd:key(ci #)}
+    determines the key symbol from the #th confidence interval; this is only
+    useful if multiple confidence intervals are included in the plot.
+
+{marker nokey}{...}
+{phang}
+    {cmd:nokey} prevents including the plot in the legend.
+
+{marker pstyle}{...}
+{phang}{cmd:pstyle(}{it:pstyle}{cmd:)} sets the overall style of the
+    plot; see help {it:{help pstyle}}. {cmd:pstyle()} affects both,
+    coefficient markers and confidence spikes. To use a different plot style
+    for confidence spikes, add {cmd:pstyle()} within
+    {helpb coefplot##ciopts:ciopts()}.
+
+{marker axis}{...}
+{phang}{cmd:axis(}{it:#}{cmd:)} specifies the scale axis to be used for the
+    plot, where {cmd:1} {ul:<} {it:#} {ul:<} {cmd:9}. The default is to place
+    all plots on the same scale axis.
+
+{marker offset}{...}
+{phang}
+    {cmd:offset(}{it:#}{cmd:)} specifies a custom offset for the plot
+    positions. The default is to create automatic offsets to prevent
+    overlap of confidence spikes as soon as there are
+    multiple plots. The spacing between coefficients is one unit, so
+    # should usually be within -0.5 and 0.5.
+
+{marker ifopt}{...}
+{phang}
+    {cmd:if(}{it:exp}{cmd:)} restricts the contents of the plot to coefficients
+    satisfying {it:exp}. The option is useful when you want to select
+    coefficients, e.g., based on their values, plot positions, or confidence
+    limits. Within {it:exp} refer to internal temporary variables as explained
+    in {help coefplot##tempvar:Accessing internal temporary variables} below.
+    For example, to include positive coefficients only, you could type
+    {cmd:if(@b>=0)}. Note that {cmd:if()} does not affect the rendition of the
+    categorical axis (unless {helpb coefplot##at:at} is specified). That is, a
+    complete categorical axis is created including labels for all collected
+    coefficients, even for the ones that have been removed from the plot by
+    {cmd:if()}.
+
+{marker weight}{...}
+{phang}
+    {cmd:weight(}{it:exp}{cmd:)} scales the size of the markers according to
+    the size of the specified weights (see
+    {help scatter##remarks14:Weighted markers} in help {helpb scatter}). Within
+    {it:exp} refer to internal temporary variables as explained in
+    {help coefplot##tempvar:Accessing internal temporary variables} below. For
+    example, to scale markers according to the inverse of standard errors, you
+    could type {cmd:weight(1/@se)}. {cmd:weight()} has no effect if marker
+    labels are specified.
+
+{phang}
+    {it:marker_options} change the look of the coefficient markers (color,
+    size, etc.); see help {it:{help marker_options}}.
+
+{marker mlabel}{...}
+{phang}
+    {cmd:mlabel} adds point estimates as marker labels. Use global option
+    {helpb coefplot##format:format()} to set the display format. For adding
+    custom labels to specific markers see model option
+    {helpb coefplot##mlabels:mlabels()} above. Not all of Stata's plot types
+    support marker labels. For example, if you use
+    {helpb coefplot##recast:recast(bar)} to change the plot type to
+    {helpb twoway_bar:bar}, no marker labels will be displayed.
+
+{phang}
+    {it:marker_label_options} change the look and
+    position of marker labels: see help {it:{help marker_label_options}}.
+
+{marker recast}{...}
+{phang}
+    {cmd:recast(}{it:plottype}{cmd:)} plots the coefficients using
+    {it:plottype}; supported plot types are
+    {helpb scatter},
+    {helpb line},
+    {helpb twoway_connected:connected},
+    {helpb twoway_area:area},
+    {helpb twoway_bar:bar},
+    {helpb twoway_spike:spike},
+    {helpb twoway_dropline:dropline}, and
+    {helpb twoway_dot:dot}. The default {it:plottype} is {helpb scatter}. The
+    chosen plot type affects the available plot options. For example, if
+    the plot type is {helpb twoway_bar:bar} then {it:{help barlook_options}}
+    will be available. See the plot type's help file for details.
+
+{marker cionly}{...}
+{phang}
+    {cmd:cionly} causes markers for point estimates to be suppressed.
+
+{marker citop}{...}
+{phang}
+    {cmd:citop} specifies that confidence intervals be drawn in front of
+    the markers for point estimates; the default is to draw confidence intervals
+    behind the markers.
+
+{marker ciopts}{...}
+{phang}
+    {cmd:ciopts(}{it:options}{cmd:)} affect the rendition of confidence
+    intervals. {it:options} are:
+
+{p2colset 13 31 33 2}{...}
+{p2col:{it:{help line_options}}}change look of spikes
+    {p_end}
+{p2col:{cmd:recast(}{it:plottype}{cmd:)}}plot the confidence intervals using
+    {it:plottype}
+    {p_end}
+{p2colreset}{...}
+
+{pmore}
+    Supported plot types are
+    {helpb twoway_rarea:rarea},
+    {helpb twoway_rbar:rbar},
+    {helpb twoway_rspike:rspike},
+    {helpb twoway_rcap:rcap},
+    {helpb twoway_rcapsym:rcapsym},
+    {helpb twoway_rscatter:rscatter},
+    {helpb twoway_rline:rline},
+    {helpb twoway_rconnected:rconnected},
+    {helpb twoway_pcspike:pcspike},
+    {helpb twoway_pcspike:pccapsym},
+    {helpb twoway_pcarrow:pcarrow} (or {cmd:pcrarrow} for the reverse),
+    {helpb twoway_pcbarrow:pcbarrow}, and
+    {helpb twoway_pcscatter:pcscatter}. The default {it:plottype} is
+    {helpb twoway_rspike:rspike}. The chosen plot type affects the available
+    options within {cmd:ciopts()}. For example, if the plot type is
+    {helpb twoway_rbar:rbar} then {it:{help barlook_options}} will be
+    available. See the plot type's help file for details.
+
+{pmore}
+    If multiple confidence intervals are requested, then
+    {it:{help stylelists}} may be specified in the options within
+    {cmd:ciopts()}. For example, {cmd:recast(rspike rcap ..)} would use
+    {helpb twoway_rspike:rspike} for the first confidence interval and
+    {helpb twoway_rcap:rcap} for the remaining confidence intervals;
+    {cmd:lwidth(thin medium thick)} would use thin lines for the first
+    confidence interval, medium width lines for the second, and thick lines
+    for the third.
+
+{marker cismooth}{...}
+{phang}
+    {cmd:cismooth}[{cmd:(}{it:options}{cmd:)}] adds smoothed confidence
+    intervals. {it:options} are:
+
+{p2colset 13 33 35 2}{...}
+{p2col:{cmd:n(}{it:n}{cmd:)}}number of (equally spaced) confidence levels;
+    default is {cmd:n(50)}; levels are placed in steps of 100/{it:n} from 100/2{it:n} to
+    100-100/2{it:n} (e.g., 1, 3, 5, ..., 99 for {it:n}=50)
+    {p_end}
+{p2col:{cmdab:lw:idth(}{it:min max}{cmd:)}}set range of
+    (relative) line widths; the default is {cmd:range(2 15)}
+    ({it:max} is exact only for {it:n}=50)
+    {p_end}
+{p2col:{cmdab:i:ntensity(}{it:min max}{cmd:)}}set range of
+    color intensities, as percentages; the default is {cmd:intensity(}{it:min} {cmd:100)}
+    where {it:min} is determined as 4/(ceil({it:n}/2)+3)*100 (about 14 for n=50)
+    {p_end}
+{p2col:{cmdab:c:olor(}{help colorstyle:{it:color}}{cmd:)}}set the color (without
+    intensity multiplier); the default color is determined by the graph scheme
+    {p_end}
+{p2col:{cmdab:psty:le(}{help pstyle:{it:pstyle}}{cmd:)}}set the overall style;
+    this mainly affects the color
+    {p_end}
+{p2colreset}{...}
+
+{pmore}
+    The confidence intervals produced by {cmd:cismooth} are placed behind
+    confidence intervals requested in {helpb coefplot##levels:levels()} and
+    {helpb coefplot##ci:ci()}. {helpb coefplot##ciopts:ciopts()} do not
+    apply to them.
+
+{dlgtab:Subgraph options}
+
+{marker bylabel}{...}
+{phang}
+    {cmd:bylabel(}{it:string}{cmd:)} provides a label for the subgraph. Use
+    double quotes to create multiline labels. For example,
+    {cmd:bylabel("This is a" "long label")} would create a two-line label. For
+    text effects (bold, italics, greek letters, etc.) use SMCL tags as
+    described in {it:{help graph_text}}.
+
+{pmore}
+    Subgraphs are implemented in terms of {helpb graph}'s {cmd:by()} option; see
+    {helpb coefplot##byopts:byopts()} below for options on how to combine and
+    render the subgraphs.
+
+{dlgtab:Global options}
+
+{marker horizontal}{...}
+{phang}
+    {cmd:horizontal} places coefficient values on the x axis. This is the
+    default unless {helpb coefplot##at:at} is specified.
+
+{marker vertical}{...}
+{phang}
+    {cmd:vertical} places coefficient values on the y axis. This is the
+    default if {helpb coefplot##at:at} is specified.
+
+{marker eqstrict}{...}
+{phang}
+    {cmd:eqstrict} causes equation names to be taken into account (i.e. match coefficients by
+    equation names and plot equation labels) even if there is only one equation per model.
+
+{marker order}{...}
+{phang}
+    {cmd:order(}{it:coeflist}{cmd:)} specifies the order of coefficients
+    (not allowed with {helpb coefplot##at:at}). The default is to use
+    the order as found in the input models (and place {cmd:_cons} last, within
+    equations). {it:coeflist} is a
+    space-separated list of elements such as:
+
+{p2colset 13 25 27 2}{...}
+{p2col:{cmd:.}}insert a gap
+    {p_end}
+{p2col:{it:eq}{cmd::.}}insert a gap within equation {it:eq}
+    {p_end}
+{p2col:{it:coef}}coefficient {it:coef}
+    {p_end}
+{p2col:{it:eq}{cmd::}}all coefficients from equation {it:eq}, in their current order
+    {p_end}
+{p2col:{it:eq}{cmd::}{it:coef}}coefficient {it:coef} from equation {it:eq}
+    {p_end}
+{p2colreset}{...}
+
+{pmore}
+    where {it:coef} may contain "{cmd:*}" (any string) and "{cmd:?}"
+    (any nonzero character) wildcards.
+
+{pmore}
+    If no equations are specified, then the requested order of coefficients
+    is repeated within each equation (keeping the existing order of
+    equations). Otherwise, the requested order is applied across equations.
+    Note that in the later case the first element in {cmd:order()} must be an
+    equation name. {it:eq} is applied to all subsequent elements until a
+    new {it:eq} is specified. For example,
+    {cmd:order(5:weight mpg * 4:turn *)} would yield the following order:
+    "{cmd:weight}" from equation "{cmd:5}", "{cmd:mpg}" from equation "{cmd:5}",
+    remaining coefficients from equation "{cmd:5}",
+    "{cmd:turn}" from equation "{cmd:4}", remaining coefficients from equation
+    "{cmd:4}", remaining equations if any.
+
+{marker orderby}{...}
+{phang}
+    {cmd:orderby(}[{it:subgraph}{cmd::}][{it:plot}]{cmd:)} orders the
+    coefficients by a specific model. By default, the coefficients are ordered
+    according to how they are provided to {cmd:coefplot}, with earlier plots
+    and subgraphs taking precedence over later ones (and placing {cmd:_cons}
+    last). This means that coefficients that only appear in later models will
+    be placed after the coefficients that appear in earlier models. Specify the
+    {cmd:orderby()} option if you want to change the default behavior and
+    arrange the coefficients according to their order in a specific model
+    (and, within each equation, place the other coefficients after these coefficients, but
+    before {cmd:_cons}). Arguments {it:subgraph} and {it:plot} select the relevant
+    model. For example, {cmd:orderby(2:3)} will order coefficients according to
+    the model that is displayed in the third plot of the second subgraph. If one
+    of the arguments is omitted, it defaults to one. Hence, {cmd:orderby(3)} will
+    order the coefficients according to the model displayed in the third plot
+    of the first subgraph; {cmd:orderby(2:)} will use the model displayed in the first
+    plot of the second subgraph. {cmd:orderby()} will do nothing if a specified subgraph or
+    plot does not exist. Furthermore, note that the {it:subgraph} argument
+    is not allowed if the {helpb coefplot##norecycle:norecycle} option has been
+    specified; plots are numbered uniquely across subgraphs in this case.
+
+{marker sort}{...}
+{phang}
+    {cmd:sort}[{cmd:(}{it:spec}{cmd:)}] sorts the coefficients by size. {it:spec} is
+
+            [{it:subgraph}{cmd::}][{it:plot}] [, {cmdab:d:escending} {cmd:by(}{it:stat}{cmd:)} ]
+
+{pmore}
+    where {it:subgraph} and {it:plot}, being equal to {cmd:.} or a positive
+    integer, identify the subgraph and plot to be used
+    to establish the sort order. For example, to sort based on all values in
+    the second subgraph (possibly including multiple plots), type
+    {cmd:sort(2:)} or {cmd:sort(2:.)}; to sort based on all values in the third
+    plot (possibly spanning multiple subgraphs), type {cmd:sort(3)} or
+    {cmd:sort(.:3)}; to sort based on the values of the third plot in the
+    second subgraph, type {cmd:sort(2:3)}. Specifying {cmd:sort} without
+    argument is equivalent to {cmd:sort(.:.)}, that is, to sort based on the
+    values in all available subgraphs and plots. If you specify a subgraph or
+    plot that does not exist, {cmd:sort()} will do nothing. Furthermore, if the
+    {helpb coefplot##norecycle:norecycle} option is specified, the {it:subgraph}
+    argument can be omitted as the plots will be uniquely numbered across
+    subgraphs.
+
+{pmore}
+    By default, the coefficients are sorted in ascending order of the values of
+    the point estimates. Specify suboption {cmd:descending} to use a
+    descending sort order. Furthermore, use {cmd:by(}{it:stat}{cmd:)} to change
+    the relevant statistic, where {it:stat} may be:
+
+{p2colset 13 25 27 2}{...}
+{p2col:{cmd:b}}sort by point estimate (the default){p_end}
+{p2col:{cmd:v} (or {cmd:se})}sort by variance (or standard error){p_end}
+{p2col:{cmd:t}}sort by t (or z) statistic{p_end}
+{p2col:{cmd:tabs}}sort by absolute t (or z) statistic{p_end}
+{p2col:{cmd:p}}sort by p-value{p_end}
+{p2col:{cmd:df}}sort by degrees of freedom{p_end}
+{p2col:{cmd:ll} [#]}sort by (#th) lower confidence limit; # defaults to 1{p_end}
+{p2col:{cmd:ul} [#]}sort by (#th) upper confidence limit; # defaults to 1{p_end}
+{p2col:{cmd:aux} [#]}sort by (#th) auxiliary variable (see the
+    {helpb coefplot##aux:aux()} option); # defaults to 1{p_end}
+{p2colreset}{...}
+
+{pmore}
+    In case of multiple equations, coefficients will be sorted separately
+    within each equation, keeping the original order of equations. Use the
+    {helpb coefplot##order:order()} option the change the order of the equations.
+
+{marker relocate}{...}
+{phang}
+    {cmd:relocate(}{it:spec}{cmd:)} assigns specific positions to the
+    coefficients on the category axis. {it:spec} is:
+
+            [{it:eq}{cmd::}]{it:coef} {cmd:=} # [[{it:eq}{cmd::}]{it:coef} {cmd:=} # ...]
+
+{pmore}
+    where {it:eq} and {it:coef} may contain "{cmd:*}" (any string) and
+    "{cmd:?}" (any nonzero character) wildcards. If {helpb coefplot##bycoefs:bycoefs} is
+    specified, use numbers (1, 2, ...) instead of {it:eq} and {it:coef}
+    to address the elements on the categorical axis.
+
+{pmore}The default for {cmd:coefplot} is to place coefficients
+    at integer values 1, 2, 3, ... (from top to bottom in horizontal mode,
+    from left to right in vertical mode). The {cmd:relocate()} option gives
+    you the possibility to specify alternative values. If, for example, you
+    want to place coefficient {cmd:mpg} at value 2.5 on the category axis, you
+    could type {cmd:relocate(mpg = 2.5)}. If you only want to change the
+    order of coefficients and are fine with integer positions, then use the
+    {helpb coefplot##order:order()} option. Note that the specified positions
+    are assigned before inserting gaps between equations, headings, and
+    groups (see {helpb coefplot##eqlabels:eqlabels()},
+    {helpb coefplot##headings:headings()}, and
+    {helpb coefplot##groups:groups()}). Hence, the final plot positions might
+    deviate from the specified positions if there are equation labels, headings,
+    or group labels.
+
+{marker bycoefs}{...}
+{phang}
+    {cmd:bycoefs} flips subgraphs and coefficients (not allowed with
+    {helpb coefplot##at:at}). If {cmd:bycoefs} is specified, a
+    separate subgraph is produced for each coefficient. In this
+    case, use integer numbers (1, 2, ...) instead of coefficient names
+    to address the elements on the categorical axis within options
+    {helpb coefplot##relocate:relocate()},
+    {helpb coefplot##headings:headings()}, and
+    {helpb coefplot##groups:groups()}.
+
+{marker norecycle}{...}
+{phang}
+    {cmd:norecycle} increments plot styles across subgraphs. The default is
+    to start over with each new subgraph.
+
+{marker nooffsets}{...}
+{phang}
+    {cmd:nooffsets} suppresses automatic offsets for plot positions.
+
+{marker format}{...}
+{phang}
+    {cmd:format(}{it:format}{cmd:)} sets the display format for
+    coefficients. This affects the rendition of the axis and marker
+    labels. {it:format} may be a numeric format or a date format
+    (see help {helpb format}).
+
+{marker pnum}{...}
+{phang}
+    {cmd:p{it:#}(}{help coefplot##plotopts:{it:plotopts}}{cmd:)} specifies
+    options for the {it:#}th plot. For example, type {cmd:p2(nokey)} to exclude
+    plot 2 from the legend (see {helpb coefplot##nokey:nokey}). Use the {cmd:p#()}
+    options as an alternative to specifying options directly within a plot; in
+    case of conflict, options specified within a plot take precedence
+    over options specified via {cmd:p#()}.
+
+{marker nolabels}{...}
+{phang}
+    {cmd:nolabels} causes coefficient names to be used as labels instead of
+    variable labels or value labels.
+
+{marker coeflabels}{...}
+{phang}
+    {cmd:coeflabels(}{it:spec}{cmd:)} specifies custom labels for
+    coefficients (not allowed with {helpb coefplot##at:at}). {it:spec} is
+
+{p 12 14 2}
+    [{it:coeflist} {cmd:=} {cmd:"}{it:label}{cmd:"} [{it:coeflist} {cmd:=} {cmd:"}{it:label}{cmd:"} ...]]
+    [{cmd:,} {cmdab:t:runcate(}#{cmd:)} {cmdab:w:rap(}#{cmd:)} {cmdab:nob:reak}
+    {cmdab:i:nteraction(}{it:string}{cmd:)}
+    {it:{help axis_label_options:suboptions}}]
+
+{pmore}
+    with {it:coeflist} as above for {helpb coefplot##keep:keep()}. Enclose
+    {it:label} in double quotes
+    if it contains spaces, e.g. {bind:{cmd:coeflabels(foreign = "Car Type")}}.
+    Enclose {it:label} in compound double quotes to create a multiline
+    label, e.g. {bind:{cmd:coeflabels(foreign = `""This is a" "long label""')}};
+    alternatively, apply the {cmd:wrap()} option. For text effects
+    (bold, italics, greek letters, etc.) use SMCL tags as described in
+    {it:{help graph_text}}.
+
+{pmore}
+    Option {cmd:truncate(}#{cmd:)} truncates coefficient labels to
+    a maximum length of # characters. Option {cmd:wrap(}#{cmd:)} divides
+    coefficient labels into multiple lines, where each line has a maximum
+    length of # characters. {cmd:truncate()} and {cmd:wrap()} operate on
+    words. That is, they try to fill to the maximum length without breaking
+    in the middle of a word. However, if a word is longer than # characters,
+    it will be split or truncated. Specify {cmd:nobreak} to prevent
+    {cmd:truncate()} and {cmd:wrap()} from splitting or truncating words
+    that are longer than # characters. If {cmd:truncate()} and {cmd:wrap()}
+    are both specified, {cmd:truncate()} is applied first.
+    {cmdab:interaction()} specifies the string to be used as
+    delimiter in labels for interaction terms; the default is
+    {cmd:interaction(" # ")}. {it:suboptions} are axis label suboptions as
+    described in {it:{help axis_label_options}}.
+
+{pmore}
+    Note: Labels containing multiple lines are left unchanged by {cmd:truncate()}
+    and {cmd:wrap()}. Therefore, if you don't like how {cmd:wrap()} breaks a
+    specific label, you can provide a custom variant of it in {cmd:coeflabels()}
+    while still using {cmd:wrap()} for the other labels. {cmd:truncate()}
+    and {cmd:wrap()} may fail to process a label if it contains compound
+    double quotes; the label will be left unchanged in this case.
+
+{marker noeqlabels}{...}
+{phang}
+    {cmd:noeqlabels} suppresses equation labels.
+
+{marker eqlabels}{...}
+{phang}
+    {cmd:eqlabels(}{it:spec}{cmd:)} specifies custom labels for equations, one after
+    the other (not allowed with {helpb coefplot##at:at}). {it:spec} is:
+
+{p 12 14 2}
+    [{cmd:"}{it:label}{cmd:"} [{cmd:"}{it:label}{cmd:"} ...]] [{cmd:,}
+    {cmdab:lab:els}[{cmd:(}{it:string}{cmd:)}]
+    [{cmd:{ul:no}}]{cmdab:g:ap}[{cmd:(}#{cmd:)}]  {cmdab:ashead:ings}
+    {cmdab:off:set(}#{cmd:)} {cmdab:t:runcate(}#{cmd:)} {cmdab:w:rap(}#{cmd:)}
+    {cmdab:nob:reak} {it:{help axis_label_options:suboptions}} ]
+
+{pmore}
+    Enclose labels in double quotes if they contain spaces,
+    e.g. {bind:{cmd:eqlabels("EQ one" "EQ two")}}. Enclose labels in compound
+    double quotes to create multiline labels,
+    e.g. {bind:{cmd:eqlabels(`""This is a" "long label""')}}. Alternatively,
+    apply the {cmd:wrap()} option. For text effects
+    (bold, italics, greek letters, etc.) use SMCL tags as described in
+    {it:{help graph_text}}.
+
+{pmore}
+    Option {cmd:label} causes the equation names to be treated as
+    variable names; {cmd:coefplot} will then use the corresponding variable labels
+    (and, depending on context, value labels) to label the equations. Specify
+    {cmd:label(}{it:string}{cmd:)} to set the string to be used as
+    delimiter in labels for interaction terms; typing {cmd:label} without argument
+    is equivalent to {cmd:label(" # ")}. {cmd:gap()} specifies the size of the
+    gap between equations. The
+    default is {cmd:gap(1)}. {cmd:nogap} suppresses the gap between
+    equations. {cmdab:asheadings} treats equation labels as headings;
+    see {helpb coefplot##headings:headings()}. {cmd:offset()}, only
+    allowed with {cmd:asheadings}, offsets the labels. {cmd:truncate()},
+    {cmd:wrap()}, {cmd:nobreak}, and {it:suboptions} are as above for
+    {helpb coefplot##coeflabels:coeflabels()}.
+
+{marker headings}{...}
+{phang}
+    {cmd:headings(}{it:spec}{cmd:)} adds headings between
+    coefficients (not allowed with {helpb coefplot##at:at}). {it:spec} is:
+
+{p 12 14 2}
+    {it:coeflist} {cmd:=} {cmd:"}{it:label}{cmd:"} [{it:coeflist} {cmd:=} {cmd:"}{it:label}{cmd:"} ...]
+    [{cmd:,} [{cmd:{ul:no}}]{cmdab:g:ap}[{cmd:(}#{cmd:)}]
+    {cmdab:off:set(}#{cmd:)} {cmdab:t:runcate(}#{cmd:)}
+    {cmdab:w:rap(}#{cmd:)} {cmdab:nob:reak}
+    {it:{help axis_label_options:suboptions}} ]
+
+{pmore}
+    with {it:coeflist} as above for {helpb coefplot##keep:keep()}. If
+    {helpb coefplot##bycoefs:bycoefs} is specified, use numbers 1, 2,
+    ... instead of {it:coeflist} to address the elements on the categorical
+    axis. Enclose {it:label} in double quotes if it contains
+    spaces. For example, {bind:{cmd:headings(0.foreign = "Car Type")}} will
+    print the heading "{cmd:Car Type}" before coefficient "{cmd:0.foreign}".
+    Enclose {it:label} in compound double quotes to create a multiline
+    label, e.g. {bind:{cmd:headings(foreign = `""This is a" "long heading""')}}.
+    Alternatively, apply the {cmd:wrap()} option. For text effects (bold,
+    italics, greek letters, etc.) use SMCL tags as
+    described in {it:{help graph_text}}.
+
+{pmore}
+    {cmd:gap()} and {cmdab:offset()} are as above for
+    {helpb coefplot##eqlabels:eqlabels()}. {cmd:truncate()}, {cmd:wrap()},
+    {cmd:nobreak}, and {it:suboptions} are as above for
+    {helpb coefplot##coeflabels:coeflabels()}.
+
+{marker groups}{...}
+{phang}
+    {cmd:groups(}{it:spec}{cmd:)} adds labels for groups of
+    coefficients (not allowed with {helpb coefplot##at:at}). The specified
+    label will be printed beside (or, in vertical mode, below) the identified
+    group of coefficients. {it:spec} is:
+
+{p 12 14 2}
+    {it:coeflist} {cmd:=} {cmd:"}{it:label}{cmd:"} [{it:coeflist} {cmd:=} {cmd:"}{it:label}{cmd:"} ...]
+    [{cmd:,} [{cmd:{ul:no}}]{cmdab:g:ap}[{cmd:(}#{cmd:)}]
+    {cmdab:t:runcate(}#{cmd:)} {cmdab:w:rap(}#{cmd:)}
+    {cmdab:nob:reak} {it:{help axis_label_options:suboptions}} ]
+
+{pmore}
+    with {it:coeflist} as above for {helpb coefplot##keep:keep()}. If
+    {helpb coefplot##bycoefs:bycoefs} is specified, use numbers 1, 2,
+    ... instead of {it:coeflist} to address the elements on the categorical
+    axis. Enclose {it:label} in double quotes if
+    it contains spaces. Enclose {it:label} in compound double quotes to create
+    a multiline label. Alternatively, apply the {cmd:wrap()} option. For text
+    effects (bold, italics, greek letters, etc.) use SMCL tags as described in
+    {it:{help graph_text}}.
+
+{pmore}
+    {cmd:gap()} is as above for
+    {helpb coefplot##eqlabels:eqlabels()}. {cmd:truncate()}, {cmd:wrap()},
+    {cmd:nobreak}, and {it:suboptions} are as above for
+    {helpb coefplot##coeflabels:coeflabels()}.
+
+{marker plotlabels}{...}
+{phang}
+    {cmd:plotlabels(}{it:spec}{cmd:)} specifies labels for the plots to be
+    used in the legend. Labels specified via {cmd:plotlabels()}
+    take precedence over labels specified in the
+    {helpb coefplot##label:label()} plot option. {it:spec} is:
+
+{p 12 14 2}
+    [{cmd:"}{it:label}{cmd:"} [{cmd:"}{it:label}{cmd:"} ...]] [{cmd:,} {cmdab:t:runcate(}#{cmd:)}
+    {cmdab:w:rap(}#{cmd:)} {cmdab:nob:reak} ]
+
+{pmore}
+    Enclose labels in double quotes if they contain spaces. Enclose labels in
+    compound double quotes to create multiline labels. Alternatively,
+    apply the {cmd:wrap()} option. For text effects
+    (bold, italics, greek letters, etc.) use SMCL tags as described in
+    {it:{help graph_text}}. Options {cmd:truncate()}, {cmd:wrap()}, and {cmd:nobreak} are as
+    above for {helpb coefplot##coeflabels:coeflabels()}.
+
+{marker bylabels}{...}
+{phang}
+    {cmd:bylabels(}{it:spec}{cmd:)} specifies labels for the subgraphs. Labels
+    specified via {cmd:bylabels()}
+    take precedence over labels specified in the
+    {helpb coefplot##bylabel:bylabel()} subgraph option. {it:spec} is:
+
+{p 12 14 2}
+    [{cmd:"}{it:label}{cmd:"} [{cmd:"}{it:label}{cmd:"} ...]] [{cmd:,} {cmdab:t:runcate(}#{cmd:)}
+    {cmdab:w:rap(}#{cmd:)} {cmdab:nob:reak} ]
+
+{pmore}
+    Enclose labels in double quotes if they contain spaces. Enclose labels in
+    compound double quotes to create multiline labels. Alternatively,
+    apply the {cmd:wrap()} option. For text effects
+    (bold, italics, greek letters, etc.) use SMCL tags as described in
+    {it:{help graph_text}}. Options {cmd:truncate()}, {cmd:wrap()}, and {cmd:nobreak} are as
+    above for {helpb coefplot##coeflabels:coeflabels()}.
+
+{marker grid}{...}
+{phang}
+    {cmd:grid(}{it:options}{cmd:)} affects the rendition of grid lines on the
+    category axis (not allowed with {helpb coefplot##at:at}). {it:options} are:
+
+{p 12 14 2}
+    { {cmdab:b:etween} | {cmdab:w:ithin} | {cmdab:n:one} } {it:{help axis_label_options:suboptions}}
+
+{pmore}
+    {cmdab:b:etween} places grid lines between coefficient labels;
+    {cmdab:w:ithin} places grid lines at the center of coefficient labels;
+    {cmdab:n:one} suppress grid lines. {it:suboptions} are axis label suboptions
+    as described in {it:{help axis_label_options}}. In horizontal mode, the
+    default is {cmd:within} for single plots and {cmd:between} for multiple
+    plots. In vertical mode, the default is {cmd:none}. Alternatively, use
+    {helpb axis_label_options:ytick()} and {helpb axis_label_options:xtick()}
+    to set grid lines.
+
+{marker generate}{...}
+{phang}
+    {cmd:generate}[{cmd:(}{it:prefix}{cmd:)}] generates variables containing
+    the graph data. The variable names will be prefixed by "{cmd:__}"
+    or as specified by {it:prefix}.
+
+{marker replace}{...}
+{phang}
+    {cmd:replace} allows {cmd:coefplot} to overwrite existing variables.
+
+{marker addplot}{...}
+{phang}
+    {cmd:addplot(}{it:plot}{cmd:)} adds other plots to the graph. See help
+    {it:{help addplot_option}}. By default {cmd:addplot()} has access only to
+    the first {it:r} observations in the dataset, where {it:r} is the number of
+    observations used by {cmd:coefplot} to store its internal results. If the
+    graph does not contain multiple subgraphs and
+    {helpb coefplot##generate:generate()} or {helpb coefplot##nodrop:nodrop} is
+    specified, {cmd:addplot()} has access to all observations.
+
+{marker nodrop}{...}
+{phang}
+    {cmd:nodrop} causes {cmd:coefplot} to keep all observations when generating
+    the graph. The default is to eliminate unused observations temporarily
+    to increase speed. {cmd:nodrop} may be useful in connection with the
+    {helpb coefplot##addplot:addplot()} option, if the graph does not contain
+    multiple subgraphs. {cmd:nodrop} has no effect if
+    {helpb coefplot##generate:generate()} is specified.
+    {p_end}
+
+{phang}
+    {it:twoway_options} are general twoway options, other than
+    {cmd:by()}, as documented in help {it:{help twoway_options}}.
+
+{marker byopts}{...}
+{phang}
+    {cmd:byopts(}{it:byopts}{cmd:)} determines how subgraphs
+    are combined. {it:byopts} are as described in help {it:{help by_option}}.
+
+
+{marker examples}{...}
+{title:Examples}
+
+        . {stata sysuse auto}
+        . {stata regress price mpg headroom trunk length turn}
+        . {stata coefplot, drop(_cons) xline(0)}
+
+        . {stata regress price mpg headroom trunk length turn if foreign==0}
+        . {stata estimates store domestic}
+        . {stata regress price mpg headroom trunk length turn if foreign==1}
+        . {stata estimates store foreign}
+        . {stata coefplot domestic foreign, drop(_cons) xline(0)}
+
+        . {stata coefplot domestic || foreign, drop(_cons) xline(0)}
+
+        . {stata coefplot domestic || foreign, yline(0) bycoefs vertical byopts(yrescale)}
+
+{pstd}
+    For further examples see the {browse "http://repec.sowi.unibe.ch/stata/coefplot":website},
+    the {browse "http://www.stata-journal.com/article.html?article=gr0059":Stata Journal article}, or the
+    {browse "http://ideas.repec.org/p/bss/wpaper/1.html":working paper}.
+
+
+{marker remarks}{...}
+{title:Remarks}
+
+{pstd}
+    Remarks are presented under the following headings:
+
+        {help coefplot##wildcards:Using wildcards in model names}
+        {help coefplot##place:Placement of options}
+        {help coefplot##matrix:Plotting results from matrices}
+        {help coefplot##tempvar:Accessing internal temporary variables}
+
+
+{marker wildcards}{...}
+{title:Using wildcards in model names}
+
+{pstd}
+    Instead of providing distinct model names to {cmd:coefplot}, you can also
+    specify a name pattern containing {cmd:*} (any string)
+    and {cmd:?} (any nonzero character) wildcards. {cmd:coefplot}
+    will then plot the results from all matching
+    models. If a name pattern is specified as part of a plot delimited by
+    parentheses, the results from the matching models will be combined into the
+    same plot. For example, if models {cmd:est11}, {cmd:est12}, {cmd:est13},
+    {cmd:est21}, {cmd:est22}, and {cmd:est23} are in
+    memory, typing
+
+{com}{...}
+        . coefplot (est1*, {txt:{it:opts1}}) (est2*, {txt:{it:opts2}})
+{txt}{...}
+
+{pstd}
+    is equivalent to
+
+{com}{...}
+        . coefplot (est11 \ est12 \ est13, {txt:{it:opts1}}) (est21 \ est22 \ est23, {txt:{it:opts2}})
+{txt}{...}
+
+{pstd}
+    Likewise, typing
+
+{com}{...}
+        . coefplot (est*1, {txt:{it:opts1}} \ est*2, {txt:{it:opts2}} \, {txt:{it:opts3}})
+{txt}{...}
+
+{pstd}
+    is equivalent to
+
+{com}{...}
+        . coefplot (est11, {txt:{it:opts1}} \ est21, {txt:{it:opts1}} \ est12, {txt:{it:opts2}} \ est22, {txt:{it:opts2}} \, {txt:{it:opts3}})
+{txt}{...}
+
+{pstd}
+    Alternatively, if a name pattern is specified without parentheses,
+    the matching models are treated as separate plots. For example, typing
+
+{com}{...}
+        . coefplot est1* || est2*
+{txt}{...}
+
+{pstd}
+    is equivalent to
+
+{com}{...}
+        . coefplot est11 est12 est13 || est21 est22 est23
+{txt}{...}
+
+{pstd}
+    or
+
+{com}{...}
+        . coefplot (est11) (est12) (est13) || (est21) (est22) (est23)
+{txt}{...}
+
+{pstd}
+    Use global options {helpb coefplot##pnum:p1()}, {helpb coefplot##pnum:p2()},
+    etc. to provide specific options to the different plots in this case. For
+    example, typing
+
+{com}{...}
+        . coefplot est1*, p1({txt:{it:opts1}}) p2({txt:{it:opts2}}) p3({txt:{it:opts3}})
+{txt}{...}
+
+{pstd}
+    is equivalent to
+
+{com}{...}
+        . coefplot (est11, {txt:{it:opts1}}) (est12, {txt:{it:opts2}}) (est13, {txt:{it:opts3}})
+{txt}{...}
+
+
+{marker place}{...}
+{title:Placement of options}
+
+{pstd}
+    {cmd:coefplot} has four levels of options:
+
+{phang}(1) {help coefplot##modelopts:{it:modelopts}} are options that apply to a single
+    model (or matrix). They specify the information to be displayed.
+
+{phang}(2) {help coefplot##plotopts:{it:plotopts}} are options that apply to a single
+    plot, possibly containing results from multiple models. They affect
+    the rendition of markers and confidence intervals and provide a label
+    for the plot.
+
+{phang}(3) {help coefplot##subgropts:{it:subgropts}} are options that
+    apply to a single subgraph, possibly containing multiple plots.
+
+{phang}(4) {help coefplot##globalopts:{it:globalopts}} are options that apply
+    to the overall graph.
+
+{pstd}
+    The levels are nested in the sense that upper level options include all
+    lower level options. That is,
+    {help coefplot##globalopts:{it:globalopts}} includes
+    {help coefplot##subgropts:{it:subgropts}},
+    {help coefplot##plotopts:{it:plotopts}}, and
+    {help coefplot##modelopts:{it:modelopts}};
+    {help coefplot##subgropts:{it:subgropts}} includes
+    {help coefplot##plotopts:{it:plotopts}}, and
+    {help coefplot##modelopts:{it:modelopts}};
+    {help coefplot##plotopts:{it:plotopts}} includes
+    {help coefplot##modelopts:{it:modelopts}}. However, upper level options
+    may not be specified at a lower level.
+
+{pstd}
+    If lower level options are specified at an upper level, they serve as
+    defaults for all included lower levels elements. For example, if you want
+    to draw 99% and 95% confidence intervals for all included models,
+    specify {cmd:levels(99 95)} as global option:
+
+{com}{...}
+        . coefplot model1 model2 model3, levels(99 95)
+{txt}{...}
+
+{pstd}
+    Options specified with an individual element override the defaults set
+    by upper level options. For example, if you want to draw 99% and 95%
+    confidence intervals for model 1 and model 2 and 90% confidence intervals
+    for model 3, you could type:
+
+{com}{...}
+        . coefplot model1 model2 (model3, level(90)), levels(99 95)
+{txt}{...}
+
+{pstd}
+    There are some fine distinctions about the placement of options and how they
+    are interpreted. For example, if you type
+
+{com}{...}
+        . coefplot m1, {txt:{it:opts1}} || m2, {txt:{it:opts2}} {txt:{it:opts3}}
+{txt}{...}
+
+{pstd}
+    then {it:opts2} and {it:opts3} are interpreted as global options. If you
+    want to apply {it:opts2} only to {cmd:m2} then type
+
+{com}{...}
+        . coefplot m1, {txt:{it:opts1}} || m2, {txt:{it:opts2}} ||, {txt:{it:opts3}}
+{txt}{...}
+
+{pstd}
+    Similarly, if you type
+
+{com}{...}
+        . coefplot (m1, {txt:{it:opts1}} \ m2, {txt:{it:opts2}})
+{txt}{...}
+
+{pstd}
+    then {it:opts2} will be applied to both models. To apply {it:opts2} only to
+    {cmd:m2} type
+
+{com}{...}
+        . coefplot (m1, {txt:{it:opts1}} \ m2, {txt:{it:opts2}} \)
+{txt}{...}
+
+{pstd}
+    or, if you also want to include {it:opts3} to be applied to both models,
+    type
+
+{com}{...}
+        . coefplot (m1, {txt:{it:opts1}} \ m2, {txt:{it:opts2}} \, {txt:{it:opts3}})
+{txt}{...}
+
+{pstd}
+    or
+
+{com}{...}
+        . coefplot (m1, {txt:{it:opts1}} \ m2, {txt:{it:opts2}} \), {txt:{it:opts3}}
+{txt}{...}
+
+{pstd}
+    In case of multiple subgraphs there is some ambiguity about where to
+    specify the plot options (unless global option
+    {helpb coefplot##norecycle:norecycle} is specified). You can provide plot
+    options within any of the subgraphs as plot options are collected across
+    subgraphs. However, in case of conflict, the plot options from the rightmost
+    subgraph usually take precedence over earlier plot options. In addition,
+    you can also use global options {helpb coefplot##pnum:p1()},
+    {helpb coefplot##pnum:p2()}, etc. to provide
+    options for specific plots. In case of conflict, options specified within a plot take
+    precedence over options provided via {helpb coefplot##pnum:p1()},
+    {helpb coefplot##pnum:p2()}, etc.
+
+{marker matrix}{...}
+{title:Plotting results from matrices}
+
+{pstd}
+    Use syntax {helpb coefplot##matrix:{ul:m}atrix({it:mspec})} instead of the
+    name of a stored model to plot results from a matrix. {it:mspec} may be:
+
+{p2colset 9 21 23 2}{...}
+{p2col:{it:name}}use first row of matrix {it:name}
+    {p_end}
+{p2col:{it:name}{cmd:[}#{cmd:,.]}}use #th row of
+    matrix {it:name}; may also type {it:name}{cmd:[}#{cmd:,]} or
+    {it:name}{cmd:[}#{cmd:]}
+    {p_end}
+{p2col:{it:name}{cmd:[.,}#{cmd:]}}use #th column of
+    matrix {it:name}; may also type {it:name}{cmd:[,}#{cmd:]}
+    {p_end}
+{p2colreset}{...}
+
+{pstd}
+    If the {cmd:matrix()} syntax is used, then option {helpb coefplot##b:b()} is discarded
+    and names given in {helpb coefplot##at:at()}, {helpb coefplot##ci:ci()},
+    {helpb coefplot##v:v()}, {helpb coefplot##se:se()},
+    {helpb coefplot##df:df()}, and {helpb coefplot##aux:aux()} refer to regular
+    matrices instead of {cmd:e()}-matrices. The matrix name may be omitted in these
+    options if results are to be read from the same matrix; only the
+    relevant row or column numbers have to be provided (whether the
+    numbers are interpreted as row or column numbers
+    depends what was specified in {cmd:matrix()}).
+
+{pstd}
+    For example, to plot medians and their confidence intervals as computed
+    by {helpb centile} you could type:
+
+{com}{...}
+        sysuse auto, clear
+        matrix C = J(3,3,.)
+        matrix rownames C = median ll95 ul95
+        matrix colnames C = mpg trunk turn
+        local i 0
+        foreach v of var mpg trunk turn {
+            local ++ i
+            centile `v'
+            matrix C[1,`i'] = r(c_1) \ r(lb_1) \ r(ub_1)
+        }
+        matrix list C
+        coefplot matrix(C), ci((2 3))
+{txt}{...}
+
+{pstd}
+    This is equivalent to:
+
+{com}{...}
+        coefplot matrix(C[1]), ci((C[2] C[3]))
+{txt}{...}
+
+{pstd}
+    Note that a single {cmd:coefplot} command can contain both regular syntax
+    and {cmd:matrix()} syntax. For example, to add means to the graph above
+    you could type:
+
+{com}{...}
+        mean mpg trunk turn
+        estimates store mean
+        coefplot (matrix(C), ci((2 3))) (mean)
+{txt}{...}
+
+
+{marker tempvar}{...}
+{title:Accessing internal temporary variables}
+
+{pstd}
+    {cmd:coefplot} maintains a number of internal variables that can be
+    used within
+    {helpb coefplot##ifopt:if()},
+    {helpb coefplot##weight:weight()},
+    {helpb coefplot##transform:transform()},
+    {helpb marker_label_options:mlabel()},
+    {helpb marker_label_options:mlabvposition()}, and
+    {helpb addplot_option:addplot()}. These
+    variables are:
+
+{p2colset 9 21 23 2}{...}
+{p2col:{cmd:@b}}point estimates
+    {p_end}
+{p2col:{cmd:@ll}#}lower limits of confidence interval # (may use {cmd:@ll} for {cmd:@ll1})
+    {p_end}
+{p2col:{cmd:@ul}#}upper limits of confidence interval # (may use {cmd:@ul} for {cmd:@ul1})
+    {p_end}
+{p2col:{cmd:@V}}variances
+    {p_end}
+{p2col:{cmd:@se}}standard errors
+    {p_end}
+{p2col:{cmd:@t}}t or z statistics, computed as @b/@se
+    {p_end}
+{p2col:{cmd:@df}}degrees of freedom
+    {p_end}
+{p2col:{cmd:@pval}}p-values, computed as (1-normal(|@t|))*2 or ttail(@df,|@t|)*2, depending
+    on whether df are available
+    {p_end}
+{p2col:{cmd:@at}}plot positions
+    {p_end}
+{p2col:{cmd:@plot}}plot ID (labeled)
+    {p_end}
+{p2col:{cmd:@by}}subgraph ID (labeled)
+    {p_end}
+{p2col:{cmd:@mlbl}}Marker labels set by {helpb coefplot##mlabels:mlabels()} (string variable)
+    {p_end}
+{p2col:{cmd:@mlpos}}Marker label positions set by {helpb coefplot##mlabels:mlabels()}
+    {p_end}
+{p2col:{cmd:@aux}#}auxiliary variables collected by {helpb coefplot##aux:aux()} (may use {cmd:@aux} for {cmd:@aux1})
+    {p_end}
+{p2colreset}{...}
+
+{pstd}
+    The internal variables can be used like other variables in the
+    dataset. For example, option {cmd:mlabel(@plot)} would add plot labels as marker
+    labels or option {cmd:addplot(line @at @b)} would draw a connecting line
+    through all point estimates in the graph.
+
+
+{marker saved_results}{...}
+{title:Saved results}
+
+{pstd}
+    {cmd:coefplot} returns the following macros and scalars in {cmd:r()}:
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Scalars}{p_end}
+{synopt:{cmd:r(n_ci)}}number of confidence intervals{p_end}
+{synopt:{cmd:r(n_plot)}}number of plots{p_end}
+{synopt:{cmd:r(n_subgr)}}number of subgraphs{p_end}
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Macros}{p_end}
+{synopt:{cmd:r(graph)}}copy of graph command{p_end}
+{synopt:{cmd:r(labels)}}coefficient labels{p_end}
+{synopt:{cmd:r(eqlabels)}}equation labels{p_end}
+{synopt:{cmd:r(groups)}}group labels{p_end}
+{synopt:{cmd:r(headings)}}headings{p_end}
+{synopt:{cmd:r(legend)}}contents of legend option{p_end}
+
+
+{marker author}{...}
+{title:Author}
+
+{pstd}
+    Ben Jann, University of Bern, [email protected]
+
+{pstd}
+    Thanks for citing this software in one of the following ways:
+
+{pmore}
+    Jann, B. (2014). Plotting regression coefficients and other
+    estimates. The Stata Journal 14(4): 708-737.
+
+{pmore}
+    Jann, B. (2013). Plotting regression coefficients and other estimates
+    in Stata. University of Bern Social Sciences Working Papers
+    Nr. 1. Available from
+    {browse "http://ideas.repec.org/p/bss/wpaper/1.html"}.
+
+{pmore}
+    Jann, B. (2013). coefplot: Stata module to plot regression coefficients
+    and other results. Available from
+    {browse "http://ideas.repec.org/c/boc/bocode/s457686.html"}.
+
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/e/estadd.ado

@@ -0,0 +1,2463 @@
+*! version 2.3.3  28may2014  Ben Jann
+*  1. estadd and helpers
+*  2. estadd_local
+*  3. estadd_scalar
+*  4. estadd_matrix
+*  5. estadd_mean
+*  6. estadd_sd
+*  7. estadd_beta
+*  8. estadd_coxsnell
+*  9. estadd_nagelkerke
+* 10. estadd_ysumm
+* 11. estadd_summ
+* 12. estadd_vif
+* 13. estadd_ebsd
+* 14. estadd_expb
+* 15. estadd_pcorr
+* 16. estadd_lrtest
+* 17. estadd_brent
+* 18. estadd_fitstat
+* 19. estadd_listcoef
+* 20. estadd_mlogtest
+* 21. estadd_prchange
+* 22. estadd_prvalue
+* 23. estadd_asprvalue
+* 24. estadd_margins
+* 99. copy of erepost.ado
+
+* 1.
+program estadd
+    version 8.2
+    local caller : di _caller()
+    capt _on_colon_parse `0'
+    if !_rc {
+        local 0 `"`s(before)'"'
+        local names `"`s(after)'"'
+    }
+    syntax anything(equalok id="subcommand") [if] [in] [fw aw iw pw] [, * ]
+    if regexm(`"`anything'"',"^r\((.*)\)$") {  // check -estadd r(name)-
+        capt confirm scalar `anything'
+        if _rc {
+            capt confirm matrix `anything'
+            if _rc {
+                di as err `"`anything' not found"'
+                exit 111
+            }
+            else {
+                local anything `"matrix `anything'"'
+            }
+        }
+        else {
+            local anything `"scalar `anything'"'
+        }
+    }
+    gettoken subcommand : anything
+    capt confirm name `subcommand'
+    if _rc {
+        di as err "invalid subcommand"
+        exit 198
+    }
+    if `"`options'"'!="" local options `", `options'"'
+    if `"`weight'`exp'"'!="" local wgtexp `"[`weight'`exp']"'
+
+//expand estimates names and backup current estimates if necessary
+    tempname rcurrent ecurrent
+    capt _return drop `rcurrent'
+    _return hold `rcurrent'
+    capt noisily {
+        local names: list retok names
+        if "`names'"=="" {
+            local names "."
+            local qui
+        }
+        else local qui quietly
+        foreach name of local names {
+            if "`name'"=="." {
+                capt est_expand "`name'"
+                if _rc local enames "`enames'`name' "
+                else local enames "`enames'`r(names)' "
+            }
+            else {
+                est_expand "`name'" //=> error if estimates not found
+                local enames "`enames'`r(names)' "
+            }
+        }
+        local names: list uniq enames
+        if "`names'"=="." local active
+        else {
+            capt est_expand .
+            if _rc local active "."
+            else local active "`r(names)'"
+            if "`active'"=="." | `:list posof "`active'" in names'==0 {
+                local active
+                _est hold `ecurrent', restore estsystem nullok
+            }
+        }
+    }
+    if _rc {
+        _return restore `rcurrent'
+        exit _rc
+    }
+    _return restore `rcurrent', hold
+
+// cases:
+// - if active estimates not stored yet and "`names'"==".": simply execute
+//   estadd_subcmd to active estimates
+// - else if active estimates not stored yet: backup/restore active estimates
+// - else if active estimates stored but not in `names': backup/restore active estimates
+// - else if active estimates stored: no backup but restore at end
+
+//loop over estimates names and run subcommand
+    nobreak {
+        foreach m of local names {
+            if "`names'"!="." {
+                if "`m'"=="." _est unhold `ecurrent'
+                else {
+                    capt confirm new var _est_`m' // fix e(sample)
+                    if _rc qui replace _est_`m' = 0 if _est_`m' >=.
+                    _est unhold `m'
+                }
+            }
+            backup_estimates_name
+            capt n break `qui' version `caller': estadd_`anything' `if' `in' `wgtexp' `options'
+            local rc = _rc
+            restore_estimates_name
+            if "`names'"!="." {
+                if "`m'"=="." _est hold `ecurrent', restore estsystem nullok
+                else _est hold `m', estimates varname(_est_`m')
+            }
+            if `rc' continue, break
+        }
+        if "`active'"!="" estimates restore `active', noh
+    }
+    _return restore `rcurrent'
+    if `rc' {
+        if `rc' == 199 di as error "invalid subcommand"
+        exit `rc'
+    }
+end
+
+program define backup_estimates_name, eclass
+    ereturn local _estadd_estimates_name `"`e(_estimates_name)'"'
+    ereturn local _estimates_name ""
+end
+program define restore_estimates_name, eclass
+    ereturn local _estimates_name `"`e(_estadd_estimates_name)'"'
+    ereturn local _estadd_estimates_name ""
+end
+
+program confirm_new_ename
+    capture confirm existence `e(`0')'
+    if !_rc {
+        di as err "e(`0') already defined"
+        exit 110
+    }
+end
+
+program confirm_esample
+    local efun: e(functions)
+    if `:list posof "sample" in efun'==0 {
+        di as err "e(sample) information not available"
+        exit 498
+    }
+end
+
+program confirm_numvar
+    args var
+    local ts = index("`var'",".")
+    confirm numeric variable `=substr("`var'",`ts'+1,.)'
+end
+
+program define added_macro
+    args name
+    di as txt %25s `"e(`name') : "' `""{res:`e(`name')'}""'
+end
+
+program define added_scalar
+    args name label
+    di as txt %25s `"e(`name') = "' " " as res e(`name') _c
+    if `"`label'"'!="" {
+        di as txt _col(38) `"(`label')"'
+    }
+    else di ""
+end
+
+program define added_matrix
+    args name label
+    capture {
+        local r = rowsof(e(`name'))
+        local c = colsof(e(`name'))
+    }
+    if _rc {
+        tempname tmp
+        mat `tmp' = e(`name')
+        local r = rowsof(`tmp')
+        local c = colsof(`tmp')
+    }
+    di as txt %25s `"e(`name') : "' " " ///
+        as res "`r' x `c'" _c
+    if `"`label'"'=="_rown" {
+        local thelabel: rownames e(`name')
+        local thelabel: list retok thelabel
+        if `r'>1 {
+            local thelabel: subinstr local thelabel " " ", ", all
+        }
+        di as txt _col(38) `"(`thelabel')"'
+    }
+    else if `"`label'"'!="" {
+        di as txt _col(38) `"(`label')"'
+    }
+    else di ""
+end
+
+* 2.
+* -estadd- subroutine: add local
+program estadd_loc
+    estadd_local `0'
+end
+program estadd_loca
+    estadd_local `0'
+end
+program estadd_local, eclass
+    version 8.2
+    syntax anything(equalok) [, Prefix(name) Replace Quietly ]
+    gettoken name def : anything , parse(" =:")
+    if "`replace'"=="" {
+        confirm_new_ename `prefix'`name'
+    }
+    ereturn local `prefix'`name'`def'
+    di _n as txt "added macro:"
+    added_macro `prefix'`name'
+end
+
+* 3.
+* -estadd- subroutine: add scalar
+program estadd_sca
+    estadd_scalar `0'
+end
+program estadd_scal
+    estadd_scalar `0'
+end
+program estadd_scala
+    estadd_scalar `0'
+end
+program estadd_scalar, eclass
+    version 8.2
+    syntax anything(equalok) [, Prefix(name) Replace Quietly ]
+    if regexm("`anything'","^r\((.*)\)$") {     // estadd scalar r(name)
+        local name = regexs(1)
+        capt confirm name `name'
+        confirm scalar `anything'
+        if _rc error 198
+        local equ  "`anything'"
+    }
+    else {
+        local isname 0
+        gettoken name equ0: anything, parse(" =")
+        capt confirm name `name'
+        if _rc error 198
+        else if `"`equ0'"'==""  {               // estadd scalar name
+            local isname 1
+            local equ  "scalar(`name')"
+        }
+        else {                                  // estadd scalar name [=] exp
+            gettoken trash equ : equ0, parse(" =")
+            if `"`trash'"'!="=" {
+                local equ `"`equ0'"'
+            }
+        }
+    }
+    if "`replace'"=="" {
+        confirm_new_ename `prefix'`name'
+    }
+    ereturn scalar `prefix'`name' = `equ'
+    di _n as txt "added scalar:"
+    added_scalar `prefix'`name'
+end
+
+* 4.
+* -estadd- subroutine: add matrix
+program estadd_mat
+    estadd_matrix `0'
+end
+program estadd_matr
+    estadd_matrix `0'
+end
+program estadd_matri
+    estadd_matrix `0'
+end
+program estadd_matrix, eclass
+    version 8.2
+    syntax anything(equalok) [, Prefix(name) Replace Quietly ]
+    if regexm("`anything'","^r\((.*)\)$") {     // estadd matrix r(name)
+        local name = regexs(1)
+        capt confirm name `name'
+        if _rc error 198
+        confirm matrix `anything'
+        local equ  "`anything'"
+    }
+    else {
+        local isname 0
+        gettoken name equ0: anything, parse(" =")
+        capt confirm name `name'
+        if _rc error 198
+        else if `"`equ0'"'==""  {               // estadd matrix name
+            local isname 1
+            local equ  "`name'"
+        }
+        else {                                  // estadd matrix name [=] exp
+            gettoken trash equ : equ0, parse(" =")
+            if `"`trash'"'!="=" {
+                local equ `"`equ0'"'
+            }
+        }
+    }
+    if "`replace'"=="" {
+        confirm_new_ename `prefix'`name'
+    }
+    tempname M
+    mat `M' = `equ'
+    ereturn matrix `prefix'`name' = `M'
+    di _n as txt "added matrix:"
+    added_matrix `prefix'`name'
+end
+
+* 5.
+* -estadd- subroutine: means of regressors
+program define estadd_mean, eclass
+    version 8.2
+    syntax [, Prefix(name) Replace Quietly ]
+//check availability of e(sample)
+    confirm_esample
+//check e()-names
+    if "`replace'"=="" confirm_new_ename `prefix'mean
+//use aweights with -summarize-
+    local wtype `e(wtype)'
+    if "`wtype'"=="pweight" local wtype aweight
+//subpop?
+    local subpop "`e(subpop)'"
+    if "`subpop'"=="" local subpop 1
+//copy coefficients matrix and determine varnames
+    tempname results
+    mat `results' = e(b)
+    local vars: colnames `results'
+//loop over variables: calculate -mean-
+    local j 0
+    foreach var of local vars {
+        local ++j
+        capture confirm_numvar `var'
+        if _rc mat `results'[1,`j'] = .z
+        else {
+            capt su `var' [`wtype'`e(wexp)'] if e(sample) & `subpop', meanonly
+            mat `results'[1,`j'] = cond(_rc,.,r(mean))
+        }
+    }
+//return the results
+    ereturn matrix `prefix'mean = `results'
+    di _n as txt "added matrix:"
+    added_matrix `prefix'mean
+end
+
+* 6.
+* -estadd- subroutine: standard deviations of regressors
+program define estadd_sd, eclass
+    version 8.2
+    syntax [, noBinary Prefix(name) Replace Quietly ]
+//check availability of e(sample)
+    confirm_esample
+//check e()-names
+    if "`replace'"=="" confirm_new_ename `prefix'sd
+//use aweights with -summarize-
+    local wtype `e(wtype)'
+    if "`wtype'"=="pweight" local wtype aweight
+//subpop?
+    local subpop "`e(subpop)'"
+    if "`subpop'"=="" local subpop 1
+//copy coefficients matrix and determine varnames
+    tempname results
+    mat `results' = e(b)
+    local vars: colnames `results'
+//loop over variables: calculate -mean-
+    local j 0
+    foreach var of local vars {
+        local ++j
+        capture confirm_numvar `var'
+        if _rc mat `results'[1,`j'] = .z
+        else {
+            capture assert `var'==0 | `var'==1 if e(sample) & `subpop'
+            if _rc | "`binary'"=="" {
+                capt su `var' [`wtype'`e(wexp)'] if e(sample) & `subpop'
+                mat `results'[1,`j'] = cond(_rc,.,r(sd))
+            }
+            else mat `results'[1,`j'] = .z
+        }
+    }
+//return the results
+    ereturn matrix `prefix'sd = `results'
+    di _n as txt "added matrix:"
+    added_matrix `prefix'sd
+end
+
+* 7.
+* -estadd- subroutine: standardized coefficients
+program define estadd_beta, eclass
+    version 8.2
+    syntax [, Prefix(name) Replace Quietly ]
+//check availability of e(sample)
+    confirm_esample
+//check e()-names
+    if "`replace'"=="" confirm_new_ename `prefix'beta
+//use aweights with -summarize-
+    local wtype `e(wtype)'
+    if "`wtype'"=="pweight" local wtype aweight
+//subpop?
+    local subpop "`e(subpop)'"
+    if "`subpop'"=="" local subpop 1
+//copy coefficients matrix and determine varnames
+    tempname results sddep
+    mat `results' = e(b)
+    local vars: colnames `results'
+    local eqs: coleq `results', q
+    local depv "`e(depvar)'"
+//loop over variables: calculate -beta-
+    local j 0
+    local lastdepvar
+    foreach var of local vars {
+        local depvar: word `++j' of `eqs'
+        if "`depvar'"=="_" local depvar "`depv'"
+        capture confirm_numvar `depvar'
+        if _rc mat `results'[1,`j'] = .z
+        else {
+            if "`depvar'"!="`lastdepvar'" {
+                capt su `depvar' [`wtype'`e(wexp)'] if e(sample) & `subpop'
+                scalar `sddep' = cond(_rc,.,r(sd))
+            }
+            capture confirm_numvar `var'
+            if _rc mat `results'[1,`j'] = .z
+            else {
+                capt su `var' [`wtype'`e(wexp)'] if e(sample) & `subpop'
+                mat `results'[1,`j'] = cond(_rc,.,`results'[1,`j'] * r(sd) / `sddep')
+            }
+        }
+        local lastdepvar "`depvar'"
+    }
+//return the results
+    ereturn matrix `prefix'beta = `results'
+    di _n as txt "added matrix:"
+    added_matrix `prefix'beta
+end
+
+* 8.
+* -estadd- subroutine: Cox & Snell Pseudo R-Squared
+program define estadd_coxsnell, eclass
+    version 8.2
+    syntax [, Prefix(name) Replace Quietly ]
+//check e()-names
+    if "`replace'"=="" confirm_new_ename `prefix'coxsnell
+//compute statistic
+    tempname results
+    scalar `results' = 1 - exp((e(ll_0)-e(ll))*2/e(N))  // = 1 - exp(e(ll_0)-e(ll))^(2/e(N))
+//return the results
+    *di as txt "Cox & Snell Pseudo R2 = " as res `results'
+    ereturn scalar `prefix'coxsnell = `results'
+    di _n as txt "added scalar:"
+    added_scalar `prefix'coxsnell
+end
+
+* 9.
+* -estadd- subroutine: Nagelkerke Pseudo R-Squared
+program define estadd_nagelkerke, eclass
+    version 8.2
+    syntax [, Prefix(name) Replace Quietly ]
+//check e()-names
+    if "`replace'"=="" confirm_new_ename `prefix'nagelkerke
+//compute statistic
+    tempname results
+    scalar `results' = (1 - exp((e(ll_0)-e(ll))*2/e(N))) / (1 - exp(e(ll_0)*2/e(N)))
+        // = (1 - exp(e(ll_0)-e(ll))^(2/e(N))) / (1 - exp(e(ll_0))^(2/e(N)))
+//return the results
+    *di as txt "Nagelkerke Pseudo R2 = " as res `results'
+    ereturn scalar `prefix'nagelkerke = `results'
+    di _n as txt "added scalar:"
+    added_scalar `prefix'nagelkerke
+end
+
+* 10.
+* -estadd- subroutine: summary statistics for dependent variable
+program define estadd_ysumm, eclass
+    version 8.2
+    syntax [, MEan SUm MIn MAx RAnge sd Var cv SEMean SKewness ///
+     Kurtosis MEDian p1 p5 p10 p25 p50 p75 p90 p95 p99 iqr q all ///
+     Prefix(passthru) Replace Quietly ]
+//check availability of e(sample)
+    confirm_esample
+//default prefix
+    if `"`prefix'"'=="" local prefix y
+    else {
+        local 0 ", `prefix'"
+        syntax [, prefix(name) ]
+    }
+//use aweights with -summarize-
+    local wtype `e(wtype)'
+    if "`wtype'"=="pweight" local wtype aweight
+//subpop?
+    local subpop "`e(subpop)'"
+    if "`subpop'"=="" local subpop 1
+//determine list of stats
+    tempname results
+    local Stats p99 p95 p90 p75 p50 p25 p10 p5 p1 kurtosis ///
+     skewness var sd max min sum mean
+    if "`all'"!="" {
+        local stats `Stats'
+        local range range
+        local cv cv
+        local semean semean
+        local iqr iqr
+        local sumtype detail
+    }
+    else {
+        if "`q'"!="" {
+            local p25 p25
+            local p50 p50
+            local p75 p75
+        }
+        if "`median'"!="" local p50 p50
+        foreach stat of local Stats {
+            if "``stat''"!="" {
+                local stats: list stats | stat
+            }
+        }
+        if "`stats'"=="" & "`range'"=="" & "`cv'"=="" & ///
+         "`semean'"=="" & "`iqr'"=="" local stats sd max min mean
+        local sumtype sum mean min max
+        if "`:list stats - sumtype'"=="" & "`cv'"=="" & ///
+         "`semean'"=="" & "`iqr'"=="" local sumtype meanonly
+        else {
+            local sumtype `sumtype' Var sd
+            if "`:list stats - sumtype'"=="" & "`iqr'"=="" local sumtype
+            else local sumtype detail
+        }
+    }
+    local Stats: subinstr local stats "var" "Var"
+    local nstats: word count `iqr' `semean' `cv' `range' `stats'
+    if "`replace'"=="" {
+        foreach stat in `iqr' `semean' `cv' `range' `stats' {
+            confirm_new_ename `prefix'`=lower("`stat'")'
+        }
+    }
+//calculate stats
+    local var: word 1 of `e(depvar)'
+    mat `results' = J(`nstats',1,.z)
+    qui su `var' [`wtype'`e(wexp)'] if e(sample) & `subpop', `sumtype'
+    local i 0
+    if "`iqr'"!="" {
+        mat `results'[`++i',1] = r(p75) - r(p25)
+    }
+    if "`semean'"!="" {
+        mat `results'[`++i',1] = r(sd) / sqrt(r(N))
+    }
+    if "`cv'"!="" {
+        mat `results'[`++i',1] = r(sd) / r(mean)
+    }
+    if "`range'"!="" {
+        mat `results'[`++i',1] = r(max) - r(min)
+    }
+    foreach stat of local Stats {
+        mat `results'[`++i',1] = r(`stat')
+    }
+//return the results
+    local i 0
+    di as txt _n "added scalars:"
+    foreach stat in `iqr' `semean' `cv' `range' `stats' {
+        local sname = lower("`stat'")
+        ereturn scalar `prefix'`sname' = `results'[`++i',1]
+        added_scalar `prefix'`sname'
+    }
+end
+
+* 11.
+* -estadd- subroutine: various summary statistics
+program define estadd_summ, eclass
+    version 8.2
+    syntax [, MEan SUm MIn MAx RAnge sd Var cv SEMean SKewness ///
+     Kurtosis MEDian p1 p5 p10 p25 p50 p75 p90 p95 p99 iqr q all ///
+     Prefix(name) Replace Quietly ]
+//check availability of e(sample)
+    confirm_esample
+//use aweights with -summarize-
+    local wtype `e(wtype)'
+    if "`wtype'"=="pweight" local wtype aweight
+//subpop?
+    local subpop "`e(subpop)'"
+    if "`subpop'"=="" local subpop 1
+//determine list of stats
+    tempname results results2
+    local Stats p99 p95 p90 p75 p50 p25 p10 p5 p1 kurtosis ///
+     skewness var sd max min sum mean
+    if "`all'"!="" {
+        local stats `Stats'
+        local range range
+        local cv cv
+        local semean semean
+        local iqr iqr
+        local sumtype detail
+    }
+    else {
+        if "`q'"!="" {
+            local p25 p25
+            local p50 p50
+            local p75 p75
+        }
+        if "`median'"!="" local p50 p50
+        foreach stat of local Stats {
+            if "``stat''"!="" {
+                local stats: list stats | stat
+            }
+        }
+        if "`stats'"=="" & "`range'"=="" & "`cv'"=="" & ///
+         "`semean'"=="" & "`iqr'"=="" local stats sd max min mean
+        local sumtype sum mean min max
+        if "`:list stats - sumtype'"=="" & "`cv'"=="" & ///
+         "`semean'"=="" & "`iqr'"=="" local sumtype meanonly
+        else {
+            local sumtype `sumtype' Var sd
+            if "`:list stats - sumtype'"=="" & "`iqr'"=="" local sumtype
+            else local sumtype detail
+        }
+    }
+    local Stats: subinstr local stats "var" "Var"
+    local nstats: word count `iqr' `semean' `cv' `range' `stats'
+    if "`replace'"=="" {
+        foreach stat in `iqr' `semean' `cv' `range' `stats' {
+            confirm_new_ename `prefix'`=lower("`stat'")'
+        }
+    }
+//copy coefficients matrix and determine varnames
+    mat `results' = e(b)
+    local vars: colnames `results'
+    if `nstats'>1 {
+        mat `results' = `results' \ J(`nstats'-1,colsof(`results'),.z)
+    }
+//loop over variables: calculate stats
+    local j 0
+    foreach var of local vars {
+        local ++j
+        capture confirm_numvar `var'
+        if _rc mat `results'[1,`j'] = .z
+        else {
+            capt su `var' [`wtype'`e(wexp)'] if e(sample) & `subpop', `sumtype'
+            local i 0
+            if "`iqr'"!="" {
+                mat `results'[`++i',`j'] = cond(_rc,.,r(p75) - r(p25))
+            }
+            if "`semean'"!="" {
+                mat `results'[`++i',`j'] = cond(_rc,.,r(sd) / sqrt(r(N)))
+            }
+            if "`cv'"!="" {
+                mat `results'[`++i',`j'] = cond(_rc,.,r(sd) / r(mean))
+            }
+            if "`range'"!="" {
+                mat `results'[`++i',`j'] = cond(_rc,.,r(max) - r(min))
+            }
+            foreach stat of local Stats {
+                mat `results'[`++i',`j'] = cond(_rc,.,r(`stat'))
+            }
+        }
+    }
+//return the results
+    local i 0
+    di as txt _n "added matrices:"
+    foreach stat in `iqr' `semean' `cv' `range' `stats' {
+        local sname = lower("`stat'")
+        mat `results2' = `results'[`++i',1...]
+        ereturn matrix `prefix'`sname' = `results2'
+        added_matrix `prefix'`sname'
+    }
+end
+
+* 12.
+* -estadd- subroutine: variance inflation factors
+program define estadd_vif, eclass
+    version 8.2
+    local caller : di _caller()
+    syntax [, TOLerance SQRvif Prefix(name) Replace Quietly ]
+//check availability of e(sample)
+    confirm_esample
+//check e()-names
+    if "`replace'"=="" {
+        confirm_new_ename `prefix'vif
+        if "`tolerance'"!="" confirm_new_ename `prefix'tolerance
+        if "`sqrvif'"!="" confirm_new_ename `prefix'sqrvif
+    }
+//copy coefficients matrix and set to .z
+    tempname results results2 results3
+    matrix `results' = e(b)
+    forv j = 1/`=colsof(`results')' {
+        mat `results'[1,`j'] = .z
+    }
+    if "`tolerance'"!="" mat `results2' = `results'
+    if "`sqrvif'"!="" mat `results3' = `results'
+//compute VIF and add to results vector
+    capt n `quietly' version `caller': vif
+    if _rc {
+        if _rc == 301 di as err "-estadd:vif- can only be used after -regress-"
+        exit _rc
+    }
+    local i 0
+    local name "`r(name_`++i')'"
+    while "`name'"!="" {
+        local j = colnumb(`results',"`name'")
+        if `j'<. {
+            matrix `results'[1,`j'] = r(vif_`i')
+            if "`tolerance'"!="" matrix `results2'[1,`j'] = 1 / r(vif_`i')
+            if "`sqrvif'"!="" matrix `results3'[1,`j'] = sqrt( r(vif_`i') )
+        }
+        local name "`r(name_`++i')'"
+    }
+//return the results
+    if "`sqrvif'"!="" | "`tolerance'"!="" di as txt _n "added matrices:"
+    else di as txt _n "added matrix:"
+    if "`sqrvif'"!="" {
+        ereturn matrix `prefix'sqrvif = `results3'
+        added_matrix `prefix'sqrvif
+    }
+    if "`tolerance'"!="" {
+        ereturn matrix `prefix'tolerance = `results2'
+        added_matrix `prefix'tolerance
+    }
+    ereturn matrix `prefix'vif = `results'
+    added_matrix `prefix'vif
+end
+
+* 13.
+* -estadd- subroutine: standardized factor change coefficients
+program define estadd_ebsd, eclass
+    version 8.2
+    syntax [, Prefix(name) Replace Quietly ]
+//check availability of e(sample)
+    confirm_esample
+//check e()-names
+    if "`replace'"=="" confirm_new_ename `prefix'ebsd
+//use aweights with -summarize-
+    local wtype `e(wtype)'
+    if "`wtype'"=="pweight" local wtype aweight
+//subpop?
+    local subpop "`e(subpop)'"
+    if "`subpop'"=="" local subpop 1
+//copy coefficients matrix and determine varnames
+    tempname results
+    mat `results' = e(b)
+    local vars: colnames `results'
+//loop over variables: calculate -mean-
+    local j 0
+    foreach var of local vars {
+        local ++j
+        capture confirm_numvar `var'
+        if _rc mat `results'[1,`j'] = .z
+        else {
+            capt su `var' [`wtype'`e(wexp)'] if e(sample) & `subpop'
+            mat `results'[1,`j'] = cond(_rc,.,exp( `results'[1,`j'] * r(sd)))
+        }
+    }
+//return the results
+    ereturn matrix `prefix'ebsd = `results'
+    di _n as txt "added matrix:"
+    added_matrix `prefix'ebsd
+end
+
+* 14.
+* -estadd- subroutine: exponentiated coefficients
+program define estadd_expb, eclass
+    version 8.2
+    syntax [, noCONStant Prefix(name) Replace Quietly ]
+//check e()-names
+    if "`replace'"=="" confirm_new_ename `prefix'expb
+//copy coefficients matrix and determine names of coefficients
+    tempname results
+    mat `results' = e(b)
+    local coefs: colnames `results'
+//loop over coefficients
+    local j 0
+    foreach coef of local coefs {
+        local ++j
+        if `"`constant'"'!="" & `"`coef'"'=="_cons" {
+            mat `results'[1,`j'] = .z
+        }
+        else {
+            mat `results'[1,`j'] = exp(`results'[1,`j'])
+        }
+    }
+//return the results
+    ereturn matrix `prefix'expb = `results'
+    di _n as txt "added matrix:"
+    added_matrix `prefix'expb
+end
+
+* 15.
+* -estadd- subroutine: partial and semi-partial correlations
+program define estadd_pcorr, eclass
+    version 8.2
+    syntax [, semi Prefix(name) Replace Quietly ]
+//check availability of e(sample)
+    confirm_esample
+//check e()-names
+    if "`replace'"=="" {
+        if "`semi'"!="" confirm_new_ename `prefix'spcorr
+        confirm_new_ename `prefix'pcorr
+    }
+//copy coefficients matrix and set to .z
+    tempname results results2
+    matrix `results' = e(b)
+    forv j = 1/`=colsof(`results')' {
+        mat `results'[1,`j'] = .z
+    }
+    local eqs: coleq `results', quoted
+    local eq: word 1 of `eqs'
+    mat `results2' = `results'[1,"`eq':"]
+    local vars: colnames `results2'
+    foreach var of local vars {
+        capt confirm numeric var `var'
+        if !_rc local temp "`temp'`var' "
+    }
+    local vars "`temp'"
+    if "`semi'"!="" mat `results2' = `results'
+    else {
+        mat drop `results2'
+        local results2
+    }
+    local depv: word 1 of `e(depvar)'
+//compute statistics and add to results vector
+    local wtype `e(wtype)'
+    if inlist("`wtype'","pweight","iweight") local wtype aweight
+    _estadd_pcorr_compute `depv' `vars' [`wtype'`e(wexp)'] if e(sample), ///
+     eq(`eq') results(`results') results2(`results2')
+//return the results
+    if "`semi'"!="" {
+        di as txt _n "added matrices:"
+        ereturn matrix `prefix'spcorr = `results2'
+        added_matrix `prefix'spcorr
+    }
+    else di as txt _n "added matrix:"
+    ereturn matrix `prefix'pcorr = `results'
+    added_matrix `prefix'pcorr
+end
+program define _estadd_pcorr_compute // based on pcorr.ado by StataCorp
+                                     // and pcorr2.ado by Richard Williams
+    syntax varlist(min=1) [aw fw] [if], eq(str) results(str) [ results2(str) ]
+    marksample touse
+    tempname hcurrent
+    _est hold `hcurrent', restore
+    quietly reg `varlist' [`weight'`exp'] if `touse'
+    if (e(N)==0 | e(N)>=.) error 2000
+    local NmK = e(df_r)
+    local R2 = e(r2)
+    gettoken depv varlist: varlist
+    foreach var of local varlist {
+        quietly test `var'
+        if r(F)<. {
+            local s "1"
+            if _b[`var']<0 local s "-1"
+            local c = colnumb(`results',"`eq':`var'")
+            mat `results'[1,`c'] = `s' * sqrt(r(F)/(r(F)+`NmK'))
+            if "`results2'"!="" {
+                mat `results2'[1,`c'] = `s' * sqrt(r(F)*((1-`R2')/`NmK'))
+            }
+        }
+    }
+end
+
+* 16.
+* -estadd- subroutine: Likelihood-ratio test
+program define estadd_lrtest, eclass
+    version 8.2
+    local caller : di _caller()
+    syntax anything(id="model") [, Name(name) Prefix(name) Replace Quietly * ]
+    if "`name'"=="" local name lrtest_
+//check e()-names
+    if "`replace'"=="" {
+        confirm_new_ename `prefix'`name'p
+        confirm_new_ename `prefix'`name'chi2
+        confirm_new_ename `prefix'`name'df
+    }
+//compute statistics
+    `quietly' version `caller': lrtest `anything', `options'
+//return the results
+    ereturn scalar `prefix'`name'p = r(p)
+    ereturn scalar `prefix'`name'chi2 = r(chi2)
+    ereturn scalar `prefix'`name'df = r(df)
+    di _n as txt "added scalars:"
+    added_scalar `prefix'`name'p
+    added_scalar `prefix'`name'chi2
+    added_scalar `prefix'`name'df
+end
+
+* 17.
+* -estadd- subroutine: support for -brant- by Long and Freese
+* (see http://www.indiana.edu/~jslsoc/spost.htm)
+program define estadd_brant, eclass
+    version 8.2
+    local caller : di _caller()
+    syntax [ , Prefix(name) Replace Quietly * ]
+    capt findfile brant.ado
+    if _rc {
+        di as error "fitstat.ado from the -spost9_ado- package by Long and Freese required"
+        di as error `"type {stata "net from http://www.indiana.edu/~jslsoc/stata"}"'
+        error 499
+    }
+// check names
+    if "`replace'"=="" {
+        foreach name in brant_chi2 brant_df brant_p brant {
+            confirm_new_ename `prefix'`name'
+        }
+    }
+// compute and return the results
+    `quietly' version `caller': brant, `options'
+    di as txt _n "added scalars:"
+    foreach stat in chi2 df p {
+        ereturn scalar `prefix'brant_`stat' = r(`stat')
+        added_scalar `prefix'brant_`stat'
+    }
+    tempname mat
+    matrix `mat' = r(ivtests)
+    matrix `mat' = `mat''
+    ereturn matrix `prefix'brant = `mat'
+    di as txt _n "added matrix:"
+    added_matrix `prefix'brant _rown
+end
+
+* 18.
+* -estadd- subroutine: support for -fitstat- by Long and Freese
+* (see http://www.indiana.edu/~jslsoc/spost.htm)
+program define estadd_fitstat, eclass
+    version 8.2
+    local caller : di _caller()
+    syntax [ , Prefix(name) Replace Quietly Bic * ]
+    capt findfile fitstat.ado
+    if _rc {
+        di as error "fitstat.ado from the -spost9_ado- package by Long and Freese required"
+        di as error `"type {stata "net from http://www.indiana.edu/~jslsoc/stata"}"'
+        error 499
+    }
+    `quietly' version `caller': fitstat, `bic' `options'
+    local stats: r(scalars)
+    local allstats                                                  ///
+        dev dev_df lrx2 lrx2_df lrx2_p r2_adj r2_mf r2_mfadj r2_ml  ///
+        r2_cu r2_mz r2_ef v_ystar v_error r2_ct r2_ctadj aic aic_n  ///
+        bic bic_p statabic stataaic n_rhs n_parm
+    local stats: list allstats & stats
+    if "`bic'"!="" {
+        local bic aic aic_n bic bic_p statabic stataaic
+        local stats: list bic & stats
+    }
+
+
+// check names
+    if "`replace'"=="" {
+        foreach stat of local stats {
+            if inlist("`stat'", "bic", "aic") local rname `stat'0
+            else local rname `stat'
+            confirm_new_ename `prefix'`rname'
+        }
+    }
+
+// return the results
+    di as txt _n "added scalars:"
+    foreach stat of local stats {
+        if inlist("`stat'", "bic", "aic") local rname `stat'0
+        else local rname `stat'
+        ereturn scalar `prefix'`rname' = r(`stat')
+        added_scalar `prefix'`rname'
+    }
+end
+
+* 19.
+* -estadd- subroutine: support for -listcoef- by Long and Freese
+* (see http://www.indiana.edu/~jslsoc/spost.htm)
+program define estadd_listcoef, eclass
+    version 8.2
+    local caller : di _caller()
+    syntax [anything] [ , Prefix(name) Replace Quietly ///
+     nosd gt lt ADJacent Matrix EXpand * ]
+
+// handle some options and look for e(sample)
+    if `"`matrix'"'!="" {
+        local matrix matrix
+    }
+    if `"`e(cmd)'"'=="slogit" & "`expand'"!="" {
+        di as err "-expand- option not supported"
+        exit 198
+    }
+    confirm_esample
+
+// set some constants
+    local listcoef_matrices  "xs ys std fact facts pct pcts"
+    if "`sd'"=="" local listcoef_matrices "`listcoef_matrices' sdx"
+
+// run listcoef
+    capt findfile listcoef.ado
+    if _rc {
+        di as error "-listcoef- from the -spost9_ado- package by Long and Freese required"
+        di as error `"type {stata "net from http://www.indiana.edu/~jslsoc/stata"}"'
+        error 499
+    }
+    `quietly' version `caller': listcoef `anything' , matrix `gt' `lt' `adjacent' `options'
+
+// check existing e()'s
+    if "`replace'"=="" {
+        confirm_new_ename `prefix'pvalue
+        foreach matrix of local listcoef_matrices {
+            _estadd_listcoef_ChkEName b_`matrix', prefix(`prefix')
+        }
+    }
+
+// grab r()-results and post in e()
+    di as txt _n "added matrices:"
+    if inlist(`"`e(cmd)'"',"mlogit","mprobit") {
+        _estadd_listcoef_AddResToNomModl `listcoef_matrices', prefix(`prefix') `gt' `lt' `adjacent'
+    }
+    else {
+        foreach matrix of local listcoef_matrices {
+            _estadd_listcoef_AddMatToE `matrix', prefix(`prefix')
+        }
+    }
+end
+program define _estadd_listcoef_ChkEName
+    syntax name [, prefix(str) ]
+    capt confirm matrix r(`namelist')
+    if _rc exit
+    confirm_new_ename `prefix'`namelist'
+end
+program define _estadd_listcoef_AddMatToE, eclass
+    syntax name [, prefix(str) ]
+    capt confirm matrix r(b_`namelist')
+    if _rc exit
+    tempname tmp
+    matrix `tmp' = r(b_`namelist')
+    capt confirm matrix r(b2_`namelist')
+    if _rc==0 {
+        local eqnames: coleq e(b), quoted
+        local eqnames: list uniq eqnames
+        local eqname: word 1 of `eqnames'
+        mat coleq `tmp' = `"`eqname'"'
+        tempname tmp2
+        matrix `tmp2' = r(b2_`namelist')
+        local eqname: word 2 of `eqnames'
+        mat coleq `tmp2' = `"`eqname'"'
+        mat `tmp' = `tmp' , `tmp2'
+        mat drop `tmp2'
+    }
+    ereturn matrix `prefix'b_`namelist' = `tmp'
+    added_matrix `prefix'b_`namelist' _rown
+end
+program define _estadd_listcoef_AddResToNomModl, eclass
+    syntax anything(name=listcoef_matrices) [, prefix(str) gt lt ADJacent ]
+    if "`lt'"=="" & "`gt'"=="" {
+        local lt lt
+        local gt gt
+    }
+    local adjacent = "`adjacent'"!=""
+    local lt = "`lt'"!=""
+    local gt = "`gt'"!=""
+
+// outcomes and labels
+    tempname outcomes
+    if `"`e(cmd)'"'=="mlogit" {
+        if c(stata_version) < 9 local type cat
+        else                    local type out
+        mat `outcomes' = e(`type')
+        local noutcomes = colsof(`outcomes')
+        local eqnames `"`e(eqnames)'"'
+        if (`:list sizeof eqnames'<`noutcomes') {
+            local ibase = e(ibase`type')
+        }
+        else local ibase 0
+        forv i = 1/`noutcomes' {
+            if `i'==`ibase' {
+                local outcomelab`i' `"`e(baselab)'"'
+            }
+            else {
+                gettoken eq eqnames : eqnames
+                local outcomelab`i' `"`eq'"'
+            }
+            if `"`outcomelab`i''"'=="" {
+                local outcomelab`i': di `outcomes'[1,`i']
+            }
+        }
+    }
+    else if `"`e(cmd)'"'=="mprobit" {
+        mat `outcomes' = e(outcomes)'
+        local noutcomes = colsof(`outcomes')
+        forv i = 1/`noutcomes' {
+            local outcomelab`i' `"`e(out`i')'"'
+        }
+    }
+    else {
+        di as err `"`e(cmd)' not supported"'
+        exit 499
+    }
+
+// collect vectors
+    tempname stats
+    mat `stats' = r(b) \ r(b_z) \ r(b_z) \ r(b_p)
+    forv i = 1/`=colsof(`stats')' {
+        mat `stats'[2,`i'] = `stats'[1,`i'] / `stats'[3,`i']
+    }
+    mat rown `stats' = "b" "se" "z" "P>|z|"
+    local enames "b_raw b_se b_z b_p"
+    foreach matrix of local listcoef_matrices {
+        capt confirm matrix r(b_`matrix')
+        if _rc continue
+        mat `stats' = `stats' \ r(b_`matrix')
+        local enames `"`enames' b_`matrix'"'
+    }
+
+// select/reorder contrasts of interest
+    local contrast "r(contrast)"
+    local ncontrast = colsof(`contrast')
+    tempname stats0 temp
+    matrix rename `stats' `stats0'
+    forv i = 1/`noutcomes' {
+        local out1 = `outcomes'[1, `i']
+        local j 0
+        forv j = 1/`noutcomes' {
+            local out2 = `outcomes'[1, `j']
+            if `out1'==`out2' continue
+            if `adjacent' & abs(`i'-`j')>1 continue
+            if `lt'==0 & `out1'<`out2' continue
+            if `gt'==0 & `out1'>`out2' continue
+            forv l = 1/`ncontrast' {
+                if el(`contrast',1,`l')!=`out1' continue
+                if el(`contrast',2,`l')!=`out2' continue
+                mat `temp' = `stats0'[1..., `l']
+                mat coleq `temp' = `"`outcomelab`i''-`outcomelab`j''"'
+                mat `stats' = nullmat(`stats'), `temp'
+            }
+        }
+    }
+    capt mat drop `stats0'
+
+// post rows to e()
+    local i 0
+    foreach ename of local enames {
+        local ++i
+        mat `temp' = `stats'[`i', 1...]
+        ereturn matrix `prefix'`ename' = `temp'
+        added_matrix `prefix'`ename' _rown
+    }
+end
+
+* 20.
+* -estadd- subroutine: support for -mlogtest- by Long and Freese
+* (see http://www.indiana.edu/~jslsoc/spost.htm)
+program define estadd_mlogtest, eclass
+    version 8.2
+    local caller : di _caller()
+    syntax [anything] [ , Prefix(name) Replace Quietly set(passthru) * ]
+    `quietly' version `caller': mlogtest `anything' , `set' `options'
+    local rmat: r(matrices)
+
+    // check names
+    if `"`replace'"'=="" {
+        foreach m in combine lrcomb {
+            if `:list m in rmat'==0 continue
+            forv r = 1/`=rowsof(r(`m'))' {
+                local cat1 = el(r(`m'),`r',1)
+                local cat2 = el(r(`m'),`r',2)
+                confirm_new_ename `prefix'`m'_`cat1'_`cat2'_chi2
+                confirm_new_ename `prefix'`m'_`cat1'_`cat2'_df
+                confirm_new_ename `prefix'`m'_`cat1'_`cat2'_p
+            }
+        }
+        foreach m in hausman suest smhsiao {
+            if `:list m in rmat'==0 continue
+            forv r = 1/`=rowsof(r(`m'))' {
+                local cat = el(r(`m'),`r',1)
+                confirm_new_ename `prefix'`m'_`cat'_chi2
+                confirm_new_ename `prefix'`m'_`cat'_df
+                confirm_new_ename `prefix'`m'_`cat'_p
+            }
+        }
+        if `"`set'"'!="" {
+            foreach m in wald lrtest {
+                if `:list m in rmat'==0 continue
+                local i 0
+                local r = rownumb(r(`m'),"set_`++i'")
+                while(`r'<.) {
+                    confirm_new_ename `prefix'`m'_set`i'_chi2
+                    confirm_new_ename `prefix'`m'_set`i'_df
+                    confirm_new_ename `prefix'`m'_set`i'_p
+                    local r = rownumb(r(`m'),"set_`++i'")
+                }
+            }
+        }
+        foreach m in wald lrtest {
+            if `:list m in rmat'==0 continue
+            local r .
+            if `"`set'"'!="" local r = rownumb(r(`m'),"set_1")-1
+            if `r'<1 continue
+            confirm_new_ename `prefix'`m'
+       }
+    }
+
+    local di_added_scalars `"di _n as txt "added scalars:"'
+    // combine
+    foreach m in combine lrcomb {
+        if `:list m in rmat'==0 continue
+        `di_added_scalars'
+        local di_added_scalars
+        forv r = 1/`=rowsof(r(`m'))' {
+            local cat1 = el(r(`m'),`r',1)
+            local cat2 = el(r(`m'),`r',2)
+            eret scalar `prefix'`m'_`cat1'_`cat2'_chi2 = el(r(`m'),`r',3)
+            added_scalar `prefix'`m'_`cat1'_`cat2'_chi2
+            eret scalar `prefix'`m'_`cat1'_`cat2'_df   = el(r(`m'),`r',4)
+            added_scalar `prefix'`m'_`cat1'_`cat2'_df
+            eret scalar `prefix'`m'_`cat1'_`cat2'_p    = el(r(`m'),`r',5)
+            added_scalar `prefix'`m'_`cat1'_`cat2'_p
+        }
+    }
+    // iia
+    foreach m in hausman suest smhsiao {
+        if `:list m in rmat'==0 continue
+        `di_added_scalars'
+        local di_added_scalars
+        if "`m'"=="smhsiao" local skip 2
+        else                local skip 0
+        forv r = 1/`=rowsof(r(`m'))' {
+            local cat = el(r(`m'),`r',1)
+            eret scalar `prefix'`m'_`cat'_chi2 = el(r(`m'),`r',2+`skip')
+            added_scalar `prefix'`m'_`cat'_chi2
+            eret scalar `prefix'`m'_`cat'_df   = el(r(`m'),`r',3+`skip')
+            added_scalar `prefix'`m'_`cat'_df
+            eret scalar `prefix'`m'_`cat'_p    = el(r(`m'),`r',4+`skip')
+            added_scalar `prefix'`m'_`cat'_p
+        }
+    }
+
+    // wald/lrtest
+    tempname tmp
+    if `"`set'"'!="" {
+        foreach m in wald lrtest {
+            if `:list m in rmat'==0 continue
+            local i 0
+            local r = rownumb(r(`m'),"set_`++i'")
+            if `r'>=. continue
+            `di_added_scalars'
+            local di_added_scalars
+            while(`r'<.) {
+                eret scalar `prefix'`m'_set`i'_chi2 = el(r(`m'),`r',1)
+                added_scalar `prefix'`m'_set`i'_chi2
+                eret scalar `prefix'`m'_set`i'_df   = el(r(`m'),`r',2)
+                added_scalar `prefix'`m'_set`i'_df
+                eret scalar `prefix'`m'_set`i'_p    = el(r(`m'),`r',3)
+                added_scalar `prefix'`m'_set`i'_p
+                local r = rownumb(r(`m'),"set_`++i'")
+            }
+        }
+    }
+    local di_added_matrices `"di _n as txt "added matrices:"'
+    foreach m in wald lrtest {
+        if `:list m in rmat'==0 continue
+        local r .
+        if `"`set'"'!="" local r = rownumb(r(`m'),"set_1")-1
+        if `r'<1 continue
+        `di_added_matrices'
+        local di_added_matrices
+        mat `tmp' = r(`m')
+        mat `tmp' = `tmp'[1..`r',1...]'
+        eret mat `prefix'`m' = `tmp'
+        added_matrix `prefix'`m' _rown
+    }
+
+end
+
+
+* 21.
+* -estadd- subroutine: support for -prchange- by Long and Freese
+* (see http://www.indiana.edu/~jslsoc/spost.htm)
+program define estadd_prchange
+    version 8.2
+    local caller : di _caller()
+    syntax [anything] [if] [in] [ , Prefix(name) Replace Quietly ///
+        PAttern(str) Binary(str) Continuous(str) NOAvg Avg split SPLIT2(name) ///
+            adapt /// old syntax; now works as synonym for noavg
+        Outcome(passthru) Fromto noBAse * ]
+
+// handle some options
+    if `"`split2'"'!="" local split split
+    if "`split'"!="" & `"`outcome'"'!="" {
+        di as err "split and outcome() not both allowed"
+        exit 198
+    }
+    if "`split'"!="" & `"`avg'`noavg'"'!="" {
+        di as err "split and avg not both allowed"
+        exit 198
+    }
+    if "`avg'"!="" & `"`outcome'"'!="" {
+        di as err "avg and outcome not both allowed"
+        exit 198
+    }
+    if "`avg'"!="" & "`noavg'"!="" {
+        di as err "avg and noavg not both allowed"
+        exit 198
+    }
+    if `"`adapt'"'!=""  local noavg noavg
+    if `:list sizeof binary'>1 | `:list sizeof continuous'>1  error 198
+    estadd_prchange_ExpandType binary `"`binary'"'
+    estadd_prchange_ExpandType continuous `"`continuous'"'
+    if `"`binary'"'==""     local binary 2
+    if `"`continuous'"'=="" local continuous 4
+    if `"`pattern'"'!="" {
+        estadd_prchange_ExpandType pattern `"`pattern'"'
+    }
+
+// check e(sample)
+    confirm_esample
+
+// run prchange
+    capt findfile prchange.ado
+    if _rc {
+        di as error "-prchange- from the -spost9_ado- package by Long and Freese required"
+        di as error `"type {stata "net from http://www.indiana.edu/~jslsoc/stata"}"'
+        error 499
+    }
+    `quietly' version `caller': prchange `anything' `if' `in', `base' `outcome' `fromto' `options'
+
+// determine type of model (ordinal: nomord = 1; nominal: nomord = 2)
+    local nomord = (r(modeltype)=="typical nomord")
+    if inlist(`"`e(cmd)'"',"mlogit","mprobit") local nomord = 2
+    if "`avg'`noavg'"!="" {
+        if `nomord'==0 {
+            di as err "avg not allowed with this model"
+            exit 198
+        }
+    }
+    if !`nomord' & "`split'"!="" {
+        di as err "split not allowed with this model"
+        exit 198
+    }
+
+// determine outcome number (in prchange-returns)
+    if `"`outcome'"'!="" {
+        if `nomord' {
+            forv i = 1/`=colsof(r(catval))' {
+                if el(r(catval), 1, `i') == r(outcome) {
+                    local outcomenum `i'
+                    continue, break
+                }
+            }
+            if "`outcomenum'"=="" { // should never happen
+                di as err `"outcome `outcome' not found"'
+                exit 499
+            }
+        }
+        else {
+            local outcomenum =  colnumb(r(predval), `"`r(outcome)'"')
+        }
+    }
+
+// check names
+    if "`replace'"=="" {
+        if `"`outcome'"'!="" | "`split'"!="" | `nomord'==0 {
+            confirm_new_ename `prefix'predval
+            if `"`outcome'"'!="" | "`split'"!="" {
+                confirm_new_ename `prefix'outcome
+            }
+        }
+        else {
+            forv i = 1/`=colsof(r(catval))' {
+                local theoutcome: di el(r(catval),1,`i')
+                confirm_new_ename `prefix'predval`theoutcome'
+            }
+        }
+        confirm_new_ename `prefix'delta
+        confirm_new_ename `prefix'centered
+        confirm_new_ename `prefix'dc
+        if "`fromto'"!="" {
+            confirm_new_ename `prefix'dcfrom
+            confirm_new_ename `prefix'dcto
+        }
+        if "`nobase'"=="" {
+            confirm_new_ename `prefix'X
+        }
+    }
+
+// grab r()-results and post in e()
+    if "`split'"!="" {
+        if `"`split2'"'=="" {
+            local split2 `"`e(_estadd_estimates_name)'"'
+            if `"`split2'"'=="" {
+                local split2 `"`e(cmd)'"'
+            }
+            local split2 `"`split2'_"'
+        }
+        _estadd_prchange_StoreEachOutc `split2' , nomord(`nomord') ///
+            pattern(`pattern') binary(`binary') continuous(`continuous') ///
+            `base' `fromto' prefix(`prefix')
+    }
+    else {
+        _estadd_prchange_AddStuffToE, nomord(`nomord') outcome(`outcomenum') ///
+            pattern(`pattern') binary(`binary') continuous(`continuous') ///
+            `avg' `noavg' `base' `fromto' prefix(`prefix')
+    }
+end
+program estadd_prchange_ExpandType
+    args name list
+    foreach l of local list {
+        local w = length(`"`l'"')
+        if      `"`l'"'==substr("minmax",1,max(2,`w'))      local type 1
+        else if `"`l'"'==substr("01",1,max(1,`w'))          local type 2
+        else if `"`l'"'==substr("delta",1,max(1,`w'))       local type 3
+        else if `"`l'"'==substr("sd",1,max(1,`w'))          local type 4
+        else if `"`l'"'==substr("margefct",1,max(1,`w'))    local type 5
+        else {
+            di as err `"'`l'' not allowed"'
+            exit 198
+        }
+        local newlist `newlist' `type'
+    }
+    c_local `name' `newlist'
+end
+program define _estadd_prchange_AddStuffToE, eclass
+//      input                            add
+// =========================    ========================================
+// outcome() nomord    opt      change changenm change# predval  outcome
+//   no        0        -         x                      last
+//   yes       0        -         x                       x        x
+//   no       1/2       -                 x       all    all
+//   yes      1/2       -                          x      x        x
+//   no       1/2      avg                x              all
+//   no       1/2     noavg                       all    all
+//  nobase==""  => add X, SD, Min, Max
+//  all models  => add centered, delta
+    syntax , nomord(str) [ pattern(passthru) binary(passthru) continuous(passthru) ///
+        outcome(str) NOAVG avg nobase fromto prefix(str) split ] //
+// prepare predval and determine value of outcome
+    if `"`outcome'"'!="" {
+        tempname predv
+        mat `predv' = r(predval)
+        mat `predv' = `predv'[1...,`outcome']
+        if `nomord' {
+            local theoutcome: di el(r(catval),1,`outcome')
+        }
+        else {
+            local theoutcome: colnames `predv'
+        }
+    }
+// add scalars
+    di _n as txt "added scalars:"
+// - predval and outcome
+    local cpredval = colsof(r(predval))
+    if `"`outcome'"'!="" {
+        ereturn scalar `prefix'predval = `predv'[1,1]
+        added_scalar `prefix'predval `"`lab_predval'"'
+        ereturn scalar `prefix'outcome = `theoutcome'
+        added_scalar `prefix'outcome
+    }
+    else if `nomord' { // add all
+        forv i=1/`cpredval' {
+            local theoutcome: di el(r(catval),1,`i')
+            ereturn scalar `prefix'predval`theoutcome' = el(r(predval),1,`i')
+            added_scalar `prefix'predval`theoutcome'
+        }
+    }
+    else { // add last
+        ereturn scalar `prefix'predval = el(r(predval),1,`cpredval')
+        added_scalar `prefix'predval
+    }
+// - delta and centered
+    ereturn scalar `prefix'delta = r(delta)
+    added_scalar `prefix'delta
+    ereturn scalar `prefix'centered = r(centered)
+    added_scalar `prefix'centered
+// add matrices
+    di _n as txt "added matrices:"
+    if `nomord'==0 {
+        if r(modeltype)=="twoeq count" & "`test'"=="" {
+            local eq: coleq e(b)
+            local eq: word 1 of `eq'
+        }
+        _estadd_prchange_PostMat r(change), prefix(`prefix') ///
+            name(dc) `pattern' `binary' `continuous' `fromto' eq(`eq')
+    }
+    else {
+        if `"`outcome'"'=="" {
+            if "`avg'"!="" local nomordmat "r(changemn)"
+            else {
+                tempname nomordmat
+                _estadd_prchange_GatherNomChMat `nomordmat' `noavg'
+            }
+            _estadd_prchange_PostMat `nomordmat', prefix(`prefix') ///
+                name(dc) `pattern' `binary' `continuous' `fromto'
+        }
+        else {
+            if `nomord'==2 {
+                _estadd_prchange_GetEqnmNomModl `theoutcome'
+            }
+            if `"`split'"'!="" {
+                _estadd_prchange_PostMat r(change`theoutcome'), prefix(`prefix') ///
+                    name(dc) `pattern' `binary' `continuous' `fromto' eq(`eq')
+            }
+            else {
+                _estadd_prchange_PostMat r(change), prefix(`prefix') ///
+                    name(dc) `pattern' `binary' `continuous' `fromto' eq(`eq')
+            }
+        }
+    }
+    if `"`base'"'=="" {
+        _estadd_prchange_PostMat r(baseval), prefix(`prefix') name(X)
+    }
+    if `"`pattern'"'=="" {
+        _estadd_prchange_dcNote, prefix(`prefix') name(dc) `binary' `continuous'
+    }
+end
+program define _estadd_prchange_dcNote
+    syntax [ , prefix(str) name(str) binary(str) continuous(str) ]
+    local res `""{res:minmax} change" "{res:01} change" "{res:delta} change" "{res:sd} change" "{res:margefct}""'
+    local bres: word `binary' of `res'
+    local cres: word `continuous' of `res'
+    di _n as txt `"first row in e(dc) contains:"'
+    di _n `"  `bres' for binary variables"'
+    di    `"  `cres' for continuous variables"'
+end
+program define _estadd_prchange_PostMat, eclass
+    syntax anything, name(str) [ Fromto eq(str) prefix(str) ///
+        pattern(passthru) binary(passthru) continuous(passthru) ]
+    capt confirm matrix `anything'
+    if _rc exit
+    tempname tmp1
+    local nmlist "`name'"
+    matrix `tmp1' = `anything'
+    if `"`eq'"'!="" {
+        mat coleq `tmp1' = `"`eq'"'
+    }
+    if `"`pattern'`binary'`continuous'"'!="" {
+        tempname pattmat
+        _estadd_prchange_Merge `tmp1', pattmat(`pattmat') `pattern' `binary' `continuous' `fromto'
+    }
+    if "`fromto'"!="" {
+        local nmlist "`nmlist' `name'from `name'to"
+        tempname tmp tmp2 tmp3
+        mat rename `tmp1' `tmp'
+        local r = rowsof(`tmp')
+        local i = 1
+        while (`i'<=`r') {
+            if (`r'-`i')>=2 {
+                mat `tmp2' = nullmat(`tmp2') \ `tmp'[`i++',1...] // from
+                mat `tmp3' = nullmat(`tmp3') \ `tmp'[`i++',1...] // to
+            }
+            mat `tmp1' = nullmat(`tmp1') \ `tmp'[`i++',1...]
+        }
+        mat drop `tmp'
+    }
+    local i 0
+    foreach nm of local nmlist {
+        local ++i
+        local rown: rown `tmp`i''
+        mat rown `tmp`i'' = `rown'  // fix problem with leading blanks in equations
+        ereturn matrix `prefix'`nm' = `tmp`i''
+        added_matrix `prefix'`nm' _rown
+    }
+    if `"`pattmat'"'!="" {
+        ereturn matrix `prefix'pattern = `pattmat'
+        added_matrix `prefix'pattern
+    }
+end
+program define _estadd_prchange_Merge
+    syntax name(name=tmp1) [, pattmat(str) pattern(str) binary(str) continuous(str) fromto ]
+    tempname tmp
+    mat rename `tmp1' `tmp'
+    local r = cond("`fromto'"!="", 3, 1)
+    mat `tmp1' = `tmp'[1..`r',1...]*.
+    mat `pattmat' = `tmp'[1,1...]*.
+    local rtot = rowsof(`tmp')
+    mat rown `tmp1' = main
+    mat rown `pattmat' = :type
+    local vars: colnames `tmp1'
+    local eqs: coleq `tmp1', quoted
+    local j 0
+    foreach var of local vars {
+        local ++j
+        gettoken eq eqs : eqs
+        if `"`eq'"'!=`"`lasteq'"' gettoken type rest : pattern
+        else                      gettoken type rest : rest
+        local lasteq `"`eq'"'
+        if `"`type'"'=="" {
+            capt assert `var'==0|`var'==1 if e(sample) & `var'<.
+            if _rc local type `continuous'
+            else   local type `binary'
+        }
+        local ii = (`type'-1)*`r'+1
+        forv i = 1/`r' {
+            if `r'>1 & `i'<3 & `ii'>=`rtot' {
+                mat `tmp1'[`i',`j'] = .z
+            }
+            else {
+                mat `tmp1'[`i',`j'] = `tmp'[`ii++',`j']
+            }
+        }
+        mat `pattmat'[1,`j'] = `type'
+    }
+    mat `tmp1' = `tmp1' \ `tmp'
+end
+program define _estadd_prchange_GatherNomChMat
+    args mat noavg
+    local cmd `"`e(cmd)'"'
+    tempname tmpmat
+    if `"`noavg'"'=="" {
+        mat `tmpmat' = r(changemn)
+        mat coleq `tmpmat' = `"Avg|Chg|"'
+        mat `mat' = `tmpmat'
+    }
+    if `"`cmd'"'=="mlogit" {
+        if c(stata_version) < 9 local outcat cat
+        else local outcat out
+        local k_cat = e(k_`outcat')
+        local eqnames `"`e(eqnames)'"'
+        if `k_cat'>`:list sizeof eqnames' { // no base equation
+            local ibase = e(ibase`outcat')
+            local baselab `"`e(baselab)'"'
+            if `"`baselab'"'=="" {
+                local baselab `"`e(base`outcat')'"'
+            }
+            forv i = 1/`k_cat' {
+                if `i'==`ibase' {
+                    local eq `"`"`baselab'"'"'
+                }
+                else gettoken eq eqnames : eqnames, quotes
+                local temp `"`temp' `eq'"'
+            }
+            local eqnames: list retok temp
+        }
+        local i 0
+        foreach eq of local eqnames {
+            local ++i
+            local theoutcome: di el(e(`outcat'),1,`i')
+            mat `tmpmat' = r(change`theoutcome')
+            mat coleq `tmpmat' = `"`eq'"'
+            mat `mat' = nullmat(`mat'), `tmpmat'
+        }
+    }
+    else if `"`cmd'"'=="mprobit" {
+        local eqnames `"`e(outeqs)'"'
+        local i 0
+        foreach eq of local eqnames {
+            local ++i
+            local theoutcome: di el(e(outcomes),`i',1)
+            mat `tmpmat' = r(change`theoutcome')
+            mat coleq `tmpmat' = `"`eq'"'
+            mat `mat' = nullmat(`mat'), `tmpmat'
+        }
+    }
+    else { // ordered models
+        local eqnames : colnames r(catval)
+        local i 0
+        foreach eq of local eqnames {
+            local ++i
+            local theoutcome: di el(r(catval),1,`i')
+            mat `tmpmat' = r(change`theoutcome')
+            mat coleq `tmpmat' = `"`eq'"'
+            mat `mat' = nullmat(`mat'), `tmpmat'
+        }
+    }
+end
+program define _estadd_prchange_GetEqnmNomModl
+    args theoutcome
+    local cmd `"`e(cmd)'"'
+    if `"`cmd'"'=="mlogit" {
+        if c(stata_version) < 9 local outcat cat
+        else local outcat out
+        local k_cat = e(k_`outcat')
+        local eqnames `"`e(eqnames)'"'
+        local nobase = (`k_cat'>`:list sizeof eqnames')
+        if `nobase' {
+            local ibase = e(ibase`outcat')
+            local baselab `"`e(baselab)'"'
+        }
+        forv i = 1/`k_cat' {
+            if `nobase' {
+                if `i'==`ibase' {
+                    local eq `"`baselab'"'
+                }
+                else gettoken eq eqnames : eqnames
+            }
+            else gettoken eq eqnames : eqnames
+            if el(e(`outcat'),1,`i')==`theoutcome' {
+                local value `"`eq'"'
+                continue, break
+            }
+        }
+    }
+    else if `"`cmd'"'=="mprobit" {
+        local eqnames `"`e(outeqs)'"'
+        local i 0
+        foreach eq of local eqnames {
+            if el(e(outcomes),`++i',1)==`theoutcome' {
+                local value `"`eq'"'
+                continue, break
+            }
+        }
+    }
+    if `"`value'"'=="" local value `theoutcome'
+    c_local eq `"`value'"'
+end
+program define _estadd_prchange_StoreEachOutc // only for nomord models
+    syntax anything [, nomord(str) nobase fromto prefix(passthru) ///
+        pattern(passthru) binary(passthru) continuous(passthru) ]
+// backup estimates
+    tempname hcurrent
+    _est hold `hcurrent', copy restore estsystem
+    if `"`nomord'"'=="2" {  // backup b and V
+        tempname b bi V Vi
+        mat `b' = e(b)
+        mat `V' = e(V)
+    }
+// cycle through categories
+    local k_kat = colsof(r(predval))
+    tempname catval catvali
+    mat `catval' = r(catval)
+    forv i=1/`k_kat' {
+        mat `catvali' = `catval'[1...,`i']
+        local catlabi: colnames `catvali'
+        local catnumi: di `catvali'[1,1]
+        if `"`nomord'"'=="2" {
+            _estadd_prchange_GetEqnmNomModl `catnumi'
+            if colnumb(`b', `"`eq':"')<. {
+                mat `bi' = `b'[1...,`"`eq':"']
+                mat `Vi' = `V'[`"`eq':"',`"`eq':"']
+            }
+            else {  // base outcome; get first eq and set zero
+                local tmp : coleq `b', q
+                gettoken tmp : tmp
+                mat `bi' = `b'[1...,`"`tmp':"'] * 0
+                mat `Vi' = `V'[`"`tmp':"',`"`tmp':"'] * 0
+            }
+            mat coleq `bi' = ""
+            mat coleq `Vi' = ""
+            mat roweq `Vi' = ""
+            erepost b=`bi' V=`Vi'
+        }
+        `qui' _estadd_prchange_AddStuffToE, split nomord(1) outcome(`i') ///
+            `base' `fromto' `pattern' `binary' `continuous' `prefix'
+        `qui' di ""
+        local qui qui
+        _eststo `anything'`catnumi', title(`"`catlabi'"') // store without e(sample)
+        di as txt "results for outcome " as res `catnumi' ///
+         as txt " stored as " as res "`anything'`catnumi'"
+    }
+// retore estimates
+    _est unhold `hcurrent'
+end
+
+* 22.
+* -estadd- subroutine: support for -prvalue- by Long and Freese
+* (see http://www.indiana.edu/~jslsoc/spost.htm)
+program define estadd_prvalue, eclass
+    version 9.2
+    local caller : di _caller()
+    syntax [anything] [if] [in] [ , Prefix(passthru) Replace Quietly ///
+        LABel(str) Title(passthru) swap Diff * ]
+
+// post
+    if `"`anything'"'!="" {
+        gettoken post post2 : anything
+        if `"`post'"'!="post" {
+            di as err `"`post' not allowed"'
+            exit 198
+        }
+        else if `"`label'"'!="" {
+            di as err "label() not allowed"
+            exit 198
+        }
+        _estadd_prvalue_Post `post2' `if' `in', `prefix' `replace' `quietly' ///
+            `title' `swap' `diff' `options'
+        exit
+    }
+    else if `"`title'"'!="" {
+        di as err "title() not allowed"
+        exit 198
+    }
+    else if "`swap'"!="" {
+        di as err "swap not allowed"
+        exit 198
+    }
+
+// look for e(sample)
+    confirm_esample
+
+// run prvalue
+    capt findfile prvalue.ado
+    if _rc {
+        di as error "-prvalue- from the -spost9_ado- package by Long and Freese required"
+        di as error `"type {stata "net from http://www.indiana.edu/~jslsoc/stata"}"'
+        error 499
+    }
+    `quietly' version `caller': prvalue `if' `in', `diff' `options'
+
+// append?
+    capture confirm existence `e(_estadd_prvalue)'
+    local append = (_rc==0) & ("`replace'"=="")
+    tempname prvalue prvalue_x prvalue_x2
+    if `append' {
+        mat `prvalue'   = e(_estadd_prvalue)
+        mat `prvalue_x' = e(_estadd_prvalue_x)
+        capt mat `prvalue_x2' = e(_estadd_prvalue_x2)
+        local ires = rowsof(`prvalue') + 1
+    }
+    else local ires 1
+    if `"`label'"'=="" {
+        local label "pred`ires'"
+    }
+    else {
+        local label = substr(`"`label'"', 1, 30)  // 30 characters max
+        local problemchars `": . `"""'"'
+        foreach char of local problemchars {
+            local label: subinstr local label `"`char'"' "_", all
+        }
+    }
+
+// collect results
+    tempname pred
+    mat `pred' = r(pred)
+    if `"`diff'"'!="" {
+        _estadd_prvalue_GetRidOfD `pred'
+    }
+    _estadd_prvalue_ReshapePred `pred', label(`label')
+    _estadd_prvalue_AddPred `prvalue' `pred' `append'
+    _estadd_prvalue_AddX `prvalue_x', label(`label')
+    capture confirm matrix r(x2)
+    local hasx2 = _rc==0
+    if `hasx2' {
+        _estadd_prvalue_AddX `prvalue_x2', label(`label') two
+    }
+
+// post in e()
+    di as txt _n cond(`append',"updated","added") " matrices:"
+    ereturn matrix _estadd_prvalue = `prvalue'
+    added_matrix _estadd_prvalue
+    ereturn matrix _estadd_prvalue_x = `prvalue_x'
+    added_matrix _estadd_prvalue_x
+    if `hasx2' {
+        ereturn matrix _estadd_prvalue_x2 = `prvalue_x2'
+        added_matrix _estadd_prvalue_x2
+    }
+end
+program _estadd_prvalue_GetRidOfD
+    args pred
+    local coln: colnames `pred'
+    local firstcol: word 1 of `coln'
+    local nfirstcol = substr("`firstcol'",2,.)
+    local coln : subinstr local coln "`firstcol'" "`nfirstcol'" , word
+    mat coln `pred' = `coln'
+end
+program _estadd_prvalue_ReshapePred
+    syntax anything, label(str)
+    tempname tmp res
+    local r = rowsof(`anything')
+    forv i=1/`r' {
+        mat `tmp' = `anything'[`i',1...]
+        local nm: rownames `tmp'
+        mat coleq `tmp' = `"`nm'"'
+        mat `res' = nullmat(`res'), `tmp'
+    }
+    mat rown `res' = `"`label'"'
+    mat `anything' = `res'
+end
+program _estadd_prvalue_AddPred
+    args prvalue pred append
+    if `append' {
+        local coln1: colfullnames `prvalue'
+        local coln2: colfullnames `pred'
+        if `"`coln1'"'!=`"`coln2'"' {
+            di as err "incompatible prvalue results"
+            exit 498
+        }
+    }
+    mat `prvalue' = nullmat(`prvalue') \ `pred'
+end
+program  _estadd_prvalue_AddX
+    syntax anything, label(str) [ two ]
+    if "`two'"!="" local two 2
+    tempname tmp
+    mat `tmp' = r(x`two')
+    mat rown `tmp' = `"`label'"'
+    mat `anything' = nullmat(`anything') \ `tmp'
+end
+program _estadd_prvalue_Post, eclass
+    syntax [name(name=post2)] [ , Prefix(name) Replace Quietly ///
+        Title(passthru) swap ]
+    capture confirm matrix e(_estadd_prvalue)
+    if _rc {
+        di as err "prvalue results not found"
+        exit 498
+    }
+// backup estimates
+    tempname hcurrent
+    _est hold `hcurrent', copy restore estsystem
+    local cmd = e(cmd)
+    local depvar = e(depvar)
+    local N = e(N)
+    local estname `"`e(_estadd_estimates_name)'"'
+
+// get results
+    tempname prvalue prvalue_x prvalue_x2
+    mat `prvalue' = e(_estadd_prvalue)
+    mat `prvalue_x' = e(_estadd_prvalue_x)
+    capture confirm matrix e(_estadd_prvalue_x2)
+    local hasx2 = _rc==0
+    if `hasx2' {
+        mat `prvalue_x2' = e(_estadd_prvalue_x2)
+    }
+
+// return prvalues
+    tempname tmp tmp2 b se
+    if "`swap'"=="" {
+        local eqs: coleq `prvalue', q
+        local eqs: list uniq eqs
+        foreach eq of local eqs {
+            mat `tmp' = `prvalue'[1...,`"`eq':"']
+            mat `tmp2' = `tmp'[1...,1]'
+            mat coleq `tmp2' = `"`eq'"'
+            mat roweq `tmp2' = ""
+            mat `b' = nullmat(`b'), `tmp2'
+            mat `tmp2' = `tmp'[1...,`"`eq':SE"']'
+            mat coleq `tmp2' = `"`eq'"'
+            mat roweq `tmp2' = ""
+            mat `se' = nullmat(`se'), `tmp2'
+        }
+        mat drop `tmp' `tmp2'
+    }
+    else {
+        local r = rowsof(`prvalue')
+        local c = colsof(`prvalue')
+        local coln: colnames `prvalue'
+        local eqs: coleq `prvalue', q
+        mat coln `prvalue' = `eqs'
+        mat coleq `prvalue' = `coln'
+        local coln: list uniq coln
+        local ncol: list sizeof coln
+        local icol: list posof "SE" in coln
+        forv i=1/`r' {
+            mat `tmp' = `prvalue'[`i',1...]
+            local labl : rownames `tmp'
+            forv j=1(`ncol')`c' {
+                mat `tmp2' = nullmat(`tmp2'), `tmp'[1...,`j']
+            }
+            mat coleq `tmp2' = `"`labl'"'
+            mat `b' = nullmat(`b'), `tmp2'
+            mat drop `tmp2'
+            forv j=`icol'(`ncol')`c' {
+                mat `tmp2' = nullmat(`tmp2'), `tmp'[1...,`j']
+            }
+            mat coleq `tmp2' = `"`labl'"'
+            mat `se' = nullmat(`se'), `tmp2'
+            mat drop `tmp2'
+        }
+        mat drop `tmp'
+    }
+    ereturn post `b', obs(`N')
+    ereturn local model "`cmd'"
+    ereturn local cmd "estadd_prvalue"
+    ereturn local depvar "`depvar'"
+    di as txt _n "scalars:"
+    added_scalar N
+    di as txt _n "macros:"
+    added_macro depvar
+    added_macro cmd
+    added_macro model
+    added_macro properties
+    di as txt _n "matrices:"
+    added_matrix b "predictions"
+    ereturn matrix se = `se'
+    added_matrix se "standard errors"
+    local istat 0
+    foreach stat in LB UB Category Cond {
+        local elabel: word `++istat' of "lower CI bounds" "upper CI bounds" ///
+            "outcome values" "conditional predictions"
+        if "`swap'"=="" {
+            foreach eq of local eqs {
+                local colnumb = colnumb(`prvalue',`"`eq':`stat'"')
+                if `colnumb'>=. continue
+                mat `tmp2' = `prvalue'[1...,`colnumb']'
+                mat coleq `tmp2' = `"`eq'"'
+                mat roweq `tmp2' = ""
+                mat `tmp' = nullmat(`tmp'), `tmp2'
+            }
+        }
+        else {
+            local icol: list posof "`stat'" in coln
+            if `icol'==0 continue
+            forv i=1/`r' {
+                mat `tmp2' = `prvalue'[`i',1...]
+                local labl : rownames `tmp2'
+                mat coleq `tmp2' = `"`labl'"'
+                forv j=`icol'(`ncol')`c' {
+                    mat `tmp' = nullmat(`tmp'), `tmp2'[1...,`j']
+                }
+            }
+            mat drop `tmp2'
+        }
+        capt confirm matrix `tmp'
+        if _rc==0 {
+            ereturn matrix `prefix'`stat' = `tmp'
+            added_matrix `prefix'`stat' "`elabel'"
+        }
+    }
+
+// return x-values
+    matrix `prvalue_x' = `prvalue_x''
+    ereturn matrix `prefix'X = `prvalue_x'
+    added_matrix `prefix'X _rown
+    if `hasx2' {
+        matrix `prvalue_x2' = `prvalue_x2''
+        ereturn matrix `prefix'X2 = `prvalue_x2'
+        added_matrix `prefix'X2 _rown
+    }
+
+// store
+    if "`post2'"!="" {
+        _eststo `estname'`post2', `title'
+        di as txt _n "results stored as " as res "`estname'`post2'"
+    }
+    else if `"`title'"'!="" {
+        estimates change ., `title'
+    }
+
+// retore estimates
+    if "`post2'"!="" {
+        _est unhold `hcurrent'
+    }
+    else {
+        _est unhold `hcurrent', not
+    }
+end
+
+* 23.
+* -estadd- subroutine: support for -asprvalue- by Long and Freese
+* (see http://www.indiana.edu/~jslsoc/spost.htm)
+program define estadd_asprvalue, eclass
+    version 9.2
+    local caller : di _caller()
+    syntax [anything] [ , Prefix(passthru) Replace Quietly ///
+        LABel(str) Title(passthru) swap * ]
+
+// post
+    if `"`anything'"'!="" {
+        gettoken post post2 : anything
+        if `"`post'"'!="post" {
+            di as err `"`post' not allowed"'
+            exit 198
+        }
+        else if `"`label'"'!="" {
+            di as err "label() not allowed"
+            exit 198
+        }
+        _estadd_asprvalue_Post `post2' , `prefix' `replace' `quietly' ///
+            `title' `swap' `options'
+        exit
+    }
+    else if `"`title'"'!="" {
+        di as err "title() not allowed"
+        exit 198
+    }
+    else if "`swap'"!="" {
+        di as err "swap not allowed"
+        exit 198
+    }
+
+// look for e(sample)
+    confirm_esample
+
+// run prvalue
+    capt findfile asprvalue.ado
+    if _rc {
+        di as error "-asprvalue- from the -spost9_ado- package by Long and Freese required"
+        di as error `"type {stata "net from http://www.indiana.edu/~jslsoc/stata"}"'
+        error 499
+    }
+    `quietly' version `caller': asprvalue , `options'
+
+// append?
+    capture confirm existence `e(_estadd_asprval)'
+    local append = (_rc==0) & ("`replace'"=="")
+    tempname asprval asprval_asv asprval_csv
+    if `append' {
+        mat `asprval'          = e(_estadd_asprval)
+        capt mat `asprval_asv' = e(_estadd_asprval_asv)
+        capt mat `asprval_csv' = e(_estadd_asprval_csv)
+        local ires = rowsof(`asprval') + 1
+    }
+    else local ires 1
+    if `"`label'"'=="" {
+        local label "pred`ires'"
+    }
+    else {
+        local label = substr(`"`label'"', 1, 30)  // 30 characters max
+        local problemchars `": . `"""'"'
+        foreach char of local problemchars {
+            local label: subinstr local label `"`char'"' "_", all
+        }
+    }
+
+// collect results
+    tempname res
+    mat `res' = r(p)
+    _estadd_asprvalue_Reshape `res', label(`label')
+    _estadd_asprvalue_Add `asprval' `res' `append'
+    capture confirm matrix r(asv)
+    local hasasv = _rc==0
+    if `hasasv' {
+        mat `res' = r(asv)
+        _estadd_asprvalue_Reshape `res', label(`label')
+        _estadd_asprvalue_Add `asprval_asv' `res' `append'
+    }
+    capture confirm matrix r(csv)
+    local hascsv = _rc==0
+    if `hascsv' {
+        _estadd_asprvalue_AddCsv `asprval_csv', label(`label')
+    }
+
+// post in e()
+    di as txt _n cond(`append',"updated","added") " matrices:"
+    ereturn matrix _estadd_asprval = `asprval'
+    added_matrix _estadd_asprval
+    if `hasasv' {
+        ereturn matrix _estadd_asprval_asv = `asprval_asv'
+        added_matrix _estadd_asprval_asv
+    }
+    if `hascsv' {
+        ereturn matrix _estadd_asprval_csv = `asprval_csv'
+        added_matrix _estadd_asprval_csv
+    }
+end
+program _estadd_asprvalue_Reshape
+    syntax anything, label(str)
+    tempname tmp res
+    local r = rowsof(`anything')
+    forv i=1/`r' {
+        mat `tmp' = `anything'[`i',1...]
+        local nm: rownames `tmp'
+        mat coleq `tmp' = `"`nm'"'
+        mat `res' = nullmat(`res'), `tmp'
+    }
+    mat rown `res' = `"`label'"'
+    mat `anything' = `res'
+end
+program _estadd_asprvalue_Add
+    args master using append
+    if `append' {
+        local coln1: colfullnames `master'
+        local coln2: colfullnames `using'
+        if `"`coln1'"'!=`"`coln2'"' {
+            di as err "incompatible asprvalue results"
+            exit 498
+        }
+    }
+    mat `master' = nullmat(`master') \ `using'
+end
+program _estadd_asprvalue_AddCsv
+    syntax anything, label(str)
+    tempname tmp
+    mat `tmp' = r(csv)
+    mat rown `tmp' = `"`label'"'
+    mat `anything' = nullmat(`anything') \ `tmp'
+end
+program _estadd_asprvalue_Post, eclass
+    syntax [name(name=post2)] [ , Prefix(name) Replace Quietly ///
+        Title(passthru) swap ]
+    capture confirm matrix e(_estadd_asprval)
+    if _rc {
+        di as err "asprvalue results not found"
+        exit 498
+    }
+
+// backup estimates
+    tempname hcurrent
+    _est hold `hcurrent', copy restore estsystem
+    local cmd = e(cmd)
+    local depvar = e(depvar)
+    local N = e(N)
+    local estname `"`e(_estadd_estimates_name)'"'
+
+// get results
+    tempname asprval asprval_asv asprval_csv
+    mat `asprval' = e(_estadd_asprval)
+    capture confirm matrix e(_estadd_asprval_asv)
+    local hasasv = _rc==0
+    if `hasasv' {
+        mat `asprval_asv' = e(_estadd_asprval_asv)
+    }
+    capture confirm matrix e(_estadd_asprval_csv)
+    local hascsv = _rc==0
+    if `hascsv' {
+        mat `asprval_csv' = e(_estadd_asprval_csv)
+    }
+
+// return predictions
+    tempname tmp tmp2 b
+    if "`swap'"=="" {
+        local eqs: coleq `asprval', q
+        local eqs: list uniq eqs
+        foreach eq of local eqs {
+            mat `tmp' = `asprval'[1...,`"`eq':"']
+            mat `tmp2' = `tmp'[1...,1]'
+            mat coleq `tmp2' = `"`eq'"'
+            mat roweq `tmp2' = ""
+            mat `b' = nullmat(`b'), `tmp2'
+        }
+        mat drop `tmp' `tmp2'
+    }
+    else {
+        local r = rowsof(`asprval')
+        local coln: colnames `asprval'
+        local eqs: coleq `asprval', q
+        mat coln `asprval' = `eqs'
+        forv i=1/`r' {
+            mat `tmp' = `asprval'[`i',1...]
+            local labl : rownames `tmp'
+            mat coleq `tmp' = `"`labl'"'
+            mat `b' = nullmat(`b'), `tmp'
+        }
+        mat drop `tmp'
+    }
+    ereturn post `b', obs(`N')
+    ereturn local model "`cmd'"
+    ereturn local cmd "estadd_asprvalue"
+    ereturn local depvar "`depvar'"
+    di as txt _n "scalars:"
+    added_scalar N
+    di as txt _n "macros:"
+    added_macro depvar
+    added_macro cmd
+    added_macro model
+    added_macro properties
+    di as txt _n "matrices:"
+    added_matrix b "predictions"
+
+// return asv-values
+    if `hasasv' {
+        if "`swap'"=="" {
+            local vars: coleq `asprval_asv'
+            local vars: list uniq vars
+            local cats: colnames `asprval_asv'
+            local cats: list uniq cats
+            foreach var of local vars {
+                foreach cat of local cats {
+                    mat `tmp2' = `asprval_asv'[1...,`"`var':`cat'"']'
+                    mat coleq `tmp2' = `"`cat'"'
+                    mat roweq `tmp2' = ""
+                    mat `tmp' = nullmat(`tmp'), `tmp2'
+                }
+                mat rown `tmp' = `"`var'"'
+                mat `b' = nullmat(`b') \ `tmp'
+                mat drop `tmp'
+            }
+        }
+        else {
+            local r = rowsof(`asprval_asv')
+            local vars: coleq `asprval_asv'
+            local vars: list uniq vars
+            forv i=1/`r' {
+                foreach var of local vars {
+                    mat `tmp2' = `asprval_asv'[`i',`"`var':"']
+                    local lbl: rownames `tmp2'
+                    mat coleq `tmp2' = `"`lbl'"'
+                    mat rown `tmp2' = `"`var'"'
+                    mat `tmp' = nullmat(`tmp') \ `tmp2'
+                }
+                mat `b' = nullmat(`b') , `tmp'
+                mat drop `tmp'
+            }
+        }
+        ereturn matrix `prefix'asv = `b'
+        added_matrix `prefix'asv _rown
+    }
+// return csv-values
+    if `hascsv' {
+        matrix `asprval_csv' = `asprval_csv''
+        ereturn matrix `prefix'csv = `asprval_csv'
+        added_matrix `prefix'csv _rown
+    }
+
+// store
+    if "`post2'"!="" {
+        _eststo `estname'`post2', `title'
+        di as txt _n "results stored as " as res "`estname'`post2'"
+    }
+    else if `"`title'"'!="" {
+        estimates change ., `title'
+    }
+
+// retore estimates
+    if "`post2'"!="" {
+        _est unhold `hcurrent'
+    }
+    else {
+        _est unhold `hcurrent', not
+    }
+end
+
+* 24. estadd_margins
+program define estadd_margins, eclass
+    version 11.0
+    local caller : di _caller()
+    syntax [ anything(everything equalok)] [fw aw iw pw] [, Prefix(name) Replace Quietly * ]
+
+// set default prefix
+    if "`prefix'"=="" local prefix "margins_"
+
+// compute and return the results
+    if `"`weight'`exp'"'!="" local wgtexp `"[`weight'`exp']"'
+    `quietly' version `caller': margins `anything' `wgtexp', `options'
+
+// check names
+    local rscalars: r(scalars)
+    local rmacros: r(macros)
+    local rmatrices: r(matrices)
+    local rmatrices: subinstr local rmatrices "V" "se", word
+    if "`replace'"=="" {
+        foreach nmlist in rscalars rmacros rmatrices  {
+            foreach name of local `nmlist' {
+                confirm_new_ename `prefix'`name'
+            }
+        }
+    }
+
+// add results
+    di as txt _n "added scalars:"
+    foreach name of local rscalars {
+        ereturn scalar `prefix'`name' = r(`name')
+        added_scalar `prefix'`name'
+    }
+    di as txt _n "added macros:"
+    foreach name of local rmacros {
+        ereturn local `prefix'`name' `"`r(`name')'"'
+        added_macro `prefix'`name'
+    }
+    di as txt _n "added matrices:"
+    tempname tmpmat
+    foreach name of local rmatrices {
+        if "`name'"=="se" {
+            mat `tmpmat' = vecdiag(r(V))
+            forv i = 1/`=colsof(`tmpmat')' {
+                mat `tmpmat'[1,`i'] = sqrt(`tmpmat'[1,`i'])
+            }
+        }
+        else {
+            mat `tmpmat' = r(`name')
+        }
+        eret matrix `prefix'`name' = `tmpmat'
+        added_matrix `prefix'`name'
+    }
+end
+
+* 99.
+* copy of erepost.ado, version 1.0.1, Ben Jann, 30jul2007
+* used by estadd_listcoef and estadd_prchange
+prog erepost, eclass
+    version 8.2
+    syntax [anything(equalok)] [, cmd(str) noEsample Esample2(varname) REName ///
+        Obs(passthru) Dof(passthru) PROPerties(passthru) * ]
+    if "`esample'"!="" & "`esample2'"!="" {
+        di as err "only one allowed of noesample and esample()"
+        exit 198
+    }
+// parse [b = b] [V = V]
+    if `"`anything'"'!="" {
+        tokenize `"`anything'"', parse(" =")
+        if `"`7'"'!="" error 198
+        if `"`1'"'=="b" {
+            if `"`2'"'=="=" & `"`3'"'!="" {
+                local b `"`3'"'
+                confirm matrix `b'
+            }
+            else error 198
+            if `"`4'"'=="V" {
+                if `"`5'"'=="=" & `"`6'"'!="" {
+                    local v `"`6'"'
+                    confirm matrix `b'
+                }
+                else error 198
+            }
+            else if `"`4'"'!="" error 198
+        }
+        else if `"`1'"'=="V" {
+            if `"`4'"'!="" error 198
+            if `"`2'"'=="=" & `"`3'"'!="" {
+                local v `"`3'"'
+                confirm matrix `v'
+            }
+            else error 198
+        }
+        else error 198
+    }
+//backup existing e()'s
+    if "`esample2'"!="" {
+        local sample "`esample2'"
+    }
+    else if "`esample'"=="" {
+        tempvar sample
+        gen byte `sample' = e(sample)
+    }
+    local emacros: e(macros)
+    if `"`properties'"'!="" {
+        local emacros: subinstr local emacros "properties" "", word
+    }
+    foreach emacro of local emacros {
+        local e_`emacro' `"`e(`emacro')'"'
+    }
+    local escalars: e(scalars)
+    if `"`obs'"'!="" {
+        local escalars: subinstr local escalars "N" "", word
+    }
+    if `"`dof'"'!="" {
+        local escalars: subinstr local escalars "df_r" "", word
+    }
+    foreach escalar of local escalars {
+        tempname e_`escalar'
+        scalar `e_`escalar'' = e(`escalar')
+    }
+    local ematrices: e(matrices)
+    if "`b'"=="" & `:list posof "b" in ematrices' {
+        tempname b
+        mat `b' = e(b)
+    }
+    if "`v'"=="" & `:list posof "V" in ematrices' {
+        tempname v
+        mat `v' = e(V)
+    }
+    local bV "b V"
+    local ematrices: list ematrices - bV
+    foreach ematrix of local ematrices {
+        tempname e_`ematrix'
+        matrix `e_`ematrix'' = e(`ematrix')
+    }
+// rename
+    if "`b'"!="" & "`v'"!="" & "`rename'"!="" {
+        local eqnames: coleq `b', q
+        local vnames: colnames `b'
+        mat coleq `v' = `eqnames'
+        mat coln `v' = `vnames'
+        mat roweq `v' = `eqnames'
+        mat rown `v' = `vnames'
+    }
+// post results
+    if "`esample'"=="" {
+        eret post `b' `v', esample(`sample') `obs' `dof' `properties' `options'
+    }
+    else {
+        eret post `b' `v', `obs' `dof' `properties' `options'
+    }
+    foreach emacro of local emacros {
+        eret local `emacro' `"`e_`emacro''"'
+    }
+    if `"`cmd'"'!="" {
+        eret local cmd `"`cmd'"'
+    }
+    foreach escalar of local escalars {
+        eret scalar `escalar' = scalar(`e_`escalar'')
+    }
+    foreach ematrix of local ematrices {
+        eret matrix `ematrix' = `e_`ematrix''
+    }
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/e/estadd.hlp

@@ -0,0 +1,935 @@
+{smcl}
+{* 13sep2013}{...}
+{hi:help estadd}{right:also see: {helpb esttab}, {helpb estout}, {helpb eststo}, {helpb estpost}}
+{right: {browse "http://repec.org/bocode/e/estout"}}
+{hline}
+
+{title:Title}
+
+{p 4 4 2}{hi:estadd} {hline 2} Add results to (stored) estimates
+
+
+{title:Syntax}
+
+{p 8 15 2}
+{cmd:estadd} {it:{help estadd##subcommands:subcommand}} [{cmd:,}
+{it:{help estadd##opts:options}} ] [ {cmd::} {it:namelist} ]
+
+
+    where {it:namelist} is {cmd:_all} | {cmd:*} | {it:name} [{it:name} ...]
+
+{marker subcommands}
+    {it:subcommands}{col 26}description
+    {hline 65}
+    Elementary
+      {helpb estadd##local:{ul:loc}al} {it:name ...}{col 26}{...}
+add a macro
+      {helpb estadd##scalar:{ul:sca}lar} {it:name} {cmd:=} {it:exp}{col 26}{...}
+add a scalar
+      {helpb estadd##matrix:{ul:mat}rix} {it:name} {cmd:=} {it:mat}{col 26}{...}
+add a matrix
+      {helpb estadd##rreturn:r({it:name})}{col 26}{...}
+add contents of {cmd:r(}{it:name}{cmd:)} (matrix or scalar)
+
+    Statistics for each
+    coefficient
+      {helpb estadd##beta:beta}{col 26}{...}
+standardized coefficients
+      {helpb estadd##vif:vif}{col 26}{...}
+variance inflation factors (after {cmd:regress})
+      {helpb estadd##pcorr:pcorr}{col 26}{...}
+partial (and semi-partial) correlations
+      {helpb estadd##expb:expb}{col 26}{...}
+exponentiated coefficients
+      {helpb estadd##ebsd:ebsd}{col 26}{...}
+standardized factor change coefficients
+      {helpb estadd##mean:mean}{col 26}{...}
+means of regressors
+      {helpb estadd##sd:sd}{col 26}{...}
+standard deviations of regressors
+      {helpb estadd##summ:summ}{col 26}{...}
+various descriptives of the regressors
+
+    Summary statistics
+      {helpb estadd##coxsnell:coxsnell}{col 26}{...}
+Cox & Snell's pseudo R-squared
+      {helpb estadd##nagelkerke:nagelkerke}{col 26}{...}
+Nagelkerke's pseudo R-squared
+      {helpb estadd##lrtest:lrtest} {it:model}{col 26}{...}
+likelihood-ratio test
+      {helpb estadd##ysumm:ysumm}{col 26}{...}
+descriptives of the dependent variable
+
+    Other
+      {helpb estadd##margins:margins}{col 26}{...}
+add results from {cmd:margins} (Stata 11 or newer)
+
+    {help estadd##spost:SPost}
+      {helpb estadd##brant:brant}{col 26}{...}
+add results from {cmd:brant} (if installed)
+      {helpb estadd##fitstat:fitstat}{col 26}{...}
+add results from {cmd:fitstat} (if installed)
+      {helpb estadd##listcoef:listcoef}{col 26}{...}
+add results from {cmd:listcoef} (if installed)
+      {helpb estadd##mlogtest:mlogtest}{col 26}{...}
+add results from {cmd:mlogtest} (if installed)
+      {helpb estadd##prchange:prchange}{col 26}{...}
+add results from {cmd:prchange} (if installed)
+      {helpb estadd##prvalue:prvalue}{col 26}{...}
+add results from {cmd:prvalue} (if installed)
+      {helpb estadd##asprvalue:asprvalue}{col 26}{...}
+add results from {cmd:asprvalue} (if installed)
+    {hline 65}
+
+{marker opts}
+    {it:{help estadd##options:options}}{col 26}description
+    {hline 65}
+      {cmdab:r:eplace}{col 26}{...}
+permit overwriting existing {cmd:e()}'s
+      {cmdab:p:refix(}{it:string}{cmd:)}{col 26}{...}
+specify prefix for names of added results
+      {cmdab:q:uietly}{col 26}{...}
+suppress output from subcommand (if any)
+      {it:subcmdopts}{col 26}{...}
+subcommand specific options
+    {hline 65}
+
+
+{title:Description}
+
+{p 4 4 2}
+{cmd:estadd} adds additional results to the {cmd:e()}-returns of an
+estimation command (see help {help estcom}, help {helpb ereturn}). If no
+{it:namelist} is provided, then the results are added to the
+currently active estimates (i.e. the model fit last). If these
+estimates have been previously stored, the stored copy of the
+estimates will also be modified. Alternatively, if {it:namelist} is
+provided after the colon, results are added to all indicated sets of
+stored estimates (see help {helpb estimates store} or help
+{helpb eststo}). You may use the {cmd:*} and {cmd:?}
+wildcards in {it:namelist}. Execution is silent if {it:namelist} is
+provided.
+
+{p 4 4 2}
+Adding additional results to the {cmd:e()}-returns is useful, for example,
+if the estimates be tabulated by commands such as {helpb estout}
+or {helpb esttab}. See the {help estadd##examples:Examples} section below for
+illustration of the usage of {cmd:estadd}.
+
+{p 4 4 2}Technical note: Some of the subcommands below make use of the
+information contained in {cmd:e(sample)} to determine estimation sample.
+These subcommands return error if the estimates do not contain
+{cmd:e(sample)}.
+
+
+{title:Subcommands}
+
+{dlgtab:Elementary}
+{marker local}
+{p 4 8 2}
+{cmd:estadd} {cmdab:loc:al} {it:name ...}
+
+{p 8 8 2}
+adds in macro {cmd:e(}{it:name}{cmd:)} the specified contents (also
+see help {helpb ereturn}).
+
+{marker scalar}
+{p 4 8 2}
+{cmd:estadd} {cmdab:sca:lar} {it:name} {cmd:=} {it:exp}
+
+{p 8 8 2}
+adds in scalar {cmd:e(}{it:name}{cmd:)} the evaluation of {it:exp}
+(also see help {helpb ereturn}).
+
+{p 4 8 2}
+{cmd:estadd} {cmdab:sca:lar} {cmd:r(}{it:name}{cmd:)}
+
+{p 8 8 2}
+adds in scalar {cmd:e(}{it:name}{cmd:)} the value of scalar {cmd:r(}{it:name}{cmd:)}.
+
+{p 4 8 2}
+{cmd:estadd} {cmdab:sca:lar} {it:name}
+
+{p 8 8 2}
+adds in scalar {cmd:e(}{it:name}{cmd:)} the the value of scalar {it:name}.
+
+{marker matrix}
+{p 4 8 2}
+{cmd:estadd} {cmdab:mat:rix} {it:name} {cmd:=} {it:matrix_expression}
+
+{p 8 8 2}
+adds in matrix {cmd:e(}{it:name}{cmd:)} the evaluation of {it:matrix_expression}
+(also see help {helpb matrix define}).
+
+{p 4 8 2}
+{cmd:estadd} {cmdab:mat:rix} {cmd:r(}{it:name}{cmd:)}
+
+{p 8 8 2}
+adds in matrix {cmd:e(}{it:name}{cmd:)} a copy of matrix {cmd:r(}{it:name}{cmd:)}.
+
+{p 4 8 2}
+{cmd:estadd} {cmdab:mat:rix} {it:name}
+
+{p 8 8 2}
+adds in matrix {cmd:e(}{it:name}{cmd:)} a copy of matrix {it:name}.
+
+{marker rreturn}
+{p 4 8 2}
+{cmd:estadd} {cmd:r(}{it:name}{cmd:)}
+
+{p 8 8 2}
+adds in {cmd:e(}{it:name}{cmd:)} the value of scalar {cmd:r(}{it:name}{cmd:)}
+or a copy of matrix {cmd:r(}{it:name}{cmd:)}, depending on the nature of
+{cmd:r(}{it:name}{cmd:)}.
+
+
+{dlgtab:Statistics for each coefficient}
+{marker beta}
+{p 4 8 2}
+{cmd:estadd} {cmd:beta}
+
+{p 8 8 2}
+adds in {cmd:e(beta)} the standardized beta coefficients.
+
+{marker vif}
+{p 4 8 2}
+{cmd:estadd} {cmd:vif} [{cmd:,} {cmdab:tol:erance} {cmdab:sqr:vif} ]
+
+{p 8 8 2}
+adds in {cmd:e(vif)} the variance inflation factors (VIFs) for the
+regressors (see help {helpb vif}). Note that {cmd:vif} only works
+with estimates produced by {helpb regress}. {cmd:tolerance}
+additionally adds the tolerances (1/VIF) in {cmd:e(tolerance)}.
+{cmd:sqrvif} additionally adds the square roots of the VIFs in
+{cmd:e(sqrvif)}.
+
+{marker pcorr}
+{p 4 8 2}
+{cmd:estadd} {cmd:pcorr} [{cmd:, semi} ]
+
+{p 8 8 2}
+adds the partial correlations (see help {helpb pcorr}) and,
+optionally, the semi-partial correlations between the dependent
+variable and the individual regressors (see, e.g., the {cmd:pcorr2}
+package from the SSC Archive). In the case of multiple-equations
+models, the results are computed for the first equation only. The
+partial correlations will be returned in {cmd:e(pcorr)} and, if
+{cmd:semi} is specified, the semi-partial correlations will be
+returned in {cmd:e(spcorr)}.
+
+{marker expb}
+{p 4 8 2}
+{cmd:estadd} {cmd:expb} [{cmd:,} {cmdab:nocons:tant} ]
+
+{p 8 8 2}
+adds in {cmd:e(expb)} the exponentiated coefficients (see the help
+{it:{help eform_option}}). {cmd:noconstant} excludes the constant
+from the added results.
+
+{marker ebsd}
+{p 4 8 2}
+{cmd:estadd} {cmd:ebsd}
+
+{p 8 8 2}
+adds in {cmd:e(ebsd)} the standardized factor change coefficients,
+i.e. exp(b_jS_j), where b_j is the raw coefficient and S_j is the
+standard deviation of regressor j, that are sometimes reported for
+logistic regression (see Long 1997).
+
+{marker mean}
+{p 4 8 2}
+{cmd:estadd} {cmd:mean}
+
+{p 8 8 2}
+adds in {cmd:e(mean)} the means of the regressors.
+
+{marker sd}
+{p 4 8 2}
+{cmd:estadd} {cmd:sd} [{cmd:,} {cmdab:nob:inary} ]
+
+{p 8 8 2}
+adds in {cmd:e(sd)} the standard deviations of the regressors.
+{cmd:nobinary} suppresses the computation of the standard deviation
+for 0/1 variables.
+
+{marker summ}
+{p 4 8 2}
+{cmd:estadd} {cmd:summ} [{cmd:,} {it:stats} ]
+
+{p 8 8 2}
+adds vectors of the regressors' descriptive statistics to the
+estimates. The following {it:stats} are available:
+{p_end}
+{marker stats}
+        {it:stats}{col 26}description
+        {hline 59}
+          {cmdab:me:an}{col 26}mean
+          {cmdab:su:m}{col 26}sum
+          {cmdab:mi:n}{col 26}minimum
+          {cmdab:ma:x}{col 26}maximum
+          {cmdab:ra:nge}{col 26}range = max - min
+          {cmd:sd}{col 26}standard deviation
+          {cmdab:v:ar}{col 26}variance
+          {cmd:cv}{col 26}coefficient of variation (sd/mean)
+          {cmdab:sem:ean}{col 26}standard error of mean = sd/sqrt(n)
+          {cmdab:sk:ewness}{col 26}skewness
+          {cmdab:k:urtosis}{col 26}kurtosis
+          {cmd:p1}{col 26}1st percentile
+          {cmd:p5}{col 26}5th percentile
+          {cmd:p10}{col 26}10th percentile
+          {cmd:p25}{col 26}25th percentile
+          {cmd:p50}{col 26}50th percentile
+          {cmd:p75}{col 26}75th percentile
+          {cmd:p90}{col 26}90th percentile
+          {cmd:p95}{col 26}95th percentile
+          {cmd:p99}{col 26}99th percentile
+          {cmd:iqr}{col 26}interquartile range = p75 - p25
+          {cmd:all}{col 26}all of the above
+          {cmdab:med:ian}{col 26}equivalent to specifying "{cmd:p50}"
+          {cmd:q}{col 26}equivalent to specifying "{cmd:p25 p50 p75}"
+        {hline 59}
+
+{p 8 8 2}
+The default is {cmd:mean sd min max}. Alternatively, indicate the
+desired statistics. For example, to add information on the
+regressors' skewness and kurtosis, type
+
+            {inp:. estadd summ, skewness kurtosis}
+
+{p 8 8 2}
+The statistics names are used as the names for the returned {cmd:e()}
+matrices. For example, {cmd:estadd summ, mean} will store the means
+of the regressors in {cmd:e(mean)}.
+
+
+{dlgtab:Summary statistics}
+{marker coxsnell}
+{p 4 8 2}
+{cmd:estadd} {cmd:coxsnell}
+
+{p 8 8 2}
+adds in {cmd:e(coxsnell)} the Cox & Snell pseudo R-squared, which is
+defined as
+
+{p 12 12 2}
+r2_coxsnell = 1 - ( L0 / L1 )^(2/N)
+
+{p 8 8 2}
+where L0 is the likelihood of the model without regressors, L1 the
+likelihood of the full model, and N is the sample size.
+
+{marker nagelkerke}
+{p 4 8 2}
+{cmd:estadd} {cmd:nagelkerke}
+
+{p 8 8 2}
+adds in {cmd:e(nagelkerke)} the Nagelkerke pseudo R-squared (or Cragg
+& Uhler pseudo R-squared), which is defined as
+
+{p 12 12 2}
+r2_nagelkerke = r2_coxsnell / (1 - L0^(2/N))
+
+{marker lrtest}
+{p 4 8 2}
+{cmd:estadd} {cmd:lrtest} {it:model} [{cmd:,} {cmdab:n:ame:(}{it:string}{cmd:)}
+{it:{help lrtest:lrtest_options}} ]
+
+{p 8 8 2}
+adds the results from a likelihood-ratio test, where {it:model} is
+the comparison model (see help {helpb lrtest}). Added are
+{cmd:e(lrtest_chi2)}, {cmd:e(lrtest_df)}, and {cmd:e(lrtest_p)}. The
+names may be modified using the {cmd:name()} option. Specify
+{cmd:name(}{it:myname}{cmd:)} to add {cmd:e(}{it:myname}{cmd:chi2)},
+{cmd:e(}{it:myname}{cmd:df)}, and {cmd:e(}{it:myname}{cmd:p)}. See
+help {helpb lrtest} for the {it:lrtest_options}.
+
+{marker ysumm}
+{p 4 8 2}
+{cmd:estadd} {cmd:ysumm} [{cmd:,} {it:stats} ]
+
+{p 8 8 2}
+adds descriptive statistics of the dependent variable. See the
+{helpb estadd##summ:summ} subcommand above for a list of the available
+{it:stats}. The default is {cmd:mean sd min max}. The default prefix
+for the names of the added scalars is {cmd:y} (e.g. the mean of the
+dependent variable will be returned in {cmd:e(ymean)}). Use
+{cmd:estadd}'s {cmd:prefix()} option to change the prefix. If a model
+has multiple dependent variables, results for the first variable will
+be added.
+
+{dlgtab:Other}
+{marker margins}
+{p 4 8 2}
+{cmd:estadd} {cmd:margins} [{it:marginlist}] [{it:if}] [{it:in}] [{it:weight}] [, {it:options} ]
+
+{p 8 8 2} 
+adds results from the {cmd:margins} command, which was introduced 
+in Stata 11. See help {helpb margins} for options. All results returned by 
+{cmd:margins} except {cmd:e(V)} are added using "{cmd:margins_}" as a default 
+prefix. For example, the margins are added in {cmd:e(margins_b)}. The 
+standard errors are added in {cmd:e(margins_se)}. Use the {helpb estadd##opts:prefix()} 
+option to change the default prefix.
+
+{marker spost}
+{dlgtab:SPost}
+
+{p 4 4 2} The following subcommands are wrappers for
+commands from Long and Freese's {helpb SPost} package (see
+{browse "http://www.indiana.edu/~jslsoc/spost.htm":http://www.indiana.edu/~jslsoc/spost.htm}). Type
+
+        . {net "from http://www.indiana.edu/~jslsoc/stata":net from http://www.indiana.edu/~jslsoc/stata}
+
+{p 4 4 2}
+to obtain the latest {cmd:SPost} version (spost9_ado). {cmd:SPost} for Stata 8 (spostado) is not
+supported.
+
+{p 4 4 2}For examples on using the subcommands see
+{browse "http://repec.org/bocode/e/estout/spost.html":http://repec.org/bocode/e/estout/spost.html}.
+
+{marker brant}
+{p 4 8 2}
+{cmd:estadd brant} [{cmd:,} {it:{help brant:brant_options}} ]
+
+{p 8 8 2}
+applies {helpb brant} from Long and
+Freese's {helpb SPost} package and adds the returned results to
+{cmd:e()}. You may specify {it:brant_options} as described in
+help {helpb brant}. The following results are added:
+
+        {cmd:e(}{it:...}{cmd:)}        Contents
+        {hline 60}
+        Scalars
+          {cmd:brant_chi2}  Chi-squared of overall Brant test
+          {cmd:brant_df}    Degrees of freedom of overall Brant test
+          {cmd:brant_p}     P-value of overall Brant test
+
+        Matrix
+          {cmd:brant}       Test results for individual regressors
+                      (rows: chi2, p<chi2)
+        {hline 60}
+
+{p 4 4 2}To address the rows of {cmd:e(brant)} in {helpb estout}'s {cmd:cells()} 
+option type {cmd:brant[chi2]} and {cmd:brant[p<chi2]}.
+
+{marker fitstat}
+{p 4 8 2}
+{cmd:estadd fitstat} [{cmd:,} {it:{help fitstat:fitstat_options}} ]
+
+{p 8 8 2}
+applies {helpb fitstat} from Long and
+Freese's {helpb SPost} package and adds the returned scalars to
+{cmd:e()}. You may specify {it:fitstat_options} as described in
+help {helpb fitstat}. Depending on model
+and options, a selection of the following scalar statistics is added:
+
+        {cmd:e(}{it:...}{cmd:)}        Contents
+        {hline 60}
+        {cmd:dev}           Deviance (D)
+        {cmd:dev_df}        Degrees of freedom of D
+        {cmd:lrx2}          LR or Wald X2
+        {cmd:lrx2_df}       Degrees of freedom of X2
+        {cmd:lrx2_p}        Prob > LR or Wald X2
+        {cmd:r2_adj}        Adjusted R2
+        {cmd:r2_mf}         McFadden's R2
+        {cmd:r2_mfadj}      McFadden's Adj R2
+        {cmd:r2_ml}         ML (Cox-Snell) R2
+        {cmd:r2_cu}         Cragg-Uhler(Nagelkerke) R2
+        {cmd:r2_mz}         McKelvey & Zavoina's R2
+        {cmd:r2_ef}         Efron's R2
+        {cmd:v_ystar}       Variance of y*
+        {cmd:v_error}       Variance of error
+        {cmd:r2_ct}         Count R2
+        {cmd:r2_ctadj}      Adj Count R2
+        {cmd:aic0}          AIC
+        {cmd:aic_n}         AIC*n
+        {cmd:bic0}          BIC
+        {cmd:bic_p}         BIC'
+        {cmd:statabic}      BIC used by Stata
+        {cmd:stataaic}      AIC used by Stata
+        {cmd:n_rhs}         Number of rhs variables
+        {cmd:n_parm}        Number of parameters
+        {hline 60}
+
+{marker listcoef}
+{p 4 8 2}
+{cmd:estadd listcoef} [{it:varlist}] [{cmd:,} {cmd:nosd} {it:{help listcoef:listcoef_options}} ]
+
+{p 8 8 2}
+applies {helpb listcoef} from Long and
+Freese's {helpb SPost} package and adds the returned results to
+{cmd:e()}. You may specify {it:listcoef_options} as described in
+help {helpb listcoef}. Furthermore,  option {cmd:nosd} suppresses 
+adding the standard deviations of the variables in {cmd:e(b_sdx)}.
+
+{p 8 8 2}Depending on the estimation command and options, several of the
+following matrices are added:
+
+        {cmd:e(}{it:...}{cmd:)}        Contents
+        {hline 60}
+        {cmd:b_xs}          x-standardized coefficients
+        {cmd:b_ys}          y-standardized coefficients
+        {cmd:b_std}         Fully standardized coefficients
+        {cmd:b_fact}        Factor change coefficients
+        {cmd:b_facts}       Standardized factor change coefficients
+        {cmd:b_pct}         Percent change coefficients
+        {cmd:b_pcts}        Standardized percent change coefficients
+        {cmd:b_sdx}         Standard deviation of the Xs
+        {hline 60}
+
+{p 8 8 2}For nominal models ({helpb mlogit}, {helpb mprobit}) the 
+original parametrization of {cmd:e(b)} may not match the contrasts 
+computed by {cmd:listcoef}. To be able to tabulate standardized 
+coefficients along with the raw coefficients for the requested 
+contrasts, the following additional matrices are added for 
+these models:
+
+        {cmd:e(}{it:...}{cmd:)}        Contents
+        {hline 60}
+        {cmd:b_raw}         raw coefficients
+        {cmd:b_se}          standard errors of raw coefficients
+        {cmd:b_z}           z statistics
+        {cmd:b_p}           p-values
+        {hline 60}
+
+{marker mlogtest}
+{p 4 8 2}
+{cmd:estadd mlogtest} [{it:varlist}] [{cmd:,} {it:{help mlogtest:mlogtest_options}} ]
+
+{p 8 8 2}
+applies {helpb mlogtest} from Long and
+Freese's {helpb SPost} package and adds the returned results to
+{cmd:e()}. You may specify {it:mlogtest_options} as described in
+help {helpb mlogtest}.
+
+{p 8 8 2}Depending on the specified options, a selection of the following
+returns are added:
+
+        {cmd:e(}{it:...}{cmd:)}               Contents
+        {hline 60}
+        Scalars
+          {cmd:hausman_set}{it:#}{cmd:_chi2}  Hausman IIA tests using {helpb hausman}
+          {cmd:hausman_set}{it:#}{cmd:_df}
+          {cmd:hausman_set}{it:#}{cmd:_p}
+
+          {cmd:suest_set}{it:#}{cmd:_chi2}    Hausman IIA tests using {helpb suest}
+          {cmd:suest_set}{it:#}{cmd:_df}
+          {cmd:suest_set}{it:#}{cmd:_p}
+
+          {cmd:smhsiao_set}{it:#}{cmd:_chi2}  Small-Hsiao IIA tests
+          {cmd:smhsiao_set}{it:#}{cmd:_df}
+          {cmd:smhsiao_set}{it:#}{cmd:_p}
+
+          {cmd:combine_}{it:#1}{cmd:_}{it:#2}{cmd:_chi2} Wald tests for combination of outcomes
+          {cmd:combine_}{it:#1}{cmd:_}{it:#2}{cmd:_df}
+          {cmd:combine_}{it:#1}{cmd:_}{it:#2}{cmd:_p}
+
+          {cmd:lrcomb_}{it:#1}{cmd:_}{it:#2}{cmd:_chi2}  LR tests for combination of outcomes
+          {cmd:lrcomb_}{it:#1}{cmd:_}{it:#2}{cmd:_df}
+          {cmd:lrcomb_}{it:#1}{cmd:_}{it:#2}{cmd:_p}
+
+          {cmd:wald_set}{it:#}{cmd:_chi2}     Wald tests for sets of independent
+          {cmd:wald_set}{it:#}{cmd:_df}       variables
+          {cmd:wald_set}{it:#}{cmd:_p}
+
+          {cmd:lrtest_set}{it:#}{cmd:_chi2}   LR tests for sets of independent
+          {cmd:lrtest_set}{it:#}{cmd:_df}     variables
+          {cmd:lrtest_set}{it:#}{cmd:_p}
+
+        Matrices
+          {cmd:wald}               Wald tests for individual variables
+                             (rows: chi2, df, p)
+          {cmd:lrtest}             LR tests for individual variables
+                             (rows: chi2, df, p)
+        {hline 60}
+
+{p 4 4 2}To address the rows of {cmd:e(wald)} and {cmd:e(lrtest)} in {helpb estout}'s 
+{cmd:cells()} option type the row names in brackets, for example, {cmd:wald[p]} or 
+{cmd:lrtest[chi2]}.
+
+{marker prchange}
+{p 4 8 2}
+{cmd:estadd prchange} [{it:varlist}] [{cmd:if} {it:exp}] [{cmd:in} {it:range}] [{cmd:,}
+ {cmdab:pa:ttern(}{it:typepattern}{cmd:)} {cmdab:b:inary(}{it:type}{cmd:)} {cmdab:c:ontinuous(}{it:type}{cmd:)}
+ [{cmd:no}]{cmdab:a:vg} {cmd:split}[{cmd:(}{it:prefix}{cmd:)}] {it:{help prchange:prchange_options}} ]
+
+{p 8 8 2}
+applies {helpb prchange} from Long and
+Freese's {helpb SPost} package and adds the returned results to
+{cmd:e()}. You may specify {it:prchange_options} as described in
+help {helpb prchange}. In particular, the {cmd:outcome()} option may be
+used with models for count, ordered, or nominal outcomes
+to request results for a specific outcome. Further options are:
+
+{p 8 12 2}{cmd:pattern(}{it:typepattern}{cmd:)}, {cmd:binary(}{it:type}{cmd:)}, and
+{cmd:continuous(}{it:type}{cmd:)} to determine which types of discrete change
+effects are added as the main results. The default is to add the 0 to 1
+change effect for binary variables and the standard deviation change effect
+for continuous variables. Use {cmd:binary(}{it:type}{cmd:)} and
+{cmd:continuous(}{it:type}{cmd:)} to change these defaults. Available
+types are:
+
+                {it:type}        Description
+                {hline 48}
+                {cmdab:mi:nmax}      minimum to maximum change effect
+                {cmdab:0:1}          0 to 1 change effect
+                {cmdab:d:elta}       {cmd:delta()} change effect
+                {cmdab:s:d}          standard deviation change effect
+                {cmdab:m:argefct}    marginal effect (some models only)
+                {hline 48}
+
+{p 12 12 2}Use {cmd:pattern(}{it:typepattern}{cmd:)} if you want to determine the
+type of the added effects individually for each regressor. For example,
+{bind:{cmd:pattern(minmax sd delta)}} would add {cmd:minmax} for the first regressor,
+{cmd:sd} for the second, and {cmd:delta} for the third, and then proceed
+using the defaults for the remaining variables.
+
+{p 8 12 2}{cmd:avg} to request that only the average results over 
+all outcomes are added if applied to ordered
+or nominal models ({helpb ologit}, {helpb oprobit}, {helpb slogit}, {helpb mlogit}, {helpb mprobit}). The 
+default is to add the average results as well as the individual results for 
+the different outcomes (unless {helpb prchange}'s {cmd:outcome()} option is 
+specified, in which case only results for the indicated outcome are 
+added). Furthermore, specify {cmd:noavg} to suppress the average results 
+and only add the outcome-specific results. {cmd:avg} cannot be combined with {cmd:split} 
+or {cmd:outcome()}. 
+
+{p 8 12 2}{cmd:split}[{cmd:(}{it:prefix}{cmd:)}] to save 
+each outcome's results in a separate estimation set if applied to ordered
+or nominal models ({helpb ologit}, {helpb oprobit}, {helpb slogit}, {helpb mlogit},
+{helpb mprobit}). The estimation sets are named
+{it:prefix}{it:#}, where {it:#} is the value of the outcome at hand. If no
+{it:prefix} is provided, the name of the estimation set followed by an
+underscore is used as the prefix. If the estimation set has no name
+(because it has not been stored yet) the name of the estimation command
+followed by an underscore is used as the prefix (e.g. {cmd:ologit_}). The
+estimation sets stored by the {cmd:split} option are intended for
+tabulation only and should not be used with other post-estimation
+commands.
+
+{p 8 8 2}Depending on model and options, several of the following matrices
+and scalars are added:
+
+        {cmd:e(}{it:...}{cmd:)}        Contents
+        {hline 60}
+        Scalars
+          {cmd:centered}    {cmd:1} if effects are centered, {cmd:0} else
+          {cmd:delta}       Value of {cmd:delta()}
+          {cmd:predval}[{it:#}]  Prediction(s) at the base values
+          {cmd:outcome}     Outcome value ({cmd:outcome()}/{cmd:split} only)
+
+        Matrices
+          {cmd:dc}          Discrete change effects (rows: main, minmax,
+                      01, delta, sd [, margefct])
+          {cmd:pattern}     Types of effects in the main row of {cmd:e(dc)}
+          {cmd:X}           Base values and descriptive statistics
+                      (rows: X, SD, Min, Max)
+        {hline 60}
+
+{p 8 8 2}The {cmd:e(dc)} and {cmd:e(X)} matrices have multiple rows. The
+{cmd:e(dc)} matrix contains the main results as determined by
+{cmd:pattern()}, {cmd:binary()}, and {cmd:continuous()} in the first row.
+The second and following rows contain the separate results for each type of
+effect using the labels provided by {cmd:prchange} as row names. Type
+{cmd:dc[}{it:#}{cmd:]} or {cmd:dc[}{it:rowname}{cmd:]} to address the rows
+in {helpb estout}'s {cmd:cells()} option, where {it:#} is the row number 
+or {it:rowname} is the
+row name. For example, type {cmd:dc[-+sd/2]} to address the centered
+standard deviation change effects. To tabulate the main results (1st row),
+simply type {cmd:dc}. {cmd:e(pattern)} indicates the types of effects
+contained in the main row of {cmd:e(dc)} using numeric codes. The codes are 1
+for the minimum to maximum change effect, 2 for the 0 to 1 change effect, 3
+for the {cmd:delta()} change effect, 4 for the standard deviation change
+effect, and 5 for the marginal effect. {cmd:e(X)} has four rows
+containing the base values, standard deviations, minimums, and maximums. If
+the {cmd:fromto} option is specified, two additional matrices,
+{cmd:e(dcfrom)} and {cmd:e(dcto)} are added. 
+
+{marker prvalue}
+{p 4 8 2}
+{cmd:estadd prvalue} [{cmd:if} {it:exp}] [{cmd:in} {it:range}] [{cmd:,} {cmdab:lab:el:(}{it:string}{cmd:)}
+{it:{help prvalue:prvalue_options}} ]
+
+{p 4 8 2}
+{cmd:estadd prvalue} {cmd:post} [{it:name}] [{cmd:,} {cmdab:t:itle:(}{it:string}{cmd:)} {cmd:swap} ]
+
+{p 8 8 2} applies {helpb prvalue} from Long and Freese's {helpb SPost}
+package and adds the returned results to {cmd:e()}. The procedure is to
+first collect a series of predictions by repeated calls to
+{cmd:estadd prvalue} and then apply {cmd:estadd prvalue post} to prepare the results
+for tabulation as in the following example:
+
+            {com}. logit lfp k5 k618 age wc hc lwg inc
+            . estadd prvalue, x(inc 10) label(low inc)
+            . estadd prvalue, x(inc 20) label(med inc)
+            . estadd prvalue, x(inc 30) label(high inc)
+            . estadd prvalue post
+            . estout{txt}
+
+{p 8 8 2} You may specify {it:prvalue_options} with {cmd:estadd prvalue} as
+described in help {helpb prvalue}. For example, use {cmd:x()} and
+{cmd:rest()} to set the values of the independent variables. Use
+{cmd:label()} to label the single calls. "pred#" is used as label if
+{cmd:label()} is omitted, where # is the number of the call. Labels may
+contain spaces but they will be trimmed to a maximum
+length of 30 characters and some characters ({cmd::},
+{cmd:.}, {cmd:"}) will be replaced by underscore. The results
+from the single calls are collected in matrix {cmd:e(_estadd_prvalue)}
+(predictions) and matrix {cmd:e(_estadd_prvalue_x)} (x-values). Specify
+{cmd:replace} to drop results from previous calls.
+
+{p 8 8 2}
+{cmd:estadd prvalue post} posts the collected predictions in {cmd:e(b)}
+so that they can be tabulated. The following results are saved:
+
+        {cmd:e(}{it:...}{cmd:)}        Contents
+        {hline 60}
+        Scalars
+          {cmd:N}           number of observations
+
+        Macros
+          {cmd:depvar}      name of dependent variable
+          {cmd:cmd}         {cmd:estadd_prvalue}
+          {cmd:model}       model estimation command
+          {cmd:properties}  {cmd:b}
+
+        Matrices
+          {cmd:b}           predictions
+          {cmd:se}          standard errors
+          {cmd:LB}          lower confidence interval bounds
+          {cmd:UB}          upper confidence interval bounds
+          {cmd:Category}    outcome values
+          {cmd:Cond}        conditional predictions (some models only)
+          {cmd:X}           values of predictors (for each prediction)
+          {cmd:X2}          second equation predictors (some models only)
+        {hline 60}
+
+{p 8 8 2} {cmd:estadd prvalue post} replaces the current model unless
+{it:name} is specified, in which case the results are stored under {it:name} and the model
+remains active. However, if the model has a name
+(because it has been stored), the name of the model is used as a prefix.
+If, for example, the model has been stored as {cmd:model1}, then
+{cmd:estadd prvalue post} stores its results under {cmd:model1}{it:name}.
+Use {cmd:title()} to specify a title for the stored results.
+
+{p 8 8 2}The default for {cmd:estadd prvalue post} is to arrange
+{cmd:e(b)} in a way so that predictions are grouped by outcome (i.e. outcome labels are used
+as equations). Alternatively, specify {cmd:swap} to group predictions by
+{cmd:prvalue} calls (i.e. to use the prediction labels as equations).
+
+{p 8 8 2}{cmd:e(X)} contains one row for each independent variable. To address the rows in
+{helpb estout}'s {cmd:cells()} option type {cmd:X[}{it:varname}{cmd:]}, where {it:varname} is
+the name of the variable of interest. {cmd:e(X2)}, if provided, is analogous to {cmd:e(X)}.
+
+{marker asprvalue}
+{p 4 8 2}
+{cmd:estadd asprvalue} [{cmd:,} {cmdab:lab:el:(}{it:string}{cmd:)}
+{it:{help asprvalue:asprvalue_options}} ]
+
+{p 4 8 2}
+{cmd:estadd asprvalue} {cmd:post} [{it:name}] [{cmd:,} {cmdab:t:itle:(}{it:string}{cmd:)} {cmd:swap} ]
+
+{p 8 8 2} applies {helpb asprvalue} from Long and Freese's {helpb SPost}
+package and adds the returned results to {cmd:e()}. The procedure is to
+first collect a series of predictions by repeated calls to
+{cmd:estadd asprvalue} and then apply {cmd:estadd asprvalue post} to prepare the results
+for tabulation as in the following example:
+
+            {com}. clogit choice train bus time invc, group(id)
+            . estadd asprvalue, cat(train bus) label(at means)
+            . estadd asprvalue, cat(train bus) rest(asmean) label(at asmeans)
+            . estadd asprvalue post
+            . estout{txt}
+
+{p 8 8 2} You may specify {it:asprvalue_options} with {cmd:estadd asprvalue} as
+described in help {helpb asprvalue}. For example, use {cmd:x()} and
+{cmd:rest()} to set the values of the independent variables.  Use
+{cmd:label()} to label the single calls. "pred#" is used as label if
+{cmd:label()} is omitted, where # is the number of the call.  Labels may
+contain spaces but they will be trimmed to a maximum
+length of 30 characters and some characters ({cmd::},
+{cmd:.}, {cmd:"}) will be replaced by underscore. The results
+from the single calls are collected in matrices {cmd:e(_estadd_asprval)}
+(predictions), {cmd:e(_estadd_asprval_asv)} (values of alternative-specific
+variables), and {cmd:e(_estadd_asprval_csv)} (values of case-specific
+variables). Specify {cmd:replace} to drop results from previous calls.
+
+{p 8 8 2}
+{cmd:estadd asprvalue post} posts the collected predictions in {cmd:e(b)}
+so that they can be tabulated. The following results are saved:
+
+        {cmd:e(}{it:...}{cmd:)}        Contents
+        {hline 60}
+        Scalars
+          {cmd:N}           number of observations
+
+        Macros
+          {cmd:depvar}      name of dependent variable
+          {cmd:cmd}         {cmd:estadd_asprvalue}
+          {cmd:model}       model estimation command
+          {cmd:properties}  {cmd:b}
+
+        Matrices
+          {cmd:b}           predictions
+          {cmd:asv}         alternative-specific variables (if available)
+          {cmd:csv}         case-specific variables (if available)
+        {hline 60}
+
+{p 8 8 2} {cmd:estadd asprvalue post} replaces the current model unless
+{it:name} is specified, in which case the results are stored under
+{it:name} and the model remains active. However, if the model has a name
+(because it has been stored), the name of the model is used as a prefix.
+If, for example, the model has been stored as {cmd:model1}, then
+{cmd:estadd asprvalue post} stores its results under {cmd:model1}{it:name}.
+Use {cmd:title()} to specify a title for the stored results.
+
+{p 8 8 2}The default for {cmd:estadd asprvalue post} is to arrange
+{cmd:e(b)} in a way so that predictions are grouped by outcome (i.e. outcome labels are used
+as equations). Alternatively, specify {cmd:swap} to group predictions by
+{cmd:prvalue} calls (i.e. to use the prediction labels as equations).
+
+{p 8 8 2}{cmd:e(asv)} and {cmd:e(csv)} contain one row for each variable.
+To address the rows in {helpb estout}'s {cmd:cells()} option type
+{cmd:asv[}{it:varname}{cmd:]} or {cmd:csv[}{it:varname}{cmd:]}, where
+{it:varname} is the name of the variable of interest.
+
+{marker options}
+{title:Options}
+
+{p 4 8 2}
+{cmd:replace} permits {cmd:estadd} to overwrite existing {cmd:e()}
+macros, scalars, or matrices.
+
+{p 4 8 2}
+{cmd:prefix(}{it:string}{cmd:)} denotes a prefix for the names of the
+added results. The default prefix is an empty string. For example, if
+{cmd:prefix(}{it:string}{cmd:)} is specified, the {cmd:beta}
+subcommand will return the matrix {cmd:e(}{it:string}{cmd:beta)}.
+
+{p 4 8 2}{cmd:quietly} suppresses the output from the called subcommand and displays only
+the list of added results. Note that many of {cmd:estadd}'s subcommands do not generate
+output, in which case {cmd:quietly} has no effect.
+
+{p 4 8 2}
+{it:subcmdopts} are subcommand specific options. See the descriptions
+of the subcommands above.
+
+{marker examples}
+{title:Examples}
+
+{p 4 4 2}Example 1: Add {cmd:r()}-returns from other programs to the
+current estimates
+
+        {com}. sysuse auto
+        {txt}(1978 Automobile Data)
+
+        {com}. quietly regress price mpg weight
+        {txt}
+        {com}. test mpg=weight
+
+        {txt} ( 1)  {res}mpg - weight = 0
+
+        {txt}       F(  1,    71) ={res}    0.36
+        {txt}{col 13}Prob > F ={res}    0.5514
+        {txt}
+        {com}. estadd scalar p_diff = r(p)
+
+        {txt}added scalar:
+                     e(p_diff) =  {res}.55138216
+        {txt}
+        {com}. estout, stats(p_diff)
+        {res}
+        {txt}{hline 25}
+        {txt}                        b
+        {txt}{hline 25}
+        {txt}mpg         {res}    -49.51222{txt}
+        {txt}weight      {res}     1.746559{txt}
+        {txt}_cons       {res}     1946.069{txt}
+        {txt}{hline 25}
+        {txt}p_diff      {res}     .5513822{txt}
+        {txt}{hline 25}
+
+
+{p 4 4 2}Example 2: Add means and standard deviations of the model's regressors
+to the current estimates
+
+        {com}. quietly logit foreign price mpg
+        {txt}
+        {com}. estadd summ, mean sd
+
+        {txt}added matrices:
+                         e(sd) :  {res}1 x 3
+                       {txt}e(mean) :  {res}1 x 3
+        {txt}
+        {com}. estout, cells("mean sd") drop(_cons)
+        {res}
+        {txt}{hline 38}
+        {txt}                     mean           sd
+        {txt}{hline 38}
+        {txt}price       {res}     6165.257     2949.496{txt}
+        {txt}mpg         {res}      21.2973     5.785503{txt}
+        {txt}{hline 38}
+
+
+{p 4 4 2}
+Example 3: Add standardized beta coefficients to stored estimates
+
+        {com}. eststo: quietly regress price mpg
+        {txt}({res}est1{txt} stored)
+
+        {com}. eststo: quietly regress price mpg foreign
+        {txt}({res}est2{txt} stored)
+
+        {com}. estadd beta: *
+        {txt}
+        {com}. estout, cells(beta)  drop(_cons)
+        {res}
+        {txt}{hline 38}
+        {txt}                     est1         est2
+        {txt}                     beta         beta
+        {txt}{hline 38}
+        {txt}mpg         {res}    -.4685967    -.5770712{txt}
+        {txt}foreign     {res}                  .2757378{txt}
+        {txt}{hline 38}
+
+
+{p 4 4 2}See
+{browse "http://repec.org/bocode/e/estout":http://repec.org/bocode/e/estout}
+for additional examples.
+
+
+{title:Writing one's own subcommands}
+
+{p 4 4 2}
+A program providing a new {cmd:estadd} subcommand should be called
+{cmd:estadd_}{it:mysubcommand} (see help {helpb program} for advice
+on defining programs). {it:mysubcommand} will be available to {cmd:estadd} as a new
+{it:subcommand} after the program definition has been executed or
+saved to a file called "estadd_{it:mysubcommand}.ado" in either the
+current directory or somewhere else in the {cmd:adopath}
+(see help {helpb sysdir}).
+
+{p 4 4 2}
+Use the subcommands provided within "estadd.ado" as a starting
+point for writing new subcommands. See
+{browse "http://repec.org/bocode/e/estout/estadd.html#estadd007":http://repec.org/bocode/e/estout/estadd.html#estadd007}
+for an example.
+
+
+{title:Author}
+
+{p 4 4 2} Ben Jann, Institute of Sociology, University of Bern, [email protected]
+
+
+{title:Also see}
+
+    Manual:  {hi:[R] estimates}
+
+{p 4 13 2}Online:  help for
+ {helpb estimates},
+ {helpb ereturn},
+ {helpb program},
+ {helpb esttab}, 
+ {helpb estout}, 
+ {helpb eststo}, 
+ {helpb estpost}
+{p_end}

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/e/estpost.ado

@@ -0,0 +1,1839 @@
+*! version 1.1.6  06aug2010  Ben Jann
+* 1. estpost
+* 2. estpost_summarize
+* 3. estpost_tabulate
+* 4. estpost_tabstat
+* 5. estpost_ttest
+* 6. estpost_correlate
+* 7. estpost_stci (Stata 9 required)
+* 8. estpost_ci
+* 9. estpost_prtest
+* 10. estpost__svy_tabulate
+* 99. _erepost
+
+* 1. estpost
+program estpost, rclass // rclass => remove r()'s left behind by subcommand
+    version 8.2
+    local caller : di _caller()
+    capt syntax [, * ]
+    if _rc==0 { // => for bootstrap
+        _coef_table_header
+        ereturn display, `options'
+        exit
+    }
+    gettoken subcommand rest : 0, parse(" ,:")
+    capt confirm name `subcommand'
+    if _rc {
+        di as err "invalid subcommand"
+        exit 198
+    }
+
+    local l = length(`"`subcommand'"')
+         if `"`subcommand'"'==substr("summarize",1,max(2,`l')) local subcommand "summarize"
+    else if `"`subcommand'"'==substr("tabulate",1,max(2,`l'))  local subcommand "tabulate"
+    else if `"`subcommand'"'==substr("correlate",1,max(3,`l')) local subcommand "correlate"
+    else if `"`subcommand'"'=="svy" {
+        _estpost_parse_svy `macval(rest)'
+    }
+    else if substr(`"`subcommand'"',1,5)=="_svy_" {
+        di as err "invalid subcommand"
+        exit 198
+    }
+
+    capt local junk: properties estpost_`subcommand' // does not work in Stata 8
+    if _rc==199 {
+        di as err "invalid subcommand"
+        exit 198
+    }
+
+    version `caller': estpost_`subcommand' `macval(rest)'
+    //eret list
+end
+program _estpost_markout2 // marks out obs that are missing on *all* variables
+    gettoken touse varlist: 0
+    if `:list sizeof varlist'>0 {
+        tempname touse2
+        gen byte `touse2' = 0
+        foreach var of local varlist {
+            qui replace `touse2' = 1 if !missing(`var')
+        }
+        qui replace `touse' = 0 if `touse2'==0
+    }
+end
+program _estpost_parse_svy
+    version 9.2
+    _on_colon_parse `0'
+    local 0 `"`s(after)'"'
+    gettoken subcommand rest : 0, parse(" ,")
+    local l = length(`"`subcommand'"')
+    if `"`subcommand'"'==substr("tabulate",1,max(2,`l'))  local subcommand "tabulate"
+    c_local subcommand `"_svy_`subcommand'"'
+    c_local rest `"`s(before)' : `rest'"'
+end
+program _estpost_namesandlabels // used by some routines such as estpost_tabulate
+    version 8.2                 // returns locals names, savenames, and labels
+    args varname values0 labels0
+    if `"`values0'"'=="" { // generate values: 1 2 3 ...
+        local i 0
+        foreach label of local labels0 {
+            local values0 `values0' `++i'
+        }
+    }
+    local haslabels 0
+    if `"`labels0'"'=="" & "`varname'"!="" {
+        local vallab: value label `varname'
+    }
+    while (1) {
+        gettoken value values0 : values0
+        if "`value'"=="" continue, break  //=> exit loop
+        if `"`vallab'"'!="" {
+            local lbl: label `vallab' `value', strict
+        }
+        else {
+            gettoken lbl labels0 : labels0
+        }
+        if index("`value'",".") {
+            local haslabels 1
+            if `"`lbl'"'=="" {
+                local lbl "`value'"
+            }
+            local value: subinstr local value "." "_missing_"
+        }
+        local names0 `names0' `value'
+        if `"`lbl'"'!="" {
+            local labels `"`labels'`lblspace'`value' `"`lbl'"'"'
+            local lblspace " "
+        }
+        if `haslabels' continue
+        if `"`lbl'"'=="" {
+            local names `"`names'`space'`value'"'
+            local savenames `"`savenames'`space'`value'"'
+        }
+        else {
+            if regexm(`"`lbl'"', `"[:."]"') local haslabels 1
+            else if length(`"`lbl'"')>30    local haslabels 1
+            else {
+                local names `"`names'`space'`"`lbl'"'"'
+                local lbl: subinstr local lbl " " "_", all
+                local savenames `"`savenames'`space'`lbl'"'
+            }
+        }
+        local space " "
+    }
+    if `haslabels' {
+        local names `names0'
+        local savenames `names0'
+    }
+    c_local names       `"`names'"'         // to be used as matrix row- or colnames
+    c_local savenames   `"`savenames'"'     // names without spaces (for matlist)
+    if `haslabels' {
+        c_local labels      `"`labels'"'    // label dictionary
+    }
+    else c_local labels ""
+end
+program _estpost_eqnamesandlabels // used by some routines such as estpost_tabulate
+    version 8.2                   // returns locals eqnames and eqlabels
+    args varname values0 labels0
+    if `"`values0'"'=="" { // generate values: 1 2 3 ...
+        local i 0
+        foreach label of local labels0 {
+            local values0 `values0' `++i'
+        }
+    }
+    local haslabels 0
+    if `"`labels0'"'=="" & "`varname'"!="" {
+        local vallab: value label `varname'
+    }
+    while (1) {
+        gettoken value values0 : values0
+        if "`value'"=="" continue, break  //=> exit loop
+        if `"`vallab'"'!="" {
+            local lbl: label `vallab' `value', strict
+        }
+        else {
+            gettoken lbl labels0 : labels0
+        }
+        if index("`value'",".") {
+            local haslabels 1
+            if `"`lbl'"'=="" {
+                local lbl "`value'"
+            }
+            local value: subinstr local value "." "_missing_"
+        }
+        local names0 `names0' `value'
+        if `"`lbl'"'=="" local lbl "`value'"
+        local labels `"`labels'`lblspace'`"`lbl'"'"'
+        local lblspace " "
+        if `haslabels' continue
+        if `"`lbl'"'=="" {
+            local names `"`names'`space'`value'"'
+        }
+        else {
+            if regexm(`"`lbl'"', `"[:."]"') local haslabels 1
+            else if length(`"`lbl'"')>30    local haslabels 1
+            else {
+                local names `"`names'`space'`"`lbl'"'"'
+            }
+        }
+        local space " "
+    }
+    if `haslabels' {
+        local names `names0'
+    }
+    c_local eqnames       `"`names'"'         // to be used as matrix roweqs or coleqs
+    if `haslabels' {
+        c_local eqlabels  `"`labels'"'        // list of labels
+    }
+    else c_local eqlabels ""
+end
+
+* 2. estpost_summarize: wrapper for -summarize-
+prog estpost_summarize, eclass
+    version 8.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax [varlist] [if] [in] [aw fw iw] [, ESample Quietly ///
+        LISTwise CASEwise Detail MEANonly ]
+    if "`casewise'"!="" local listwise listwise
+
+    // sample
+    if "`listwise'"!="" marksample touse
+    else {
+        marksample touse, nov
+        _estpost_markout2 `touse' `varlist'
+    }
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // gather results
+    local nvars: list sizeof varlist
+    tempname emptymat
+    mat `emptymat' = J(1, `nvars', .)
+    mat coln `emptymat' = `varlist'
+    local i 0
+    local rnames ""
+    foreach v of local varlist {
+        local ++i
+        qui summarize `v' if `touse' [`weight'`exp'], `detail' `meanonly'
+        local rnamesi: r(scalars)
+        local rnamesi: list rnamesi - rnames
+        if `"`rnamesi'"'!="" {
+            foreach name of local rnamesi {
+                tempname _`name'
+                mat `_`name'' = `emptymat'
+            }
+            local rnames: list rnames | rnamesi
+        }
+        foreach rname of local rnames {
+            mat `_`rname''[1,`i'] = r(`rname')
+        }
+    }
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        local rescoln
+        foreach rname of local rnames {
+            mat `res' = nullmat(`res'), `_`rname'''
+            if "`rname'"=="N" {
+                local rescoln `rescoln' e(count)
+            }
+            else {
+                local rescoln `rescoln' e(`rname')
+            }
+        }
+        mat coln `res' = `rescoln'
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g)
+        }
+        else {
+            matlist `res', nohalf lines(oneline)
+        }
+        mat drop `res'
+    }
+
+    // post results
+    local b
+    local V
+    if c(stata_version)<9 { // b and V required in Stata 8
+        tempname b V
+        mat `b' = J(1, `nvars', 0)
+        mat coln `b' = `varlist'
+        mat `V' = `b'' * `b'
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `b' `V', obs(`N') `esample'
+
+    eret scalar k = `nvars'
+
+    eret local wexp `"`exp'"'
+    eret local wtype `"`weight'"'
+    eret local subcmd "summarize"
+    eret local cmd "estpost"
+
+    local nmat: list sizeof rnames
+    forv i=`nmat'(-1)1 {
+        local rname: word `i' of `rnames'
+        if "`rname'"=="N" {
+            eret matrix count = `_N'
+            continue
+        }
+        eret matrix `rname' = `_`rname''
+    }
+end
+
+
+* 2. estpost_tabulate: wrapper for -tabulate-
+prog estpost_tabulate, eclass
+    version 8.2
+    local caller : di _caller() // not used
+    syntax varlist(min=1 max=2) [if] [in] [fw aw iw pw] [, * ]
+    if `:list sizeof varlist'==1 {
+        version `caller': estpost_tabulate_oneway `0'
+    }
+    else {
+        version `caller': estpost_tabulate_twoway `0'
+    }
+end
+prog estpost_tabulate_oneway, eclass
+    version 8.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax varname [if] [in] [fw aw iw] [, ESample Quietly ///
+        noTOTal subpop(passthru) Missing sort noLabel ]
+
+    // sample
+    if "`missing'"!="" marksample touse, nov strok
+    else               marksample touse, strok
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // handle string variables
+    capt confirm numeric variable `varlist'
+    if _rc {
+        tempname varname
+        qui encode `varlist' if `touse', generate(`varname')
+    }
+    else local varname `varlist'
+
+    // gather results
+    tempname count vals
+    tab `varname' if `touse' [`weight'`exp'], nofreq ///
+        matcell(`count') matrow(`vals') `subpop' `missing' `sort'
+    local N = r(N)
+    mat `count' = `count''
+    local R = r(r)
+    forv r = 1/`R' {
+        local value: di `vals'[`r',1]
+        local values `values' `value'
+    }
+    if "`label'"=="" {
+        _estpost_namesandlabels `varname' "`values'" // sets names, savenames, labels
+    }
+    else {
+        _estpost_namesandlabels  "" "`values'"
+    }
+    if "`total'"=="" {
+        mat `count' = `count', `N'
+        local names `"`names' Total"'
+        local savenames `"`savenames' Total"'
+        local linesopt "lines(rowtotal)"
+    }
+    mat colname `count' = `names'
+    tempname percent cum
+    mat `percent' = `count'/`N'*100
+    mat `cum' = J(1, colsof(`count'), .z)
+    mat colname `cum' = `names'
+    mat `cum'[1,1] = `count'[1,1]
+    forv r = 2/`R' {
+        mat `cum'[1,`r'] = `cum'[1,`r'-1] + `count'[1,`r']
+    }
+    mat `cum' = `cum'/`N'*100
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        mat `res' = `count'', `percent'', `cum''
+        mat coln `res' = e(b) e(pct) e(cumpct)
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g) nodotz
+        }
+        else {
+            mat rown `res' = `savenames'
+            matlist `res', nohalf `linesopt' rowtitle(`varlist') nodotz
+        }
+        mat drop `res'
+        if `"`labels'"'!="" {
+            di _n as txt "row labels saved in macro e(labels)"
+        }
+    }
+
+    // post results
+    local V
+    if c(stata_version)<9 { // V required in Stata 8
+        tempname V
+        mat `V' = `count'' * `count' * 0
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `count' `V', depname(`varlist') obs(`N') `esample'
+    eret scalar r = r(r)
+    eret local wexp `"`exp'"'
+    eret local wtype `"`weight'"'
+    eret local labels `"`labels'"'
+    eret local depvar "`varlist'"
+    eret local subcmd "tabulate"
+    eret local cmd "estpost"
+    eret mat cumpct = `cum'
+    eret mat pct   = `percent'
+end
+prog estpost_tabulate_twoway, eclass
+    version 8.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax varlist(min=2 max=2) [if] [in] [fw aw iw] [, ESample Quietly ///
+        noTOTal Missing noLabel ///
+        CHi2 Exact Exact2(passthru) Gamma LRchi2 Taub v All noLOg ]
+    local v = upper("`v'")
+    local qui2 "`quietly'"
+    local hastests = `"`chi2'`exact'`exact2'`gamma'`lrchi2'`taub'`v'`all'"'!=""
+    if `hastests' local nofreq nofreq
+    else local qui2 "quietly"
+
+    // sample
+    if "`missing'"!="" marksample touse, nov strok
+    else               marksample touse, strok
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // handle string variables
+    gettoken rvar cvar : varlist
+    gettoken cvar : cvar
+    foreach d in r c {
+        capt confirm numeric variable ``d'var'
+        if _rc {
+            tempname `d'varname
+            qui encode ``d'var' if `touse', generate(``d'varname')
+        }
+        else local `d'varname ``d'var'
+    }
+
+    // gather results
+    tempname cell rvals cvals
+    if `hastests' {
+        `quietly' di ""
+    }
+    `qui2' tab `rvarname' `cvarname' if `touse' [`weight'`exp'], `nofreq' ///
+        matcell(`cell') matrow(`rvals') matcol(`cvals') `missing' ///
+        `chi2' `exact' `exact2' `gamma' `lrchi2' `taub' `v' `all' `log'
+    mat `cvals' = `cvals''
+    local N = r(N)
+    tempname rtot ctot
+    mat `ctot' = J(1,rowsof(`cell'),1) * `cell'
+    mat `rtot' =  `cell' * J(colsof(`cell'),1,1)
+    foreach d in r c {
+        local I = r(`d')
+        forv i = 1/`I' {
+            local value: di ``d'vals'[`i',1]
+            local `d'values ``d'values' `value'
+        }
+    }
+    if "`label'"=="" {
+        _estpost_namesandlabels `rvarname' "`rvalues'"   // sets names, savenames, labels
+        _estpost_eqnamesandlabels `cvarname' "`cvalues'" // sets eqnames, eqlabels
+    }
+    else {
+        _estpost_namesandlabels "" "`rvalues'"   // sets names, savenames, labels
+        _estpost_eqnamesandlabels "" "`cvalues'" // sets eqnames, eqlabels
+    }
+    local savenames0 `"`savenames'"'
+    local savenames
+    if "`total'"=="" {
+        mat `ctot' = `ctot', `N'
+        mat `cell' = (`cell', `rtot') \ `ctot'
+        mat `rtot' = `rtot' \ `N'
+        local names      `"`names' Total"'
+        local savenames0 `"`savenames0' Total"'
+        local eqnames    `"`eqnames' Total"'
+    }
+    mat rowname `cell' = `names'
+    tempname count col row tot tmp
+    forv i = 1/`=colsof(`cell')' {
+        gettoken eq eqnames : eqnames
+        mat `tmp' = `cell'[1...,`i']
+        mat roweq `tmp' = `"`eq'"'
+        mat `tmp' = `tmp''
+        mat `count' = nullmat(`count'), `tmp'
+        mat `col' = nullmat(`col'), `tmp' / `ctot'[1,`i']*100
+        forv j = 1/`=colsof(`tmp')' {
+            mat `tmp'[1,`j'] = `tmp'[1,`j'] / `rtot'[`j',1]*100
+        }
+        mat `row' = nullmat(`row'), `tmp'
+        local savenames `"`savenames' `savenames0'"'
+    }
+    mat `tot' = `count' / `N'*100
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        mat `res' = `count'', `tot'', `col'', `row''
+        mat coln `res' = e(b) e(pct) e(colpct) e(rowpct)
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g)
+        }
+        else {
+            mat rown `res' = `savenames'
+            di _n as res %-12s abbrev("`cvar'",12) as txt " {c |}{space 44}"
+            matlist `res', twidth(12) format(%9.0g) noblank nohalf rowtitle(`rvar')
+        }
+        mat drop `res'
+        if `"`labels'`eqlabels'"'!="" {
+            di ""
+            if `"`labels'"'!="" {
+                di as txt "row labels saved in macro e(labels)"
+            }
+            if `"`eqlabels'"'!="" {
+                di as txt "column labels saved in macro e(eqlabels)"
+            }
+        }
+    }
+
+    // post results
+    local V
+    if c(stata_version)<9 { // V required in Stata 8
+        tempname V
+        mat `V' = `count'' * `count' * 0
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `count' `V', obs(`N') `esample'
+    local rscalars: r(scalars)
+    local rscalars: subinstr local rscalars "N" "", word
+    foreach rsc of local rscalars {
+        eret scalar `rsc' = r(`rsc')
+    }
+    eret local wexp `"`exp'"'
+    eret local wtype `"`weight'"'
+    eret local labels `"`labels'"'
+    eret local eqlabels `"`eqlabels'"'
+    eret local colvar "`cvar'"
+    eret local rowvar "`rvar'"
+    eret local subcmd "tabulate"
+    eret local cmd "estpost"
+    eret mat rowpct = `row'
+    eret mat colpct = `col'
+    eret mat pct = `tot'
+end
+
+
+* 4. estpost_tabstat: wrapper for -tabstat-
+prog estpost_tabstat, eclass
+    version 8.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax varlist [if] [in] [aw fw] [, ESample Quietly ///
+          Statistics(passthru) stats(passthru) LISTwise CASEwise ///
+          by(varname) noTotal Missing Columns(str) ]
+    if "`casewise'"!="" local listwise listwise
+    local l = length(`"`columns'"')
+    if `"`columns'"'==substr("variables",1,max(1,`l')) local columns "variables"
+    else if `"`columns'"'==substr("statistics",1,max(1,`l')) local columns "statistics"
+    else if `"`columns'"'=="stats" local columns "statistics"
+    else if `"`columns'"'=="" {
+        if `:list sizeof varlist'>1 local columns "variables"
+        else local columns "statistics"
+    }
+    else {
+        di as err `"columns(`columns') invalid"'
+        exit 198
+    }
+
+    // sample
+    if "`listwise'"!="" marksample touse
+    else {
+        marksample touse, nov
+        _estpost_markout2 `touse' `varlist'
+    }
+    if "`by'"!="" {
+        if "`missing'"=="" markout `touse' `by', strok
+        local byopt "by(`by')"
+    }
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // gather results
+    if "`total'"!="" & "`by'"=="" {
+        di as txt "nothing to post"
+        eret clear
+        exit
+    }
+    qui tabstat `varlist' if `touse' [`weight'`exp'], save ///
+        `statistics' `stats' `byopt' `total' `missing' columns(`columns')
+    tempname tmp
+    capt confirm matrix r(StatTot)
+    if _rc {
+        mat `tmp' = r(Stat1)
+    }
+    else {
+        mat `tmp' = r(StatTot)
+    }
+    if `"`columns'"'=="statistics" {
+        local cnames: rownames `tmp'
+        local cnames: subinstr local cnames "N" "count", word all
+        local cnames: subinstr local cnames "se(mean)" "semean", word all
+        local R = colsof(`tmp')
+        local stats "`cnames'"
+        local vars: colnames `tmp'
+    }
+    else {
+        local cnames: colnames `tmp'
+        local R = rowsof(`tmp')
+        local stats: rownames `tmp'
+        local stats: subinstr local stats "N" "count", word all
+        local stats: subinstr local stats "se(mean)" "semean", word all
+        local vars "`cnames'"
+        local cnames: subinstr local cnames "b" "_b", word all
+        local cnames: subinstr local cnames "V" "_V", word all
+    }
+    local j 0
+    foreach cname of local cnames {
+        tempname _`++j'
+    }
+    local groups: r(macros)
+    local g: list sizeof groups
+    local space
+    local labels
+    forv i = 1/`g' {
+        local labels `"`labels'`space'`"`r(name`i')'"'"'
+    }
+    if `R'==1 {
+        _estpost_namesandlabels "" "" `"`labels'"'   // sets names, savenames, labels
+    }
+    else {
+        _estpost_eqnamesandlabels "" "" `"`labels'"' // sets eqnames, eqlabels
+        local names `"`eqnames'"'
+        local labels `"`eqlabels'"'
+    }
+    forv i = 1/`g' {
+        gettoken name names : names
+        mat `tmp' = r(Stat`i')
+        mat rown `tmp' = `stats'
+        if `"`columns'"'=="statistics" {
+            mat `tmp' = `tmp''
+        }
+        if `R'==1 {
+            mat rown `tmp' = `"`name'"'
+        }
+        else {
+            mat roweq `tmp' = `"`name'"'
+        }
+        local j 0
+        foreach cname of local cnames {
+            local ++j
+            mat `_`j'' = nullmat(`_`j''), `tmp'[1..., `j']'
+        }
+    }
+    if "`total'"=="" {
+        mat `tmp' = r(StatTot)
+        mat rown `tmp' = `stats'
+        if `"`columns'"'=="statistics" {
+            mat `tmp' = `tmp''
+        }
+        if `g'>0 {
+            if `R'==1 {
+                mat rown  `tmp' = "Total"
+                local savenames `"`savenames' Total"'
+                local rowtotal "lines(rowtotal)"
+            }
+            else {
+                mat roweq `tmp' = "Total"
+                if `"`labels'"'!="" {
+                    local labels `"`labels' Total"'
+                }
+            }
+        }
+        local j 0
+        foreach cname of local cnames {
+            local ++j
+            mat `_`j'' = nullmat(`_`j''), `tmp'[1..., `j']'
+        }
+    }
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        local rescoln
+        local j 0
+        foreach cname of local cnames {
+            local ++j
+            mat `res' = nullmat(`res'), `_`j'''
+            local rescoln `rescoln' e(`cname')
+        }
+        mat coln `res' = `rescoln'
+        di _n as txt "Summary statistics: `stats'"
+        di    as txt "     for variables: `vars'"
+        if "`by'"!="" {
+            di as txt "  by categories of: `by'"
+        }
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g)
+        }
+        else {
+            if `R'==1 & `g'>0 {
+                mat rown `res' = `savenames'
+            }
+            matlist `res', nohalf `rowtotal' rowtitle(`by')
+        }
+        if `"`labels'"'!="" {
+            di _n as txt "category labels saved in macro e(labels)"
+        }
+        mat drop `res'
+    }
+
+    // post results
+    local b
+    local V
+    if c(stata_version)<9 { // b and V required in Stata 8
+        tempname b V
+        mat `b' = `_1' \ J(1, colsof(`_1'), 0)
+        mat `b' = `b'[2,1...]
+        mat `V' = `b'' * `b'
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `b' `V', obs(`N') `esample'
+
+    eret local labels `"`labels'"'
+    eret local byvar "`by'"
+    eret local vars "`vars'"
+    eret local stats "`stats'"
+    eret local wexp `"`exp'"'
+    eret local wtype `"`weight'"'
+    eret local subcmd "tabstat"
+    eret local cmd "estpost"
+
+    local nmat: list sizeof cnames
+    forv j=`nmat'(-1)1 {
+        local cname: word `j' of `cnames'
+        eret matrix `cname' = `_`j''
+    }
+end
+
+
+* 5. estpost_ttest: wrapper for -ttest- (two-sample)
+prog estpost_ttest, eclass
+    version 8.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax varlist(numeric) [if] [in] , by(varname) [ ESample Quietly ///
+         LISTwise CASEwise UNEqual Welch ]
+    if "`casewise'"!="" local listwise listwise
+
+    // sample
+    if "`listwise'"!="" marksample touse
+    else {
+        marksample touse, nov
+        _estpost_markout2 `touse' `varlist'
+    }
+    markout `touse' `by', strok
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // gather results
+    local nvars: list sizeof varlist
+    tempname diff count
+    mat `diff' = J(1, `nvars', .)
+    mat coln `diff' = `varlist'
+    mat `count' = `diff'
+    local mnames se /*sd*/ t df_t p_l p p_u N_1 mu_1 /*sd_1*/ N_2 mu_2 /*sd_2*/
+    foreach m of local mnames {
+        tempname `m'
+        mat ``m'' = `diff'
+    }
+    local i 0
+    foreach v of local varlist {
+        local ++i
+        qui ttest `v' if `touse', by(`by') `unequal' `welch'
+        mat `diff'[1,`i'] = r(mu_1) - r(mu_2)
+        mat `count'[1,`i'] = r(N_1) + r(N_2)
+        foreach m of local mnames {
+            mat ``m''[1,`i'] = r(`m')
+        }
+    }
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        mat `res' = `diff'', `count''
+        local rescoln "e(b) e(count)"
+        foreach m of local mnames {
+            mat `res' = `res', ``m'''
+            local rescoln `rescoln' e(`m')
+        }
+        mat coln `res' = `rescoln'
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g)
+        }
+        else {
+            matlist `res', nohalf lines(oneline)
+        }
+        mat drop `res'
+    }
+
+    // post results
+    local V
+    if c(stata_version)<9 { // V required in Stata 8
+        tempname V
+        mat `V' = diag(vecdiag(`se'' * `se'))
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `diff' `V', obs(`N') `esample'
+
+    eret scalar k = `nvars'
+
+    eret local wexp `"`exp'"'
+    eret local wtype `"`weight'"'
+    eret local welch "`welch'"
+    eret local unequal "`unequal'"
+    eret local byvar "`by'"
+    eret local subcmd "ttest"
+    eret local cmd "estpost"
+
+    local nmat: list sizeof mnames
+    forv i=`nmat'(-1)1 {
+        local m: word `i' of `mnames'
+        eret matrix `m' = ``m''
+    }
+    eret matrix count = `count'
+end
+
+
+* 6. estpost_correlate: wrapper for -correlate-
+prog estpost_correlate, eclass
+    version 8.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax varlist [if] [in] [aw fw iw pw] [, ESample Quietly ///
+        LISTwise CASEwise ///
+        Matrix noHalf Print(real 1) /*Covariance*/ Bonferroni SIDak ]
+    if "`casewise'"!="" local listwise listwise
+    if "`bonferroni'"!="" & "`sidak'"!="" {
+        di as err "only one of bonferroni and sidak allowed"
+        exit 198
+    }
+    local pw = ("`weight'"=="pweight")
+    if `:list sizeof varlist'<=1 & `"`matrix'"'=="" {
+        di as err "too few variables specified"
+        exit 102
+    }
+    if `"`matrix'"'!="" & `"`half'"'!="" local fullmatrix fullmatrix
+
+    // sample
+    if "`listwise'"!="" marksample touse
+    else {
+        marksample touse, nov
+        _estpost_markout2 `touse' `varlist'
+    }
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // gather results
+    tempname b rho pval count
+    if "`bonferroni'`sidak'"!="" {
+        local nvars : list sizeof varlist
+        local k = `nvars' * (`nvars'-1) / 2
+    }
+    foreach depvar of local varlist {
+        if `"`fullmatrix'"'!="" {
+            local indepvars `varlist'
+        }
+        else if `"`matrix'"'!="" {
+            local indepvars `depvar' `ferest()'
+        }
+        else {
+            local indepvars `ferest()'
+        }
+        foreach v of local indepvars {
+            qui reg `depvar' `v' [`weight'`exp'] if `touse'
+            local r = sqrt(e(r2)) * (-1)^(_b[`v']<0)
+            local n = e(N)
+            mat `b' = nullmat(`b'), `r'
+            if "`depvar'"=="`v'" {
+                mat `rho'  = nullmat(`rho'), `r'
+                mat `count' = nullmat(`count'), `n'
+                mat `pval' = nullmat(`pval'), .z
+                continue
+            }
+            local p = Ftail(e(df_m), e(df_r), e(F))
+            if `pw' {
+                qui reg `v' `depvar' [`weight'`exp'] if `touse'
+                local p = max(`p', Ftail(e(df_m), e(df_r), e(F)))
+            }
+            if "`bonferroni'"!="" {
+                local p = min(1, `k'*`p')
+            }
+            else if "`sidak'"!="" {
+                local p = min(1, 1 - (1-`p')^`k')
+            }
+            if `p'>`print' {
+                local r .z
+                local n .z
+                local p .z
+            }
+            mat `rho'  = nullmat(`rho'), `r'
+            mat `count' = nullmat(`count'), `n'
+            mat `pval' = nullmat(`pval'), `p'
+        }
+        if `"`matrix'`fullmatrix'"'=="" {
+            local colnames `indepvars'
+            local depname `depvar'
+            continue, break
+        }
+        foreach v of local indepvars {
+            local colnames `"`colnames'`depvar':`v' "'
+        }
+    }
+    mat coln `b' = `colnames'
+    mat coln `rho' = `colnames'
+    mat coln `count' = `colnames'
+    mat coln `pval' = `colnames'
+    local vce `"`e(vce)'"'          // from last -regress- call
+    local vcetype `"`e(vcetype)'"'
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        mat `res' = `b'', `rho'', `pval'', `count''
+        mat coln `res' = e(b) e(rho) e(p) e(count)
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g) nodotz
+        }
+        else {
+            matlist `res', nohalf lines(oneline) rowtitle(`depname') nodotz
+        }
+        mat drop `res'
+    }
+
+    // post results
+    local V
+    if c(stata_version)<9 { // V required in Stata 8
+        tempname V
+        mat `V' = `b'' * `b' * 0
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `b' `V', depname(`depname') obs(`N') `esample'
+    eret local vcetype `"`vcetype'"'
+    eret local vce `"`vce'"'
+    eret local wexp `"`exp'"'
+    eret local wtype `"`weight'"'
+    eret local depvar `depname'
+    eret local subcmd "correlate"
+    eret local cmd "estpost"
+    eret matrix count = `count'
+    eret matrix p = `pval'
+    eret matrix rho = `rho'
+end
+
+
+* 7. estpost_stci: wrapper for -stci-
+prog estpost_stci, eclass
+    version 9.2                 // Stata 8 not supported because levelsof is used
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax [if] [in] [ , ESample Quietly by(varname) ///
+        Median Rmean Emean p(numlist >0 <100 integer max=1) ///
+        CCorr Level(real `c(level)') ]
+    local stat "p50"
+    if `"`p'"'!="" {
+        local stat `"p`p'"'
+        local p `"p(`p')"'
+    }
+    else if "`rmean'"!=""   local stat "rmean"
+    else if "`emean'"!=""   local stat "emean"
+
+    // sample
+    marksample touse
+    if `"`by'"'!="" {
+        markout `touse' `by', strok
+    }
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // get results
+    tempname _`stat' se N_sub lb ub
+    if "`by'"!="" {
+        qui levelsof `by' if `touse', local(levels)
+        capt confirm string variable `by'
+        if _rc {
+            local vallab: value label `by'
+            if `"`vallab'"'!="" {
+                _estpost_namesandlabels `by' `"`levels'"'  // sets names, savenames, labels
+            }
+            else {
+                local names `"`levels'"'
+                local savenames `"`levels'"'
+            }
+        }
+        else {
+            _estpost_namesandlabels `by' "" `"`levels'"'  // sets names, savenames, labels
+        }
+    }
+    local levels `"`levels' "total""'
+    local names `"`names' "total""'
+    local savenames `"`savenames' "total""'
+    gettoken l rest : levels, quotes
+    while (`"`l'"'!="") {
+        if `"`rest'"'=="" local lcond
+        else              local lcond `" & `by'==`l'"'
+        qui stci if `touse'`lcond', `median' `rmean' `emean' `p' `ccorr' level(`level')
+        mat `_`stat'' = nullmat(`_`stat''), r(`stat')
+        mat `se' = nullmat(`se'), r(se)
+        mat `N_sub' = nullmat(`N_sub'), r(N_sub)
+        mat `lb' = nullmat(`lb'), r(lb)
+        mat `ub' = nullmat(`ub'), r(ub)
+        gettoken l rest : rest, quotes
+    }
+    foreach m in _`stat' se N_sub lb ub {
+        mat coln ``m'' = `names'
+    }
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        mat `res' = `N_sub'', `_`stat''', `se'', `lb'', `ub''
+        mat coln `res' = e(count) e(`stat') e(se) e(lb) e(ub)
+        di as txt "(confidence level is " `level' "%)"
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g) nodotz
+        }
+        else {
+            mat rown `res' = `savenames'
+            matlist `res', nohalf lines(rowtotal) nodotz
+        }
+        mat drop `res'
+        if `"`labels'"'!="" {
+            di _n as txt "labels saved in macro e(labels)"
+        }
+    }
+
+    // post results
+    local b
+    local V
+    if c(stata_version)<9 { // b and V required in Stata 8
+        tempname b V
+        mat `b' = `_`stat'' \ J(1, colsof(`_`stat''), 0)
+        mat `b' = `b'[2,1...]
+        mat `V' = `b'' * `b'
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `b' `V', obs(`N') `esample'
+    eret scalar level = `level'
+
+    eret local ccorr `ccorr'
+    eret local labels `"`labels'"'
+    eret local subcmd "stci"
+    eret local cmd "estpost"
+
+    eret matrix ub = `ub'
+    eret matrix lb = `lb'
+    eret matrix se = `se'
+    eret matrix `stat' = `_`stat''
+    eret matrix count = `N_sub'
+end
+
+
+* 8. estpost_ci: wrapper for -ci-
+prog estpost_ci, eclass
+    version 8.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax [varlist] [if] [in] [aw fw], [ ESample Quietly ///
+         LISTwise CASEwise Level(real `c(level)') ///
+         Binomial EXAct WAld Wilson Agresti Jeffreys ///
+         Poisson Exposure(varname) ///
+         ]
+    if "`casewise'"!="" local listwise listwise
+    if "`exposure'"!="" local exposureopt "exposure(`exposure')"
+    if "`binomial'"!="" & "`exact'`wald'`wilson'`agresti'`jeffreys'"=="" local exact exact
+
+    // sample
+    if "`listwise'"!="" marksample touse
+    else {
+        marksample touse, nov
+        _estpost_markout2 `touse' `varlist'
+    }
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // gather results
+    local mnames se lb ub
+    tempname mean count `mnames'
+    local i 0
+    foreach v of local varlist {
+        local ++i
+        qui ci `v' if `touse' [`weight'`exp'], level(`level') ///
+            `binomial' `exact' `wald' `wilson' `agresti' `jeffreys' ///
+            `poisson' `exposureopt'
+        if r(N)>=. continue
+        mat `mean' = nullmat(`mean'), r(mean)
+        mat `count' = nullmat(`count'), r(N)
+        foreach m of local mnames {
+            mat ``m'' = nullmat(``m''), r(`m')
+        }
+        local rnames "`rnames' `v'"
+    }
+    capt confirm matrix `count'
+    if _rc {
+        di as txt "nothing to post"
+        eret clear
+        exit
+    }
+    foreach m in mean count `mnames' {
+        mat coln ``m'' = `rnames'
+    }
+    if "`listwise'"=="" { // update sample
+        if colsof(`count') < `: list sizeof varlist' {
+            _estpost_markout2 `touse' `rnames'
+            qui count if `touse'
+            local N = r(N)
+        }
+    }
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        mat `res' = `mean'', `count''
+        local rescoln "e(b) e(count)"
+        foreach m of local mnames {
+            mat `res' = `res', ``m'''
+            local rescoln `rescoln' e(`m')
+        }
+        mat coln `res' = `rescoln'
+        di as txt "(confidence level is " `level' "%)"
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g)
+        }
+        else {
+            matlist `res', nohalf lines(oneline)
+        }
+        mat drop `res'
+    }
+
+    // post results
+    local V
+    if c(stata_version)<9 { // V required in Stata 8
+        tempname V
+        mat `V' = diag(vecdiag(`se'' * `se'))
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `mean' `V', obs(`N') `esample'
+
+    eret scalar k = colsof(`count')
+    eret scalar level = `level'
+
+    eret local wexp `"`exp'"'
+    eret local wtype `"`weight'"'
+    eret local exposure "`exposure'"
+    eret local poisson "`poisson'"
+    eret local binomial "`exact'`wald'`wilson'`agresti'`jeffreys'"
+    eret local subcmd "ci"
+    eret local cmd "estpost"
+
+    local nmat: list sizeof mnames
+    forv i=`nmat'(-1)1 {
+        local m: word `i' of `mnames'
+        eret matrix `m' = ``m''
+    }
+    eret matrix count = `count'
+end
+
+
+* 9. estpost_prtest: wrapper for -prtest- (two-sample)
+prog estpost_prtest, eclass
+    version 8.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax varlist(numeric) [if] [in] , by(varname) [ ESample Quietly ///
+         LISTwise CASEwise  ]
+    if "`casewise'"!="" local listwise listwise
+
+    // sample
+    if "`listwise'"!="" marksample touse
+    else {
+        marksample touse, nov
+        _estpost_markout2 `touse' `varlist'
+    }
+    markout `touse' `by', strok
+    qui count if `touse'
+    local N = r(N)
+    if `N'==0 error 2000
+
+    // gather results
+    local nvars: list sizeof varlist
+    tempname diff count
+    mat `count' = J(1, `nvars', .)
+    mat coln `count' = `varlist'
+    mat `diff' = `count'
+    local mnames se se0 z p_l p p_u N_1 P_1 N_2 P_2
+    foreach m of local mnames {
+        tempname `m'
+        mat ``m'' = `count'
+    }
+    local i 0
+    foreach v of local varlist {
+        local ++i
+        qui prtest `v' if `touse', by(`by')
+        mat `count'[1,`i'] = r(N_1) + r(N_2)
+        mat `diff'[1,`i'] = r(P_1) - r(P_2)
+        mat `se'[1,`i'] = sqrt(r(P_1)*(1-r(P_1))/r(N_1) + r(P_2)*(1-r(P_2))/r(N_2))
+        mat `se0'[1,`i'] = `diff'[1,`i'] / r(z)
+        mat `p_l'[1,`i'] = normal(r(z))
+        mat `p'[1,`i'] = (1-normal(abs(r(z))))*2
+        mat `p_u'[1,`i'] = 1-normal(r(z))
+        foreach m in z N_1 P_1 N_2 P_2 {
+            mat ``m''[1,`i'] = r(`m')
+        }
+    }
+
+    // display
+    if "`quietly'"=="" {
+        tempname res
+        mat `res' = `diff'', `count''
+        local rescoln "e(b) e(count)"
+        foreach m of local mnames {
+            mat `res' = `res', ``m'''
+            local rescoln `rescoln' e(`m')
+        }
+        mat coln `res' = `rescoln'
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g)
+        }
+        else {
+            matlist `res', nohalf lines(oneline)
+        }
+        mat drop `res'
+    }
+
+    // post results
+    local V
+    if c(stata_version)<9 { // V required in Stata 8
+        tempname V
+        mat `V' = diag(vecdiag(`se'' * `se'))
+    }
+    if "`esample'"!="" local esample esample(`touse')
+    eret post `diff' `V', obs(`N') `esample'
+
+    eret scalar k = `nvars'
+
+    eret local wexp `"`exp'"'
+    eret local wtype `"`weight'"'
+    eret local byvar "`by'"
+    eret local subcmd "prtest"
+    eret local cmd "estpost"
+
+    local nmat: list sizeof mnames
+    forv i=`nmat'(-1)1 {
+        local m: word `i' of `mnames'
+        eret matrix `m' = ``m''
+    }
+    eret matrix count = `count'
+end
+
+
+* 10. estpost__svy_tabulate: wrapper for -svy:tabulate-
+prog estpost__svy_tabulate
+    version 9.2
+    local caller : di _caller()
+    _on_colon_parse `0'
+    local svyopts `"svyopts(`s(before)')"'
+    local 0       `"`s(after)'"'
+    syntax varlist(min=1 max=2) [if] [in] [ , * ]
+    if `:list sizeof varlist'==1 {
+        version `caller': _svy_tabulate_oneway `varlist' `if' `in', ///
+            `svyopts' `options'
+    }
+    else {
+         version `caller': _svy_tabulate_twoway `varlist' `if' `in', ///
+            `svyopts' `options'
+    }
+end
+prog _svy_tabulate_oneway
+    version 9.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax varname [if] [in] [, ESample Quietly ///
+        svyopts(str asis) MISSing Level(cilevel) ///
+        noTOTal noMARGinals noLabel PROPortion PERcent ///
+        CELl COUnt se ci deff deft * ]
+    if "`marginals'"!=""   local total "nototal"
+    else if "`total'"!=""  local marginals "nomarginals"
+
+    // run svy:tabulate
+    `quietly' svy `svyopts' : tabulate `varlist' `if' `in', ///
+        level(`level') `cell' `count' `se' `ci' `deff' `deft' ///
+        `missing' `marginals' `label' `proportion' `percent' `options'
+    if "`count'"!="" & "`cell'`se'`ci'`deff'`deft'"=="" { // => return count in e(b)
+        quietly svy `svyopts' : tabulate `varlist' `if' `in', count se ///
+            level(`level') `missing' `marginals' `label' `proportion' `percent' `options'
+    }
+
+    // get labels
+    qui levelsof `varlist' if e(sample), `missing' local(levels)
+    local R : list sizeof levels
+    if e(r)!=`R' {
+        di as err "unexpected error; number of rows unequal number of levels"
+        exit 499
+    }
+    capt confirm string variable `varlist'
+    if _rc {
+        if "`label'"=="" {
+            _estpost_namesandlabels `varlist' "`levels'"   // sets names, savenames, labels
+        }
+        else {
+            _estpost_namesandlabels "" "`levels'"   // sets names, savenames, labels
+        }
+    }
+    else {
+        _estpost_namesandlabels "" "" `"`levels'"' // sets names, savenames, labels
+    }
+
+    // collect results
+    tempname cell count obs b se lb ub deff deft
+    local N_pop = cond(e(N_subpop)<., e(N_subpop), e(N_pop))
+    local N_obs = cond(e(N_sub)<., e(N_sub), e(N))
+    local tval = invttail(e(df_r), (100-`level')/200)
+    mat `cell'  = e(Prop)'
+    mat `count' = `cell' * `N_pop'
+    capture confirm matrix e(ObsSub)
+    if _rc {
+        mat `obs'   = e(Obs)'
+    }
+    else {
+        mat `obs'   = e(ObsSub)'
+    }
+    capture confirm matrix e(Deff)
+    if _rc local DEFF  ""
+    else   {
+        local DEFF deff
+        mat `deff'  = e(Deff)
+    }
+    capture confirm matrix e(Deft)
+    if _rc local DEFT  ""
+    else   {
+        local DEFT deft
+        mat `deft'  = e(Deft)
+    }
+    mat `b' = e(b)
+    mata: st_matrix(st_local("se"), sqrt(diagonal(st_matrix("e(V)")))')
+    if "`total'"=="" {
+        mat `cell'  = `cell', 1
+        mat `count' = `count', `N_pop'
+        mat `obs'   = `obs', `N_obs'
+        if "`DEFF'"!="" mat `deff'  = `deff', .z
+        if "`DEFT'"!="" mat `deft'  = `deft', .z
+        if e(setype)=="count" {
+            mat `b' = `b', `N_pop'
+            mat `se' = `se', sqrt(el(e(V_col),1,1))
+        }
+        else { // e(setype)=="cell"
+            mat `b' = `b', 1
+            mat `se' = `se', 0
+        }
+        local names `"`names' "Total""'
+        local savenames `"`savenames' "Total""'
+        local linesopt "lines(rowtotal)"
+
+    }
+    if e(setype)!="count" {
+        mata: st_matrix( st_local("lb"), invlogit( ///
+            logit(st_matrix(st_local("b"))) - strtoreal(st_local("tval")) * ///
+                st_matrix(st_local("se")) :/ ///
+                (st_matrix(st_local("b")) :* (1 :- st_matrix(st_local("b"))))))
+        mata: st_matrix( st_local("ub"), invlogit( ///
+            logit(st_matrix(st_local("b"))) + strtoreal(st_local("tval")) * ///
+                st_matrix(st_local("se")) :/ ///
+                (st_matrix(st_local("b")) :* (1 :- st_matrix(st_local("b"))))))
+        if "`total'"=="" {
+            mat `lb'[1, colsof(`lb')] = .z
+            mat `ub'[1, colsof(`ub')] = .z
+        }
+    }
+    else {
+        mata: st_matrix( st_local("lb"), st_matrix(st_local("b")) - ///
+            strtoreal(st_local("tval")) * st_matrix(st_local("se")) )
+        mata: st_matrix( st_local("ub"), st_matrix(st_local("b")) + ///
+            strtoreal(st_local("tval")) * st_matrix(st_local("se")) )
+    }
+    foreach m in cell count obs b se lb ub `DEFF' `DEFT' {
+        capt mat coln ``m'' = `names'
+    }
+    if "`percent'"!="" {
+        mat `cell' = `cell' * 100
+        if e(setype)!="count" {
+            mat `b' = `b' * 100
+            mat `se' = `se' * 100
+            mat `lb' = `lb' * 100
+            mat `ub' = `ub' * 100
+        }
+    }
+
+    // display
+    if "`quietly'"=="" {
+        /*
+        tempname res
+        mat `res' = `b'', `se'', `lb'', `ub'', `deff'', `deft'' ///, `cell'', `count'', `obs''
+        mat coln `res' = e(b) e(se) e(lb) e(ub) e(deff) e(deft) /// e(cell) e(count) e(obs)
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g) nodotz
+        }
+        else {
+            mat rown `res' = `savenames'
+            matlist `res', nohalf `linesopt' rowtitle(`varlist') nodotz
+        }
+        mat drop `res'
+        */
+        local plabel = cond("`percent'"!="","percentages","proportions")
+        local blabel = cond("`e(setype)'"=="count", "weighted counts", "`e(setype)' `plabel'")
+        di _n as txt "saved vectors:"
+        di as txt %20s "e(b) = "     " " as res "`blabel'"
+        di as txt %20s "e(se) = "    " " as res "standard errors of `blabel'"
+        di as txt %20s "e(lb) = "    " " as res "lower `level'% confidence bounds for `blabel'"
+        di as txt %20s "e(ub) = "    " " as res "upper `level'% confidence bounds for `blabel'"
+        if "`DEFF'"!="" ///
+            di as txt %20s "e(deff) = "  " " as res "deff for variances of `blabel'"
+        if "`DEFT'"!="" ///
+            di as txt %20s "e(deft) = "  " " as res "deft for variances of `blabel'"
+        di as txt %20s "e(cell) = "  " " as res "cell `plabel'"
+        di as txt %20s "e(count) = " " " as res "weighted counts"
+        di as txt %20s "e(obs) = "   " " as res "number of observations"
+        if `"`labels'"'!="" {
+            di _n as txt "row labels saved in macro e(labels)"
+        }
+    }
+
+    // post results
+    erepost b=`b', cmd(estpost) nov `esample'
+    qui estadd local labels `"`labels'"'
+    qui estadd local subcmd "tabulate"
+    qui estadd scalar level = `level'
+    foreach m in obs count cell `DEFT' `DEFF' ub lb se {
+        qui estadd matrix `m' = ``m'', replace
+    }
+end
+prog _svy_tabulate_twoway
+    version 9.2
+    local caller : di _caller() // not used
+
+    // syntax
+    syntax varlist(min=1 max=2) [if] [in] [, ESample Quietly ///
+        svyopts(str asis) MISSing Level(cilevel) ///
+        noTOTal noMARGinals noLabel PROPortion PERcent ///
+        CELl COUnt COLumn row se ci deff deft * ]
+    if "`marginals'"!=""   local total "nototal"
+    else if "`total'"!=""  local marginals "nomarginals"
+
+    // run svy:tabulate
+    `quietly' svy `svyopts' : tabulate `varlist' `if' `in', ///
+        level(`level') `cell' `count' `column' `row' `se' `ci' `deff' `deft' ///
+        `missing' `marginals' `label' `proportion' `percent' `options'
+    if `: word count `count' `column' `row''==1 & "`cell'`se'`ci'`deff'`deft'"=="" {
+        quietly svy `svyopts' : tabulate `varlist' `if' `in', `count' `column' `row' se ///
+            level(`level') `missing' `marginals' `label' `proportion' `percent' `options'
+    }
+
+    // get labels
+    local rvar `"`e(rowvar)'"'
+    qui levelsof `rvar' if e(sample), `missing' local(levels)
+    local R : list sizeof levels
+    if e(r)!=`R' {
+        di as err "unexpected error; number of rows unequal number of rowvar levels"
+        exit 499
+    }
+    capt confirm string variable `rvar'
+    if _rc {
+        if "`label'"=="" {
+            _estpost_namesandlabels `rvar' "`levels'"   // sets names, savenames, labels
+        }
+        else {
+            _estpost_namesandlabels "" "`levels'"   // sets names, savenames, labels
+        }
+    }
+    else {
+        _estpost_namesandlabels "" "" `"`levels'"' // sets names, savenames, labels
+    }
+    local cvar `"`e(colvar)'"'
+    qui levelsof `cvar' if e(sample), `missing' local(levels)
+    local C : list sizeof levels
+    if e(c)!=`C' {
+        di as err "unexpected error; number of column unequal number of colvar levels"
+        exit 499
+    }
+    local savenames0 `"`savenames'"'
+    local savenames
+    capt confirm string variable `cvar'
+    if _rc {
+        if "`label'"=="" {
+            _estpost_eqnamesandlabels `cvar' "`levels'"   // sets eqnames, eqlabels
+        }
+        else {
+            _estpost_eqnamesandlabels "" "`levels'"    // sets eqnames, eqlabels
+        }
+    }
+    else {
+        _estpost_eqnamesandlabels "" "" `"`levels'"'  // sets eqnames, eqlabels
+    }
+
+    // collect results
+    tempname tmp cell row col count obs b se lb ub deff deft
+    local N_pop = cond(e(N_subpop)<., e(N_subpop), e(N_pop))
+    local N_obs = cond(e(N_sub)<., e(N_sub), e(N))
+    local tval = invttail(e(df_r), (100-`level')/200)
+    mat `cell' = e(Prop)    // r x c matrix
+    mat `cell' = (`cell', `cell' * J(`C',1,1)) \ (J(1,`R',1) * `cell', 1)
+    mat `count' = `cell' * `N_pop'
+    mat `tmp' = `cell'[1..., `C'+1]
+    mata: st_matrix(st_local("row"), st_matrix(st_local("cell")) :/ ///
+        st_matrix(st_local("tmp")))
+    mat `tmp' = `cell'[`R'+1, 1...]
+    mata: st_matrix(st_local("col"), st_matrix(st_local("cell")) :/ ///
+        st_matrix(st_local("tmp")))
+    mat drop `tmp'
+    capture confirm matrix e(ObsSub)
+    if _rc {
+        mat `obs' = e(Obs)    // r x c matrix
+    }
+    else {
+        mat `obs' = e(ObsSub) // r x c matrix
+    }
+    capt confirm matrix e(Deff)
+    if _rc local DEFF ""
+    else {
+        local DEFF deff
+        mat `deff'  = e(Deff)   // vector
+    }
+    capt confirm matrix e(Deft)
+    if _rc local DEFT ""
+    else {
+        local DEFT deft
+        mat `deft'  = e(Deft)   // vector
+    }
+    mat `b' = e(b)          // vector
+    mata: st_matrix(st_local("se"), sqrt(diagonal(st_matrix("e(V)")))') // vector
+    if e(setype)=="count"       local btype count
+    else if e(setype)=="row"    local btype row
+    else if e(setype)=="column" local btype col
+    else                        local btype cell
+    foreach m in `DEFF' `DEFT' b se { // vector -> r x c matrix
+        forv r = 1/`R' {
+            local from = (`r'-1)*`C' + 1
+            local to = `r'*`C'
+            mat `tmp' = nullmat(`tmp') \ ``m''[1, `from'..`to']
+        }
+        mat drop ``m''
+        mat rename `tmp' ``m''
+    }
+    if "`total'"=="" {
+        mat `obs' = (`obs', `obs' * J(`C',1,1)) \ (J(1,`R',1) * `obs', `N_obs')
+        if "`DEFF'"!="" mat `deff'  = (`deff', e(Deff_row)') \ (e(Deff_col), .z)
+        if "`DEFT'"!="" mat `deft'  = (`deft', e(Deft_row)') \ (e(Deft_col), .z)
+        mat `b' = (`b', ``btype''[1..`R',`C'+1]) \ ``btype''[`R'+1,1...]
+        mata: st_matrix(st_local("se"), ///
+            ((st_matrix(st_local("se")), sqrt(diagonal(st_matrix("e(V_row)")))) ///
+            \ (sqrt(diagonal(st_matrix("e(V_col)")))', .z)))
+        if "`btype'"=="row" {
+            mat `se' = `se'[1..., 1..`C'], J(`R'+1, 1, .z)
+        }
+        else if "`btype'"=="col" {
+            mat `se' = `se'[1..`R', 1...] \ J(1, `C'+1, .z)
+        }
+        local names `"`names' "Total""'
+        local savenames0 `"`savenames0' "Total""'
+        local eqnames `"`eqnames' "Total""'
+    }
+    else {
+        mat `cell' = `cell'[1..`R', 1..`C']
+        mat `count' = `count'[1..`R', 1..`C']
+        mat `row' = `row'[1..`R', 1..`C']
+        mat `col' = `col'[1..`R', 1..`C']
+    }
+    if "`btype'"!="count" {
+        mata: st_matrix( st_local("lb"), invlogit( ///
+            logit(st_matrix(st_local("b"))) - strtoreal(st_local("tval")) * ///
+                st_matrix(st_local("se")) :/ ///
+                (st_matrix(st_local("b")) :* (1 :- st_matrix(st_local("b"))))))
+        mata: st_matrix( st_local("ub"), invlogit( ///
+            logit(st_matrix(st_local("b"))) + strtoreal(st_local("tval")) * ///
+                st_matrix(st_local("se")) :/ ///
+                (st_matrix(st_local("b")) :* (1 :- st_matrix(st_local("b"))))))
+    }
+    else {
+        mata: st_matrix( st_local("lb"), st_matrix(st_local("b")) - ///
+            strtoreal(st_local("tval")) * st_matrix(st_local("se")) )
+        mata: st_matrix( st_local("ub"), st_matrix(st_local("b")) + ///
+            strtoreal(st_local("tval")) * st_matrix(st_local("se")) )
+    }
+    if "`total'"=="" {
+        if "`btype'"=="row" {
+            mat `lb' = `lb'[1..., 1..`C'] , J(`R'+1, 1, .z)
+            mat `ub' = `ub'[1..., 1..`C'] , J(`R'+1, 1, .z)
+        }
+        else if  "`btype'"=="col" {
+            mat `lb' = `lb'[1..`R', 1...] \ J(1, `C'+1, .z)
+            mat `ub' = `ub'[1..`R', 1...] \ J(1, `C'+1, .z)
+        }
+        else {
+            mat `lb'[`R'+1, `C'+1] = .z
+            mat `ub'[`R'+1, `C'+1] = .z
+        }
+    }
+    foreach m in cell count obs row col `DEFF' `DEFT' b se lb ub { // r x c matrix -> vector
+        mat rown ``m'' = `names'
+        gettoken eq rest : eqnames
+        forv c = 1/`=colsof(``m'')' {
+            mat roweq ``m'' = `"`eq'"'
+            mat `tmp' = nullmat(`tmp'), ``m''[1...,`c']'
+            gettoken eq rest : rest
+        }
+        mat drop ``m''
+        mat rename `tmp' ``m''
+    }
+    if "`percent'"!="" {
+        mat `cell' = `cell' * 100
+        mat `col' = `col' * 100
+        mat `row' = `row' * 100
+        if e(setype)!="count" {
+            mat `b' = `b' * 100
+            mat `se' = `se' * 100
+            mat `lb' = `lb' * 100
+            mat `ub' = `ub' * 100
+        }
+    }
+
+    // display
+    if "`quietly'"=="" {
+        /*
+        forv c = 1/`=colsof(`cell')' {
+            local savenames `"`savenames' `savenames0'"'
+        }
+        tempname res
+        mat `res' = `b'', `se'', `lb'', `ub'', `deff'', `deft'', `cell'', `row'', `col'', `count'', `obs''
+        mat coln `res' = e(b) e(se) e(lb) e(ub) e(deff) e(deft) e(cell) e(row) e(col) e(count) e(obs)
+        if c(stata_version)<9 {
+            mat list `res', noheader nohalf format(%9.0g) nodotz
+        }
+        else {
+            mat rown `res' = `savenames'
+            di _n as res %-12s abbrev("`cvar'",12) as txt " {c |}{space 44}"
+            matlist `res', twidth(12) format(%9.0g) noblank nohalf ///
+                rowtitle(`rvar') nodotz
+        }
+        mat drop `res'
+        */
+        local plabel = cond("`percent'"!="","percentages","proportions")
+        local blabel = cond("`e(setype)'"=="count", "weighted counts", "`e(setype)' `plabel'")
+        di _n as txt "saved vectors:"
+        di as txt %20s "e(b) = "     " " as res "`blabel'"
+        di as txt %20s "e(se) = "    " " as res "standard errors of `blabel'"
+        di as txt %20s "e(lb) = "    " " as res "lower `level'% confidence bounds for `blabel'"
+        di as txt %20s "e(ub) = "    " " as res "upper `level'% confidence bounds for `blabel'"
+        if "`DEFF'"!="" ///
+            di as txt %20s "e(deff) = "  " " as res "deff for variances of `blabel'"
+        if "`DEFT'"!="" ///
+            di as txt %20s "e(deft) = "  " " as res "deft for variances of `blabel'"
+        di as txt %20s "e(cell) = "  " " as res "cell `plabel'"
+        di as txt %20s "e(row) = "   " " as res "row `plabel'"
+        di as txt %20s "e(col) = "   " " as res "column `plabel'"
+        di as txt %20s "e(count) = " " " as res "weighted counts"
+        di as txt %20s "e(obs) = "   " " as res "number of observations"
+        if `"`labels'`eqlabels'"'!="" {
+            di ""
+            if `"`labels'"'!="" {
+                di as txt "row labels saved in macro e(labels)"
+            }
+            if `"`eqlabels'"'!="" {
+                di as txt "column labels saved in macro e(eqlabels)"
+            }
+        }
+    }
+
+    // post results
+    erepost b=`b', cmd(estpost) nov `esample'
+    qui estadd local eqlabels `"`eqlabels'"'
+    qui estadd local labels `"`labels'"'
+    qui estadd local subcmd "tabulate"
+    qui estadd scalar level = `level'
+    foreach m in obs count row col cell `DEFT' `DEFF' ub lb se {
+        qui estadd matrix `m' = ``m'', replace
+    }
+end
+
+* 11. estpost_margins: wrapper for -margins- (Stata 11)
+prog estpost_margins, eclass
+    version 11
+    local caller : di _caller()
+
+    // syntax
+    _parse comma anything 0 : 0
+    syntax [ , /*ESample*/ Quietly ///
+        post * ]
+    if "`post'"!="" {
+        di as err "post not allowed"
+        exit 198
+    }
+
+    // run margins
+    `quietly' version `caller': margins `anything', `options'
+
+    // post results
+    capt postrtoe, noclear resize
+    if _rc<=1 {     // -postrtoe- does not work, e.g., with -regress-
+        error _rc   // _rc=1 (break)
+        exit
+    }
+    tempname b V
+    mat `b' = r(b)
+    mat `V' = r(V)
+    erepost b = `b' V = `V' /*, `esample'*/
+    foreach r in `:r(scalars)' {
+        eret scalar `r' = r(`r')
+    }
+    foreach r in `:r(macros)' {
+        eret local `r' `"`r(`r')'"'
+    }
+    tempname tmp
+    foreach r in `:r(matrices)' {
+        if inlist("`r'", "b", "V") continue
+        mat `tmp' = r(`r')
+        eret matrix `r' = `tmp'
+    }
+end
+
+* 99.
+* copy of erepost.ado, version 1.0.1, Ben Jann, 30jul2007
+* 14jan2009: noV option added => repost e(b) and remove e(V) if not specified
+prog erepost, eclass
+    version 8.2
+    syntax [anything(equalok)] [, NOV cmd(str) noEsample Esample2(varname) REName ///
+        Obs(passthru) Dof(passthru) PROPerties(passthru) * ]
+    if "`esample'"!="" & "`esample2'"!="" {
+        di as err "only one allowed of noesample and esample()"
+        exit 198
+    }
+// parse [b = b] [V = V]
+    if `"`anything'"'!="" {
+        tokenize `"`anything'"', parse(" =")
+        if `"`7'"'!="" error 198
+        if `"`1'"'=="b" {
+            if `"`2'"'=="=" & `"`3'"'!="" {
+                local b `"`3'"'
+                confirm matrix `b'
+            }
+            else error 198
+            if `"`4'"'=="V" {
+                if `"`5'"'=="=" & `"`6'"'!="" {
+                    local v `"`6'"'
+                    confirm matrix `b'
+                }
+                else error 198
+            }
+            else if `"`4'"'!="" error 198
+        }
+        else if `"`1'"'=="V" {
+            if `"`4'"'!="" error 198
+            if `"`2'"'=="=" & `"`3'"'!="" {
+                local v `"`3'"'
+                confirm matrix `v'
+            }
+            else error 198
+        }
+        else error 198
+    }
+//backup existing e()'s
+    if "`esample2'"!="" {
+        local sample "`esample2'"
+    }
+    else if "`esample'"=="" {
+        tempvar sample
+        gen byte `sample' = e(sample)
+    }
+    local emacros: e(macros)
+    if `"`properties'"'!="" {
+        local emacros: subinstr local emacros "properties" "", word
+    }
+    foreach emacro of local emacros {
+        local e_`emacro' `"`e(`emacro')'"'
+    }
+    local escalars: e(scalars)
+    if `"`obs'"'!="" {
+        local escalars: subinstr local escalars "N" "", word
+    }
+    if `"`dof'"'!="" {
+        local escalars: subinstr local escalars "df_r" "", word
+    }
+    foreach escalar of local escalars {
+        tempname e_`escalar'
+        scalar `e_`escalar'' = e(`escalar')
+    }
+    local ematrices: e(matrices)
+    if "`v'"=="" & "`nov'"!="" {   // added 14jan2009
+        local nov V
+        local ematrices : list ematrices - nov
+    }
+    if "`b'"=="" & `:list posof "b" in ematrices' {
+        tempname b
+        mat `b' = e(b)
+    }
+    if "`v'"=="" & `:list posof "V" in ematrices' {
+        tempname v
+        mat `v' = e(V)
+    }
+    local bV "b V"
+    local ematrices: list ematrices - bV
+    foreach ematrix of local ematrices {
+        tempname e_`ematrix'
+        matrix `e_`ematrix'' = e(`ematrix')
+    }
+// rename
+    if "`b'"!="" & "`v'"!="" & "`rename'"!="" {
+        local eqnames: coleq `b', q
+        local vnames: colnames `b'
+        mat coleq `v' = `eqnames'
+        mat coln `v' = `vnames'
+        mat roweq `v' = `eqnames'
+        mat rown `v' = `vnames'
+    }
+// post results
+    if "`esample'"=="" {
+        eret post `b' `v', esample(`sample') `obs' `dof' `properties' `options'
+    }
+    else {
+        eret post `b' `v', `obs' `dof' `properties' `options'
+    }
+    foreach emacro of local emacros {
+        eret local `emacro' `"`e_`emacro''"'
+    }
+    if `"`cmd'"'!="" {
+        eret local cmd `"`cmd'"'
+    }
+    foreach escalar of local escalars {
+        eret scalar `escalar' = scalar(`e_`escalar'')
+    }
+    foreach ematrix of local ematrices {
+        eret matrix `ematrix' = `e_`ematrix''
+    }
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/e/estpost.hlp

@@ -0,0 +1,1322 @@
+{smcl}
+{* 13sep2013}{...}
+{hi:help estpost}{right:also see: {helpb esttab}, {helpb estout}, {helpb eststo}, {helpb estadd}}
+{right: {browse "http://repec.org/bocode/e/estout"}}
+{hline}
+
+{title:Title}
+
+{p 4 4 2}{hi:estpost} {hline 2} Post results from various commands in {cmd:e()}
+
+
+{title:Syntax}
+
+{p 8 15 2}
+{cmd:estpost} {it:{help estpost##commands:command}} [...]
+
+{marker commands}
+    {it:command}{col 26}description
+    {hline 66}
+    {helpb estpost##summarize:{ul:su}mmarize}{col 26}{...}
+post summary statistics
+    {helpb estpost##tabstat:tabstat}{col 26}{...}
+post summary statistics
+    {helpb estpost##ttest:ttest}{col 26}{...}
+post two-group mean-comparison tests
+    {helpb estpost##prtest:prtest}{col 26}{...}
+post two-group tests of proportions
+    {helpb estpost##tabulate:{ul:ta}bulate}{col 26}{...}
+post one-way or two-way frequency table
+    {helpb estpost##svy_tabulate:svy: {ul:ta}bulate}{col 26}{...}
+post frequency table for survey data
+    {helpb estpost##correlate:{ul:cor}relate}{col 26}{...}
+post correlations
+    {helpb estpost##ci:ci}{col 26}{...}
+post confidence intervals for means,
+    {col 26}{...}
+    proportions, or counts
+    {helpb estpost##stci:stci}{col 26}{...}
+post confidence intervals for means
+    {col 26}{...}
+    and percentiles of survival time
+    {helpb estpost##margins:margins}{col 26}{...}
+post results from {cmd:margins} (Stata 11 or newer)
+    {hline 66}
+
+
+{title:Description}
+
+{p 4 4 2}
+{cmd:estpost} posts results from various Stata commands in {cmd:e()}
+so that they can be tabulated using {helpb esttab} or {helpb estout}. Type
+{helpb ereturn:ereturn list} after {cmd:estpost} to list the elements saved
+in {cmd:e()}.
+
+
+{title:Commands}
+{marker summarize}
+{dlgtab:summarize}
+
+{p 4 15 2}
+{cmd:estpost} {cmdab:su:mmarize}
+    [{it:{help varlist}}] [{it:{help if}}] [{it:{help in}}] [{it:{help weight}}]
+    [{cmd:,}
+        {cmdab:d:etail}
+        {cmdab:mean:only}
+        {cmdab:list:wise}
+        {cmdab:case:wise}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}
+    posts summary statistics computed by {helpb summarize}. If no
+    {it:varlist} is specified, summary statistics are calculated for all
+    variables in the dataset.
+
+{p 4 4 2}
+    {cmd:aweight}s, {cmd:fweight}s, and {cmd:iweight}s are allowed
+    (however, {cmd:iweight}s may not be used with the {cmd:detail} option);
+    see {help weight}.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:detail} and {cmd:meanonly} as described in help {helpb summarize}.
+
+{p 8 12 2}
+        {cmd:listwise} to handle missing values through listwise deletion,
+        meaning that an observation is omitted from the estimation
+        sample if any of the variables in {it:varlist} is missing for that
+        observation. The default is to determine the used observations for
+        each variable separately without regard to whether other variables
+        are missing. {cmd:casewise} is a synonym for {cmd:listwise}.
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}The following results vectors are saved in {cmd:e()}:
+
+        {lalign 13:{cmd:e(count)}}number of observations
+        {lalign 13:{cmd:e(mean)}}mean
+        {lalign 13:{cmd:e(min)}}minimum
+        {lalign 13:{cmd:e(max)}}maximum
+        {lalign 13:{cmd:e(sum)}}sum of variable
+        {lalign 13:{cmd:e(sum_w)}}sum of the weights
+        {lalign 13:{cmd:e(Var)}}variance (unless {cmd:meanonly})
+        {lalign 13:{cmd:e(sd)}}standard deviation (unless {cmd:meanonly})
+        {lalign 13:{cmd:e(p1)}}1st percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(p5)}}5th percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(p10)}}10th percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(p25)}}25th percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(p50)}}50th percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(p75)}}75th percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(p90)}}90th percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(p95)}}95th percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(p99)}}99th percentile ({cmd:detail} only)
+        {lalign 13:{cmd:e(skewness)}}skewness ({cmd:detail} only)
+        {lalign 13:{cmd:e(kurtosis)}}kurtosis ({cmd:detail} only)
+
+{p 4 4 2}
+    Example:
+
+{* begin example summarize }{...}
+        {com}. sysuse auto, clear
+        {txt}(1978 Automobile Data)
+
+        {com}. estpost summarize price mpg rep78 foreign
+
+        {txt}{ralign 12:} {c |} {ralign 9:e(count)}  {ralign 9:e(sum_w)}  {ralign 9:e(mean)}  {ralign 9:e(Var)}  {ralign 9:e(sd)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf: 6165.257}}}  {ralign 9:{res:{sf:  8699526}}}  {ralign 9:{res:{sf: 2949.496}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf:  21.2973}}}  {ralign 9:{res:{sf: 33.47205}}}  {ralign 9:{res:{sf: 5.785503}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf:       69}}}  {ralign 9:{res:{sf:       69}}}  {ralign 9:{res:{sf: 3.405797}}}  {ralign 9:{res:{sf: .9799659}}}  {ralign 9:{res:{sf: .9899323}}}
+        {ralign 12:foreign} {c |} {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf: .2972973}}}  {ralign 9:{res:{sf: .2117734}}}  {ralign 9:{res:{sf: .4601885}}}
+
+        {ralign 12:} {c |} {ralign 9:e(min)}  {ralign 9:e(max)}  {ralign 9:e(sum)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf:     3291}}}  {ralign 9:{res:{sf:    15906}}}  {ralign 9:{res:{sf:   456229}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf:       12}}}  {ralign 9:{res:{sf:       41}}}  {ralign 9:{res:{sf:     1576}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:        5}}}  {ralign 9:{res:{sf:      235}}}
+        {ralign 12:foreign} {c |} {ralign 9:{res:{sf:        0}}}  {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:       22}}}
+
+        {com}. esttab ., cells("mean sd count") noobs
+        {res}
+        {txt}{hline 51}
+        {txt}                      (1)
+        {txt}
+        {txt}                     mean           sd        count
+        {txt}{hline 51}
+        {txt}price       {res}     6165.257     2949.496           74{txt}
+        {txt}mpg         {res}      21.2973     5.785503           74{txt}
+        {txt}rep78       {res}     3.405797     .9899323           69{txt}
+        {txt}foreign     {res}     .2972973     .4601885           74{txt}
+        {txt}{hline 51}
+{* end example }{txt}{...}
+
+{marker tabstat}
+{dlgtab:tabstat}
+
+{p 4 15 2}
+{cmd:estpost} {cmdab:tabstat}
+    {it:{help varlist}} [{it:{help if}}] [{it:{help in}}] [{it:{help weight}}]
+    [{cmd:,}
+        {cmdab:s:tatistics:(}{it:{help tabstat##statname:statname}} [{it:...}]{cmd:)}
+        {cmdab:c:olumns:(}{cmdab:v:ariables}|{cmdab:s:tatistics:)}
+        {cmd:by(}{it:varname}{cmd:)}
+        {cmdab:not:otal}
+        {cmdab:m:issing}
+        {cmdab:list:wise}
+        {cmdab:case:wise}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}
+    posts summary statistics computed by {helpb tabstat}. {cmd:aweight}s and
+    {cmd:fweight}s are allowed; see {help weight}.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:statistics()}, {cmd:columns()}, {cmd:by()}, {cmd:nototal},
+        and {cmd:missing} as described in help {helpb tabstat}.
+
+{p 8 12 2}
+        {cmd:listwise} to handle missing values through listwise deletion,
+        meaning that an observation is omitted from the estimation
+        sample if any of the variables in {it:varlist} is missing for that
+        observation. The default is to determine the used observations for
+        each variable separately without regard to whether other variables
+        are missing. {cmd:casewise} is a synonym for {cmd:listwise}.
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}A vector of results is saved in {cmd:e()} for each specified
+variable or statistic, depending on {cmd:columns()}.
+
+{p 4 4 2}
+    Examples:
+
+{* begin example tabstat }{...}
+        {com}. sysuse auto, clear
+        {txt}(1978 Automobile Data)
+
+        {com}. estpost tabstat price mpg rep78, listwise ///
+        >     statistics(mean sd)
+
+        {txt}Summary statistics: mean sd
+             for variables: price mpg rep78
+
+        {ralign 12:} {c |} {ralign 9:e(price)}  {ralign 9:e(mpg)}  {ralign 9:e(rep78)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}
+        {ralign 12:mean} {c |} {ralign 9:{res:{sf: 6146.043}}}  {ralign 9:{res:{sf: 21.28986}}}  {ralign 9:{res:{sf: 3.405797}}}
+        {ralign 12:sd} {c |} {ralign 9:{res:{sf:  2912.44}}}  {ralign 9:{res:{sf: 5.866408}}}  {ralign 9:{res:{sf: .9899323}}}
+
+        {com}. esttab ., cells("price mpg rep78")
+        {res}
+        {txt}{hline 51}
+        {txt}                      (1)
+        {txt}
+        {txt}                    price          mpg        rep78
+        {txt}{hline 51}
+        {txt}mean        {res}     6146.043     21.28986     3.405797{txt}
+        {txt}sd          {res}      2912.44     5.866408     .9899323{txt}
+        {txt}{hline 51}
+        {txt}N           {res}           69                          {txt}
+        {txt}{hline 51}
+
+        {com}. estpost tabstat price mpg rep78, listwise ///
+        >     statistics(mean sd) columns(statistics)
+
+        {txt}Summary statistics: mean sd
+             for variables: price mpg rep78
+
+        {ralign 12:} {c |} {ralign 9:e(mean)}  {ralign 9:e(sd)}
+        {hline 13}{c   +}{hline 11}{hline 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf: 6146.043}}}  {ralign 9:{res:{sf:  2912.44}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf: 21.28986}}}  {ralign 9:{res:{sf: 5.866408}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf: 3.405797}}}  {ralign 9:{res:{sf: .9899323}}}
+
+        {com}. esttab ., cells("mean(fmt(a3)) sd")
+        {res}
+        {txt}{hline 38}
+        {txt}                      (1)
+        {txt}
+        {txt}                     mean           sd
+        {txt}{hline 38}
+        {txt}price       {res}       6146.0       2912.4{txt}
+        {txt}mpg         {res}        21.29        5.866{txt}
+        {txt}rep78       {res}        3.406        0.990{txt}
+        {txt}{hline 38}
+        {txt}N           {res}           69             {txt}
+        {txt}{hline 38}
+
+        {com}. estpost tabstat price mpg rep78, by(foreign) ///
+        >     statistics(mean sd) columns(statistics) listwise
+
+        {txt}Summary statistics: mean sd
+             for variables: price mpg rep78
+          by categories of: foreign
+
+        {ralign 12:foreign} {c |} {ralign 9:e(mean)}  {ralign 9:e(sd)}
+        {hline 13}{c   +}{hline 11}{hline 11}
+        {res:{lalign 13:Domestic}}{c |}{space 11}{space 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf:  6179.25}}}  {ralign 9:{res:{sf: 3188.969}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf: 19.54167}}}  {ralign 9:{res:{sf: 4.753312}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf: 3.020833}}}  {ralign 9:{res:{sf:  .837666}}}
+        {hline 13}{c   +}{hline 11}{hline 11}
+        {res:{lalign 13:Foreign}}{c |}{space 11}{space 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf: 6070.143}}}  {ralign 9:{res:{sf: 2220.984}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf: 25.28571}}}  {ralign 9:{res:{sf: 6.309856}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf: 4.285714}}}  {ralign 9:{res:{sf: .7171372}}}
+        {hline 13}{c   +}{hline 11}{hline 11}
+        {res:{lalign 13:Total}}{c |}{space 11}{space 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf: 6146.043}}}  {ralign 9:{res:{sf:  2912.44}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf: 21.28986}}}  {ralign 9:{res:{sf: 5.866408}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf: 3.405797}}}  {ralign 9:{res:{sf: .9899323}}}
+
+        {com}. esttab ., main(mean) aux(sd) nostar unstack ///
+        >     noobs nonote label
+        {res}
+        {txt}{hline 59}
+        {txt}                              (1)
+        {txt}
+        {txt}                         Domestic      Foreign        Total
+        {txt}{hline 59}
+        {txt}Price               {res}       6179.3       6070.1       6146.0{txt}
+                            {res} {ralign 12:{txt:(}3189.0{txt:)}} {ralign 12:{txt:(}2221.0{txt:)}} {ralign 12:{txt:(}2912.4{txt:)}}{txt}
+
+        {txt}Mileage (mpg)       {res}        19.54        25.29        21.29{txt}
+                            {res} {ralign 12:{txt:(}4.753{txt:)}} {ralign 12:{txt:(}6.310{txt:)}} {ralign 12:{txt:(}5.866{txt:)}}{txt}
+
+        {txt}Repair Record 1978  {res}        3.021        4.286        3.406{txt}
+                            {res} {ralign 12:{txt:(}0.838{txt:)}} {ralign 12:{txt:(}0.717{txt:)}} {ralign 12:{txt:(}0.990{txt:)}}{txt}
+        {txt}{hline 59}
+{* end example }{txt}{...}
+
+{marker ttest}
+{dlgtab:ttest}
+
+{p 4 15 2}
+{cmd:estpost} {cmdab:ttest}
+    {it:{help varlist}} [{it:{help if}}] [{it:{help in}}]{cmd:,}
+    {cmd:by(}{it:groupvar}{cmd:)}
+    [
+        {cmdab:une:qual} {cmdab:w:elch}
+        {cmdab:list:wise}
+        {cmdab:case:wise}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}
+    posts two-group mean-comparison tests computed by {helpb ttest}.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:by()}, {cmd:unequal}, and {cmd:welch} as described in
+        help {helpb ttest}.
+
+{p 8 12 2}
+        {cmd:listwise} to handle missing values through listwise deletion,
+        meaning that an observation is omitted from the estimation
+        sample if any of the variables in {it:varlist} is missing for that
+        observation. The default is to determine the used observations for
+        each variable separately without regard to whether other variables
+        are missing. {cmd:casewise} is a synonym for {cmd:listwise}.
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}The following results vectors are saved in {cmd:e()}:
+
+        {lalign 13:{cmd:e(b)}}mean difference
+        {lalign 13:{cmd:e(count)}}number of observations
+        {lalign 13:{cmd:e(se)}}standard error of difference
+        {lalign 13:{cmd:e(t)}}t statistic
+        {lalign 13:{cmd:e(df_t)}}degrees of freedom
+        {lalign 13:{cmd:e(p_l)}}lower one-sided p-value
+        {lalign 13:{cmd:e(p)}}two-sided p-value
+        {lalign 13:{cmd:e(p_u)}}upper one-sided p-value
+        {lalign 13:{cmd:e(N_1)}}number of observations in group 1
+        {lalign 13:{cmd:e(mu_1)}}mean in group 1
+        {lalign 13:{cmd:e(N_2)}}number of observations in group 2
+        {lalign 13:{cmd:e(mu_2)}}mean in group 2
+
+{p 4 4 2}
+    Example:
+
+{* begin example ttest }{...}
+        {com}. sysuse auto, clear
+        {txt}(1978 Automobile Data)
+
+        {com}. estpost ttest price mpg headroom trunk, by(foreign)
+
+        {txt}{ralign 12:} {c |} {ralign 9:e(b)}  {ralign 9:e(count)}  {ralign 9:e(se)}  {ralign 9:e(t)}  {ralign 9:e(df_t)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf:-312.2587}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf: 754.4488}}}  {ralign 9:{res:{sf:-.4138899}}}  {ralign 9:{res:{sf:       72}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf:-4.945804}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf: 1.362162}}}  {ralign 9:{res:{sf:-3.630848}}}  {ralign 9:{res:{sf:       72}}}
+        {ralign 12:headroom} {c |} {ralign 9:{res:{sf: .5402098}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf: .2070884}}}  {ralign 9:{res:{sf: 2.608596}}}  {ralign 9:{res:{sf:       72}}}
+        {ralign 12:trunk} {c |} {ralign 9:{res:{sf: 3.340909}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf: 1.022208}}}  {ralign 9:{res:{sf: 3.268327}}}  {ralign 9:{res:{sf:       72}}}
+
+        {ralign 12:} {c |} {ralign 9:e(p_l)}  {ralign 9:e(p)}  {ralign 9:e(p_u)}  {ralign 9:e(N_1)}  {ralign 9:e(mu_1)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf: .3400925}}}  {ralign 9:{res:{sf: .6801851}}}  {ralign 9:{res:{sf: .6599075}}}  {ralign 9:{res:{sf:       52}}}  {ralign 9:{res:{sf: 6072.423}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf: .0002627}}}  {ralign 9:{res:{sf: .0005254}}}  {ralign 9:{res:{sf: .9997373}}}  {ralign 9:{res:{sf:       52}}}  {ralign 9:{res:{sf: 19.82692}}}
+        {ralign 12:headroom} {c |} {ralign 9:{res:{sf: .9944757}}}  {ralign 9:{res:{sf: .0110486}}}  {ralign 9:{res:{sf: .0055243}}}  {ralign 9:{res:{sf:       52}}}  {ralign 9:{res:{sf: 3.153846}}}
+        {ralign 12:trunk} {c |} {ralign 9:{res:{sf:   .99917}}}  {ralign 9:{res:{sf:   .00166}}}  {ralign 9:{res:{sf:   .00083}}}  {ralign 9:{res:{sf:       52}}}  {ralign 9:{res:{sf:    14.75}}}
+
+        {ralign 12:} {c |} {ralign 9:e(N_2)}  {ralign 9:e(mu_2)}
+        {hline 13}{c   +}{hline 11}{hline 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf:       22}}}  {ralign 9:{res:{sf: 6384.682}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf:       22}}}  {ralign 9:{res:{sf: 24.77273}}}
+        {ralign 12:headroom} {c |} {ralign 9:{res:{sf:       22}}}  {ralign 9:{res:{sf: 2.613636}}}
+        {ralign 12:trunk} {c |} {ralign 9:{res:{sf:       22}}}  {ralign 9:{res:{sf: 11.40909}}}
+
+        {com}. esttab ., wide
+        {res}
+        {txt}{hline 41}
+        {txt}                      (1)
+        {txt}
+        {txt}{hline 41}
+        {txt}price       {res}       -312.3    {ralign 12:{txt:(}-0.41{txt:)}}{txt}
+        {txt}mpg         {res}       -4.946*** {ralign 12:{txt:(}-3.63{txt:)}}{txt}
+        {txt}headroom    {res}        0.540*   {ralign 12:{txt:(}2.61{txt:)}}{txt}
+        {txt}trunk       {res}        3.341**  {ralign 12:{txt:(}3.27{txt:)}}{txt}
+        {txt}{hline 41}
+        {txt}N           {res}           74                {txt}
+        {txt}{hline 41}
+        {txt}t statistics in parentheses
+        {txt}* p<0.05, ** p<0.01, *** p<0.001
+{* end example }{txt}{...}
+
+{marker prtest}
+{dlgtab:prtest}
+
+{p 4 15 2}
+{cmd:estpost} {cmdab:prtest}
+    {it:{help varlist}} [{it:{help if}}] [{it:{help in}}]{cmd:,}
+    {cmd:by(}{it:groupvar}{cmd:)}
+    [
+        {cmdab:list:wise}
+        {cmdab:case:wise}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}
+    posts two-group tests of proportions computed by {helpb prtest}.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:by()} as described in
+        help {helpb prtest}.
+
+{p 8 12 2}
+        {cmd:listwise} to handle missing values through listwise deletion,
+        meaning that an observation is omitted from the estimation
+        sample if any of the variables in {it:varlist} is missing for that
+        observation. The default is to determine the used observations for
+        each variable separately without regard to whether other variables
+        are missing. {cmd:casewise} is a synonym for {cmd:listwise}.
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}The following results vectors are saved in {cmd:e()}:
+
+        {lalign 13:{cmd:e(b)}}difference in proportions
+        {lalign 13:{cmd:e(count)}}number of observations
+        {lalign 13:{cmd:e(se)}}standard error of difference
+        {lalign 13:{cmd:e(se0)}}standard error under Ho
+        {lalign 13:{cmd:e(z)}}z statistic
+        {lalign 13:{cmd:e(p_l)}}lower one-sided p-value
+        {lalign 13:{cmd:e(p)}}two-sided p-value
+        {lalign 13:{cmd:e(p_u)}}upper one-sided p-value
+        {lalign 13:{cmd:e(N_1)}}number of observations in group 1
+        {lalign 13:{cmd:e(P_1)}}proportion in group 1
+        {lalign 13:{cmd:e(N_2)}}number of observations in group 2
+        {lalign 13:{cmd:e(P_2)}}proportion in group 2
+
+{p 4 4 2}
+    Example:
+
+{* begin example prtest }{...}
+        {com}. webuse cure2, clear
+        {txt}
+        {com}. estpost prtest cure, by(sex)
+
+        {txt}{ralign 12:} {c |} {ralign 9:e(b)}  {ralign 9:e(count)}  {ralign 9:e(se)}  {ralign 9:e(se0)}  {ralign 9:e(z)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:cure} {c |} {ralign 9:{res:{sf:-.0729167}}}  {ralign 9:{res:{sf:      109}}}  {ralign 9:{res:{sf: .0933123}}}  {ralign 9:{res:{sf: .0942404}}}  {ralign 9:{res:{sf:-.7737309}}}
+
+        {ralign 12:} {c |} {ralign 9:e(p_l)}  {ralign 9:e(p)}  {ralign 9:e(p_u)}  {ralign 9:e(N_1)}  {ralign 9:e(P_1)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:cure} {c |} {ralign 9:{res:{sf:  .219545}}}  {ralign 9:{res:{sf:   .43909}}}  {ralign 9:{res:{sf:  .780455}}}  {ralign 9:{res:{sf:       64}}}  {ralign 9:{res:{sf:   .59375}}}
+
+        {ralign 12:} {c |} {ralign 9:e(N_2)}  {ralign 9:e(P_2)}
+        {hline 13}{c   +}{hline 11}{hline 11}
+        {ralign 12:cure} {c |} {ralign 9:{res:{sf:       45}}}  {ralign 9:{res:{sf: .6666667}}}
+
+        {com}. esttab ., cell("b se0 z p")
+        {res}
+        {txt}{hline 64}
+        {txt}                      (1)
+        {txt}
+        {txt}                        b          se0            z            p
+        {txt}{hline 64}
+        {txt}cure        {res}    -.0729167     .0942404    -.7737309       .43909{txt}
+        {txt}{hline 64}
+        {txt}N           {res}          109                                       {txt}
+        {txt}{hline 64}
+{* end example }{txt}{...}
+
+{marker tabulate}
+{dlgtab:tabulate}
+
+{p 4 4 2}One-way table:
+
+{p 8 15 2}
+{cmd:estpost} {cmdab:ta:bulate}
+    {it:varname} [{it:{help if}}] [{it:{help in}}] [{it:{help weight}}]
+    [{cmd:,}
+        {cmdab:m:issing}
+        {cmdab:nol:abel}
+        {cmd:sort}
+        {cmd:subpop(}{it:varname}{cmd:)}
+        {cmdab:notot:al}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}Two-way table:
+
+{p 8 15 2}
+{cmd:estpost} {cmdab:ta:bulate}
+    {it:varname1} {it:varname2} [{it:{help if}}] [{it:{help in}}] [{it:{help weight}}]
+    [{cmd:,}
+        {cmdab:m:issing}
+        {cmdab:nol:abel}
+        {cmdab:ch:i2}
+        {cmdab:e:xact}[{cmd:(}{it:#}{cmd:)}]
+        {cmdab:g:amma}
+        {cmdab:lr:chi2}
+        {cmdab:t:aub}
+        {cmdab:v}
+        {cmdab:notot:al}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}
+    {cmd:estpost tabulate} posts a one-way or two-way table
+    computed by {helpb tabulate}. {cmd:aweight}s, {cmd:fweight}s,
+    and {cmd:iweight}s are allowed;  see {help weight}.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:missing},
+        {cmd:nolabel},
+        {cmd:sort},
+        {cmd:subpop()},
+        {cmd:chi2},
+        {cmd:exact},
+        {cmd:gamma},
+        {cmd:lrchi2},
+        {cmd:taub}, and
+        {cmd:v}
+        as described in help {helpb tabulate}.
+
+{p 8 12 2}
+        {cmdab:nototal} to omit row and column totals.
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}The following vectors are saved in {cmd:e()}:
+
+        {lalign 13:{cmd:e(b)}}frequency counts
+        {lalign 13:{cmd:e(pct)}}percent
+        {lalign 13:{cmd:e(cumpct)}}cumulative percent (one-way only)
+        {lalign 13:{cmd:e(colpct)}}column percent (two-way only)
+        {lalign 13:{cmd:e(rowpct)}}row percent (two-way only)
+
+{p 4 4 2}If two-way options such as, e.g., {cmd:chi2} or {cmd:exact} are
+specified, the results of the tests added as scalars in {cmd:e()} using the
+names documented in {helpb tabulate:{bind:[R] tabulate}}.
+
+{p 4 4 2}The value labels of the row variable are stored as names in the
+saved vectors, unless
+no label exceeds 30 characters or contains unsuitable characters in which case
+the labels are stored in macro {cmd:e(labels)}. Type
+{cmd:varlabels(`e(labels)')} in {helpb esttab} or {helpb estout} to
+use the labels stored {cmd:e(labels)}. The value labels of the column variable
+are stored as equation names or, alternatively,
+in macro {cmd:e(eqlabels)}. Type {cmd:eqlabels(`e(eqlabels)')} in
+{helpb esttab} or {helpb estout} to use the labels stored in {cmd:e(eqlabels)}.
+
+{p 4 4 2}Examples:
+
+{* begin example tabulate }{...}
+        {com}. sysuse auto, clear
+        {txt}(1978 Automobile Data)
+
+        {com}. estpost tabulate foreign
+
+        {txt}{ralign 12:foreign} {c |} {ralign 9:e(b)}  {ralign 9:e(pct)}  {ralign 9:e(cumpct)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}
+        {ralign 12:Domestic} {c |} {ralign 9:{res:{sf:       52}}}  {ralign 9:{res:{sf: 70.27027}}}  {ralign 9:{res:{sf: 70.27027}}}
+        {ralign 12:Foreign} {c |} {ralign 9:{res:{sf:       22}}}  {ralign 9:{res:{sf: 29.72973}}}  {ralign 9:{res:{sf:      100}}}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}
+        {ralign 12:Total} {c |} {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf:      100}}}  {ralign 9:{res:{sf:{space 9}}}}
+
+        {com}. esttab ., cells("b pct(fmt(2)) cumpct(fmt(2))") noobs
+        {res}
+        {txt}{hline 51}
+        {txt}                      (1)
+        {txt}                  foreign
+        {txt}                        b          pct       cumpct
+        {txt}{hline 51}
+        {txt}Domestic    {res}           52        70.27        70.27{txt}
+        {txt}Foreign     {res}           22        29.73       100.00{txt}
+        {txt}Total       {res}           74       100.00             {txt}
+        {txt}{hline 51}
+
+        {com}. estpost tabulate rep78 foreign
+
+        {res}foreign     {txt} {c |}{space 44}
+        {ralign 12:rep78} {c |} {ralign 9:e(b)}  {ralign 9:e(pct)}  {ralign 9:e(colpct)}  {ralign 9:e(rowpct)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}
+        {res:{lalign 13:Domestic}}{c |}{space 11}{space 11}{space 11}{space 11}
+        {ralign 12:1} {c |} {ralign 9:{res:{sf:        2}}}  {ralign 9:{res:{sf: 2.898551}}}  {ralign 9:{res:{sf: 4.166667}}}  {ralign 9:{res:{sf:      100}}}
+        {ralign 12:2} {c |} {ralign 9:{res:{sf:        8}}}  {ralign 9:{res:{sf:  11.5942}}}  {ralign 9:{res:{sf: 16.66667}}}  {ralign 9:{res:{sf:      100}}}
+        {ralign 12:3} {c |} {ralign 9:{res:{sf:       27}}}  {ralign 9:{res:{sf: 39.13043}}}  {ralign 9:{res:{sf:    56.25}}}  {ralign 9:{res:{sf:       90}}}
+        {ralign 12:4} {c |} {ralign 9:{res:{sf:        9}}}  {ralign 9:{res:{sf: 13.04348}}}  {ralign 9:{res:{sf:    18.75}}}  {ralign 9:{res:{sf:       50}}}
+        {ralign 12:5} {c |} {ralign 9:{res:{sf:        2}}}  {ralign 9:{res:{sf: 2.898551}}}  {ralign 9:{res:{sf: 4.166667}}}  {ralign 9:{res:{sf: 18.18182}}}
+        {ralign 12:Total} {c |} {ralign 9:{res:{sf:       48}}}  {ralign 9:{res:{sf: 69.56522}}}  {ralign 9:{res:{sf:      100}}}  {ralign 9:{res:{sf: 69.56522}}}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}
+        {res:{lalign 13:Foreign}}{c |}{space 11}{space 11}{space 11}{space 11}
+        {ralign 12:1} {c |} {ralign 9:{res:{sf:        0}}}  {ralign 9:{res:{sf:        0}}}  {ralign 9:{res:{sf:        0}}}  {ralign 9:{res:{sf:        0}}}
+        {ralign 12:2} {c |} {ralign 9:{res:{sf:        0}}}  {ralign 9:{res:{sf:        0}}}  {ralign 9:{res:{sf:        0}}}  {ralign 9:{res:{sf:        0}}}
+        {ralign 12:3} {c |} {ralign 9:{res:{sf:        3}}}  {ralign 9:{res:{sf: 4.347826}}}  {ralign 9:{res:{sf: 14.28571}}}  {ralign 9:{res:{sf:       10}}}
+        {ralign 12:4} {c |} {ralign 9:{res:{sf:        9}}}  {ralign 9:{res:{sf: 13.04348}}}  {ralign 9:{res:{sf: 42.85714}}}  {ralign 9:{res:{sf:       50}}}
+        {ralign 12:5} {c |} {ralign 9:{res:{sf:        9}}}  {ralign 9:{res:{sf: 13.04348}}}  {ralign 9:{res:{sf: 42.85714}}}  {ralign 9:{res:{sf: 81.81818}}}
+        {ralign 12:Total} {c |} {ralign 9:{res:{sf:       21}}}  {ralign 9:{res:{sf: 30.43478}}}  {ralign 9:{res:{sf:      100}}}  {ralign 9:{res:{sf: 30.43478}}}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}
+        {res:{lalign 13:Total}}{c |}{space 11}{space 11}{space 11}{space 11}
+        {ralign 12:1} {c |} {ralign 9:{res:{sf:        2}}}  {ralign 9:{res:{sf: 2.898551}}}  {ralign 9:{res:{sf: 2.898551}}}  {ralign 9:{res:{sf:      100}}}
+        {ralign 12:2} {c |} {ralign 9:{res:{sf:        8}}}  {ralign 9:{res:{sf:  11.5942}}}  {ralign 9:{res:{sf:  11.5942}}}  {ralign 9:{res:{sf:      100}}}
+        {ralign 12:3} {c |} {ralign 9:{res:{sf:       30}}}  {ralign 9:{res:{sf: 43.47826}}}  {ralign 9:{res:{sf: 43.47826}}}  {ralign 9:{res:{sf:      100}}}
+        {ralign 12:4} {c |} {ralign 9:{res:{sf:       18}}}  {ralign 9:{res:{sf: 26.08696}}}  {ralign 9:{res:{sf: 26.08696}}}  {ralign 9:{res:{sf:      100}}}
+        {ralign 12:5} {c |} {ralign 9:{res:{sf:       11}}}  {ralign 9:{res:{sf: 15.94203}}}  {ralign 9:{res:{sf: 15.94203}}}  {ralign 9:{res:{sf:      100}}}
+        {ralign 12:Total} {c |} {ralign 9:{res:{sf:       69}}}  {ralign 9:{res:{sf:      100}}}  {ralign 9:{res:{sf:      100}}}  {ralign 9:{res:{sf:      100}}}
+
+        {com}. esttab ., cell(colpct(fmt(2))) unstack noobs
+        {res}
+        {txt}{hline 51}
+        {txt}                      (1)
+        {txt}
+        {txt}                 Domestic      Foreign        Total
+        {txt}                   colpct       colpct       colpct
+        {txt}{hline 51}
+        {txt}1           {res}         4.17         0.00         2.90{txt}
+        {txt}2           {res}        16.67         0.00        11.59{txt}
+        {txt}3           {res}        56.25        14.29        43.48{txt}
+        {txt}4           {res}        18.75        42.86        26.09{txt}
+        {txt}5           {res}         4.17        42.86        15.94{txt}
+        {txt}Total       {res}       100.00       100.00       100.00{txt}
+        {txt}{hline 51}
+
+        {com}. esttab ., cell(colpct(fmt(2)) count(fmt(g) par keep(Total))) ///
+        >     collabels(none) unstack noobs nonumber nomtitle          ///
+        >     eqlabels(, lhs("Repair Rec."))                           ///
+        >     varlabels(, blist(Total "{c -(}hline @width{c )-}{c -(}break{c )-}"))
+        {res}
+        {txt}{hline 51}
+        {txt}Repair Rec.      Domestic      Foreign        Total
+        {txt}{hline 51}
+        {txt}1           {res}         4.17         0.00         2.90{txt}
+        {txt}2           {res}        16.67         0.00        11.59{txt}
+        {txt}3           {res}        56.25        14.29        43.48{txt}
+        {txt}4           {res}        18.75        42.86        26.09{txt}
+        {txt}5           {res}         4.17        42.86        15.94{txt}
+        {txt}{hline 51}{break}        Total       {res}       100.00       100.00       100.00{txt}
+                    {res}                                       {txt}
+        {txt}{hline 51}
+{* end example }{txt}{...}
+
+{marker svy_tabulate}
+{dlgtab:svy: tabulate}
+
+{p 4 4 2}One-way table:
+
+{p 8 15 2}
+{cmd:estpost} {cmd:svy} [{it:vcetype}] [, {it:svy_options}] {cmd::} {cmdab:ta:bulate}
+    {it:varname} [{it:{help if}}] [{it:{help in}}]
+    [{cmd:,}
+        {cmdab:notot:al}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+        {help svy_tabulate_oneway:{it:svy_tabulate_opts}}
+    ]
+
+{p 4 4 2}Two-way table:
+
+{p 8 15 2}
+{cmd:estpost} {cmd:svy} [{it:vcetype}] [, {it:svy_options}] {cmd::} {cmdab:ta:bulate}
+    {it:varname1} {it:varname2} [{it:{help if}}] [{it:{help in}}]
+    [{cmd:,}
+        {cmdab:notot:al}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+        {help svy_tabulate_oneway:{it:svy_tabulate_opts}}
+    ]
+
+{p 4 4 2}
+    {cmd:estpost svy: tabulate} posts a one-way or two-way table
+    for complex survey data computed by {helpb svy_tabulate:svy: tabulate}. Stata 9 or newer
+    is required.
+
+{p 4 4 2}
+    Options are as described in {helpb svy_tabulate_oneway:[SVY] svy: tabulate oneway} or
+        {helpb svy_tabulate_twoway:[SVY] svy: tabulate twoway}, respectively, and:
+
+{p 8 12 2}
+        {cmdab:nototal} to omit row and column totals (synonym for {cmd:nomarginals}).
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}{cmd:estpost svy: tabulate} posts results in {cmd:e()} (except {cmd:e(V)})
+as documented in {helpb svy_tabulate_oneway:[SVY] svy: tabulate oneway} and
+{helpb svy_tabulate_twoway:[SVY] svy: tabulate twoway}, respectively,
+and adds or replaces the following matrices:
+
+        {lalign 10:{cmd:e(b)}}cell, column, or row proportions or percentages,
+                    or weighted counts, depending on options
+        {lalign 10:{cmd:e(se)}}standard errors of {cmd:e(b)}
+        {lalign 10:{cmd:e(lb)}}lower confidence bounds for {cmd:e(b)}
+        {lalign 10:{cmd:e(ub)}}upper confidence bounds for {cmd:e(b)}
+        {lalign 10:{cmd:e(deff)}}deff for variances of {cmd:e(b)}
+        {lalign 10:{cmd:e(deft)}}deft for variances of {cmd:e(b)}
+        {lalign 10:{cmd:e(cell)}}cell proportion or percentages
+        {lalign 10:{cmd:e(row)}}row proportion or percentages (two-way only)
+        {lalign 10:{cmd:e(col)}}column proportion or percentages (two-way only)
+        {lalign 10:{cmd:e(count)}}weighted counts
+        {lalign 10:{cmd:e(obs)}}number of observations
+
+{p 4 4 2}The value labels of the row variable are stored as names in the
+saved vectors, unless
+no label exceeds 30 characters or contains unsuitable characters in which case
+the labels are stored in macro {cmd:e(labels)}. Type
+{cmd:varlabels(`e(labels)')} in {helpb esttab} or {helpb estout} to
+use the labels stored {cmd:e(labels)}. The value labels of the column variable
+are stored as equation names or, alternatively,
+in macro {cmd:e(eqlabels)}. Type {cmd:eqlabels(`e(eqlabels)')} in
+{helpb esttab} or {helpb estout} to use the labels stored in {cmd:e(eqlabels)}.
+
+{p 4 4 2}Examples:
+
+{* begin example svy_tabulate }{...}
+        {com}. webuse nhanes2b, clear
+        {txt}
+        {com}. svyset psuid [pweight=finalwgt], strata(stratid)
+
+              {txt}pweight:{col 16}{res}finalwgt
+                  {txt}VCE:{col 16}{res}linearized
+          {txt}Single unit:{col 16}{res}missing
+             {txt}Strata 1:{col 16}{res}stratid
+                 {txt}SU 1:{col 16}{res}psuid
+                {txt}FPC 1:{col 16}<zero>
+        {p2colreset}{...}
+
+        {com}. estpost svy: tabulate race
+        {txt}(running tabulate on estimation sample)
+
+        {col 1}Number of strata{col 20}= {res}       31{txt}{col 48}Number of obs{col 67}= {res}     10351
+        {txt}{col 1}Number of PSUs{col 20}= {res}       62{txt}{col 48}Population size{col 67}={res}  117157513
+        {txt}{col 48}Design df{col 67}= {res}        31
+
+        {txt}{hline 10}{c TT}{hline 12}
+        1=white,  {c |}
+        2=black,  {c |}
+        3=other   {c |} proportions
+        {hline 10}{c +}{hline 12}
+            White {c |}       {res}.8792
+            {txt}Black {c |}       {res}.0955
+            {txt}Other {c |}       {res}.0253
+                  {txt}{c |}
+            Total {c |}           {res}1
+        {txt}{hline 10}{c BT}{hline 12}
+          Key:  {col 1}proportions  =  {res}cell proportions
+
+        {txt}saved vectors:
+                     e(b) =  {res}cell proportions
+                    {txt}e(se) =  {res}standard errors of cell proportions
+                    {txt}e(lb) =  {res}lower 95% confidence bounds for cell proportions
+                    {txt}e(ub) =  {res}upper 95% confidence bounds for cell proportions
+                  {txt}e(deff) =  {res}deff for variances of cell proportions
+                  {txt}e(deft) =  {res}deft for variances of cell proportions
+                  {txt}e(cell) =  {res}cell proportions
+                 {txt}e(count) =  {res}weighted counts
+                   {txt}e(obs) =  {res}number of observations
+        {txt}
+        {com}. esttab ., cell("b(f(4)) se deft")
+        {res}
+        {txt}{hline 51}
+        {txt}                      (1)
+        {txt}
+        {txt}                        b           se         deft
+        {txt}{hline 51}
+        {txt}White       {res}       0.8792       0.0167       5.2090{txt}
+        {txt}Black       {res}       0.0955       0.0127       4.4130{txt}
+        {txt}Other       {res}       0.0253       0.0105       6.8246{txt}
+        {txt}Total       {res}       1.0000       0.0000             {txt}
+        {txt}{hline 51}
+        {txt}N           {res}        10351                          {txt}
+        {txt}{hline 51}
+
+        {com}. estpost svy: tabulate race diabetes, row percent
+        {txt}(running tabulate on estimation sample)
+
+        {col 1}Number of strata{col 20}= {res}       31{txt}{col 48}Number of obs{col 67}= {res}     10349
+        {txt}{col 1}Number of PSUs{col 20}= {res}       62{txt}{col 48}Population size{col 67}={res}  117131111
+        {txt}{col 48}Design df{col 67}= {res}        31
+
+        {txt}{hline 10}{c TT}{hline 20}
+        1=white,  {c |}  diabetes, 1=yes,
+        2=black,  {c |}        0=no
+        3=other   {c |}     0      1  Total
+        {hline 10}{c +}{hline 20}
+            White {c |}  {res}96.8  3.195    100
+            {txt}Black {c |}  {res}94.1  5.903    100
+            {txt}Other {c |} {res}97.97  2.034    100
+                  {txt}{c |}
+            Total {c |} {res}96.58  3.425    100
+        {txt}{hline 10}{c BT}{hline 20}
+          Key:  {col 1}{res}row percentages
+
+        {txt}  Pearson:
+        {col 5}Uncorrected{col 19}chi2({res}2{txt}){col 35}= {res}  21.3483
+        {txt}{col 5}Design-based{col 19}F({res}1.52{txt}, {res}47.26{txt}){col 35}= {res}  15.0056{col 51}{txt}P = {res}0.0000
+
+        {txt}saved vectors:
+                     e(b) =  {res}row percentages
+                    {txt}e(se) =  {res}standard errors of row percentages
+                    {txt}e(lb) =  {res}lower 95% confidence bounds for row percentages
+                    {txt}e(ub) =  {res}upper 95% confidence bounds for row percentages
+                  {txt}e(deff) =  {res}deff for variances of row percentages
+                  {txt}e(deft) =  {res}deft for variances of row percentages
+                  {txt}e(cell) =  {res}cell percentages
+                   {txt}e(row) =  {res}row percentages
+                   {txt}e(col) =  {res}column percentages
+                 {txt}e(count) =  {res}weighted counts
+                   {txt}e(obs) =  {res}number of observations
+        {txt}
+        {com}. esttab ., b(2) se(2) scalars(F_Pear) nostar unstack ///
+        >     mtitle(`e(colvar)')
+        {res}
+        {txt}{hline 51}
+        {txt}                      (1)
+        {txt}                 diabetes
+        {txt}                        0            1        Total
+        {txt}{hline 51}
+        {txt}White       {res}        96.80         3.20       100.00{txt}
+                    {res} {ralign 12:{txt:(}0.20{txt:)}} {ralign 12:{txt:(}0.20{txt:)}}             {txt}
+
+        {txt}Black       {res}        94.10         5.90       100.00{txt}
+                    {res} {ralign 12:{txt:(}0.61{txt:)}} {ralign 12:{txt:(}0.61{txt:)}}             {txt}
+
+        {txt}Other       {res}        97.97         2.03       100.00{txt}
+                    {res} {ralign 12:{txt:(}0.76{txt:)}} {ralign 12:{txt:(}0.76{txt:)}}             {txt}
+
+        {txt}Total       {res}        96.58         3.42       100.00{txt}
+                    {res} {ralign 12:{txt:(}0.18{txt:)}} {ralign 12:{txt:(}0.18{txt:)}}             {txt}
+        {txt}{hline 51}
+        {txt}N           {res}        10349                          {txt}
+        {txt}F_Pear      {res}        15.01                          {txt}
+        {txt}{hline 51}
+        {txt}Standard errors in parentheses
+{* end example }{txt}{...}
+
+{marker correlate}
+{dlgtab:correlate}
+
+{p 4 15 2}
+{cmd:estpost} {cmdab:cor:relate}
+    {it:{help varlist}} [{it:{help if}}] [{it:{help in}}] [{it:{help weight}}]
+    [{cmd:,}
+        {cmdab:m:atrix}
+        {cmdab:noh:alf}
+        {cmdab:print:(}{it:#}{cmd:)}
+        {cmdab:b:onferroni}
+        {cmdab:sid:ak}
+        {cmdab:list:wise}
+        {cmdab:case:wise}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}
+    posts the pairwise correlations between the first variable in
+    {it:varlist} and the remaining variables. Alternatively, if the
+    {cmd:matrix} option is specified, all pairwise correlations among the
+    variable in {it:varlist} are posted.
+
+{p 4 4 2}
+    {cmd:aweight}s, {cmd:fweight}s,
+    {cmd:iweight}s and {cmd:pweight}s are  allowed; see {help weight}.
+
+{p 4 4 2}
+    Methods and formulas are as described in
+    {helpb correlate:{bind:[R] correlate}}. However, if {cmd:pweight}s
+    are specified, the p-values of the correlations are computed
+    as suggested in the Stata FAQ on
+    {browse "http://www.stata.com/support/faqs/stat/survey.html":"Estimating correlations with survey data"}.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:matrix} to return the (lower triangle) of the correlation
+        matrix of the variables in {it:varlist}. The default is to return
+        the pairwise correlations between the first variable in
+        {it:varlist} and the remaining variables.
+
+{p 8 12 2}
+        {cmd:nohalf} to return the full correlation matrix rather than just
+        the lower triangle. {cmd:nohalf} has no effect unless {cmd:matrix}
+        is specified.
+
+{p 8 12 2}
+        {cmd:print(}{it:#}{cmd:)} to suppress (leave blank)
+        correlation coefficients with a p-value larger than
+        {it:#}. {cmd:print()} only affects what is saved in
+        {cmd:e(rho)}, {cmd:e(p)}, and {cmd:e(count)}, but
+        not what is saved in {cmd:e(b)}.
+
+{p 8 12 2}
+        {cmd:bonferroni} to apply the Bonferroni adjustment to the
+        p-values.
+
+{p 8 12 2}
+        {cmd:sidak} to apply the Sidak adjustment to the
+        p-values.
+
+{p 8 12 2}
+        {cmd:listwise} to handle missing values through listwise deletion,
+        meaning that an observation is omitted from the estimation sample
+        if any of the variables in {it:varlist} is missing for that
+        observation. The default is to handle missing values by pairwise
+        deletion, i.e. all available observations are used to calculate a
+        pairwise correlation without regard to whether variables outside
+        that pair are missing. {cmd:casewise} is a synonym for
+        {cmd:listwise}.
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}The following vectors are saved in {cmd:e()}:
+
+        {lalign 13:{cmd:e(b)}}correlation coefficients
+        {lalign 13:{cmd:e(rho)}}correlation coefficients
+        {lalign 13:{cmd:e(p)}}p-values
+        {lalign 13:{cmd:e(count)}}number of observations
+
+{p 4 4 2}Examples:
+
+{* begin example correlate }{...}
+        {com}. sysuse auto, clear
+        {txt}(1978 Automobile Data)
+
+        {com}. estpost correlate price mpg turn foreign, matrix
+
+        {txt}{ralign 12:} {c |} {ralign 9:e(b)}  {ralign 9:e(rho)}  {ralign 9:e(p)}  {ralign 9:e(count)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}
+        {res:{lalign 13:price}}{c |}{space 11}{space 11}{space 11}{space 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:{space 9}}}}  {ralign 9:{res:{sf:       74}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf:-.4685967}}}  {ralign 9:{res:{sf:-.4685967}}}  {ralign 9:{res:{sf: .0000255}}}  {ralign 9:{res:{sf:       74}}}
+        {ralign 12:turn} {c |} {ralign 9:{res:{sf: .3096174}}}  {ralign 9:{res:{sf: .3096174}}}  {ralign 9:{res:{sf: .0072662}}}  {ralign 9:{res:{sf:       74}}}
+        {ralign 12:foreign} {c |} {ralign 9:{res:{sf: .0487195}}}  {ralign 9:{res:{sf: .0487195}}}  {ralign 9:{res:{sf: .6801851}}}  {ralign 9:{res:{sf:       74}}}
+        {res:{lalign 13:mpg}}{c |}{space 11}{space 11}{space 11}{space 11}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:{space 9}}}}  {ralign 9:{res:{sf:       74}}}
+        {ralign 12:turn} {c |} {ralign 9:{res:{sf:-.7191863}}}  {ralign 9:{res:{sf:-.7191863}}}  {ralign 9:{res:{sf: 5.30e-13}}}  {ralign 9:{res:{sf:       74}}}
+        {ralign 12:foreign} {c |} {ralign 9:{res:{sf: .3933974}}}  {ralign 9:{res:{sf: .3933974}}}  {ralign 9:{res:{sf: .0005254}}}  {ralign 9:{res:{sf:       74}}}
+        {res:{lalign 13:turn}}{c |}{space 11}{space 11}{space 11}{space 11}
+        {ralign 12:turn} {c |} {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:{space 9}}}}  {ralign 9:{res:{sf:       74}}}
+        {ralign 12:foreign} {c |} {ralign 9:{res:{sf:-.6310965}}}  {ralign 9:{res:{sf:-.6310965}}}  {ralign 9:{res:{sf: 1.66e-09}}}  {ralign 9:{res:{sf:       74}}}
+        {res:{lalign 13:foreign}}{c |}{space 11}{space 11}{space 11}{space 11}
+        {ralign 12:foreign} {c |} {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:        1}}}  {ralign 9:{res:{sf:{space 9}}}}  {ralign 9:{res:{sf:       74}}}
+
+        {com}. esttab ., not unstack compress noobs
+        {res}
+        {txt}{hline 62}
+        {txt}                 (1)
+        {txt}
+        {txt}               price          mpg         turn      foreign
+        {txt}{hline 62}
+        {txt}price     {res}         1                                          {txt}
+        {txt}mpg       {res}    -0.469***         1                             {txt}
+        {txt}turn      {res}     0.310**     -0.719***         1                {txt}
+        {txt}foreign   {res}    0.0487        0.393***    -0.631***         1   {txt}
+        {txt}{hline 62}
+        {txt}* p<0.05, ** p<0.01, *** p<0.001
+
+        {com}. bysort foreign: eststo: ///
+        >     estpost correlate price turn weight rep78, listwise
+
+        {txt}{hline 60}
+        -> Domestic
+
+        {ralign 12:price} {c |} {ralign 9:e(b)}  {ralign 9:e(rho)}  {ralign 9:e(p)}  {ralign 9:e(count)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:turn} {c |} {ralign 9:{res:{sf: .4328091}}}  {ralign 9:{res:{sf: .4328091}}}  {ralign 9:{res:{sf: .0021229}}}  {ralign 9:{res:{sf:       48}}}
+        {ralign 12:weight} {c |} {ralign 9:{res:{sf: .6864719}}}  {ralign 9:{res:{sf: .6864719}}}  {ralign 9:{res:{sf: 7.19e-08}}}  {ralign 9:{res:{sf:       48}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf:-.0193249}}}  {ralign 9:{res:{sf:-.0193249}}}  {ralign 9:{res:{sf: .8962741}}}  {ralign 9:{res:{sf:       48}}}
+        ({res}est1{txt} stored)
+
+        {hline 60}
+        -> Foreign
+
+        {ralign 12:price} {c |} {ralign 9:e(b)}  {ralign 9:e(rho)}  {ralign 9:e(p)}  {ralign 9:e(count)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:turn} {c |} {ralign 9:{res:{sf: .5102425}}}  {ralign 9:{res:{sf: .5102425}}}  {ralign 9:{res:{sf: .0181155}}}  {ralign 9:{res:{sf:       21}}}
+        {ralign 12:weight} {c |} {ralign 9:{res:{sf: .8315886}}}  {ralign 9:{res:{sf: .8315886}}}  {ralign 9:{res:{sf: 2.99e-06}}}  {ralign 9:{res:{sf:       21}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf: .1797879}}}  {ralign 9:{res:{sf: .1797879}}}  {ralign 9:{res:{sf: .4354917}}}  {ralign 9:{res:{sf:       21}}}
+        ({res}est2{txt} stored)
+
+        {com}. esttab est1 est2, not mtitles
+        {res}
+        {txt}{hline 44}
+        {txt}                      (1)             (2)
+        {txt}                 Domestic         Foreign
+        {txt}{hline 44}
+        {txt}turn        {res}        0.433**         0.510*  {txt}
+        {txt}weight      {res}        0.686***        0.832***{txt}
+        {txt}rep78       {res}      -0.0193           0.180   {txt}
+        {txt}{hline 44}
+        {txt}N           {res}           48              21   {txt}
+        {txt}{hline 44}
+        {txt}* p<0.05, ** p<0.01, *** p<0.001
+{* end example }{txt}{...}
+
+{marker ci}
+{dlgtab:ci}
+
+{p 4 15 2}
+{cmd:estpost} {cmdab:ci}
+    [{it:{help varlist}}] [{it:{help if}}] [{it:{help in}}] [{it:{help weight}}]
+    [{cmd:,}
+        {cmdab:b:inomial}
+        {cmdab:p:oisson} {cmdab:e:xposure:(}{it:varname}{cmd:)}
+        {cmdab:ex:act} {cmdab:wa:ld} {cmdab:w:ilson} {cmdab:a:gresti} {cmdab:j:effreys}
+        {cmdab:l:evel:(}{it:#}{cmd:)}
+        {cmdab:list:wise}
+        {cmdab:case:wise}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}
+    posts standard errors and confidence intervals computed by
+    {helpb ci}. {cmd:aweight}s and {cmd:fweight}s are allowed,
+    but {cmd:aweight}s may not be specified with options
+    {cmd:binomial} or {cmd:poisson};
+    see {help weight}.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:binomial}, {cmd:poisson}, {cmd:exposure()},
+        {cmd:exact}, {cmd:wald}, {cmd:wilson}, {cmd:agresti},
+        {cmd:jeffreys}, and {cmd:level()}
+        as described in help {helpb ci}.
+
+{p 8 12 2}
+        {cmd:listwise} to handle missing values through listwise deletion,
+        meaning that an observation is omitted from the estimation
+        sample if any of the variables in {it:varlist} is missing for that
+        observation. The default is to determine the used observations for
+        each variable separately without regard to whether other variables
+        are missing. {cmd:casewise} is a synonym for {cmd:listwise}.
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}The following results vectors are saved in {cmd:e()}:
+
+        {lalign 13:{cmd:e(b)}}mean
+        {lalign 13:{cmd:e(count)}}number of observations
+        {lalign 13:{cmd:e(se)}}estimate of standard error
+        {lalign 13:{cmd:e(lb)}}lower bound of confidence interval
+        {lalign 13:{cmd:e(ub)}}upper bound of confidence interval
+
+{p 4 4 2}
+    Examples:
+
+{* begin example ci }{...}
+        {com}. sysuse auto, clear
+        {txt}(1978 Automobile Data)
+
+        {com}. estpost ci price mpg rep78, listwise
+        {txt}(confidence level is 95%)
+
+        {ralign 12:} {c |} {ralign 9:e(b)}  {ralign 9:e(count)}  {ralign 9:e(se)}  {ralign 9:e(lb)}  {ralign 9:e(ub)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:price} {c |} {ralign 9:{res:{sf: 6146.043}}}  {ralign 9:{res:{sf:       69}}}  {ralign 9:{res:{sf: 350.6166}}}  {ralign 9:{res:{sf: 5446.399}}}  {ralign 9:{res:{sf: 6845.688}}}
+        {ralign 12:mpg} {c |} {ralign 9:{res:{sf: 21.28986}}}  {ralign 9:{res:{sf:       69}}}  {ralign 9:{res:{sf: .7062326}}}  {ralign 9:{res:{sf: 19.88059}}}  {ralign 9:{res:{sf: 22.69912}}}
+        {ralign 12:rep78} {c |} {ralign 9:{res:{sf: 3.405797}}}  {ralign 9:{res:{sf:       69}}}  {ralign 9:{res:{sf: .1191738}}}  {ralign 9:{res:{sf: 3.167989}}}  {ralign 9:{res:{sf: 3.643605}}}
+
+        {com}. esttab ., cells("b lb ub") label
+        {res}
+        {txt}{hline 59}
+        {txt}                              (1)
+        {txt}
+        {txt}                                b           lb           ub
+        {txt}{hline 59}
+        {txt}Price               {res}     6146.043     5446.399     6845.688{txt}
+        {txt}Mileage (mpg)       {res}     21.28986     19.88059     22.69912{txt}
+        {txt}Repair Record 1978  {res}     3.405797     3.167989     3.643605{txt}
+        {txt}{hline 59}
+        {txt}Observations        {res}           69                          {txt}
+        {txt}{hline 59}
+
+        {com}. eststo exact: estpost ci foreign, binomial exact
+        {txt}(confidence level is 95%)
+
+        {ralign 12:} {c |} {ralign 9:e(b)}  {ralign 9:e(count)}  {ralign 9:e(se)}  {ralign 9:e(lb)}  {ralign 9:e(ub)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:foreign} {c |} {ralign 9:{res:{sf: .2972973}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf: .0531331}}}  {ralign 9:{res:{sf:  .196584}}}  {ralign 9:{res:{sf: .4148353}}}
+
+        {com}. eststo agresti: estpost ci foreign, binomial agresti
+        {txt}(confidence level is 95%)
+
+        {ralign 12:} {c |} {ralign 9:e(b)}  {ralign 9:e(count)}  {ralign 9:e(se)}  {ralign 9:e(lb)}  {ralign 9:e(ub)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:foreign} {c |} {ralign 9:{res:{sf: .2972973}}}  {ralign 9:{res:{sf:       74}}}  {ralign 9:{res:{sf: .0531331}}}  {ralign 9:{res:{sf:  .204807}}}  {ralign 9:{res:{sf: .4097942}}}
+
+        {com}. esttab exact agresti, cells(lb ub) mtitles
+        {res}
+        {txt}{hline 38}
+        {txt}                      (1)          (2)
+        {txt}                    exact      agresti
+        {txt}                    lb/ub        lb/ub
+        {txt}{hline 38}
+        {txt}foreign     {res}      .196584      .204807{txt}
+                    {res}     .4148353     .4097942{txt}
+        {txt}{hline 38}
+        {txt}N           {res}           74           74{txt}
+        {txt}{hline 38}
+{* end example }{txt}{...}
+
+{marker stci}
+{dlgtab:stci}
+
+{p 4 15 2}
+{cmd:estpost} {cmd:stci}
+    [{it:{help if}}] [{it:{help in}}]
+    [{cmd:,}
+        {cmd:by(}{it:groupvar}{cmd:)}
+        {cmdab:m:edian}
+        {cmdab:r:mean}
+        {cmdab:e:mean}
+        {cmd:p(}{it:#}{cmd:)}
+        {cmdab:cc:orr}
+        {cmdab:l:evel:(}{it:#}{cmd:)}
+        {cmdab:q:uietly}
+        {cmdab:es:ample}
+    ]
+
+{p 4 4 2}
+    posts confidence intervals for means
+    and percentiles of survival time computed by {helpb stci}. Stata 9 or
+    newer is required.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:by(}{it:groupvar}{cmd:)}
+        to report separate summaries for each group defined by
+        {it:groupvar}, along with an overall total.
+
+{p 8 12 2}
+        {cmd:median},
+        {cmd:rmean},
+        {cmd:emean},
+        {cmd:p()},
+        {cmd:ccorr}, and
+        {cmd:level()}
+        as described in help {helpb stci}.
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {cmd:esample} to mark the estimation sample in {cmd:e(sample)}.
+
+{p 4 4 2}The following vectors are saved in {cmd:e()}:
+
+        {lalign 13:{cmd:e(count)}}number of subjects
+        {lalign 13:{cmd:e(p50)}}median (if {cmd:median} specified; the default)
+        {lalign 13:{cmd:e(p}{it:#}{cmd:)}}#th percentile (if {cmd:p(}{it:#}{cmd:)} specified)
+        {lalign 13:{cmd:e(rmean)}}restricted mean (if {cmd:rmean} specified)
+        {lalign 13:{cmd:e(emean)}}extended mean (if {cmd:emean} specified)
+        {lalign 13:{cmd:e(se)}}standard error
+        {lalign 13:{cmd:e(lb)}}lower bound of CI
+        {lalign 13:{cmd:e(ub)}}upper bound of CI
+
+{p 4 4 2}
+    Examples:
+
+{* begin example stci }{...}
+        {com}. webuse page2, clear
+        {txt}
+        {com}. estpost stci
+        {txt}(confidence level is 95%)
+
+        {ralign 12:} {c |} {ralign 9:e(count)}  {ralign 9:e(p50)}  {ralign 9:e(se)}  {ralign 9:e(lb)}  {ralign 9:e(ub)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:total} {c |} {ralign 9:{res:{sf:       40}}}  {ralign 9:{res:{sf:      232}}}  {ralign 9:{res:{sf: 2.562933}}}  {ralign 9:{res:{sf:      213}}}  {ralign 9:{res:{sf:      239}}}
+
+        {com}. esttab ., cell("count p50 se lb ub") noobs compress
+        {res}
+        {txt}{hline 60}
+        {txt}                 (1)
+        {txt}
+        {txt}               count       p50        se        lb        ub
+        {txt}{hline 60}
+        {txt}total     {res}        40       232  2.562933       213       239{txt}
+        {txt}{hline 60}
+
+        {com}. estpost stci, by(group)
+        {txt}(confidence level is 95%)
+
+        {ralign 12:} {c |} {ralign 9:e(count)}  {ralign 9:e(p50)}  {ralign 9:e(se)}  {ralign 9:e(lb)}  {ralign 9:e(ub)}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:1} {c |} {ralign 9:{res:{sf:       19}}}  {ralign 9:{res:{sf:      216}}}  {ralign 9:{res:{sf: 5.171042}}}  {ralign 9:{res:{sf:      190}}}  {ralign 9:{res:{sf:      234}}}
+        {ralign 12:2} {c |} {ralign 9:{res:{sf:       21}}}  {ralign 9:{res:{sf:      233}}}  {ralign 9:{res:{sf: 2.179595}}}  {ralign 9:{res:{sf:      232}}}  {ralign 9:{res:{sf:      280}}}
+        {hline 13}{c   +}{hline 11}{hline 11}{hline 11}{hline 11}{hline 11}
+        {ralign 12:total} {c |} {ralign 9:{res:{sf:       40}}}  {ralign 9:{res:{sf:      232}}}  {ralign 9:{res:{sf: 2.562933}}}  {ralign 9:{res:{sf:      213}}}  {ralign 9:{res:{sf:      239}}}
+
+        {com}. esttab ., cell("count p50 se lb ub") noobs compress
+        {res}
+        {txt}{hline 60}
+        {txt}                 (1)
+        {txt}
+        {txt}               count       p50        se        lb        ub
+        {txt}{hline 60}
+        {txt}1         {res}        19       216  5.171042       190       234{txt}
+        {txt}2         {res}        21       233  2.179595       232       280{txt}
+        {txt}total     {res}        40       232  2.562933       213       239{txt}
+        {txt}{hline 60}
+{* end example }{txt}{...}
+
+{marker margins}
+{dlgtab:margins}
+
+{p 4 15 2}
+{cmd:estpost} {cmd:margins}
+    [{it:{help fvvarlist:marginlist}}] [{it:{help if}}] [{it:{help in}}] [{it:{help weight}}]
+    [{cmd:,}
+        {cmdab:q:uietly}
+        {it:{help margins:margins_opions}}
+    ]
+
+{p 4 4 2}
+    posts results from the {helpb margins} command, that was introduced in
+    Stata 11.
+
+{p 4 4 2}
+    Options are:
+
+{p 8 12 2}
+        {cmd:quietly} to suppress the output.
+
+{p 8 12 2}
+        {it:margins_opions} as described in help {helpb margins} (except {cmd:post}).
+
+{p 4 4 2}{cmd:estpost margins} replaces the current {cmd:e(b)} and
+{cmd:e(V)} with {cmd:r(b)} and {cmd:r(V)} from {helpb margins} and
+also copies all other matrixes, scalars, and macros from {helpb margins} into
+{cmd:e()} (possibly replacing identically named existing entries).
+
+{p 4 4 2}
+    Examples:
+
+{* begin example margins }{...}
+        {com}. sysuse auto, clear
+        {txt}(1978 Automobile Data)
+
+        {com}. quietly logit foreign price mpg weight
+        {txt}
+        {com}. estpost margins, dydx(*) quietly
+        {txt}
+        {com}. esttab ., cell("b se") pr2
+        {res}
+        {txt}{hline 38}
+        {txt}                      (1)
+        {txt}                  foreign
+        {txt}                        b           se
+        {txt}{hline 38}
+        {txt}price       {res}     .0000686     .0000136{txt}
+        {txt}mpg         {res}    -.0089607      .006596{txt}
+        {txt}weight      {res}    -.0005069      .000055{txt}
+        {txt}{hline 38}
+        {txt}N           {res}           74             {txt}
+        {txt}pseudo R-sq {res}        0.619             {txt}
+        {txt}{hline 38}
+{* end example }{txt}{...}
+
+
+{title:Author}
+
+{p 4 4 2} Ben Jann, Institute of Sociology, University of Bern, [email protected]
+
+
+{title:Also see}
+
+    Manual:  {hi:[R] estimates}
+
+{p 4 13 2}Online:  help for
+ {helpb estimates},
+ {helpb estout},
+ {helpb esttab},
+ {helpb eststo},
+ {helpb estadd}
+{p_end}

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/e/eststo.ado

@@ -0,0 +1,343 @@
+*! version 1.1.0  05nov2008  Ben Jann
+
+program define eststo, byable(onecall)
+    version 8.2
+    local caller : di _caller()
+// --- eststo clear ---
+    if `"`1'"'=="clear" {
+        if `"`0'"'!="clear" {
+            di as err "invalid syntax"
+            exit 198
+        }
+        if "`_byvars'"!="" error 190
+        _eststo_clear
+        exit
+    }
+// --- update globals ---
+    _eststo_cleanglobal
+// --- eststo dir ---
+    if `"`1'"'=="dir" {
+        if `"`0'"'!="dir" {
+            di as err "invalid syntax"
+            exit 198
+        }
+        if "`_byvars'"!="" error 190
+        _eststo_dir
+        exit
+    }
+// --- eststo drop ---
+    if `"`1'"'=="drop" {
+        if "`_byvars'"!="" error 190
+        _eststo_`0'
+        exit
+    }
+// --- eststo store (no by) ---
+    if "`_byvars'"=="" {
+        version `caller': _eststo_store `0'
+        exit
+    }
+// --- eststo store (by) ---
+// - check sorting
+    local sortedby : sortedby
+    local i 0
+    foreach byvar of local _byvars {
+        local sortedbyi : word `++i' of `sortedby'
+        if "`byvar'"!="`sortedbyi'" error 5
+    }
+// - parse command on if qualified
+    capt _on_colon_parse `0'
+    if _rc error 190
+    if `"`s(after)'"'=="" error 190
+    local estcom `"`s(after)'"'
+    local 0 `"`s(before)'"'
+    if substr(trim(`"`estcom'"'),1,3)=="svy" {
+        di as err "svy commands not allowed with by ...: eststo:"
+        exit 190
+    }
+    AddBygrpToIfqualifier `estcom'
+// - parse syntax of _eststo_store call in order to determine
+//   whether title() or missing was specified (note that
+//   -estimates change- cannot be used to set the titles since
+//   it does not work with -noesample-)
+    TitleAndMissing `0'
+// - generate byindex
+    tempname _byindex
+    qui egen long `_byindex' = group(`_byvars'), label `missing'
+    qui su `_byindex', meanonly
+    if r(N)==0 error 2000
+    local Nby = r(max)
+// - loop over bygroups
+    forv i = 1/`Nby' {
+        local ibylab: label (`_byindex') `i'
+        di as txt _n "{hline}"
+        di as txt `"-> `ibylab'"'   // could be improved
+        if `titleopt'==0 local ibytitle
+        else if `titleopt'==1 local ibytitle `" title(`ibylab')"'
+        else if `titleopt'==2 local ibytitle `", title(`ibylab')"'
+        capture noisily {
+            version `caller': _eststo_store `0'`ibytitle' : `estcmd'
+        }
+        if _rc {
+            if "`_byrc0'"=="" error _rc
+        }
+    }
+end
+
+prog TitleAndMissing
+    capt syntax [anything] , Title(string) [ MISsing * ]
+    if _rc==0 {
+        c_local titleopt 0
+        c_local missing "`missing'"
+    }
+    else {
+        syntax [anything] [ , MISsing * ]
+        if `"`missing'`options'"'!="" c_local titleopt 1
+        else c_local titleopt 2
+        c_local missing "`missing'"
+    }
+end
+
+program AddBygrpToIfqualifier
+    syntax anything(equalok) [if/] [in] [using] [fw aw pw iw] [, * ]
+    local estcom `"`macval(anything)' if (\`_byindex'==\`i')"'
+    if `"`macval(if)'"'!="" {
+        local estcom `"`macval(estcom)' & (`macval(if)')"'
+    }
+    if `"`macval(in)'"'!="" {
+        local estcom `"`macval(estcom)' `macval(in)'"'
+    }
+    if `"`macval(using)'"'!="" {
+        local estcom `"`macval(estcom)' `macval(using)'"'
+    }
+    if `"`macval(weight)'"'!="" {
+        local estcom `"`macval(estcom)' [`macval(weight)'`macval(exp)']"'
+    }
+    if `"`macval(options)'"'!="" {
+        local estcom `"`macval(estcom)', `macval(options)'"'
+    }
+    c_local estcmd `"`macval(estcom)'"'
+end
+
+program define _eststo_clear
+    local names $eststo
+    foreach name of local names {
+        capt estimates drop `name'
+    }
+    global eststo
+    global eststo_counter
+end
+
+program define _eststo_dir
+    if `"$eststo"'!="" {
+        estimates dir $eststo
+    }
+end
+
+program define _eststo_cleanglobal
+    local enames $eststo
+    if `"`enames'"'!="" {
+        tempname hcurrent
+        _return hold `hcurrent'
+        qui _estimates dir
+        local snames `r(names)'
+        _return restore `hcurrent'
+    }
+    local names: list enames & snames
+    global eststo `names'
+    if "`names'"=="" global eststo_counter
+end
+
+program define _eststo_drop
+    local droplist `0'
+    if `"`droplist'"'=="" {
+        di as error "someting required"
+        exit 198
+    }
+    local names $eststo
+    foreach item of local droplist {
+        capt confirm integer number `item'
+        if _rc {
+            local dropname `item'
+        }
+        else {
+            if `item'<1 {
+                di as error "`item' not allowed"
+                exit 198
+            }
+            local dropname est`item'
+        }
+        local found 0
+        foreach name in `names' {
+            if match("`name'",`"`dropname'"') {
+                local found 1
+                estimates drop `name'
+                local names: list names - name
+                di as txt "(" as res "`name'" as txt " dropped)"
+            }
+        }
+        if `found'==0 {
+            di as txt "(no matches found for " as res `"`dropname'"' as txt ")"
+        }
+    }
+    global eststo `names'
+end
+
+
+program define _eststo_store, eclass
+    local caller : di _caller()
+    capt _on_colon_parse `0'
+    if !_rc {
+        local command `"`s(after)'"'
+        local 0 `"`s(before)'"'
+    }
+    syntax [name] [, ///
+        Title(passthru) ///
+        Prefix(name) ///
+        Refresh Refresh2(numlist integer max=1 >0) ///
+        ADDscalars(string asis) ///
+        noEsample ///
+        noCopy ///
+        MISsing svy /// doesn't do anything
+        ]
+    if `"`prefix'"'=="" local prefix "est"
+
+// get previous eststo names and counter
+    local names $eststo
+    local counter $eststo_counter
+    if `"`counter'"'=="" local counter 0
+
+// if name provided; set refresh on if name already in list
+    if "`namelist'"!="" {
+        if "`refresh2'"!="" {
+            di as error "refresh() not allowed"
+            exit 198
+        }
+        local name `namelist'
+        if `:list name in names' local refresh refresh
+        else {
+            if "`refresh'"!="" {
+                di as txt "(" as res "`name'" as txt " not found)"
+            }
+            local refresh
+        }
+        if "`refresh'"=="" local ++counter
+    }
+// if no name provided
+    else {
+        if "`refresh2'"!="" local refresh refresh
+        if "`refresh'"!="" {
+// refresh2 not provided => refresh last (if available)
+            if "`refresh2'"=="" {
+                if "`names'"=="" {
+                    di as txt "(nothing to refresh)"
+                    local refresh
+                }
+                else local name: word `:list sizeof names' of `names'
+            }
+// refresh2 provided => check availability
+            else {
+                if `:list posof "`prefix'`refresh2'" in names' {
+                    local name `prefix'`refresh2'
+                }
+                else {
+                    di as txt "(" as res "`prefix'`refresh2'" as txt " not found)"
+                    local refresh
+                }
+            }
+        }
+        if "`refresh'"=="" local ++counter
+// set default name
+        if "`name'"=="" local name `prefix'`counter'
+    }
+
+// run estimation command if provided
+    if `"`command'"'!="" {
+        version `caller': `command'
+    }
+
+// add scalars to e()
+    if `"`addscalars'"'!="" {
+        capt ParseAddscalars `addscalars'
+        if _rc {
+            di as err `"addscalars() invalid"'
+            exit 198
+        }
+        if "`replace'"=="" {
+            local elist `: e(scalars)' `: e(macros)' `: e(matrices)' `: e(functions)'
+        }
+        local forbidden b V sample
+        while (1) {
+            gettoken lhs rest: rest
+            if `:list lhs in forbidden' {
+                di as err `"`lhs' not allowed in addscalars()"'
+                exit 198
+            }
+            if "`replace'"=="" {
+                if `:list lhs in elist' {
+                    di as err `"e(`lhs') already defined"'
+                    exit 110
+                }
+            }
+            gettoken rhs rest: rest, bind
+            capt eret scalar `lhs' = `rhs'
+            if _rc {
+                di as err `"addscalars() invalid"'
+                exit 198
+            }
+            capture local result = e(`lhs')
+            di as txt "(e(" as res `"`lhs'"' as txt ") = " ///
+             as res `result' as txt " added)"
+            if `"`rest'"'=="" continue, break
+        }
+    }
+// add e(cmd) if missing
+    if `"`e(cmd)'"'=="" {
+        if `"`: e(scalars)'`: e(macros)'`: e(matrices)'`: e(functions)'"'!="" {
+            eret local cmd "."
+        }
+    }
+
+// store estimates with e(sample)
+    estimates store `name' , `copy' `title'
+
+// remove e(sample) if -noesample- specified
+    if "`esample'"!="" {
+        capt confirm new var _est_`name'
+        if _rc {
+            tempname hcurrent
+            _est hold `hcurrent', restore estsystem nullok
+            qui replace _est_`name' = . in 1
+            _est unhold `name'
+            capt confirm new var _est_`name'
+            if _rc qui drop _est_`name'
+            else {
+                di as error "somethings wrong; please contact author of -eststo- " ///
+                 "(see e-mail in help {help eststo})"
+                exit 498
+            }
+            _est hold `name', estimates varname(_est_`name')
+                // varname() only needed so that _est hold does not return error
+                // if variable `name' exists
+        }
+    }
+
+// report
+    if "`refresh'"=="" {
+        global eststo `names' `name'
+        global eststo_counter `counter'
+        if `"`namelist'"'=="" {
+            di as txt "(" as res "`name'" as txt " stored)"
+        }
+    }
+    else {
+        if `"`namelist'"'=="" {
+            di as txt "(" as res "`name'" as txt " refreshed)"
+        }
+    }
+end
+
+program ParseAddscalars
+    syntax anything [ , Replace ]
+    c_local rest `"`anything'"'
+    c_local replace `replace'
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/e/eststo.hlp

@@ -0,0 +1,347 @@
+{smcl}
+{* 13sep2013}{...}
+{hi:help eststo}{right:also see: {helpb esttab}, {helpb estout}, {helpb estadd}, {helpb estpost}}
+{right: {browse "http://repec.org/bocode/e/estout"}}
+{hline}
+
+{title:Title}
+
+{p 4 4 2}{hi:eststo} {hline 2} Store estimates
+
+
+{title:Syntax}{smcl}
+
+{p 8 15 2}
+[{cmd:_}]{cmd:eststo} [{it:name}]
+[{cmd:,} {it:{help eststo##options:options}} ]
+[ {cmd::} {it:{help estimation_command}} ]
+
+{p 8 15 2}
+[{cmd:_}]{cmd:eststo dir}
+
+{p 8 15 2}
+[{cmd:_}]{cmd:eststo drop} {{it:#}|{it:name}} [ {{it:#}|{it:name}} ... ]
+
+{p 8 15 2}
+[{cmd:_}]{cmd:eststo clear}
+
+{marker options}
+    {it:options}{col 23}description
+    {hline 56}
+    [{ul:{cmd:no}}]{cmdab:e:sample}{col 23}{...}
+do not/do store {cmd:e(sample)}
+    {cmdab:t:itle:(}{it:string}{cmd:)}{col 23}{...}
+specify a title for the stored set
+    {cmdab:p:refix:(}{it:prefix}{cmd:)}{col 23}{...}
+specify a name prefix; default is {cmd:est}
+    {cmdab:add:scalars(}{it:...}{cmd:)}{col 23}{...}
+add scalar statistics
+    {cmdab:r:efresh}[{cmd:(}{it:#}{cmd:)}]{col 23}{...}
+overwrite a previously stored set
+    {cmdab:noc:opy}{col 23}{...}
+clear {cmd:e()} after storing the set
+    {cmdab:mis:sing}{col 23}{...}
+use missing values in the {cmd:by} groups
+    {hline 56}
+        
+{p 4 4 2}
+{cmd:by} is allowed with {cmd:eststo} if {cmd:eststo} 
+is used as a prefix command, i.e. specify
+
+        {cmd:by} {it:...} {cmd::} {cmd:eststo} {it:...} {cmd::} {it:estimation_command}
+        
+{p 4 4 2}
+to apply {it:estimation_command} to each {cmd:by} group and store an estimation
+set for each group; see help {help by}. Note that the implementation of {cmd:by} 
+with {cmd:eststo} requires {it:estimation_command} 
+to follow {help language:standard Stata syntax} and 
+allow the {it:{help if}} qualifier. Do not use the 
+{bind:{cmd:by} {it:...}{cmd:: eststo:}} construct with
+{cmd:svy} commands.   
+
+
+{title:Description}
+
+{p 4 4 2}
+{cmd:eststo} stores a  copy of the active estimation results for later
+tabulation. If {it:name} is provided, the estimation set is stored
+under {it:name}. If {it:name} is not provided, the estimation set is
+stored under {cmd:est}{it:#}, where {it:#} is a counter for the
+number of stored estimation sets.  
+
+{p 4 4 2}
+{cmd:eststo} may be used in two ways: Either after fitting a model as
+in
+
+        {com}. regress y x
+        . eststo{txt}
+
+{p 4 4 2}
+or as a prefix command (see help {help prefix}):
+
+        {com}. eststo: regress y x{txt}
+
+{p 4 4 2}
+{cmd:_eststo} is a variant on {cmd:eststo} that, by default, does not
+store the estimation sample information contained in {cmd:e(sample)}.
+Essentially, {cmd:_eststo} is a shortcut to {cmd:eststo, noesample}.
+
+{p 4 4 2}
+{cmd:eststo dir} displays a list of the stored estimates.
+
+{p 4 4 2}
+{cmd:eststo drop} drops estimation sets stored by {cmd:eststo}. If {it:name} is
+provided, the estimation set stored under {it:name}
+is dropped (if {cmd:*} or {cmd:?} wildcards are used {it:name}, 
+all matching sets are dropped). Alternatively, if {it:#} is provided, 
+the estimation set stored as {cmd:est}{it:#} is dropped.
+
+{p 4 4 2}
+{cmd:eststo clear} drops all estimation sets stored by {cmd:eststo} (and clears
+{cmd:eststo}'s global macros).
+
+{p 4 4 2}
+{cmd:eststo} is an alternative to official Stata's
+{helpb estimates store}. The main differences are:
+
+{p 8 12 2}
+{space 1}o{space 2}{cmd:eststo} does not require the user to specify a
+name for the stored estimation set.
+
+{p 8 12 2}
+{space 1}o{space 2}{cmd:eststo} may be used as a prefix command (see
+help {help prefix}).
+
+{p 8 12 2}
+{space 1}o{space 2}{cmd:eststo} provides the possibility to store
+estimates without the {cmd:e(sample)} function (either specify the
+{cmd:noesample} option or use the {cmd:_eststo} command). Omitting
+{cmd:e(sample)} saves memory and also speeds up tabulation programs
+such as {helpb estimates table}, {helpb estout} or {helpb esttab}.
+{hi:Warning:} Some post-estimation commands may not work with
+estimation sets that do not contain the {cmd:e(sample)}.
+
+{p 8 12 2}
+{space 1}o{space 2}{cmd:eststo} can add additional scalar statistics to
+be stored with the estimation set.
+
+
+{title:Options}
+{marker esample}
+{p 4 8 2}
+{cmd:esample} causes the information in {cmd:e(sample)} to be stored
+with the estimates. This is the default in {cmd:eststo}. Type
+{cmd:noesample} or use the {cmd:_eststo} command to omit the
+{cmd:e(sample)}. Note that some post-estimation commands may not be
+working correctly with estimation sets that have been stored without
+{cmd:e(sample)}.
+
+{p 4 8 2}
+{cmd:title(}{it:string}{cmd:)} specifies a title for the stored
+estimation set.
+{p_end}
+{marker addscalars}
+{p 4 8 2}
+{cmd:addscalars(}{it:name exp} [{it:...}] [{cmd:,} {cmdab:r:eplace}]{cmd:)}
+may be used to add additional results to the {cmd:e()}-scalars of the
+estimation set before storing it. Specify the names and values of the
+scalars in pairs. For example, {cmd:addscalars(one 1 two 2)} would
+add {cmd:e(one)} = {cmd:1} and {cmd:e(two)} = {cmd:2}. See below for
+an example. The {cmd:replace} suboption permits overwriting existing
+{cmd:e()}-returns. Not allowed as names are "b", "V", or "sample".
+See {helpb estadd} for a more sophisticated tool to add additional
+results to {cmd:e()}-returns.
+
+{p 4 8 2}
+{cmd:prefix(}{it:prefix}{cmd:)} specifies a custom prefix for the 
+automatic names of the stored estimation sets. The default prefix 
+is {cmd:est}. 
+
+{p 4 8 2}
+{cmd:refresh}[{cmd:(}{it:#}{cmd:)}] may be used to overwrite a
+previously stored estimation set instead of storing the estimates
+under a new name. {cmd:refresh}, specified without argument, will
+overwrite the last saved set. Alternatively,
+{cmd:refresh(}{it:#}{cmd:)} will overwrite the set named
+{cmd:est}{it:#} if it exists. If {it:name} is provided to {cmd:eststo},
+existing sets of the same name will always be overwritten whether or
+not {cmd:refresh} is specified. {cmd:refresh()} with argument is not
+allowed in this case.
+
+{p 4 8 2}
+{cmd:nocopy} specifies that after the estimation set has been stored,
+it no longer be available as the active estimation set.
+
+{p 4 8 2}
+{cmd:missing} is for use of {cmd:eststo} with the {cmd:by} prefix command and 
+causes missing values to be treated like any other values in the {cmd:by} 
+variables. The default is to discard observations with missing values in the 
+{cmd:by} variables.
+
+
+{title:Examples}
+
+{p 4 4 2}
+Applying {cmd:eststo} after fiting a model to store the model's results, 
+as in the following example:
+
+        {com}. sysuse auto
+        {txt}(1978 Automobile Data)
+        
+        {com}. quietly regress price weight
+        {txt}
+        {com}. eststo model1
+        {txt}
+        {com}. quietly regress turn weight foreign
+        {txt}
+        {com}. eststo model2
+        {txt}
+        {com}. estout
+        {res}
+        {txt}{hline 38}
+        {txt}                   model1       model2
+        {txt}                        b            b
+        {txt}{hline 38}
+        {txt}weight      {res}     2.044063     .0042183{txt}
+        {txt}foreign     {res}                 -1.809802{txt}
+        {txt}_cons       {res}    -6.707353     27.44963{txt}
+        {txt}{hline 38}
+
+
+{p 4 4 2}
+Applying {cmd:eststo} as a prefix commmand to fit and store a model in one step:
+
+        {com}. eststo model1: quietly regress price weight
+        {txt}
+        {com}. eststo model2: quietly regress turn weight foreign
+        {txt}
+        {com}. estout
+        {res}
+        {txt}{hline 38}
+        {txt}                   model1       model2
+        {txt}                        b            b
+        {txt}{hline 38}
+        {txt}weight      {res}     2.044063     .0042183{txt}
+        {txt}foreign     {res}                 -1.809802{txt}
+        {txt}_cons       {res}    -6.707353     27.44963{txt}
+        {txt}{hline 38}
+        
+        
+{p 4 4 2}
+Using {cmd:eststo} with automatic names:
+
+        {com}. eststo clear
+        {txt}
+        {com}. eststo: quietly regress price weight
+        {txt}({res}est1{txt} stored)
+        
+        {com}. eststo: quietly regress turn weight foreign
+        {txt}({res}est2{txt} stored)
+        
+        {com}. estout
+        {res}
+        {txt}{hline 38}
+        {txt}                     est1         est2
+        {txt}                        b            b
+        {txt}{hline 38}
+        {txt}weight      {res}     2.044063     .0042183{txt}
+        {txt}foreign     {res}                 -1.809802{txt}
+        {txt}_cons       {res}    -6.707353     27.44963{txt}
+        {txt}{hline 38}
+        
+
+{p 4 4 2}
+Adding ancillary statistics:
+
+        {com}. eststo clear
+        {txt}
+        {com}. quietly regress price weight mpg
+        {txt}
+        {com}. test weight = mpg
+        
+        {txt} ( 1)  {res}weight - mpg = 0
+        
+        {txt}       F(  1,    71) ={res}    0.36
+        {txt}{col 13}Prob > F ={res}    0.5514
+        {txt}
+        {com}. eststo, add(p_diff r(p))
+        {txt}(e({res}p_diff{txt}) = {res}.55138216{txt} added)
+        ({res}est1{txt} stored)
+        
+        {com}. estout, stat(p_diff)
+        {res}
+        {txt}{hline 25}
+        {txt}                     est1
+        {txt}                        b
+        {txt}{hline 25}
+        {txt}weight      {res}     1.746559{txt}
+        {txt}mpg         {res}    -49.51222{txt}
+        {txt}_cons       {res}     1946.069{txt}
+        {txt}{hline 25}
+        {txt}p_diff      {res}     .5513822{txt}
+        {txt}{hline 25}
+        
+
+{p 4 4 2}
+Using the {cmd:by} prefix to store subbroup models:
+
+        {com}. eststo clear
+        {txt}
+        {com}. quietly by foreign: eststo: quietly reg price weight mpg
+        {txt}
+        {com}. esttab, label nodepvar nonumber
+        {res}
+        {txt}{hline 52}
+        {txt}                         Domestic         Foreign   
+        {txt}{hline 52}
+        {txt}Weight (lbs.)       {res}        4.415***        5.156***{txt}
+                            {res} {ralign 12:{txt:(}4.66{txt:)}}    {ralign 12:{txt:(}5.85{txt:)}}   {txt}
+        
+        {txt}Mileage (mpg)       {res}        237.7          -19.78   {txt}
+                            {res} {ralign 12:{txt:(}1.71{txt:)}}    {ralign 12:{txt:(}-0.34{txt:)}}   {txt}
+        
+        {txt}Constant            {res}     -13285.4*        -5065.8   {txt}
+                            {res} {ralign 12:{txt:(}-2.32{txt:)}}    {ralign 12:{txt:(}-1.58{txt:)}}   {txt}
+        {txt}{hline 52}
+        {txt}Observations        {res}           52              22   {txt}
+        {txt}{hline 52}
+        {txt}t statistics in parentheses
+        {txt}* p<0.05, ** p<0.01, *** p<0.001
+
+
+{title:Returned results}
+
+{p 4 4 2}
+The name under which an estimation set is stored, is added to the set in 
+{cmd:e(_estimates_name)}.
+
+{p 4 4 2}
+In addition, {cmd:eststo} maintains two global macros. {cmd:$eststo} contains a list
+of the names of the stored estimation sets. {cmd:$eststo_counter}
+contains the count of stored estimation sets.
+
+
+{title:Acknowledgements}
+
+{p 4 4 2}
+Bill Gould suggested to make {cmd:eststo} "byable". 
+
+
+{title:Author}
+
+{p 4 4 2}
+Ben Jann, Institute of Sociology, University of Bern, [email protected]
+
+
+{title:Also see}
+
+    Manual:  {hi:[R] estimates}
+
+{p 4 13 2}Online:  help for
+ {helpb estimates},
+ {helpb esttab},
+ {helpb estout},
+ {helpb estadd},
+ {helpb estpost}
+{p_end}
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/e/esttab.ado

@@ -0,0 +1,1209 @@
+*! version 2.0.6  02jun2014  Ben Jann
+*! wrapper for estout
+
+program define esttab
+    version 8.2
+    local caller : di _caller()
+
+// mode specific defaults
+    local cdate "`c(current_date)'"
+    local ctime "`c(current_time)'"
+// - fixed
+    local fixed_open0         `""% `cdate' `ctime'""'
+    local fixed_close0        `""""'
+    local fixed_open          `""'
+    local fixed_close         `""'
+    local fixed_caption       `""@title""'
+    local fixed_open2         `""'
+    local fixed_close2        `""'
+    local fixed_toprule       `""@hline""'
+    local fixed_midrule       `""@hline""'
+    local fixed_bottomrule    `""@hline""'
+    local fixed_topgap        `""""'
+    local fixed_midgap        `""""'
+    local fixed_bottomgap     `""""'
+    local fixed_eqrule        `"begin(@hline "")"'
+    local fixed_ssl           `"N R-sq "adj. R-sq" "pseudo R-sq" AIC BIC"'
+    local fixed_lsl           `"Observations R-squared "Adjusted R-squared" "Pseudo R-squared" AIC BIC"'
+    local fixed_starlevels    `"* 0.05 ** 0.01 *** 0.001"'
+    local fixed_starlevlab    `""'
+    local fixed_begin         `""'
+    local fixed_delimiter     `"" ""'
+    local fixed_end           `""'
+    local fixed_incelldel     `"" ""'
+    local fixed_varwidth      `"\`= cond("\`label'"=="", 12, 20)'"'
+    local fixed_modelwidth    `"12"'
+    local fixed_abbrev        `"abbrev"'
+    local fixed_substitute    `""'
+    local fixed_interaction   `"" # ""'
+    local fixed_tstatlab      `"t statistics"'
+    local fixed_zstatlab      `"z statistics"'
+    local fixed_pvallab       `"p-values"'
+    local fixed_cilab         `"\`level'% confidence intervals"'
+// - smcl
+    local smcl_open0          `"{smcl} "{* % `cdate' `ctime'}{...}""'
+    local smcl_close0         `""""'
+    local smcl_open           `""'
+    local smcl_close          `""'
+    local smcl_caption        `""@title""'
+    local smcl_open2          `""'
+    local smcl_close2         `""'
+    local smcl_toprule        `""{hline @width}""'
+    local smcl_midrule        `""{hline @width}""'
+    local smcl_bottomrule     `""{hline @width}""'
+    local smcl_topgap         `""""'
+    local smcl_midgap         `""""'
+    local smcl_bottomgap      `""""'
+    local smcl_eqrule         `"begin("{hline @width}" "")"'
+    local smcl_ssl            `"`macval(fixed_ssl)'"'
+    local smcl_lsl            `"`macval(fixed_lsl)'"'
+    local smcl_starlevels     `"`macval(fixed_starlevels)'"'
+    local smcl_starlevlab     `""'
+    local smcl_begin          `""'
+    local smcl_delimiter      `"" ""'
+    local smcl_end            `""'
+    local smcl_incelldel      `"" ""'
+    local smcl_varwidth       `"`macval(fixed_varwidth)'"'
+    local smcl_modelwidth     `"`macval(fixed_modelwidth)'"'
+    local smcl_abbrev         `"`macval(fixed_abbrev)'"'
+    local smcl_substitute     `""'
+    local smcl_interaction    `"" # ""'
+    local smcl_tstatlab       `"`macval(fixed_tstatlab)'"'
+    local smcl_zstatlab       `"`macval(fixed_zstatlab)'"'
+    local smcl_pvallab        `"`macval(fixed_pvallab)'"'
+    local smcl_cilab          `"`macval(fixed_cilab)'"'
+// - tab
+    local tab_open0           `"`macval(fixed_open0)'"'
+    local tab_close0          `""""'
+    local tab_open            `""'
+    local tab_close           `""'
+    local tab_caption         `""@title""'
+    local tab_open2           `""'
+    local tab_close2          `""'
+    local tab_topgap          `""""'
+    local tab_midgap          `""""'
+    local tab_bottomgap       `""""'
+    local tab_ssl             `"`macval(fixed_ssl)'"'
+    local tab_lsl             `"`macval(fixed_lsl)'"'
+    local tab_starlevels      `"`macval(fixed_starlevels)'"'
+    local tab_starlevlab      `""'
+    local tab_begin           `""'
+    local tab_delimiter       `"_tab"'
+    local tab_end             `""'
+    local tab_incelldel       `"" ""'
+    local tab_varwidth        `""'
+    local tab_modelwidth      `""'
+    local tab_abbrev          `""'
+    local tab_substitute      `""'
+    local tab_interaction     `"" # ""'
+    local tab_tstatlab        `"`macval(fixed_tstatlab)'"'
+    local tab_zstatlab        `"`macval(fixed_zstatlab)'"'
+    local tab_pvallab         `"`macval(fixed_pvallab)'"'
+    local tab_cilab           `"`macval(fixed_cilab)'"'
+// - csv
+    local csv_open0           `"`"\`csvlhs'% `cdate' `ctime'""'"'
+    local csv_close0          `""""'
+    local csv_open            `""'
+    local csv_close           `""'
+    local csv_caption         `"`"\`csvlhs'@title""'"'
+    local csv_open2           `""'
+    local csv_close2          `""'
+    local csv_topgap          `""""'
+    local csv_midgap          `""""'
+    local csv_bottomgap       `""""'
+    local csv_ssl             `"`macval(fixed_ssl)'"'
+    local csv_lsl             `"`macval(fixed_lsl)'"'
+    local csv_starlevels      `"`macval(fixed_starlevels)'"'
+    local csv_starlevlab      `""'
+    local csv_begin           `"`"\`csvlhs'"'"'
+    local csv_delimiter       `"`"",\`csvlhs'"'"'
+    local scsv_delimiter      `"`"";\`csvlhs'"'"'
+    local csv_end             `"`"""'"'
+    local csv_incelldel       `"" ""'
+    local csv_varwidth        `""'
+    local csv_modelwidth      `""'
+    local csv_abbrev          `""'
+    local csv_substitute      `""'
+    local csv_interaction     `"" # ""'
+    local csv_tstatlab        `"`macval(fixed_tstatlab)'"'
+    local csv_zstatlab        `"`macval(fixed_zstatlab)'"'
+    local csv_pvallab         `"`macval(fixed_pvallab)'"'
+    local csv_cilab           `"`macval(fixed_cilab)'"'
+// - rtf
+    local rtf_open0           `""'
+    local rtf_close0          `""'
+      local rtf_ct            `"\yr`=year(d(`cdate'))'\mo`=month(d(`cdate'))'\dy`=day(d(`cdate'))'\hr`=substr("`ctime'",1,2)'\min`=substr("`ctime'",4,2)'"'
+      local rtf_open_l1       `"`"{\rtf1`=cond("`c(os)'"=="MacOSX", "\mac", "\ansi")'\deff0 {\fonttbl{\f0\fnil Times New Roman;}}"'"'
+      local rtf_open_l2       `" `"{\info {\author .}{\company .}{\title .}{\creatim`rtf_ct'}}"'"'
+      local rtf_open_l3       `" `"\deflang1033\plain\fs24"'"'
+      local rtf_open_l4       `" `"{\footer\pard\qc\plain\f0\fs24\chpgn\par}"'"'
+    local rtf_open            `"`rtf_open_l1'`rtf_open_l2'`rtf_open_l3'`rtf_open_l4'"'
+    local rtf_close           `""{\pard \par}" "}""'
+    local rtf_caption         `"`"{\pard\keepn\ql @title\par}"'"'
+    local rtf_open2           `""{""'
+    local rtf_close2          `""}""'
+    local rtf_toprule         `""'
+    local rtf_midrule         `""'
+    local rtf_bottomrule      `""'
+    local rtf_topgap          `""'
+    local rtf_midgap          `"{\trowd\trgaph108\trleft-108@rtfemptyrow\row}"'
+    local rtf_bottomgap       `""'
+    local rtf_eqrule          `"begin("{\trowd\trgaph108\trleft-108@rtfrowdefbrdrt\pard\intbl\ql {") replace"'
+    local rtf_ssl             `""{\i N}" "{\i R}{\super 2}" "adj. {\i R}{\super 2}" "pseudo {\i R}{\super 2}" "{\i AIC}" "{\i BIC}""'
+    local rtf_lsl             `"Observations "{\i R}{\super 2}" "Adjusted {\i R}{\super 2}" "Pseudo {\i R}{\super 2}" "{\i AIC}" "{\i BIC}""'
+    local rtf_starlevels      `""{\super *}" 0.05 "{\super **}" 0.01 "{\super ***}" 0.001"'
+    local rtf_starlevlab      `", label(" {\i p} < ")"'
+      local rtf_rowdef        `"\`=cond("\`lines'"=="", "@rtfrowdef", "@rtfrowdefbrdr")'"'
+    local rtf_begin           `"{\trowd\trgaph108\trleft-108\`rtf_rowdef'\pard\intbl\ql {"'
+    local rtf_delimiter       `"}\cell \pard\intbl\q\`=cond(`"\`alignment'"'!="", `"\`alignment'"', "c")' {"'
+    local rtf_end             `"}\cell\row}"'
+    local rtf_incelldel       `""\line ""'
+    local rtf_varwidth        `"\`= cond("\`label'"=="", 12, 20)'"'
+    local rtf_modelwidth      `"12"'
+    local rtf_abbrev          `""'
+    local rtf_substitute      `""'
+    local rtf_interaction     `"" # ""'
+    local rtf_tstatlab        `"{\i t} statistics"'
+    local rtf_zstatlab        `"{\i z} statistics"'
+    local rtf_pvallab         `"{\i p}-values"'
+    local rtf_cilab           `"\`level'% confidence intervals"'
+// - html
+    local html_open0          `"<html> <head> "<title>`=cond(`"\`macval(title)'"'=="","estimates table, created `cdate' `ctime'","@title")'</title>" </head> <body> """'
+    local html_close0         `""" </body> </html> """'
+    local html_open           `"`"<table border="0" width="\`=cond("\`width'"=="","*","\`width'")'">"'"'
+    local html_close          `""</table>""'
+    local html_caption        `""<caption>@title</caption>""'
+    local html_open2          `""'
+    local html_close2         `""'
+    local html_toprule        `""<tr><td colspan=@span><hr></td></tr>""'
+    local html_midrule        `""<tr><td colspan=@span><hr></td></tr>""'
+    local html_bottomrule     `""<tr><td colspan=@span><hr></td></tr>""'
+    local html_topgap         `""'
+    local html_midgap         `""<tr><td colspan=@span>&nbsp;</td></tr>""'
+    local html_bottomgap      `""'
+    local html_eqrule         `"begin("<tr><td colspan=@span><hr></td></tr>" "")"'
+    local html_ssl            `"<i>N</i> <i>R</i><sup>2</sup> "adj. <i>R</i><sup>2</sup>" "pseudo <i>R</i><sup>2</sup>" <i>AIC</i> <i>BIC</i>"'
+    local html_lsl            `"Observations <i>R</i><sup>2</sup> "Adjusted <i>R</i><sup>2</sup>" "Pseudo <i>R</i><sup>2</sup>" <i>AIC</i> <i>BIC</i>"'
+    local html_starlevels     `"<sup>*</sup> 0.05 <sup>**</sup> 0.01 <sup>***</sup> 0.001"'
+    local html_starlevlab     `", label(" <i>p</i> < ")"'
+    local html_begin          `"<tr><td>"'
+    local html_delimiter      `"</td><td\`=cond(`"\`alignment'"'!="", `" align="\`alignment'""', "")'>"'
+    local html_end            `"</td></tr>"'
+    local html_incelldel      `"<br />"'
+    local html_varwidth       `"\`= cond("\`label'"=="", 12, 20)'"'
+    local html_modelwidth     `"12"'
+    local html_abbrev         `""'
+    local html_substitute     `""'
+    local html_interaction    `"" # ""'
+    local html_tstatlab       `"<i>t</i> statistics"'
+    local html_zstatlab       `"<i>z</i> statistics"'
+    local html_pvallab        `"<i>p</i>-values"'
+    local html_cilab          `"\`level'% confidence intervals"'
+// - tex
+    local tex_open0           `""% `cdate' `ctime'" \documentclass{article} \`texpkgs' \`=cond("\`longtable'"!="","\usepackage{longtable}","")' \begin{document} """'
+    local tex_close0          `""" \end{document} """'
+    local tex_open            `"\`=cond("\`longtable'"=="", "\begin{table}[htbp]\centering", `"{"')'"'
+    local tex_close           `"\`=cond("\`longtable'"=="", "\end{table}", "}")'"'
+    local tex_caption         `"\caption{@title}"'
+    local tex_open2           `"\`=cond("\`longtable'"!="", "\begin{longtable}", "\begin{tabular" + cond("\`width'"=="", "}", "*}{\`width'}"))'"'
+    local tex_close2          `"\`=cond("\`longtable'"!="", "\end{longtable}", "\end{tabular" + cond("\`width'"=="", "}", "*}"))'"'
+    local tex_toprule         `"\`="\hline\hline" + cond("\`longtable'"!="", "\endfirsthead\hline\endhead\hline\endfoot\endlastfoot", "")'"'
+    local tex_midrule         `""\hline""'
+    local tex_bottomrule      `""\hline\hline""'
+    local tex_topgap          `""'
+    local tex_midgap          `"[1em]"' // `"\\\"'
+    local tex_bottomgap       `""'
+    local tex_eqrule          `"begin("\hline" "")"'
+    local tex_ssl             `"\(N\) \(R^{2}\) "adj. \(R^{2}\)" "pseudo \(R^{2}\)" \textit{AIC} \textit{BIC}"'
+    local tex_lsl             `"Observations \(R^{2}\) "Adjusted \(R^{2}\)" "Pseudo \(R^{2}\)" \textit{AIC} \textit{BIC}"'
+    local tex_starlevels      `"\sym{*} 0.05 \sym{**} 0.01 \sym{***} 0.001"'
+    local tex_starlevlab      `", label(" \(p<@\)")"'
+    local tex_begin           `""'
+    local tex_delimiter       `"&"'
+    local tex_end             `"\\\"'
+    local tex_incelldel       `"" ""'
+    local tex_varwidth        `"\`= cond("\`label'"=="", 12, 20)'"'
+    local tex_modelwidth      `"12"'
+    local tex_abbrev          `""'
+    local tex_tstatlab        `"\textit{t} statistics"'
+    local tex_zstatlab        `"\textit{z} statistics"'
+    local tex_pvallab         `"\textit{p}-values"'
+    local tex_cilab           `"\`level'\% confidence intervals"'
+    local tex_substitute      `"_ \_ "\_cons " \_cons"'
+    local tex_interaction     `"" $\times$ ""'
+// - booktabs
+    local booktabs_open0      `""% `cdate' `ctime'" \documentclass{article} \`texpkgs' \usepackage{booktabs} \`=cond("\`longtable'"!="","\usepackage{longtable}","")' \begin{document} """'
+    local booktabs_close0     `"`macval(tex_close0)'"'
+    local booktabs_open       `"`macval(tex_open)'"'
+    local booktabs_close      `"`macval(tex_close)'"'
+    local booktabs_caption    `"`macval(tex_caption)'"'
+    local booktabs_open2      `"`macval(tex_open2)'"'
+    local booktabs_close2     `"`macval(tex_close2)'"'
+    local booktabs_toprule    `"\`="\toprule" + cond("\`longtable'"!="", "\endfirsthead\midrule\endhead\midrule\endfoot\endlastfoot", "")'"'
+    local booktabs_midrule    `""\midrule""'
+    local booktabs_bottomrule `""\bottomrule""'
+    local booktabs_topgap     `"`macval(tex_topgap)'"'
+    local booktabs_midgap     `"\addlinespace"'
+    local booktabs_bottomgap  `"`macval(tex_bottomgap)'"'
+    local booktabs_eqrule     `"begin("\midrule" "")"'
+    local booktabs_ssl        `"`macval(tex_ssl)'"'
+    local booktabs_lsl        `"`macval(tex_lsl)'"'
+    local booktabs_starlevels `"`macval(tex_starlevels)'"'
+    local booktabs_starlevlab `"`macval(tex_starlevlab)'"'
+    local booktabs_begin      `"`macval(tex_begin)'"'
+    local booktabs_delimiter  `"`macval(tex_delimiter)'"'
+    local booktabs_end        `"`macval(tex_end)'"'
+    local booktabs_incelldel  `"`macval(tex_incelldel)'"'
+    local booktabs_varwidth   `"`macval(tex_varwidth)'"'
+    local booktabs_modelwidth `"`macval(tex_modelwidth)'"'
+    local booktabs_abbrev     `"`macval(tex_abbrev)'"'
+    local booktabs_tstatlab   `"`macval(tex_tstatlab)'"'
+    local booktabs_zstatlab   `"`macval(tex_zstatlab)'"'
+    local booktabs_pvallab    `"`macval(tex_pvallab)'"'
+    local booktabs_cilab      `"`macval(tex_cilab)'"'
+    local booktabs_substitute `"`macval(tex_substitute)'"'
+    local booktabs_interaction `"`macval(tex_interaction)'"'
+
+// syntax
+    syntax [anything] [using] [ , ///
+ /// coefficients and t-stats, se, etc.
+     b Bfmt(string) ///
+     noT Tfmt(string) ///
+     z Zfmt(string) ///
+     se SEfmt(string) ///
+     p Pfmt(string) ///
+     ci CIfmt(string) ///
+     BEta BEtafmt(string) ///
+     main(string) /// syntax: name format
+     aux(string) /// syntax: name format
+     abs  /// absolute t-values
+     wide ///
+     NOSTAr STAR STAR2(string asis) ///
+     staraux ///
+     NOCONstant CONstant ///
+     COEFlabels(string asis) ///
+ /// summary statistics
+     noOBS obslast ///
+     r2 R2fmt(string) ar2 AR2fmt(string) pr2 PR2fmt(string) ///
+     aic AICfmt(string) bic BICfmt(string) ///
+     SCAlars(string asis) /// syntax: "name1 [label1]" "name2 [label2]" etc.
+     sfmt(string) ///
+ /// layout
+     NOMTItles MTItles MTItles2(string asis) ///
+     NOGAPs GAPs ///
+     NOLInes LInes ///
+     ADDNotes(string asis) ///
+     COMpress ///
+     plain ///
+     smcl FIXed tab csv SCsv rtf HTMl tex BOOKTabs ///
+     Fragment ///
+     page PAGE2(str) ///
+     ALIGNment(str asis) ///
+     width(str asis) ///
+ /// other
+     Noisily ///
+     * ]
+    _more_syntax , `macval(options)'
+    _estout_options , `macval(options)'
+
+// matrix mode
+    MatrixMode, `anything'
+
+// syntax consistency etc
+    gettoken chunk using0: using
+    if `"`macval(star2)'"'!="" local star star
+    foreach opt in constant gaps lines star abbrev depvars numbers parentheses ///
+        notes mtitles type outfilenoteoff {
+        NotBothAllowed "``opt''" `no`opt''
+    }
+    NotBothAllowed "`staraux'" `nostar'
+    if `"`macval(mtitles2)'"'!="" NotBothAllowed "mtitles" `nomtitles'
+    if `"`page2'"'!=""   local page page
+    NotBothAllowed "`fragment'" `page'
+    if `"`pfmt'"'!=""    local p p
+    if `"`zfmt'"'!=""    local z z
+    if `"`sefmt'"'!=""   local se se
+    if `"`cifmt'"'!=""   local ci ci
+    if `"`betafmt'"'!="" local beta beta
+    if "`level'"==""     local level $S_level
+    if ((("`margin'"!="" | `"`margin2'"'!="") & "`nomargin'"=="") | ///
+       ("`beta'"!="") | ("`eform'"!="" & "`noeform'"=="")) ///
+       & "`constant'"==""  local noconstant noconstant
+    if `"`r2fmt'"'!="" local r2 r2
+    if `"`ar2fmt'"'!="" local ar2 ar2
+    if `"`pr2fmt'"'!="" local pr2 pr2
+    if `"`aicfmt'"'!="" local aic aic
+    if `"`bicfmt'"'!="" local bic bic
+    if "`type'"=="" & `"`using'"'!="" local notype notype
+    local nocellsopt = `"`macval(cells)'"'==""
+    if `"`width'"'!="" & `"`longtable'"'!="" {
+        di as err "width() and longtable not both allowed"
+        exit 198
+    }
+
+// format modes
+    local mode `smcl' `fixed' `tab' `csv' `scsv' `rtf' `html' `tex' `booktabs'
+    if `:list sizeof mode'>1 {
+        di as err "only one allowed of smcl, fixed, tab, csv, scsv, rtf, html, tex, or booktabs"
+        exit 198
+    }
+    if `"`using'"'!="" {
+        _getfilename `"`using0'"'
+        local fn `"`r(filename)'"'
+        _getfilesuffix `"`fn'"'
+        local suffix `"`r(suffix)'"'
+    }
+    if "`mode'"=="" {
+        if `"`using'"'!="" {
+            if inlist(`"`suffix'"', ".html", ".htm") local mode html
+            else if `"`suffix'"'==".tex"             local mode tex
+            else if `"`suffix'"'==".csv"             local mode csv
+            else if `"`suffix'"'==".rtf"             local mode rtf
+            else if `"`suffix'"'==".smcl"            local mode smcl
+            else local mode fixed
+        }
+        else local mode smcl
+    }
+    else {
+        if "`mode'"=="scsv" {
+            local csv_delimiter `"`macval(`mode'_delimiter)'"'
+            local mode "csv"
+        }
+    }
+    if `"`using'"'!="" & `"`suffix'"'=="" {
+        if inlist("`mode'","fixed","tab")         local suffix ".txt"
+        else if inlist("`mode'","csv","scsv")     local suffix ".csv"
+        else if "`mode'"=="rtf"                   local suffix ".rtf"
+        else if "`mode'"=="html"                  local suffix ".html"
+        else if inlist("`mode'","tex","booktabs") local suffix ".tex"
+        else if "`mode'"=="smcl"                  local suffix ".smcl"
+        local using `"using `"`fn'`suffix'"'"'
+        local using0 `" `"`fn'`suffix'"'"'
+    }
+    if "`mode'"=="smcl" local smcltags smcltags
+    local mode0 `mode'
+    if "`mode0'"=="booktabs" local mode0 tex
+    else if "`mode0'"=="csv" {
+        if "`plain'"=="" local csvlhs `"=""'
+        else local csvlhs `"""'
+    }
+    if "`compress'"!="" {
+        if "``mode'_modelwidth'"!="" {
+            local `mode'_modelwidth = ``mode'_modelwidth' - 3
+        }
+        if "``mode'_varwidth'"!="" {
+            local `mode'_varwidth = ``mode'_varwidth' - cond("`label'"!="", 4, 2)
+        }
+    }
+    if `"`modelwidth'"'=="" {
+        if `nocellsopt' & `"``mode'_modelwidth'"'!="" & "`ci'"!="" {
+            local modelwidth = 2*``mode'_modelwidth' - 2
+            if "`wide'"!="" local modelwidth "``mode'_modelwidth' `modelwidth'"
+        }
+        else {
+            local modelwidth "``mode'_modelwidth'"
+        }
+    }
+    if `"`varwidth'"'=="" {
+        local varwidth "``mode'_varwidth'"
+    }
+    if "`plain'"=="" & `matrixmode'==0 {
+        foreach opt in star depvars numbers parentheses notes {
+            SwitchOnIfEmpty `opt' `no`opt''
+        }
+        if "`wide'"=="" & ("`t'"=="" | "`z'`se'`p'`ci'`aux'"!="") & `nocellsopt'==1 ///
+         SwitchOnIfEmpty gaps `nogaps'
+    }
+    if "`plain'"=="" {
+        SwitchOnIfEmpty lines `nolines'
+    }
+    if `"`lines'"'!="" {
+        SwitchOnIfEmpty eqlines `noeqlines'
+    }
+    if inlist("`mode0'", "tab", "csv") {
+        local lines
+        local eqlines
+    }
+    if "`notes'"!="" & "`nolegend'"=="" & `nocellsopt'==1 & `matrixmode'==0 local legend legend
+    if "`plain'"!="" {
+        if "`bfmt'"==""    local bfmt %9.0g
+        if "`tfmt'"==""    local tfmt `bfmt'
+        if "`zfmt'"==""    local zfmt `bfmt'
+        if "`sefmt'"==""   local sefmt `bfmt'
+        if "`pfmt'"==""    local pfmt `bfmt'
+        if "`cifmt'"==""   local cifmt `bfmt'
+        if "`betafmt'"=="" local betafmt `bfmt'
+    }
+    //if "`nomtitles'"!="" local depvars
+    //else if "`depvars'"=="" local mtitles mtitles
+
+// prepare append for rtf, tex, and html
+    local outfilenoteoff2 "`outfilenoteoff'"
+    if "`outfilenoteoff2'"=="" local outfilenoteoff2 "`nooutfilenoteoff'"
+    if `"`using'"'!="" & "`append'"!="" &  ///
+     (("`mode0'"=="rtf" & "`fragment'"=="") | ///
+     ("`page'"!="" & inlist("`mode0'", "tex", "html"))) {
+        capture confirm file `using0'
+        if _rc==0 {
+            tempfile appendfile
+            if "`mode'"=="rtf" local `mode'_open
+            else local `mode'_open0
+            local append
+            if "`outfilenoteoff2'"=="" local outfilenoteoff2 outfilenoteoff
+        }
+    }
+
+// cells() option
+    if "`notes'"!="" {
+        if ("`margin'"!="" | `"`margin2'"'!="") & "`nomargin'"=="" ///
+         local thenote "`thenote'Marginal effects"
+        if "`eform'"!="" & "`noeform'"=="" ///
+         local thenote "`thenote'Exponentiated coefficients"
+    }
+    if "`bfmt'"=="" local bfmt a3
+    if `nocellsopt' & `matrixmode'==0 {
+        if "`star'"!="" & "`staraux'"=="" local bstar star
+        if "`beta'"!="" {
+            if "`main'"!="" {
+                di as err "beta() and main() not allowed both"
+                exit 198
+            }
+            if "`betafmt'"==""  local betafmt 3
+            local cells fmt(`betafmt') `bstar'
+            local cells beta(`cells')
+            if "`notes'"!="" {
+                if `"`thenote'"'!="" local thenote "`thenote'; "
+                local thenote "`thenote'Standardized beta coefficients"
+            }
+        }
+        else if "`main'"!="" {
+            tokenize "`main'"
+            if "`2'"=="" local 2 "`bfmt'"
+            local cells fmt(`2') `bstar'
+            local cells `1'(`cells')
+            if "`notes'"!="" {
+                if `"`thenote'"'!="" local thenote "`thenote'; "
+                local thenote "`thenote'`1' coefficients"
+            }
+        }
+        else {
+            local cells fmt(`bfmt') `bstar'
+            local cells b(`cells')
+        }
+        if "`t'"=="" | "`z'`se'`p'`ci'`aux'"!="" {
+            if "`onecell'"!="" {
+                local cells `cells' &
+            }
+// parse aux option
+            tokenize "`aux'"
+            local auxname `1'
+            local auxfmt `2'
+// type of auxiliary statistic
+            local aux `z' `se' `p' `ci' `auxname'
+            if `"`aux'"'=="" local aux t
+            else {
+                if `:list sizeof aux'>1 {
+                    di as err "only one allowed of z, se, p, ci, and aux()"
+                    exit 198
+                }
+            }
+            if !inlist(`"`aux'"', "t", "z")  local abs
+// parentheses/brackets
+            if "`parentheses'"!="" | "`brackets'"!="" {
+                if `"`aux'"'=="ci" {
+                    local brackets brackets
+                    if "`mode'"!="smcl" | "`onecell'"!="" local paren par
+                    else local paren `"par("{ralign @modelwidth:{txt:[}" "{txt:,}" "{txt:]}}")"'
+                }
+                else if "`brackets'"!="" {
+                    if "`mode'"!="smcl" | "`onecell'"!="" local paren "par([ ])"
+                    else local paren `"par("{ralign @modelwidth:{txt:[}" "{txt:]}}")"'
+                }
+                else {
+                    if "`mode'"!="smcl" | "`onecell'"!="" local paren par
+                    else local paren `"par("{ralign @modelwidth:{txt:(}" "{txt:)}}")"'
+                }
+            }
+// compose note
+            if "`notes'"!="" {
+                if `"`thenote'"'!="" local thenote "`thenote'; "
+                if `"`auxname'"'!="" {
+                    local thenote `"`macval(thenote)'`auxname'"'
+                }
+                else if inlist(`"`aux'"', "t", "z")  {
+                    if "`abs'"!="" local thenote `"`macval(thenote)'Absolute "'
+                    local thenote `"`macval(thenote)'``mode'_`aux'statlab'"'
+                }
+                else if `"`aux'"'=="se" {
+                    local thenote `"`macval(thenote)'Standard errors"'
+                }
+                else if `"`aux'"'=="p" {
+                    local thenote `"`macval(thenote)'``mode'_pvallab'"'
+                }
+                else if `"`aux'"'=="ci" {
+                    local thenote `"`macval(thenote)'``mode'_cilab'"'
+                }
+                if "`parentheses'"=="" {
+                    if "`wide'"=="" local thenote `"`macval(thenote)' in second row"'
+                    else local thenote `"`macval(thenote)' in second column"'
+                }
+                else if "`brackets'"!="" {
+                    local thenote `"`macval(thenote)' in brackets"'
+                }
+                else local thenote `"`macval(thenote)' in parentheses"'
+            }
+// formats
+            if "`tfmt'"==""     local tfmt 2
+            if "`zfmt'"==""     local zfmt 2
+            if "`sefmt'"==""    local sefmt `bfmt'
+            if "`pfmt'"==""     local pfmt 3
+            if "`cifmt'"==""    local cifmt `bfmt'
+            if `"`auxfmt'"'=="" local auxfmt `bfmt'
+            if `"`auxname'"'=="" {
+                local auxfmt ``aux'fmt'
+            }
+// stars
+            if "`staraux'"!="" local staraux star
+// put together
+            local temp fmt(`auxfmt') `paren' `abs' `staraux'
+            local cells `cells' `aux'(`temp')
+        }
+        if "`wide'"!="" local cells cells(`"`cells'"')
+        else            local cells cells(`cells')
+    }
+
+// stats() option
+    if `"`macval(stats)'"'=="" & `matrixmode'==0 {
+        if `"`sfmt'"'=="" local sfmt `bfmt'
+        if `"`r2fmt'"'=="" local r2fmt = cond("`plain'"!="", "`bfmt'", "3")
+        if `"`ar2fmt'"'=="" local ar2fmt = cond("`plain'"!="", "`bfmt'", "3")
+        if `"`pr2fmt'"'=="" local pr2fmt = cond("`plain'"!="", "`bfmt'", "3")
+        if `"`aicfmt'"'=="" local aicfmt `bfmt'
+        if `"`bicfmt'"'=="" local bicfmt `bfmt'
+        if "`label'"=="" {
+            local stalabs `"``mode'_ssl'"'
+        }
+        else {
+            local stalabs `"``mode'_lsl'"'
+        }
+        gettoken obslab stalabs: stalabs
+        if "`obs'"=="" & "`obslast'"=="" {
+            local sta N
+            local stalab `"`"`macval(obslab)'"'"'
+            local stafmt %18.0g
+        }
+        local i 0
+        foreach s in r2 ar2 pr2 aic bic {
+            local ++i
+            if "``s''"!="" {
+                local sta `sta' `:word `i' of r2 r2_a r2_p aic bic'
+                local chunk: word `i' of `macval(stalabs)'
+                local stalab `"`macval(stalab)' `"`macval(chunk)'"'"'
+                local stafmt `stafmt' ``s'fmt'
+            }
+        }
+        local i 0
+        CheckScalarOpt `macval(scalars)'
+        foreach addstat of local scalars {
+            local ++i
+            gettoken addstatname addstatlabel: addstat
+            local addstatlabel = substr(`"`macval(addstatlabel)'"',2,.)
+            if `: list posof `"`addstatname'"' in sta' continue
+            if `"`addstatname'"'=="N" & "`obs'"=="" & "`obslast'"!="" continue
+            if trim(`"`macval(addstatlabel)'"')=="" local addstatlabel `addstatname'
+            local addstatfmt: word `i' of `sfmt'
+            if `"`addstatfmt'"'=="" {
+                local addstatfmt: word `: list sizeof sfmt' of `sfmt'
+            }
+            local sta `sta' `addstatname'
+            local stalab `"`macval(stalab)' `"`macval(addstatlabel)'"'"'
+            local stafmt `stafmt' `addstatfmt'
+        }
+        if "`obs'"=="" & "`obslast'"!="" {
+            local sta `sta' N
+            local stalab `"`macval(stalab)' `"`macval(obslab)'"'"'
+            local stafmt `stafmt' %18.0g
+        }
+        if "`sta'"!="" {
+            local stats stats(`sta', fmt(`stafmt') labels(`macval(stalab)'))
+        }
+    }
+
+// table header
+    if `"`macval(mlabels)'"'=="" {
+        if "`mode0'"=="tex" local mspan " span prefix(\multicolumn{@span}{c}{) suffix(})"
+        if `"`depvars'"'!="" {
+            local mlabels `"mlabels(, depvar`mspan')"'
+        }
+        if `"`nomtitles'"'!="" local mlabels `"mlabels(none)"'
+        if "`mtitles'"!="" {
+            local mlabels `"mlabels(, titles`mspan')"'
+        }
+        if `"`macval(mtitles2)'"'!="" {
+            local mlabels `"mlabels(`macval(mtitles2)', titles`mspan')"'
+        }
+    }
+    if `"`macval(collabels)'"'=="" & `nocellsopt' & `matrixmode'==0 & "`plain'"=="" {
+        local collabels `"collabels(none)"'
+    }
+    if "`mode0'"=="tex" & "`numbers'"!="" {
+        local numbers "numbers(\multicolumn{@span}{c}{( )})"
+    }
+
+// pre-/posthead, pre-/postfoot, gaps and lines
+// - complete note
+    if `"`macval(thenote)'"'!="" {
+        local thenote `"`"`macval(thenote)'"'"'
+    }
+    if `"`macval(note)'"'!="" {
+        local thenote `""@note""'
+    }
+    if `"`macval(addnotes)'"'!="" {
+        if index(`"`macval(addnotes)'"', `"""')==0 {
+            local addnotes `"`"`macval(addnotes)'"'"'
+        }
+        local thenote `"`macval(thenote)' `macval(addnotes)'"'
+    }
+    if "`legend'"!="" {
+        if ("`margin'"!="" | `"`margin2'"'!="") & ///
+           "`nomargin'"=="" & "`nodiscrete'"=="" {
+            local thenote `"`macval(thenote)' "@discrete""'
+        }
+        if "`star'"!="" | `nocellsopt'==0 {
+            local thenote `"`macval(thenote)' "@starlegend""'
+        }
+    }
+// - mode specific settings
+    if "`star'"!="" {
+        if `"`macval(star2)'"'!="" {
+            FormatStarSym "`mode0'" `"`macval(star2)'"'
+            local `mode'_starlevels `"`macval(star2)'"'
+        }
+        if `"`macval(starlevels)'"'=="" {
+            local starlevels `"starlevels(`macval(`mode'_starlevels)'`macval(`mode'_starlevlab)')"'
+        }
+    }
+    foreach opt in begin delimiter end substitute interaction {
+        if `"`macval(`opt')'"'=="" & `"``mode'_`opt''"'!="" {
+            local `opt' `"`opt'(``mode'_`opt'')"'
+        }
+    }
+    if "`onecell'"!="" {
+        if `"`macval(incelldelimiter)'"'=="" {
+            local incelldelimiter `"incelldelimiter(``mode'_incelldel')"'
+        }
+    }
+    if "`noabbrev'`abbrev'"=="" {
+        local abbrev ``mode'_abbrev'
+    }
+    if `"`fragment'"'=="" {
+        if "`page'"!="" {
+            if `"`page2'"'!="" {
+                local texpkgs `""\usepackage{`page2'}""'
+            }
+            local opening `"``mode'_open0'"'
+        }
+        if `"`macval(title)'"'!="" {
+            local opening `"`macval(opening)' ``mode'_open'"'
+            if "`mode0'"=="tex" & "`star'"!="" {
+                local opening `"`macval(opening)' "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}""'
+            }
+            if !("`longtable'"!="" & "`mode0'"=="tex") {
+                local opening `"`macval(opening)' ``mode'_caption'"'
+            }
+        }
+        else if "`mode0'"=="tex" & "`star'"!="" {
+            local opening `"`macval(opening)' "{" "\def\sym#1{\ifmmode^{#1}\else\(^{#1}\)\fi}""'
+        }
+        else if "`mode0'"!="tex" {
+            local opening `"`macval(opening)' ``mode'_open'"'
+        }
+        local opening `"`macval(opening)' ``mode'_open2'"'
+        if  "`mode0'"=="tex" {
+            if `"`labcol2'"'!="" local lstubtex "lc"
+            else local lstubtex "l"
+            if `"`width'"'!="" local extracolsep "@{\hskip\tabcolsep\extracolsep\fill}"
+            if `"`macval(alignment)'"'!="" {
+                local opening `"`macval(opening)'{`extracolsep'`lstubtex'*{@E}{`macval(alignment)'}}"'
+            }
+            else {
+                if `nocellsopt' {
+                    MakeTeXColspec "`wide'" "`not'" "`star'" "`stardetach'" "`staraux'"
+                }
+                else {
+                    MakeTeXColspecAlt, `cells'
+                }
+                local opening `"`macval(opening)'{`extracolsep'`lstubtex'*{@E}{`value'}}"'
+            }
+            if "`longtable'"!="" {
+                if `"`macval(title)'"'!="" {
+                    local opening `"`macval(opening)' ``mode'_caption'\\\"'
+                }
+            }
+        }
+        if "`mode0'"=="html" {
+            local brr
+            foreach chunk of local thenote {
+                local closing `"`macval(closing)' `"`brr'`macval(chunk)'"'"'
+                local brr "<br />"
+            }
+            if `"`macval(closing)'"'!="" {
+                local closing `""<tr><td colspan=@span>" `macval(closing)' "</td></tr>""'
+            }
+        }
+        else if "`mode0'"=="tex" {
+            foreach chunk of local thenote {
+                local closing `"`macval(closing)' `"\multicolumn{@span}{l}{\footnotesize `macval(chunk)'}\\\"'"'
+            }
+        }
+        else if "`mode0'"=="csv" {
+            foreach chunk of local thenote {
+                local closing `"`macval(closing)' `"`csvlhs'`macval(chunk)'""'"'
+            }
+        }
+        else if "`mode0'"=="rtf" {
+            foreach chunk of local thenote {
+                local closing `"`macval(closing)' `"{\pard\ql\fs20 `macval(chunk)'\par}"'"'
+            }
+        }
+        else {
+            local closing `"`macval(thenote)'"'
+        }
+        local closing `"`macval(closing)' ``mode'_close2'"'
+        if `"`macval(title)'"'!="" | "`mode0'"!="tex" {
+            local closing `"`macval(closing)' ``mode'_close'"'
+        }
+        else if "`mode0'"=="tex" & "`star'"!="" {
+            local closing `"`macval(closing)' }"'
+        }
+        if "`page'"!="" {
+            local closing `"`macval(closing)' ``mode'_close0'"'
+        }
+        local toprule    `"``mode'_toprule'"'
+        local bottomrule `"``mode'_bottomrule'"'
+        local topgap     `"``mode'_topgap'"'
+        local bottomgap  `"``mode'_bottomgap'"'
+    }
+    local midrule `"``mode'_midrule'"'
+    local midgap  `"``mode'_midgap'"'
+    local eqrule  `"``mode'_eqrule'"'
+// - compose prehead()
+    if `"`macval(prehead)'"'=="" {
+        if `"`lines'"'!="" {
+            local opening `"`macval(opening)' `macval(toprule)'"'
+        }
+        else if `"`gaps'"'!="" {
+            local opening `"`macval(opening)' `macval(topgap)'"'
+        }
+        SaveRetok `macval(opening)'
+        local opening `"`macval(value)'"'
+        if `"`macval(opening)'"'!="" {
+            local prehead `"prehead(`macval(opening)')"'
+        }
+    }
+// - compose posthead()
+    if `"`macval(posthead)'"'=="" {
+        if `"`lines'"'!="" {
+            local posthead `"posthead(`macval(midrule)')"'
+        }
+        else if `"`gaps'"'!="" {
+            local posthead `"posthead(`macval(midgap)')"'
+        }
+    }
+// - compose prefoot()
+    if `"`macval(prefoot)'"'=="" & `"`macval(stats)'"'!="" {
+        if `"`lines'"'!="" {
+            local prefoot `"prefoot(`macval(midrule)')"'
+        }
+        else if `"`gaps'"'!="" {
+            local prefoot `"prefoot(`macval(midgap)')"'
+        }
+        if `"`cells'"'=="cells(none)" local prefoot
+    }
+// - compose postfoot()
+    if `"`macval(postfoot)'"'=="" {
+        if `"`lines'"'!="" {
+            local closing `"`macval(bottomrule)' `macval(closing)'"'
+        }
+        else if `"`gaps'"'!="" {
+            local closing `"`macval(bottomgap)' `macval(closing)'"'
+        }
+        SaveRetok `macval(closing)'
+        local closing `"`macval(value)'"'
+        if `"`macval(closing)'"'!="" {
+            local postfoot postfoot(`macval(closing)')
+        }
+    }
+// - varlabels
+    if `"`macval(varlabels)'"'=="" {
+        if `"`gaps'"'!="" {
+            local varl `", end("" `macval(midgap)') nolast"'
+        }
+        if "`label'"!=""  {
+            local varl `"_cons Constant`macval(varl)'"'
+        }
+        if `"`macval(coeflabels)'"'!="" {
+            local varl `"`macval(coeflabels)' `macval(varl)'"'
+        }
+        if trim(`"`macval(varl)'"')!="" {
+            local varlabels varlabels(`macval(varl)')
+        }
+    }
+// - equation labels
+    if ("`eqlines'"!="" | `"`gaps'"'!="") & "`unstack'"=="" {
+        if trim(`"`eqlabels'"')!="none" {
+            ParseEqLabels `macval(eqlabels)'
+            if `eqlabelsok' {
+                _parse comma eqllhs eqlrhs : eqlabels
+                if `"`eqlrhs'"'=="" local eqlabelscomma ", "
+                else                local eqlabelscomma " "
+                if "`eqlines'"!=""{
+                    local eqlabels `"`macval(eqlabels)'`eqlabelscomma'`macval(eqrule)' nofirst"'
+                }
+                else if `"`gaps'"'!="" {
+                    local eqlabels `"`macval(eqlabels)'`eqlabelscomma'begin(`macval(midgap)' "") nofirst"'
+                }
+            }
+        }
+    }
+    if `"`macval(eqlabels)'"'!="" {
+        local eqlabels `"eqlabels(`macval(eqlabels)')"'
+    }
+
+// noconstant option
+    if `"`drop'"'=="" {
+        if "`noconstant'"!="" {
+            local drop drop(_cons, relax)
+        }
+    }
+
+// compute beta coefficients (run estadd to add e(beta))
+    if "`beta'"!="" {
+        local estnames `"`anything'"'
+        if `"`estnames'"'=="" {
+            capt est_expand $eststo
+            if !_rc {
+                local estnames `"$eststo"'
+            }
+        }
+        version `caller': estadd beta, replace: `estnames'
+    }
+
+// use tempfile for new table
+    if `"`appendfile'"'!="" {
+        local using `"using `"`appendfile'"'"'
+    }
+
+// execute estout
+    if `"`varwidth'"'!="" local varwidth `"varwidth(`varwidth')"'
+    if `"`modelwidth'"'!="" local modelwidth `"modelwidth(`modelwidth')"'
+    if `"`style'"'=="" local style "style(esttab)"
+    CleanEstoutCmd `anything' `using' ,  ///
+     `macval(cells)' `drop' `nomargin' `margin' `margin2' `noeform' `eform'       ///
+     `nodiscrete' `macval(stats)' `stardetach' `macval(starlevels)'               ///
+     `varwidth' `modelwidth' `noabbrev' `abbrev' `unstack' `macval(begin)'        ///
+     `macval(delimiter)' `macval(end)' `macval(incelldelimiter)' `smcltags'       ///
+     `macval(title)' `macval(prehead)' `macval(posthead)' `macval(prefoot)'       ///
+     `macval(postfoot)' `label' `macval(varlabels)' `macval(mlabels)' `nonumbers' ///
+     `numbers' `macval(collabels)' `macval(eqlabels)' `macval(mgroups)'           ///
+     `macval(note)' `macval(labcol2)' `macval(substitute)' `macval(interaction)'  ///
+     `append' `notype'`type' `outfilenoteoff2' level(`level') `style'             ///
+     `macval(options)'
+    if "`noisily'"!="" {
+        gettoken chunk rest: cmd, parse(",")
+        di as txt _asis `"`chunk'"' _c
+        gettoken chunk rest: rest, bind
+        while `"`macval(chunk)'"'!="" {
+            di as txt _asis `" `macval(chunk)'"'
+            gettoken chunk rest: rest, bind
+        }
+    }
+    `macval(cmd)'
+
+// insert new table into existing document (tex, html, rtf)
+    if `"`appendfile'"'!="" {
+        local enddoctex "\end{document}"
+        local enddochtml "</body>"
+        local enddocrtf "}"
+        local enddoc "`enddoc`mode0''"
+        tempname fh
+        file open `fh' using `using0', read write
+        file seek `fh' query
+        local loc = r(loc)
+        file read `fh' line
+        while r(eof)==0 {
+            if `"`line'"'=="`enddoc'" {
+                if "`mode'"=="rtf" {
+                    file seek `fh' query
+                    local loc0 = r(loc)
+                    file read `fh' line
+                    if r(eof)==0 {
+                        local loc = `loc0'
+                        continue
+                    }
+                }
+                continue, break
+            }
+            file seek `fh' query
+            local loc = r(loc)
+            file read `fh' line
+        }
+        file seek `fh' `loc'
+        tempname new
+        file open `new' `using', read
+        file read `new' line
+        while r(eof)==0 {
+            file write `fh' `"`macval(line)'"' _n
+            file read `new' line
+        }
+        file close `fh'
+        file close `new'
+        if "`outfilenoteoff'"=="" {
+            di as txt `"(output written to {browse `using0'})"'
+        }
+    }
+end
+
+program _more_syntax
+// using subroutine (rather than second syntax call) to preserve 'using'
+    local theoptions ///
+        NODEPvars DEPvars ///
+        NOPArentheses PArentheses ///
+        BRackets ///
+        NONOTEs NOTEs /// without s in helpfile
+        LONGtable ///
+        ONEcell ///
+        NOEQLInes ///
+        NOOUTFILENOTEOFF outfilenoteoff
+    syntax [, `theoptions' * ]
+    foreach opt of local theoptions {
+        local opt = lower("`opt'")
+        c_local `opt' "``opt''"
+    }
+    c_local options     `"`macval(options)'"'
+end
+
+program _estout_options
+    syntax [, ///
+     Cells(passthru) ///
+     Drop(passthru)  ///
+ ///  Keep(string asis) ///
+ ///  Order(string asis) ///
+ ///  REName(passthru) ///
+ ///  Indicate(string asis) ///
+ ///  TRansform(string asis) ///
+ ///  EQuations(passthru) ///
+     NOEFORM eform ///EFORM2(string) ///
+     NOMargin Margin Margin2(passthru) ///
+     NODIscrete /// DIscrete(string asis) ///
+ ///  MEQs(string) ///
+ ///  NODROPPED dropped DROPPED2(string) ///
+     level(numlist max=1 int >=10 <=99) ///
+     Stats(passthru) ///
+     STARLevels(passthru) ///
+ ///  NOSTARDetach ///
+     STARDetach ///
+ ///  STARKeep(string asis) ///
+ ///  STARDrop(string asis) ///
+     VARwidth(str) ///
+     MODELwidth(str) ///
+     NOABbrev ABbrev ///
+ ///  NOUNStack
+     UNStack ///
+     BEGin(passthru) ///
+     DELimiter(passthru) ///
+     INCELLdelimiter(passthru) ///
+     end(passthru) ///
+ ///  DMarker(string) ///
+ ///  MSign(string) ///
+ ///  NOLZ lz ///
+     SUBstitute(passthru) ///
+     INTERACTion(passthru) ///
+     TItle(passthru) ///
+     NOLEgend LEgend ///
+     PREHead(passthru) ///
+     POSTHead(passthru) ///
+     PREFoot(passthru) ///
+     POSTFoot(passthru) ///
+ ///  HLinechar(string) ///
+ ///  NOLabel
+     Label ///
+     VARLabels(passthru) ///
+ ///  REFcat(string asis) ///
+     MLabels(passthru) ///
+     NONUMbers NUMbers ///NUMbers2(string asis) ///
+     COLLabels(passthru) ///
+     EQLabels(string asis) ///
+     MGRoups(passthru) ///
+     LABCOL2(passthru) ///
+ ///  NOReplace Replace ///
+ ///  NOAppend
+     Append ///
+     NOTYpe TYpe ///
+ ///  NOSHOWTABS showtabs ///
+ ///  TOPfile(string) ///
+ ///  BOTtomfile(string) ///
+     STYle(passthru) ///
+ ///  DEFaults(string) ///
+ ///  NOASIS asis ///
+ ///  NOWRAP wrap ///
+ ///  NOSMCLTAGS smcltags ///
+ ///  NOSMCLRules SMCLRules ///
+ ///  NOSMCLMIDRules SMCLMIDRules ///
+ ///  NOSMCLEQRules SMCLEQRules ///
+     note(passthru) ///
+     * ]
+    foreach opt in ///
+     cells drop noeform eform nomargin margin margin2 nodiscrete ///
+     level stats starlevels stardetach varwidth modelwidth unstack ///
+     noabbrev abbrev begin delimiter incelldelimiter end substitute ///
+     interaction title nolegend legend prehead posthead prefoot postfoot ///
+     label varlabels mlabels labcol2 nonumbers numbers collabels eqlabels ///
+     mgroups append notype type style note options {
+        c_local `opt' `"`macval(`opt')'"'
+    }
+end
+
+program MatrixMode
+    capt syntax [, Matrix(str asis) e(str asis) r(str asis) rename(str asis) ]
+    if _rc | `"`matrix'`e'`r'"'=="" {
+        c_local matrixmode 0
+        exit
+    }
+    c_local matrixmode 1
+end
+
+prog NotBothAllowed
+    args opt1 opt2
+    if `"`opt1'"'!="" {
+        if `"`opt2'"'!="" {
+            di as err `"options `opt1' and `opt2' not both allowed"'
+            exit 198
+        }
+    }
+end
+
+prog SwitchOnIfEmpty
+    args opt1 opt2
+    if `"`opt2'"'=="" {
+        c_local `opt1' `opt1'
+    }
+end
+
+prog _getfilesuffix, rclass // based on official _getfilename.ado
+    version 8
+    gettoken filename rest : 0
+    if `"`rest'"' != "" {
+        exit 198
+    }
+    local hassuffix 0
+    gettoken word rest : filename, parse(".")
+    while `"`rest'"' != "" {
+        local hassuffix 1
+        gettoken word rest : rest, parse(".")
+    }
+    if `"`word'"'=="." {
+        di as err `"incomplete filename; ends in ."'
+        exit 198
+    }
+    if index(`"`word'"',"/") | index(`"`word'"',"\") local hassuffix 0
+    if `hassuffix' return local suffix `".`word'"'
+    else           return local suffix ""
+end
+
+prog FormatStarSym
+    args mode list
+    if inlist("`mode'","rtf","html","tex") {
+        if "`mode'"=="rtf" {
+            local prefix "{\super "
+            local suffix "}"
+        }
+        else if "`mode'"=="html" {
+            local prefix "<sup>"
+            local suffix "</sup>"
+        }
+        else if "`mode'"=="tex" {
+            local prefix "\sym{"
+            local suffix "}"
+        }
+        local odd 1
+        foreach l of local list {
+            if `odd' {
+                local l `"`"`prefix'`macval(l)'`suffix'"'"'
+                local odd 0
+            }
+            else local odd 1
+            local newlist `"`macval(newlist)'`space'`macval(l)'"'
+            local space " "
+        }
+        c_local star2 `"`macval(newlist)'"'
+    }
+    //else do noting
+end
+
+prog CheckScalarOpt
+    capt syntax [anything]
+    if _rc error 198
+end
+
+prog MakeTeXColspec
+    args wide not star detach aux
+    if "`star'"!="" & "`detach'"!="" & "`aux'"=="" local value "r@{}l"
+    else local value "c"
+    if "`wide'"!="" & "`not'"=="" {
+        if "`star'"!="" & "`detach'"!="" & "`aux'"!="" local value "`value'r@{}l"
+        else local value "`value'c"
+    }
+    c_local value "`value'"
+end
+
+prog MakeTeXColspecAlt
+    syntax, cells(string asis)
+    local count 1
+    while `count' {
+        local cells: subinstr local cells " (" "(", all count(local count)
+    }
+    local count 1
+    while `"`macval(cells)'"'!="" {
+        gettoken row cells : cells, bind
+        local size 0
+        gettoken chunk row : row, bind
+        while `"`macval(chunk)'"'!="" {
+            local ++size
+            gettoken chunk row : row, bind
+        }
+        local count = max(`count',`size')
+    }
+    c_local value: di _dup(`count') "c"
+end
+
+prog SaveRetok
+    gettoken chunk 0: 0, q
+    local value `"`macval(chunk)'"'
+    gettoken chunk 0: 0, q
+    while `"`macval(chunk)'"'!="" {
+        local value `"`macval(value)' `macval(chunk)'"'
+        gettoken chunk 0: 0, q
+    }
+    c_local value `"`macval(value)'"'
+end
+
+prog CleanEstoutCmd
+    syntax [anything] [using] [ , * ]
+    local cmd estout
+    if `"`macval(anything)'"'!="" {
+        local cmd `"`macval(cmd)' `macval(anything)'"'
+    }
+    if `"`macval(using)'"'!="" {
+        local cmd `"`macval(cmd)' `macval(using)'"'
+    }
+    if `"`macval(options)'"'!="" {
+        local cmd `"`macval(cmd)', `macval(options)'"'
+    }
+    c_local cmd `"`macval(cmd)'"'
+end
+
+prog ParseEqLabels
+    syntax [anything] [, Begin(passthru) NOReplace Replace NOFirst First * ]
+    c_local eqlabelsok = `"`begin'`noreplace'`replace'`nofirst'`first'"'==""
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/e/esttab.hlp

@@ -0,0 +1,918 @@
+{smcl}
+{* 02jun2014}{...}
+{hi:help esttab}{right:also see: {helpb estout}, {helpb eststo}, {helpb estadd}, {helpb estpost}}
+{right: {browse "http://repec.org/bocode/e/estout"}}
+{hline}
+
+{title:Title}
+
+{p 4 4 2}{hi:esttab} {hline 2} Display formatted regression table
+
+
+{title:Table of contents}
+
+    {help esttab##syn:Syntax}
+    {help esttab##des:Description}
+    {help esttab##opt:Options}
+    {help esttab##exa:Examples}
+    {help esttab##aut:Backmatter}
+
+{marker syn}
+{title:Syntax}
+
+{p 8 15 2}
+{cmd:esttab} [ {it:namelist} ] [ {cmd:using} {it:filename} ] [ {cmd:,}
+{it:options} ]
+
+
+{p 4 4 2}where {it:namelist} is a name, a list of names, or {cmd:_all}. The 
+{cmd:*} and {cmd:?} wildcards are allowed in {it:namelist}. A name may also be {cmd:.}, 
+meaning the current (active) estimates.
+
+
+    {it:options}{col 26}description
+    {hline 70}
+    {help esttab##main:Main}
+      {cmd:b(}{it:{help esttab##fmt:fmt}}{cmd:)}{col 26}{...}
+specify format for point estimates
+      {cmd:beta}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]{col 26}{...}
+display beta coefficients instead of point est's
+      {cmd:main(}{it:name} [{it:{help esttab##fmt:fmt}}]{cmd:)}{col 26}{...}
+display contents of {cmd:e(}{it:name}{cmd:)} instead of point e's
+      {cmd:t(}{it:{help esttab##fmt:fmt}}{cmd:)}{col 26}{...}
+specify format for t-statistics
+      {cmd:abs}{col 26}{...}
+use absolute value of t-statistics
+      {cmd:not}{col 26}{...}
+suppress t-statistics
+      {cmd:z}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]{col 26}{...}
+display z-statistics (affects label only)
+      {cmd:se}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]{col 26}{...}
+display standard errors instead of t-statistics
+      {cmd:p}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]{col 26}{...}
+display p-values instead of t-statistics
+      {cmd:ci}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]{col 26}{...}
+display confidence intervals instead of t-stat's
+      {cmd:aux(}{it:name} [{it:{help esttab##fmt:fmt}}]{cmd:)}{col 26}{...}
+display contents of {cmd:e(}{it:name}{cmd:)} instead of t-stat's
+      [{ul:{cmd:no}}]{cmdab:con:stant}{col 26}{...}
+do not/do report the intercept
+
+    {help esttab##stars:Significance stars}
+      [{cmd:no}]{cmd:star}[{cmd:(}{it:list}{cmd:)}]{col 26}{...}
+do not/do report significance stars
+      {cmd:staraux}{col 26}{...}
+attach stars to t-stat's instead of point est's
+
+    {help esttab##stat:Summary statistics}
+      {cmd:r2}|{cmd:ar2}|{cmd:pr2}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]{col 26}{...}
+display (adjusted, pseudo) R-squared
+      {cmd:aic}|{cmd:bic}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]{col 26}{...}
+display Akaike's or Schwarz's information crit.
+      {cmdab:sca:lars:(}{it:list}{cmd:)}{col 26}{...}
+display any other scalars contained in {cmd:e()}
+      {cmd:sfmt(}{it:{help esttab##fmt:fmt}} [{it:...}]{cmd:)}{col 26}{...}
+set format(s) for {cmd:scalars()}
+      {cmd:noobs}{col 26}{...}
+do not display the number of observations
+      {cmd:obslast}{col 26}{...}
+place the number of observations last
+
+    {help esttab##layout:Layout}
+      {cmd:wide}{col 26}{...}
+place point est's and t-stat's beside one another
+      {cmdab:one:cell}{col 26}{...}
+combine point est's and t-stat's in a single cell
+      [{ul:{cmd:no}}]{cmdab:pa:rentheses}{col 26}{...}
+do not/do print parentheses around t-statistics
+      {cmdab:br:ackets}{col 26}{...}
+use brackets instead of parentheses
+      [{ul:{cmd:no}}]{cmdab:gap:s}{col 26}{...}
+suppress/add vertical spacing
+      [{ul:{cmd:no}}]{cmdab:li:nes}{col 26}{...}
+suppress/add horizontal lines
+      {cmdab:noeqli:nes}{col 26}{...}
+suppress lines between equations
+      {cmd:compress}{col 26}{...}
+reduce horizontal spacing
+      {cmd:plain}{col 26}{...}
+produce a minimally formatted table
+
+    {help esttab##label:Labeling}
+      {cmdab:l:abel}{col 26}{...}
+make use of variable labels
+      {cmdab:interact:ion:(}{it:str}{cmd:)}{col 26}{...}
+specify interaction operator
+      {cmdab:ti:tle:(}{it:string}{cmd:)}{col 26}{...}
+specify a title for the table
+      {cmdab:mti:tles}[{cmd:(}{it:list}{cmd:)}]{col 26}{...}
+specify model titles to appear in table header
+      {cmdab:nomti:tles}{col 26}{...}
+disable model titles
+      [{ul:{cmd:no}}]{cmdab:dep:vars}{col 26}{...}
+do not/do use dependent variables as model titles
+      [{ul:{cmd:no}}]{cmdab:num:bers}{col 26}{...}
+do not/do print model numbers in table header
+      {cmdab:coef:labels:(}{it:list}{cmd:)}{col 26}{...}
+specify labels for coefficients
+      [{ul:{cmd:no}}]{cmdab:note:s}{col 26}{...}
+suppress/add notes in the table footer
+      {cmdab:addn:otes:(}{it:list}{cmd:)}{col 26}{...}
+add lines at the end of the table
+
+    {help esttab##format:Document format}
+      {cmd:smcl} | {cmdab:fix:ed} | {cmd:tab} | {cmd:csv} | {cmdab:sc:sv} | {cmd:rtf} | {cmdab:htm:l} | {cmd:tex} | {cmdab:bookt:abs}
+      {col 26}{...}
+set the document format ({cmd:smcl} is the default)
+      {cmdab:f:ragment}{col 26}{...}
+suppress table opening and closing (LaTeX, HTML)
+      {cmd:page}[{cmd:(}{it:packages}{cmd:)}]{col 26}{...}
+add page opening and closing (LaTeX, HTML)
+      {cmdab:align:ment(}{it:string}{cmd:)}{col 26}{...}
+set alignment within columns (LaTeX, HTML, RTF)
+      {cmdab:width(}{it:string}{cmd:)}{col 26}{...}
+set width of table (LaTeX, HTML)
+      {cmdab:long:table}{col 26}{...}
+multi-page table (LaTeX)
+
+    {help esttab##output:Output}
+      {cmdab:r:eplace}{col 26}{...}
+overwrite an existing file
+      {cmdab:a:ppend}{col 26}{...}
+append the output to an existing file
+      {cmdab:ty:pe}{col 26}{...}
+force prining the table in the results window
+      {cmdab:n:oisily}{col 26}{...}
+display the executed {helpb estout} command
+
+    {help esttab##advanced:Advanced}
+      {cmdab:d:rop:(}{it:list}{cmd:)}{col 26}{...}
+drop individual coefficients
+      {cmdab:noomit:ted}{col 26}{...}
+drop omitted coefficients
+      {cmdab:nobase:levels}{col 26}{...}
+drop base levels of factor variables
+      {cmdab:k:eep:(}{it:list}{cmd:)}{col 26}{...}
+keep individual coefficients
+      {cmdab:o:rder:(}{it:list}{cmd:)}{col 26}{...}
+change order of coefficients
+      {cmdab:eq:uations:(}{it:list}{cmd:)}{col 26}{...}
+match the models' equations
+      {cmd:eform}{col 26}{...}
+report exponentiated coefficients
+      {cmdab:uns:tack}{col 26}{...}
+place multiple equations in separate columns
+      {it:estout_options}{col 26}{...}
+any other {helpb estout} options
+    {hline 70}
+
+{marker des}
+{title:Description}
+
+{p 4 4 2}
+{cmd:esttab} is a wrapper for {helpb estout}. It produces a
+pretty-looking publication-style regression table from stored
+estimates without much typing. The compiled table is displayed in the
+Stata results window or, optionally, written to a text file specified
+by {cmd:using} {it:filename}. If {it:filename} is specified without
+suffix, a default suffix is added depending on the specified document
+format (".smcl" for {cmd:smcl}, ".txt" for {cmd:fixed} and {cmd:tab}, ".csv" for {cmd:csv}
+and {cmd:scsv}, ".rtf" for {cmd:rft}, ".html" for {cmd:html}, and
+".tex" for {cmd:tex} and {cmd:booktabs}).
+
+{p 4 4 2}
+{it:namelist} provides the names of the stored estimation sets to be
+tabulated. You may use the {cmd:*} and {cmd:?} wildcards in
+{it:namelist}. If {it:namelist} is omitted, {cmd:esttab} tabulates the
+estimation sets stored by {cmd:eststo} (see help {helpb eststo})
+or, if no such estimates are present, the currently active
+estimates (i.e. the model fit last).
+
+{p 4 4 2}
+See help {helpb estimates} for information about storing estimation
+results. An alternative to the {cmd:estimates store} command is
+provided by {helpb eststo}.
+
+{p 4 4 2}
+{cmd:esttab} can also be used to tabulate a Stata matrix applying syntax 
+{bind:{cmd:esttab} {cmdab:m:atrix:(}{it:name}{cmd:)}}, where {it:name} 
+is the name of the matrix. Furthermore, an {cmd:e()}-matrix or {cmd:r()}-matrix
+can be tabulated specifying {cmd:esttab e(}{it:name}{cmd:)} or 
+{cmd:esttab r(}{it:name}{cmd:)}. Most options under the headings  
+'Main', 'Significance stars', and 'Summary statistics' are irrelevant 
+in this case. See help {helpb estout} for further details on tabulating matrices.
+
+{marker opt}
+{title:Options}
+{marker main}
+{dlgtab:Main}
+
+{p 4 8 2}
+{cmd:b(}{it:{help esttab##fmt:fmt}}{cmd:)} sets the numerical display format
+for the point estimates. The default format is {cmd:a3}. (See
+{help esttab##fmt:Numerical formats} below for details on available
+formats.)
+
+{p 4 8 2}
+{cmd:beta}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}] requests that
+standardized beta coefficients be displayed in place of the raw point
+estimates and, optionally, sets the display format (the default is to
+print three decimal places). Note that {cmd:beta} causes the
+intercept to be dropped from the table (unless {cmd:constant} is
+specified).{p_end}
+{marker main}
+{p 4 8 2}
+{cmd:main(}{it:name} [{it:{help esttab##fmt:fmt}}]{cmd:)} requests that
+the statistics stored in {cmd:e(}{it:name}{cmd:)} be displayed in
+place of the point estimates and, optionally, sets the display format
+(the default is to use the display format for point estimates). For
+example, {cmd:e(}{it:name}{cmd:)} may contain statistics added by
+{cmd:estadd} (see help {helpb estadd}).
+
+{p 4 8 2}
+{cmd:t(}{it:{help esttab##fmt:fmt}}{cmd:)} sets the display format for
+t-statistics. The default is to display two decimal places.
+
+{p 4 8 2}
+{cmd:abs} causes absolute values of t-statistics to be reported.
+
+{p 4 8 2}
+{cmd:not} suppresses the printing of t-statistics.
+
+{p 4 8 2}
+{cmd:z}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}] requests that
+z-statistics be displayed. z-statistics are the same as t-statistics. Hence, 
+specifying {cmd:z} does not change the table contents, it only changes the 
+label.
+
+{p 4 8 2}
+{cmd:se}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}] requests that
+standard errors be displayed in place of t-statistics and,
+optionally, sets the display format (the default is to use the
+display format for point estimates).
+
+{p 4 8 2}
+{cmd:p}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}] requests that
+p-values be displayed in place of t-statistics and, optionally, sets
+the display format (the default is to print three decimal places)
+
+{p 4 8 2}
+{cmd:ci}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}] requests that
+confidence intervals be displayed in place of t-statistics and,
+optionally, sets the display format (the default is to use the
+display format for point estimates). {cmd:level(}{it:#}{cmd:)}
+assigns the confidence level, in percent. The default is
+{cmd:level(95)} or as set by {helpb set level}.{p_end}
+{marker aux}
+{p 4 8 2}
+{cmd:aux(}{it:name} [{it:{help esttab##fmt:fmt}}]{cmd:)} requests that
+the statistics stored in {cmd:e(}{it:name}{cmd:)} be displayed in
+place of t-statistics and, optionally, sets the display format (the
+default is to use the display format for point estimates). For
+example, {cmd:e(}{it:name}{cmd:)} may contain statistics added by
+{cmd:estadd} (see help {helpb estadd}, if installed).
+
+{p 4 8 2}
+{cmd:noconstant} causes the intercept be dropped from the table.
+Specify {cmd:constant} to include the constant in situations where it
+is dropped by default.
+
+{marker stars}
+{dlgtab:Significance stars}
+
+{p 4 8 2}
+{cmd:star}[{cmd:(}{it:symbol} {it:level} [{it:...}]{cmd:)}] causes
+stars denoting the significance of the coefficients to be printed
+next to the point estimates. This is the default. Type {cmd:nostar}
+to suppress the stars. The default symbols and thresholds are:
+{cmd:*} for p<.05, {cmd:**} for p<.01, and {cmd:***} for p<.001.
+Alternatively, for example, type {bind:{cmd:star(+ 0.10 * 0.05)}} to
+set the following thresholds: {cmd:+} for p<.10 and {cmd:*} for
+p<.05. Note that the thresholds must lie in the (0,1] interval and
+must be specified in descending order.
+
+{p 4 8 2}
+{cmd:staraux} causes the significance stars be printed next to the
+t-statistics (or standard errors, etc.) instead of the point estimates.
+
+{marker stat}
+{dlgtab:Summary statistics}
+
+{p 4 8 2}
+{cmd:r2}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}],
+{cmd:ar2}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}], and
+{cmd:pr2}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]
+include the R-squared, the adjusted R-squared, and the
+pseudo-R-squared in the table footer and, optionally, set the
+corresponding display formats (the default is to display three
+decimal places).
+
+{p 4 8 2}
+{cmd:aic}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}] and
+{cmd:bic}[{cmd:(}{it:{help esttab##fmt:fmt}}{cmd:)}]
+include Akaike's and Schwarz's information criterion in the table
+footer and, optionally, set the corresponding display formats (the
+default is to use the display format for point estimates).{p_end}
+{marker scalars}
+{p 4 8 2}
+{cmd:scalars(}{it:list}{cmd:)} may be used to add other
+{cmd:e()}-scalars to the table footer (type {cmd:ereturn list} to
+display a list of available {cmd:e()}-scalars after fitting a model;
+see help {helpb ereturn}). For example, {cmd:scalars(df_m)} would
+report the model degrees of freedom for each model. {it:list} may be
+a simple list of names of {cmd:e()}-scalars, e.g.
+
+            {com}. esttab, scalars(ll_0 ll chi2){txt}
+
+{p 8 8 2}
+or, alternatively, a list of quoted name-label pairs, e.g.
+
+            {com}. esttab, scalars({bind:"ll Log lik."} {bind:"chi2 Chi-squared"}){txt}
+
+{p 4 8 2}
+{cmd:sfmt(}{it:{help esttab##fmt:fmt}} [{it:...}]{cmd:)} sets the
+display format(s) for the statistics specified in {cmd:scalars()}
+(the default is to use the display format for point estimates). If
+{cmd:sfmt()} contains less elements than {cmd:scalars()}, the last
+specified format is used for the remaining scalars. That is, only one
+format needs to be specified if the same format be used for all
+scalars.
+
+{p 4 8 2}
+{cmd:noobs} suppresses displaying information on the number of
+observations. The default is to report the number of observations for
+each model in the table footer.
+
+{p 4 8 2}
+{cmd:obslast} displays the number of observations in the last row of
+the table footer. The default is to use the first row.
+
+{marker layout}
+{dlgtab:Layout}
+{marker wide}
+{p 4 8 2}
+{cmd:wide} causes point estimates and t-statistics (or standard errors,
+etc.) to be printed beside one another instead of beneath one another.
+{p_end}
+{marker onecell}
+{p 4 8 2}
+{cmd:onecell} causes point estimates and t-statistics (or standard errors,
+etc.) to be combined in a single table cell. This option is useful primarily 
+in {cmd:rtf} or {cmd:html} mode. In these modes a line break is 
+inserted between the two statistics. The benefit from using {cmd:onecell} 
+in {cmd:rtf} or {cmd:html} mode is that long coefficients labels do not 
+derange the table layout. The default for other modes is to insert
+a blank between the statistics. Use {cmd:estout}'s 
+{helpb estout##incelldel:incelldelimiter()} option to change this.
+
+{p 4 8 2}
+{cmd:parentheses} encloses t-statistics (or standard errors, etc.) in
+parentheses. This is the default. Specify {cmd:noparentheses} to
+suppress the parentheses.
+
+{p 4 8 2}
+{cmd:brackets} uses square brackets, [], instead of parentheses. Note
+that brackets are the default for confidence intervals.
+
+{p 4 8 2}
+{cmd:gaps} adds empty rows (or, more generally, additional vertical
+space) between coefficients to increase readability (empty rows are
+also inserted between the table's header, body, and footer, unless
+{cmd:lines} is activated). This is the default unless {cmd:wide} or
+{cmd:not} is specified. Type {cmd:nogaps} to suppress the extra
+spacing.
+
+{p 4 8 2}
+{cmd:lines} adds horizontal lines to the table separating the table's
+header, body, and footer and, in the case of multiple 
+equation models, the equations. This is the default. Specify {cmd:nolines}
+to suppress the lines. Lines are always suppressed in the {cmd:tab}
+and {cmd:csv} modes. 
+
+{p 4 8 2}
+{cmd:noeqlines} suppresses the horizontal lines between equations 
+in the case of multiple equation models.{p_end}
+{marker compress}
+{p 4 8 2}
+{cmd:compress} reduces the amount of horizontal spacing (so that more
+models fit on screen without line breaking). The option has no effect
+in the {cmd:tab} and {cmd:csv} modes. Furthermore, note that in the
+TeX and HTML modes the {cmd:compress} option only changes the
+arrangement the table's code, but not the look of the compiled
+end-product. In {cmd:rtf}, however, {cmd:compress} changes the look
+of the formatted table.{p_end}
+{marker plain}
+{p 4 8 2}
+{cmd:plain} produces a minimally formatted table. It is a shorthand
+to specifying {cmd:nostar}, {cmd:nodepvars}, {cmd:nonumbers},
+{cmd:noparentheses}, {cmd:nogaps}, {cmd:nolines} and {cmd:nonotes}
+and setting all formats to {cmd:%9.0g}. Note that the disabled
+options can be switched on again. For example, type
+
+            {com}. esttab, plain star{txt}
+
+{p 8 8 2}
+to produce a plain table including significance stars.
+
+{marker label}
+{dlgtab:Labeling}
+
+{p 4 8 2}
+{cmd:label} specifies that variable labels be used instead of
+variable names (and estimation set titles be used instead of
+estimation set names). Furthermore, {cmd:label} prints "Constant"
+instead of "_cons".
+
+{p 4 8 2}
+{cmd:interaction(}{it:string}{cmd:)} specifies the string to be used 
+as delimiter for interaction terms (only relevant in Stata 11 or newer). The
+default is {cmd:interaction(" # ")}. For {cmd:tex} and {cmd:booktabs} the 
+default is {cmd:interaction(" $\times$ ")}.
+{p_end}
+{marker title}
+{p 4 8 2}
+{cmd:title(}{it:string}{cmd:)} may be used to provide a title for the
+table. If specified, {it:string} is printed at the top of the table.
+Note that specifying a title causes the table to be set up as a
+floating object in LaTeX mode. You may want to set a label for
+referencing in this case. For example, if you type
+{cmd:title(...\label{tab1})}, then "\ref{tab1}" could be used in the
+LaTeX document to point to the table.
+
+{p 4 8 2} 
+{cmd:mtitles}, without argument, specifies that for each model the title 
+(or, if empty, the name) of the stored estimation set be printed as the model's 
+title in the table header. If {cmd:mtitles} is omitted, the default is to 
+use name or label of the dependent variable as the model's title (see the 
+{cmd:depvar} option). Alternatively, use {cmd:mtitles(}{it:list}{cmd:)} 
+specifies a list of model titles. Enclose the titles
+in double quotes if they contain spaces,
+e.g. {bind:{cmd:mtitles("Model 1" "Model 2")}}. 
+
+{p 4 8 2}
+{cmd:nomtitles} suppresses printing of model titles.
+
+{p 4 8 2}
+{cmd:depvars} prints the name (or label) of the (first) dependent
+variable of a model as the model's title in the table header. This is
+the default. Specify {cmd:nodepvars} to use the names of
+the stored estimation sets as titles.
+
+{p 4 8 2}
+{cmd:numbers} includes a row containing consecutive model numbers in
+the table header. This is the default. Specify {cmd:nonumbers} to
+suppress printing the model numbers.
+
+{p 4 8 2}
+{cmd:coeflabels(}{it:name} {it:label} [...]{cmd:)} specifies labels
+for the coefficients. Specify names and labels in pairs and, if
+necessary, enclose labels in double quotes,
+e.g. {cmd:coeflabels(mpg Milage rep78 {bind:"Repair Record"})}.
+
+{p 4 8 2}
+{cmd:notes} prints notes at the end of the table explaining the
+significance symbols and the type of displayed statistics. This is
+the default. Specify {cmd:nonotes} to suppress the notes.
+
+{p 4 8 2}
+{cmd:addnotes(}{it:list}{cmd:)} may be used to add further lines of
+text at the bottom of the table. Lines containing blanks must be
+enclosed in double quotes,
+e.g. {cmd:addnotes({bind:"Line 1"} {bind:"Line 2"})}.
+
+{marker format}
+{dlgtab:Document format}
+
+{p 4 8 2}
+{cmd:smcl}, {cmd:fixed}, {cmd:tab}, {cmd:csv},  {cmd:scsv}, {cmd:rtf},
+{cmd:html}, {cmd:tex}, and {cmd:booktabs} choose the table's basic
+output format. The default format is {cmd:smcl} unless 
+{cmd:using} is specified, in which case the default format
+depends on the filename's suffix ({cmd:smcl} for ".smcl", {cmd:csv} 
+for ".csv", {cmd:rtf} for ".rtf", 
+{cmd:html} for ".htm" or ".html", {cmd:tex} for ".tex", and {cmd:fixed}
+for all other filenames). To override the default behavior, specify one of the 
+following format options.
+
+{p 8 8 2}
+{cmd:smcl} produces a {help SMCL} formatted table to be displayed in the 
+Stata results window or the Stata viewer.
+
+{p 8 8 2}
+{cmd:fixed} produces a fixed-format ASCII table. This is suitable,
+for example, if the table be displayed in a text editor.
+
+{p 8 8 2}
+{cmd:tab} produces a tab-delimited ASCII table.
+{p_end}
+{marker csv}
+{p 8 8 2}
+{cmd:csv} produces a CSV ({ul:C}omma {ul:S}eparated {ul:V}alue
+format) table for use with Microsoft Excel. Delimiter is a comma. In
+order to prevent Excel from interpreting the contents of the table
+cells, they are enclosed double quotes preceded by an equal sign
+(i.e. ="..."). However, if the {cmd:plain} option is specified, the
+table cells are enclosed in double quotes without the leading equal
+sign. The first method is appropriate if you want to preserve the
+table's formatting. The second method is appropriate if you want to
+use the table's contents for further computations in Excel.
+{p_end}
+{marker scsv}
+{p 8 8 2}
+{cmd:scsv} is a variant on the CSV format that uses a semicolon as
+the delimiter. This is appropriate for some non-English versions of
+Excel (e.g. the German version).
+{p_end}
+{marker rtf}
+{p 8 8 2}
+{cmd:rtf} produces a Rich Text Format table for use with word
+processors.
+
+{p 8 8 2}
+{cmd:html} produces a simple HTML formatted table.
+
+{p 8 8 2}
+{cmd:tex} produces a LaTeX formatted table.
+{p_end}
+{marker booktabs}
+{p 8 8 2}
+{cmd:booktabs} produces a LaTeX formatted table for use with LaTeX's
+{it:booktabs} package.
+{p_end}
+{marker fragment}
+{p 4 8 2}
+{cmd:fragment} causes the table's opening and closing specifications
+to be suppressed. This is relevant primarily in LaTeX and HTML mode.
+
+{p 4 8 2}
+{cmd:page}[{cmd:(}{it:packages}{cmd:)}] adds opening and closing code
+to define a whole LaTeX or HTML document. The default is to produce a
+raw table that can then be included into an existing LaTeX or HTML
+document. Specifying {it:packages} in parentheses causes
+{cmd:\usepackage{c -(}}{it:packages}{cmd:{c )-}} to be added to the
+preamble of the LaTeX document (note that the {it:booktabs} package
+is automatically loaded if {cmd:booktabs} is specified).
+
+{p 4 8 2}
+{cmd:alignment(}{it:string}{cmd:)} may be used to specify the
+alignment of the models' columns in LaTeX, HTML, or RTF mode.
+
+{p 8 8 2}
+In LaTeX mode {it:string} should be a LaTeX column specifier. The
+default is to center the columns. To produce right-aligned columns,
+for example, type {cmd:alignment(r)}. If the table contains multiple
+columns per model/equation, the alignment specification should define
+all columns. For example, if the {cmd:wide} option is specified, you
+could type {cmd:alignment(cr)} to, say, center the point estimates
+and right-align the t-statistics. Note that more sophisticated column
+definitions are often needed to produce appealing results. In
+particular, LaTeX's {it:dcolumn} package proves useful to align
+columns on the decimal point.
+
+{p 8 8 2}
+In HTML mode {it:string} should be a HTML alignment specifier. The
+default is to omit alignment specification, which results in left
+aligned columns. To center the columns in HTML, for example, specify
+{cmd:alignment(center)}. Other than in LaTeX mode, the same alignment
+is used for all columns if the table contains multiple columns per
+model/equation in the HTML mode.
+
+{p 8 8 2}
+In RTF mode {it:string} should be one of {cmd:l}, {cmd:c}, {cmd:r},
+and {cmd:j}. The default is to center the columns. To produce
+right-aligned columns, for example, type {cmd:alignment(r)}. The same
+alignment is used for all columns if the table contains multiple
+columns per model/equation in the RTF mode.
+
+{p 8 8 2}
+Note that {cmd:alignment()} does not change the alignment of the
+variable names/labels in the left stub of the table. They are always
+left-aligned.
+
+{p 4 8 2}
+{cmd:width(}{it:string}{cmd:)} sets the overall width of the table in
+LaTeX or HTML. {it:string} should be LaTeX or HTML literal. For
+example, specify {cmd:width(\hsize)} in LaTeX or {cmd:width(100%)} in
+HTML to span the whole page. The table columns will spread regularly
+over the specified width. Note that in RTF mode {helpb estout}'s
+{cmd:varwidth()} and {cmd:modelwidth()} options may be used to change
+the width of the table columns.
+
+{p 4 8 2}
+{cmdab:longtable} causes the {it:longtable} environment to be used in
+LaTeX. Use {cmdab:longtable} for tables that are too
+long to fit on a single page. {cmdab:longtable} cannot be combined
+with {cmd:width()}. Make sure to load the {it:longtable} package 
+in the LaTeX document, i.e. include {cmd:\usepackage{longtable}} in the 
+document's preamble.
+
+{marker output}
+{dlgtab:Output}
+
+{p 4 8 2}
+{cmd:replace} permits {cmd:esttab} to overwrite an existing file.
+
+{p 4 8 2}
+{cmd:append} specifies that the output be appended to an existing
+file. It may be used even if the file does not yet exist. Specifying
+{cmd:append} together with {cmd:page} in TeX or HTML mode causes the
+new table to be inserted at the end of the body of an existing
+document ({cmd:esttab} seeks a line reading "\end{document}" or
+"</body>", respectively, and starts appending from there;
+contents after this line will be overwritten). In RTF mode, existing
+documents are assumed to end with a line containing a single "}".
+
+{p 4 8 2}
+{cmd:type} specifies that the assembled table be printed in the
+results window and the log file. This is the default unless
+{cmd:using} is specified.
+
+{p 4 8 2}
+{cmd:noisily} displays the executed {helpb estout} command.
+
+{marker advanced}
+{dlgtab:Advanced}
+
+{p 4 8 2}
+{cmd:drop(}{it:droplist}{cmd:)} identifies the coefficients to be
+dropped from the table. A {it:droplist} comprises one or more
+specifications, separated by white space. A specification can be
+either a parameter name (e.g. {cmd:price}), an equation name followed
+by a colon (e.g. {cmd:mean:}), or a full name
+(e.g. {cmd:mean:price}). You may use the {cmd:*} and {cmd:?} wildcards
+in equation names and parameter names. Be sure to refer to the matched
+equation names, and not to the original equation names in the models,
+when using the {cmd:equations()} option to match equations.
+
+{p 4 8 2}
+{cmd:noomitted} drops omitted coefficients (only relevant in Stata 11 or 
+newer).
+
+{p 4 8 2}
+{cmd:nobaselevels} drops base levels of factor variables (only relevant 
+in Stata 11 or newer).
+
+{p 4 8 2}
+{cmd:keep(}{it:keeplist}{cmd:)} selects the coefficients to be
+included in the table. {it:keeplist} is specified analogous to
+{it:droplist} in {cmd:drop()} (see above).
+
+{p 4 8 2}
+{cmd:order(}{it:orderlist}{cmd:)} changes the order of the
+coefficients and equations within the table. {it:orderlist} is
+specified analogous to {it:droplist} in {cmd:drop()} (see above).
+Coefficients and equations that do not appear in {it:orderlist} are
+placed last (in their original order).
+
+{p 4 8 2}
+{cmd:equations(}{it:eqmatchlist}{cmd:)} specifies how the models'
+equations are to be matched. This option is passed to the internal
+call of {cmd:estimates table}. See help {helpb estimates} on how to
+specify this option. The most common usage is {cmd:equations(1)} to
+match all the first equations in the models.
+
+{p 4 8 2}
+{cmd:eform} displays the regression table in exponentiated form. The
+exponent of a coefficient is displayed in lieu of the untransformed
+coefficient; standard errors and confidence intervals are transformed
+as well. Note that the intercept is dropped in eform-mode, unless
+{cmd:constant} is specified.
+
+{p 4 8 2}
+{cmd:unstack} specifies that the individual equations from
+multiple-equation models (e.g. {cmd:mlogit}, {cmd:reg3},
+{cmd:heckman}) be placed in separate columns. The default is to place
+the equations below one another in a single column.
+
+{p 4 8 2}
+{it:estout_options} are any other {cmd:estout} options (see help
+{helpb estout}). Note that {cmd:estout} options take precedence over
+{cmd:esttab} options. For example,
+
+{p 8 20 2}
+{cmd:cells()}{space 5}disables {cmd:b()}, {cmd:beta()}, {cmd:main()},
+{cmd:t()}, {cmd:abs}, {cmd:not}, {cmd:se()}, {cmd:p()}, {cmd:ci()},
+{cmd:aux()}, {cmd:star}, {cmd:staraux}, {cmd:wide}, {cmd:onecell}, 
+{cmd:parentheses}, and {cmd:brackets},
+
+{p 8 20 2}
+{cmd:stats()}{space 5}disables {cmd:r2()}, {cmd:ar2()}, {cmd:pr2()},
+{cmd:aic()}, {cmd:bic()}, {cmd:scalars()}, {cmd:sfmt()}, {cmd:noobs},
+and {cmd:obslast}.
+
+{p 8 8 2}
+Other {cmd:estout} options that should be used with care are
+{cmd:begin()}, {cmd:delimiter()}, {cmd:end()}, {cmd:prehead()},
+{cmd:posthead()}, {cmd:prefoot()}, {cmd:postfoot()}, {cmd:mlabels()},
+and {cmd:varlabels()}. Furthermore, note that {cmd:estout}'s {cmd:style()} 
+option does not have much effect because most options that would be affected 
+by {cmd:style()} are set explicitly by {cmd:esttab}.
+
+{marker fmt}
+{dlgtab:Numerical formats}
+
+{p 4 4 2}
+Numerical display formats may be specified in {cmd:esttab} as follows:
+
+{p 5 8 2}
+1. Official Stata's display formats: You may specify formats, such as
+{cmd:%9.0g} or {cmd:%8.2f}. See help {help format} for a list
+of available formats. {cmd:%g} or {cmd:g} may be used as a
+synonym for {cmd:%9.0g}.
+
+{p 5 8 2}
+2. Fixed format: You may specify an integer value such as {cmd:0},
+{cmd:1}, {cmd:2}, etc. to request a display format with a fixed number
+of decimal places. For example, {cmd:t(3)} would display t-statistics
+with three decimal places.
+
+{p 5 8 2}
+3. Automatic format: You may specify {cmd:a1}, {cmd:a2}, ..., or
+{cmd:a9} to cause {cmd:esttab} to choose a reasonable display format for
+each number depending on the number's value. {cmd:a} may be used as a 
+synonym for {cmd:a3}. The {it:#} in
+{cmd:a}{it:#} determines the minimum precision according to the
+following rules:
+
+{p 10 12 2}
+o Absolute numbers smaller than 1 are displayed with {it:#}
+significant decimal places (i.e. with {it:#} decimal places ignoring
+any leading zeros after the decimal point). For example,
+{cmd:0.00123456} is displayed as {cmd:0.00123} if the format is
+{cmd:a3}.
+
+{p 10 12 2}
+o Absolute numbers greater than 1 are displayed with as many digits
+required to retain at least one decimal place and are displayed with
+a minimum of ({it:#} + 1) digits. For example, if the format is
+{cmd:a3}, {cmd:1.23456} is displayed as {cmd:1.235}, {cmd:12.3456} is
+displayed as {cmd:12.35}, and {cmd:1234.56} is displayed as
+{cmd:1234.6}.
+
+{p 10 12 2}
+o In any case, integers are displayed with zero decimal places, and
+very large or very small absolute numbers are displayed in
+exponential format.
+
+{marker exa}
+{title:Examples}
+
+{p 4 4 2}
+The following examples are intended to illustrate the basic usage of
+{cmd:esttab}.  Additional examples can be found at
+{browse "http://repec.org/bocode/e/estout"}. 
+
+{p 4 4 2} The procedure is to first fit and store some models (see {helpb eststo}) and then apply 
+{cmd:esttab} to these stored estimates:
+
+        {com}. eststo clear
+        {txt}
+        {com}. sysuse auto
+        {txt}(1978 Automobile Data)
+        
+        {com}. eststo: quietly regress price weight mpg
+        {txt}({res}est1{txt} stored)
+        
+        {com}. eststo: quietly regress price weight mpg foreign
+        {txt}({res}est2{txt} stored)
+        
+        {com}. esttab, ar2
+        {res}
+        {txt}{hline 44}
+        {txt}                      (1)             (2)   
+        {txt}                    price           price   
+        {txt}{hline 44}
+        {txt}weight      {res}        1.747**         3.465***{txt}
+                    {res} {ralign 12:{txt:(}2.72{txt:)}}    {ralign 12:{txt:(}5.49{txt:)}}   {txt}
+        
+        {txt}mpg         {res}       -49.51           21.85   {txt}
+                    {res} {ralign 12:{txt:(}-0.57{txt:)}}    {ralign 12:{txt:(}0.29{txt:)}}   {txt}
+        
+        {txt}foreign     {res}                       3673.1***{txt}
+                    {res}                 {ralign 12:{txt:(}5.37{txt:)}}   {txt}
+        
+        {txt}_cons       {res}       1946.1         -5853.7   {txt}
+                    {res} {ralign 12:{txt:(}0.54{txt:)}}    {ralign 12:{txt:(}-1.73{txt:)}}   {txt}
+        {txt}{hline 44}
+        {txt}N           {res}           74              74   {txt}
+        {txt}adj. R-sq   {res}        0.273           0.478   {txt}
+        {txt}{hline 44}
+        {txt}t statistics in parentheses
+        {txt}* p<0.05, ** p<0.01, *** p<0.001
+
+
+{p 4 4 2}
+The same table using labels:
+
+        {com}. esttab, ar2 label
+        {res}
+        {txt}{hline 52}
+        {txt}                              (1)             (2)   
+        {txt}                            Price           Price   
+        {txt}{hline 52}
+        {txt}Weight (lbs.)       {res}        1.747**         3.465***{txt}
+                            {res} {ralign 12:{txt:(}2.72{txt:)}}    {ralign 12:{txt:(}5.49{txt:)}}   {txt}
+        
+        {txt}Mileage (mpg)       {res}       -49.51           21.85   {txt}
+                            {res} {ralign 12:{txt:(}-0.57{txt:)}}    {ralign 12:{txt:(}0.29{txt:)}}   {txt}
+        
+        {txt}Car type            {res}                       3673.1***{txt}
+                            {res}                 {ralign 12:{txt:(}5.37{txt:)}}   {txt}
+        
+        {txt}Constant            {res}       1946.1         -5853.7   {txt}
+                            {res} {ralign 12:{txt:(}0.54{txt:)}}    {ralign 12:{txt:(}-1.73{txt:)}}   {txt}
+        {txt}{hline 52}
+        {txt}Observations        {res}           74              74   {txt}
+        {txt}Adjusted R-squared  {res}        0.273           0.478   {txt}
+        {txt}{hline 52}
+        {txt}t statistics in parentheses
+        {txt}* p<0.05, ** p<0.01, *** p<0.001
+
+
+{p 4 4 2}
+Plain table:
+
+        {com}. esttab, ar2 plain
+        {res}
+        {txt}                     est1         est2
+        {txt}                      b/t          b/t
+        {txt}weight      {res}     1.746559     3.464706{txt}
+                    {res}     2.723238     5.493003{txt}
+        {txt}mpg         {res}    -49.51222      21.8536{txt}
+                    {res}    -.5746808     .2944391{txt}
+        {txt}foreign     {res}                   3673.06{txt}
+                    {res}                  5.370142{txt}
+        {txt}_cons       {res}     1946.069    -5853.696{txt}
+                    {res}      .541018    -1.733408{txt}
+        {txt}N           {res}           74           74{txt}
+        {txt}adj. R-sq   {res}     .2734846     .4781119{txt}
+
+
+{p 4 4 2}
+Using standard errors in brackets and suppress significance stars:
+
+        {com}. esttab, se nostar brackets
+        {res}
+        {txt}{hline 38}
+        {txt}                      (1)          (2)
+        {txt}                    price        price
+        {txt}{hline 38}
+        {txt}weight      {res}        1.747        3.465{txt}
+                    {res} {ralign 12:{txt:[}0.641{txt:]}} {ralign 12:{txt:[}0.631{txt:]}}{txt}
+        
+        {txt}mpg         {res}       -49.51        21.85{txt}
+                    {res} {ralign 12:{txt:[}86.16{txt:]}} {ralign 12:{txt:[}74.22{txt:]}}{txt}
+        
+        {txt}foreign     {res}                    3673.1{txt}
+                    {res}              {ralign 12:{txt:[}684.0{txt:]}}{txt}
+        
+        {txt}_cons       {res}       1946.1      -5853.7{txt}
+                    {res} {ralign 12:{txt:[}3597.0{txt:]}} {ralign 12:{txt:[}3377.0{txt:]}}{txt}
+        {txt}{hline 38}
+        {txt}N           {res}           74           74{txt}
+        {txt}{hline 38}
+        {txt}Standard errors in brackets
+
+
+{p 4 4 2}
+Printing beta coefficients:
+
+        {com}. esttab, beta
+        {res}
+        {txt}{hline 44}
+        {txt}                      (1)             (2)   
+        {txt}                    price           price   
+        {txt}{hline 44}
+        {txt}weight      {res}        0.460**         0.913***{txt}
+                    {res} {ralign 12:{txt:(}2.72{txt:)}}    {ralign 12:{txt:(}5.49{txt:)}}   {txt}
+        
+        {txt}mpg         {res}       -0.097           0.043   {txt}
+                    {res} {ralign 12:{txt:(}-0.57{txt:)}}    {ralign 12:{txt:(}0.29{txt:)}}   {txt}
+        
+        {txt}foreign     {res}                        0.573***{txt}
+                    {res}                 {ralign 12:{txt:(}5.37{txt:)}}   {txt}
+        {txt}{hline 44}
+        {txt}N           {res}           74              74   {txt}
+        {txt}{hline 44}
+        {txt}Standardized beta coefficients; t statistics in parentheses
+        {txt}* p<0.05, ** p<0.01, *** p<0.001
+
+{marker aut}
+{title:Author}
+
+{p 4 4 2}
+Ben Jann, Institute of Sociology, University of Bern, [email protected]
+
+{marker als}
+{title:Also see}
+
+    Manual:  {hi:[R] estimates}
+
+{p 4 13 2}Online:  help for
+ {helpb estimates},
+ {help estcom},
+ {helpb estout},
+ {helpb eststo},
+ {helpb estadd},
+ {helpb estpost}
+{p_end}

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/figout.ado

@@ -0,0 +1,97 @@
+program define figout
+
+*! 1.0.1 Ian Watson 21mar07
+* 1.0.0 Ian Watson 30mar05
+* Program to create mini datasets extracted 
+* from tabout results for use in graphs
+
+
+version 8.2
+syntax using/ ///
+   , [REPlace] infile(string) ///
+   gvars(string) over(string) ///
+   start(string) stop(string)
+   
+
+if "`infile'" ~="" {
+     local infile = "`infile'"
+     local outfile = "`using'"
+   }
+   else {
+     local infile = "`using'"
+     local outfile = "`using'"
+   }
+
+if "`replace'" == "replace" {
+   local opt "replace"
+}
+
+
+tempfile tempfile 
+tempname tablefile
+tempname mainfile
+
+capture file open `mainfile' using `tempfile', write `opt'
+
+     file write `mainfile' "`over'" _tab
+     tokenize "`gvars'"
+     while "`1'" ~= "" {
+          local outword = "`1'"
+          file write `mainfile' "`outword'" _tab
+          mac shift
+     }
+     file write `mainfile' _n
+
+
+
+* open the table file with all the existing output
+
+file open `tablefile' using "`infile'", read
+
+file read `tablefile' line
+     while r(eof) == 0 {
+         if index("`line'","`start'") ~= 0 {
+            file read `tablefile' line
+               local end = 0
+               while `end' == 0 {
+                 local cleanline = subinstr("`line'","\&","and",.)
+                 local cleanline = subinstr("`line'","\","",.)
+*                 local line : subinstr local line "\&" "and"
+*                 local line : subinstr local line "\" ""
+                 tokenize "`cleanline'", parse("&")
+                 while "`1'" ~= "" {
+                    local outword = "`1'"
+                    file write `mainfile' "`outword'" _tab
+                    mac shift 2
+                 }
+                 file write `mainfile' _n
+                 file read `tablefile' line
+                 local end = index("`line'","`stop'")
+                 if r(eof)!=0 {
+                    di as err "figout failed to find your stop word or phrase"
+                    exit
+                }
+               }     
+          }     
+          else {
+             file read `tablefile' line
+          }  
+      } // end while not eof 
+      file write `mainfile' _n
+
+file close `mainfile'
+file close `tablefile'
+
+clear
+insheet using `tempfile'
+if _N!=0 {
+    local k = _N
+    egen order = fill(1/`k')
+    keep `over' `gvars' order
+    save "`outfile'.dta", `opt'
+    list
+}
+else di as err "figout failed to find your start word or phrase"
+
+end
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/figout.hlp

@@ -0,0 +1,119 @@
+{smcl}
+{* 21mar07}{...}
+{hline}
+help for {hi:figout}
+{hline}
+
+{title:Title}
+
+{p 4 4 2}{hi:figout} {hline 2} Ancillary program for {cmd:tabout} to create mini datatsets suitable for graphing
+
+{title:Table of contents}
+
+     {help figout##syn:Syntax}
+     {help figout##des:Description}
+     {help figout##opt:Options}
+     {help figout##exa:Examples}
+
+
+{marker syn}
+{title:Syntax}
+
+{p 8 15 2}    
+{cmdab:figout} {it:using}  {cmd:,}
+{cmd:infile(}{it:string}{cmd:)}
+{cmd:gvars(}{it:string}{cmd:)}
+{cmd:over(}{it:string}{cmd:)}
+{cmd:start(}{it:string}{cmd:)}
+{cmd:stop(}{it:string}{cmd:)}
+[{cmdab:rep:lace(}{it:string}{cmd:)}]
+
+
+
+{marker des}
+{title:Description}
+
+{p 4 4 2}{cmd:figout} is an ancillary program for {help tabout} to facilitate 
+the creation of graphs based on table panels. {cmd:figout} reads the output file 
+produced by {cmd:tabout} looking for a start word or phrase. It then extracts 
+the numbers it finds until it reaches the stop word or phrase.
+It only extracts the number of columns for which you indicate {cmd: gvars}, 
+which conveniently avoids extracting the totals column. Each line in the panel 
+becomes the basis for the {cmd:over} option in the subsequent graph. {cmd:figout} then loads those numbers into a mini dataset and saves it under the name you specify with {cmd:using}. If {cmd:figout} fails to find either the start word or the stop word, no mini dataset is produced and you are issued a warning. Once the mini dataset is created, it is an easy matter to create a {cmd:Stata} graph. The data is in a form suitable for graph's {cmd:over} option, and {cmd:figout} automatically creates an order variable for you, to preserve the same order that was used in your original table.
+
+{p 4 4 2}{cmd:tabout} has a comprehensive tutorial which includes a full 
+example of using {cmd:figout}. This is available from the SSC with this help 
+file. The tutorial is also available here: 
+{browse "http://www.ianwatson.com.au/stata/tabout_tutorial.pdf"}.
+
+
+{marker opt}
+{title:Options}
+
+{phang}
+{cmd:using} is required, and indicates the filename for the output of the mini Stata dataset. Note that you do not need to add the {cmd:dta} filename extension.
+
+{phang}
+{cmd:infile} is required the name of the output file produced by {\tt tabout}, for example, {\tt table1.tex}. Note that you do need to add the filename extension because you may be using {\tt figout} with any number of file types ({\LaTeX}, csv, or tab-delimited).
+
+{phang}
+{cmd:gvars} are names you wish to assign to your graph variables, and they need to match a contiguous block of cells in your table. They are basically the categories of the horizontal variable in your table.
+
+{phang}
+{cmd:over} is the name of the graph variable to be used by the {cmd:over} option in the {cmd:graph} command. It is one the panels in your table, and basically matches one of your vertical variables.
+
+{phang}
+{cmd:start} is a unique word or phrase on the line above the block of cells. It can usually refer to the panel title in a {cmd:tabout} table, unless the title is repeated in another panel.
+
+{phang}
+{cmd:stop} is a unique word or phrase on the line beneath the block of cells. In the case of LaTeX, you can just use \midrule since this generally indicates the end of a panel if you are using the {cmd:ptotal(single)} option.
+
+{phang}
+{cmd:replace} is optional and follows usual Stata convention and prevents you accidentally over-writing an existing Stata dataset with your new mini dataset. If you are confident that there are no other datasets with the same name, you can use the {cmd:replace} option and this makes it more convenient if you need to develop your {cmd:figout} code using several attempts. 
+
+
+{marker exa}
+{title:Examples}
+
+{p 4 4 2}
+The best example is the one given in the {cmd:tabout} tutorial 
+({browse "http://www.ianwatson.com.au/stata/tabout_tutorial.pdf"}) 
+where it's use in batch files is demonstrated. 
+
+
+    {com} sysuse nlsw88, clear
+    {com} gen wt = int(uniform()*10)
+
+    {com} tabout coll race smsa south [iw=wt] using fig_tab.tex, c(row) f(1) ///
+    {txt} style(tex) bt font(bold) topf(top.tex) botf(bot.tex) topstr(10cm) ///
+    {txt} botstr(nlsw88.dta) cl1(2-4) ptot(single)
+
+    {com} figout using fig_fig, infile(fig_tab.tex) rep ///
+    {txt} gvars(not_south south) ///
+    {txt} over(race) start(Race) stop(\midrule) 
+
+    {com} gr hbar not_south south, over(race, sort(order)) ///
+    {txt} ytitle("Percentage", size(medium) ) ///
+    {txt} ylab(0(10)80, angle(0) format(%9.0f) ) ///
+    {txt} bar(1,bcolor(gs4)) bar(2,bcolor(gs8)) ///
+    {txt} legend(label( 1 "Does not live in south") ///
+    {txt} label(2 "Lives in south") ///
+    {txt} pos(4) cols(1) symxsize(3) ring(0) size(medium) ) ///
+    {txt} graphregion(lstyle(solid)) ///
+    {txt} scheme(s2mono) scale(1.1) saving(fig_fig,replace) 
+    {com} gr use fig_fig.gph
+    {com} grexportpdf using fig_fig
+
+
+{title:Author}
+
+   Ian Watson
+   Freelance researcher and
+   Visiting Senior Research Fellow
+   Macquarie University
+   Sydney Australia
+   [email protected]
+   www.ianwatson.com.au
+
+Version 1.0.1 21mar2007
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm.ado

@@ -0,0 +1,589 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 2.0.1 15may2009
+* version 2.0.0 27aug2008
+* version 1.2.1 29jul2008
+* version 1.2.0 18jun2008
+* version 1.0.0 06mar2007
+
+program fmm, properties(ml_score svyb svyj svyr swml)
+version 9.2
+
+if replay() {
+  if ("`e(cmd)'" != "fmm") error 301
+  Replay `0'
+  }
+else Estimate `0'
+end
+
+program Estimate, eclass
+
+// parse the command
+syntax varlist [if] [in]							///
+		[fweight pweight iweight]			///
+		, COMPonents(string) MIXtureof(string)		///
+		[PROBability(string)					///
+		Robust CLuster(varname)	noCONStant		///
+		OFFset(varname numeric)					///
+		EXPosure(varname numeric)				///
+		SHift(real 0.05) SEarch(string) FRom(string)	///
+		DF(real 5) *]
+
+	mlopts mlopts, `options'
+	gettoken lhs rhs : varlist
+
+	if "`search'"=="" local search "off"
+
+	if "`cluster'" != "" {
+		local clopt cluster(`cluster')
+		}
+
+	if "`weight'" != "" {
+		tempvar wvar
+		quietly gen double `wvar' `exp'
+		local wgt "[`weight'=`wvar']"
+		}
+	
+	if "`offset'" != "" {
+		local offopt "offset(`offset')"
+	}
+	if "`exposure'" != "" {
+		local expopt "exposure(`exposure')"
+	}
+
+	// mark the estimation sample
+	marksample touse
+	markout `touse' `wvar' `offset' `exposure'
+	markout `touse' `probability'
+	markout `touse' `cluster', strok
+
+	global fmm_components = `components'
+	global fmm_tdf = `df'
+
+	// check syntax for number of components
+	if "`components'"<"2" | "`components'">"9" {
+		di in red "number of components, components(#), is a required option"
+		di in red "# must be an integer greater than 1 and less than 10"
+		exit 198
+	}
+
+	// check syntax for the distribution mixtureof
+	if  "`mixtureof'"!=""						///
+		& "`mixtureof'"!="gamma"			///
+		& "`mixtureof'"!="lognormal" 		///
+		& "`mixtureof'"!="negbin1"		///
+		& "`mixtureof'"!="negbin2"		///
+		& "`mixtureof'"!="normal" 		///
+		& "`mixtureof'"!="poisson"		///
+		& "`mixtureof'"!="studentt"		///
+		{
+		di in red "invalid syntax: component distribution, mixtureof(), incorrectly specified"
+		exit 198
+	}
+
+	// test collinearity for component RHS variables
+  _rmcoll `rhs' `wgt' if `touse', `constant'
+  local rhs `r(varlist)'
+  _rmcoll `probability' `wgt' if `touse', `constant'
+  local probability `r(varlist)'
+
+	// create density names and equations for ml model
+	local fx `"`fx' (component1: `lhs' = `rhs', `constant' `offopt' `expopt')"'
+	forvalues i=2/`components' {
+		local fx `"`fx' (component`i': = `rhs', `constant' `offopt' `expopt')"'
+	}
+
+	if "`mixtureof'"=="gamma" {
+		local densityname "Gamma"
+		forvalues i=1/`components' {
+			local scale `"`scale' /lnalpha`i'"'
+		}
+	}
+	if "`mixtureof'"=="lognormal" {
+		local densityname "Lognormal"
+		forvalues i=1/`components' {
+			local scale `"`scale' /lnsigma`i'"'
+		}
+	}
+	if "`mixtureof'"=="negbin1" {
+		local densityname "Negative Binomial-1"
+		forvalues i=1/`components' {
+			local scale `"`scale' /lndelta`i'"'
+		}
+	}
+	if "`mixtureof'"=="negbin2" {
+		local densityname "Negative Binomial-2"
+		forvalues i=1/`components' {
+			local scale `"`scale' /lnalpha`i'"'
+		}
+	}
+	if "`mixtureof'"=="normal" {
+		local densityname "Normal"
+		forvalues i=1/`components' {
+			local scale `"`scale' /lnsigma`i'"'
+		}
+	}
+	if "`mixtureof'"=="poisson" {
+		local densityname "Poisson"
+	}
+	if "`mixtureof'"=="studentt" {
+		local densityname "Student-t"
+		forvalues i=1/`components' {
+			local scale `"`scale' /lnsigma`i'"'
+		}
+	}
+
+
+	// SET UP MODELS WITH CONSTANT PROBABILITY SPECIFICATION
+	if "`probability'"=="" {
+		forvalues i=1/`=`components'-1' {
+			local ilp`i' "/imlogitpi`i'"
+			local ilp `" `ilp' `ilp`i'' "'
+		}
+		local Model `"`fx' `ilp' `scale' "'
+
+
+		// GENERATE STARTING VALUES
+		if "`from'"=="" {
+
+			if "`components'"=="2" {
+				tempname lln bn cbn sn bnincr s
+				if "`mixtureof'"=="gamma" {
+					// fit a glm gamma model
+					qui glm `lhs' `rhs' `wgt' if `touse' `in', family(gamma) link(log) ///
+						`constant' `offopt' `expopt'
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = 0
+					matrix `s' = `bn', `sn'
+					// fit a gamma regression model
+					`quietly' display as txt _n "Fitting Gamma regression model:"
+					ml model d2 gammareg_lf (`lhs'=`rhs', `constant' `offopt' `expopt' ) ///
+						/lndelta `wgt' if `touse' `in' ///
+						, `robust' `clopt' `mlopts' collinear missing init(`s', copy) ///
+						maximize search(off)
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = `bn'[1,`cbn']
+					matrix `bn' = `bn'[1,1..(`cbn'-1)]
+					matrix `bnincr'=`bn'
+					matrix `bnincr'[1,`cbn'-1] = `bnincr'[1,`cbn'-1]+`shift'
+				}
+				if "`mixtureof'"=="lognormal" {
+					// fit an ols regression model
+					tempvar loglhs
+					qui gen `loglhs' = ln(`lhs')
+					qui reg `loglhs' `rhs' `wgt' if `touse' `in', `constant'
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = ln(e(rmse))
+					matrix `s' = `bn', `sn'
+					// fit a loglinear regression model
+					`quietly' display as txt _n "Fitting Logormal regression model:"
+					ml model d2 lognormalreg_lf (`lhs'=`rhs', `constant' `offopt' `expopt') ///
+						/lnsigma `wgt' if `touse' `in' ///
+						, `robust' `clopt' `mlopts' collinear missing init(`s', copy) ///
+						maximize search(off)
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = `bn'[1,`cbn']
+					matrix `bn' = `bn'[1,1..(`cbn'-1)]
+					matrix `bnincr'=`bn'
+					matrix `bnincr'[1,`cbn'-1] = `bnincr'[1,`cbn'-1]*(1+`shift')
+				}
+				if "`mixtureof'"=="negbin1" {
+					// fit a nbreg model
+					`quietly' display as txt _n "Fitting Negative Binomial-1 model:"
+					nbreg `lhs' `rhs' `wgt' if `touse' `in' , `robust' `clopt' ///
+						dispersion(constant) nodisplay `constant' `offopt' `expopt'
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = `bn'[1,`cbn']
+					matrix `bn' = `bn'[1,1..(`cbn'-1)]
+					matrix `bnincr'=`bn'
+					matrix `bnincr'[1,`cbn'-1] = `bnincr'[1,`cbn'-1]+`shift'
+				}
+				if "`mixtureof'"=="negbin2" {
+					// fit a nbreg model
+					`quietly' display as txt _n "Fitting Negative Binomial-2 model:"
+					nbreg `lhs' `rhs' `wgt' if `touse' `in' , `robust' `clopt' ///
+						dispersion(mean) nodisplay `constant' `offopt' `expopt'
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = `bn'[1,`cbn']
+					matrix `bn' = `bn'[1,1..(`cbn'-1)]
+					matrix `bnincr'=`bn'
+					matrix `bnincr'[1,`cbn'-1] = `bnincr'[1,`cbn'-1]+`shift'
+				}
+				if "`mixtureof'"=="normal" {
+					// fit an ols regression model
+					qui reg `lhs' `rhs' `wgt' if `touse' `in', `constant'
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = ln(e(rmse))
+					matrix `s' = `bn', `sn'
+					// fit a linear regression model
+					`quietly' display as txt _n "Fitting Normal regression model:"
+					ml model d2 normalreg_lf (`lhs'=`rhs', `constant' `offopt' `expopt') ///
+						/lnsigma `wgt' if `touse' `in' ///
+						, `robust' `clopt' `mlopts' collinear missing init(`s', copy) ///
+						maximize search(off)
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = `bn'[1,`cbn']
+					matrix `bn' = `bn'[1,1..(`cbn'-1)]
+					matrix `bnincr'=`bn'
+					matrix `bnincr'[1,`cbn'-1] = `bnincr'[1,`cbn'-1]*(1+`shift')
+				}
+				if "`mixtureof'"=="poisson" {
+					// fit a Poisson model
+					`quietly' display as txt _n "Fitting Poisson model:"
+					poisson `lhs' `rhs' `wgt' if `touse' `in' , `robust' `clopt' ///
+						nodisplay `constant' `offopt' `expopt'
+					matrix `bn' = e(b)
+					scalar `cbn'=colsof(`bn')
+					matrix `bnincr'=`bn'
+					matrix `bnincr'[1,`cbn'] = `bnincr'[1,`cbn']+`shift'
+					matrix `s' = `bn', `bnincr', 1
+					local contin init(`s', copy) search(`search')
+				}
+				if "`mixtureof'"=="studentt" {
+					// fit an ols regression model
+					qui reg `lhs' `rhs' `wgt' if `touse' `in', `constant'
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = ln(e(rmse))
+					matrix `s' = `bn', `sn'
+					// fit a Student-t regression model
+					`quietly' display as txt _n "Fitting Student-t regression model:"
+					ml model d2 studenttreg_lf (`lhs'=`rhs', `constant' `offopt' `expopt') ///
+						/lnsigma `wgt' if `touse' `in' ///
+						, `robust' `clopt' `mlopts' collinear missing init(`s', copy) ///
+						maximize search(off)
+					matrix `bn' = e(b)
+					scalar `cbn' = colsof(`bn')
+					matrix `sn' = `bn'[1,`cbn']
+					matrix `bn' = `bn'[1,1..(`cbn'-1)]
+					matrix `bnincr'=`bn'
+					matrix `bnincr'[1,`cbn'-1] = `bnincr'[1,`cbn'-1]*(1+`shift')
+				}
+
+				if "`mixtureof'"=="poisson" {
+					matrix `s' = `bn', `bnincr', 1
+				}
+				else {
+					matrix `s' = `bn', `bnincr', 1, `sn', `sn'
+				}
+				local contin init(`s', copy) search(`search')
+
+			}  
+
+			if "`components'">"2" {
+				if "`e(cmd)'"!="fmm" | "`e(components)'"!="`=`components'-1'" ///
+				| "`e(mixtureof)'"!="`mixtureof'" | "`e(probability)'"!="" {
+					di in red "provide starting values or estimate `=`components'-1' component `mixtureof' model"
+					di in red "with constant component probabilities"
+					exit 198
+				}
+
+				if "`mixtureof'"=="poisson" {
+					forvalues i=1/`components' {
+						local tnames `" `tnames' b`i' "'
+					}
+					forvalues i=1/`=`components'-1' {
+						local tnames `" `tnames' ipi`i' pi`i' "' 
+					}
+
+					tempname b cb cb1cl C incr den s sumpi `tnames' pi`components'
+					matrix `b' = e(b)
+					scalar `cb' = colsof(`b')
+					scalar `cb1cl' = (1/(`components'-1))*(`cb'-`components'+2)
+					forvalues i=1/`=`components'-1' {
+						matrix `b`i''=`b'[1,((`i'-1)*`cb1cl'+1)..(`i'*`cb1cl')]
+					}
+
+					forvalues i=1/`=`components'-2' {
+						scalar `ipi`i'' = `b'[1,`cb'-(`components'-2)+`i']
+					}
+					scalar `den' = 1
+					forvalues i=1/`=`components'-2' {
+						scalar `den' = `den' + exp(`ipi`i'')
+					}
+					scalar `sumpi' = 0
+					forvalues i=1/`=`components'-2' {
+						scalar `pi`i'' = exp(`ipi`i'')/`den'
+						scalar `sumpi' = `sumpi' + `pi`i''
+					}
+					scalar `pi`=`components'-1'' = 1-`sumpi'
+
+					matrix `b`components'' = `b1'
+					local C 1
+					matrix `incr'=J(1,`cb1cl',0)
+					matrix `incr'[1,`cb1cl'] = `shift'
+					forvalues i=2/`=`components'-1' {
+						if `pi`i'' > `pi`=`i'-1''{
+							local C `=`i''
+							matrix `b`components'' = `b`i''
+						}
+					}
+					scalar `pi`C'' = (1-`shift')*`pi`C''
+					scalar `pi`components'' = `shift'*`pi`C''
+
+					forvalues i=1/`=`components'-1' {
+						scalar `ipi`i'' = ln(`pi`i''/`pi`components'')
+					}
+
+					forvalues i=1/`=`components'-1' {
+						local bnames `" `bnames' `b`i'', "'
+						local ipinames `" `ipinames', `ipi`i'' "'
+					}
+					matrix `s' = `bnames' `b`components''+`incr' `ipinames'
+					local contin init(`s', copy) search(`search')
+				}
+
+				if "`mixtureof'"!="poisson" {
+					forvalues i=1/`components' {
+						local tnames `" `tnames' b`i' scale`i' "'
+					}
+					forvalues i=1/`=`components'-1' {
+						local tnames `" `tnames' ipi`i' pi`i' "'
+					}
+
+					tempname b cb cb1cl C bcincr den s sumpi `tnames' pi`components'
+					matrix `b' = e(b)
+					scalar `cb' = colsof(`b')
+					scalar `cb1cl' = (1/(`components'-1))*(`cb'-2*`components'+3)
+					forvalues i=1/`=`components'-1' {
+						matrix `b`i'' = `b'[1,((`i'-1)*`cb1cl'+1)..(`i'*`cb1cl')]
+						scalar `scale`i'' = `b'[1,`cb'-`components'+1+`i']
+					}
+					forvalues i=1/`=`components'-2' {
+						scalar `ipi`i'' = `b'[1,`cb'-2*`components'+3+`i']
+					}
+					scalar `den' = 1
+					forvalues i=1/`=`components'-2' {
+						scalar `den' = `den' + exp(`ipi`i'')
+					}
+					scalar `sumpi' = 0
+					forvalues i=1/`=`components'-2' {
+						scalar `pi`i'' = exp(`ipi`i'')/`den'
+						scalar `sumpi' = `sumpi' + `pi`i''
+					}
+					scalar `pi`=`components'-1'' = 1-`sumpi'
+
+					matrix `b`components'' = `b1'
+					matrix `scale`components'' = `scale1'
+					local C 1
+					forvalues i=2/`=`components'-1' {
+						if `pi`i'' > `pi`=`i'-1''{
+							local C `=`i''
+							matrix `b`components'' = `b`i''
+							scalar `scale`components'' = `scale`i''
+						}
+					}
+					matrix `bcincr'=`b`components''
+					matrix `bcincr'[1,`cb1cl'] = `bcincr'[1,`cb1cl']*(1+`shift')
+					scalar `pi`C'' = (1-`shift')*`pi`C''
+					scalar `pi`components'' = `shift'*`pi`C''
+					forvalues i=1/`=`components'-1' {
+						scalar `ipi`i'' = ln(`pi`i''/`pi`components'')
+					}
+
+					forvalues i=1/`=`components'-1' {
+						local bnames `" `bnames' `b`i'', "'
+						local ipinames `" `ipinames', `ipi`i'' "'
+					}
+					forvalues i=1/`components' {
+						local scalenames `" `scalenames', `scale`i'' "'
+					}
+					matrix `s' = `bnames' `bcincr' `ipinames' `scalenames'
+					local contin init(`s', copy) search(`search')
+				}
+			}
+		}
+
+		// if starting values are provided
+		if `"`from'"'!="" {
+			local contin init(`from',copy) search(`search')
+		}
+
+
+		// fit the full model
+		local title "`components' component `densityname' regression"
+		`quietly' display as txt _n "Fitting `components' component `densityname' model:"
+/*		ml model d2debug fmm_`mixtureof'_lf `Model' `wgt' if `touse' `in' ///
+			, `contin' maximize */
+		ml model d2 fmm_`mixtureof'_lf `Model' `wgt' if `touse' `in' ///
+			, title(`title') `robust' `clopt' `mlopts' `contin' ///
+			collinear missing waldtest(`components') maximize
+		ereturn local cmd fmm
+		ereturn local components "`components'"
+		ereturn local mixtureof "`mixtureof'"
+		ereturn local predict "fmm_`mixtureof'_p"
+		if "`mixtureof'"=="poisson" {
+			ereturn scalar k_aux = `components'-1
+		}
+		else {
+			ereturn scalar k_aux = 2*`components'-1
+		}
+
+		Replay
+	}
+
+	// SET UP MODELS WITH REGRESSORS IN THE PROBABILITY SPECIFICATION
+	if "`probability'"!="" {
+		forvalues i=1/`=`components'-1' {
+			local ilp `" `ilp' (imlogitpi`i': = `probability')"'
+		}
+		local Model `"`fx' `ilp' `scale' "'
+
+		if "`from'"=="" {
+			if "`e(cmd)'"!="fmm" | "`e(components)'"!="`=`components''" ///
+				| "`e(mixtureof)'"!="`mixtureof'" | "`e(probability)'"!="" {
+				di in red "provide starting values or estimate `components' component `densityname' model"
+				di in red "with constant component probabilities"
+				exit 198
+			}
+
+			// get starting values from prior LC model
+			tempname s
+			mat `s'= e(b)
+			local contin init(`s') search(`search')
+		}
+
+		if `"`from'"'!="" {
+			local contin init(`from',copy) search(`search')
+		}
+
+		// fit the full model
+		local title `title'
+		`quietly' display as txt _n "Fitting `components' component `densityname' model:"
+		ml model d2 fmm_`mixtureof'_lf `Model' `wgt' if `touse' `in' ///
+			, title(`title') `robust' `clopt' `mlopts' `contin' ///
+			collinear missing waldtest(`components') maximize
+
+		ereturn local cmd fmm
+		ereturn local components "`components'"
+		ereturn local mixtureof "`mixtureof'"
+		ereturn local probability "`probability'"
+		ereturn local predict "fmm_`mixtureof'_p"
+		if "`mixtureof'"=="poisson" {
+			ereturn scalar k_aux = 0
+		}
+		else {
+			ereturn scalar k_aux = `components'
+		}
+
+		Replay
+	}
+
+end
+
+
+program Replay, eclass
+
+	ml display
+
+	local components `e(components)'
+	local mixtureof `e(mixtureof)'
+	local probability `e(probability)'
+
+	if "`mixtureof'"=="gamma" {
+		local scale `"alpha"'
+	}
+	if "`mixtureof'"=="lognormal" {
+		local scale `"sigma"'
+	}
+	if "`mixtureof'"=="negbin1" {
+		local scale "delta"
+	}
+	if "`mixtureof'"=="negbin2" {
+		local scale "alpha"
+	}
+	if "`mixtureof'"=="normal" {
+		local scale `"sigma"'
+	}
+	if "`mixtureof'"=="studentt" {
+		local scale `"sigma"'
+	}
+
+	if "`probability'"=="" {
+
+		if `components'==2 {
+			if "`mixtureof'"!="poisson" {
+				_diparm ln`scale'1, exp label(`scale'1)
+				ereturn scalar `scale'1_est = r(est)
+				ereturn scalar `scale'1_se = r(se)
+				_diparm ln`scale'2, exp label(`scale'2)
+				ereturn scalar `scale'2_est = r(est)
+				ereturn scalar `scale'2_se = r(se)
+			}
+			_diparm imlogitpi1, invlogit label(pi1)
+			ereturn scalar pi1_est = r(est)
+			ereturn scalar pi1_se = r(se)
+			local prob2 diparm(imlogitpi1, func(1-exp(@)/(1+exp(@))) ///
+							der(-exp(@)/((1+exp(@))^2)) label(pi2))
+			_diparm imlogitpi1, func(1-exp(@)/(1+exp(@))) ///
+							der(-exp(@)/((1+exp(@))^2)) label(pi2)
+			ereturn scalar pi2_est = r(est)
+			ereturn scalar pi2_se = r(se)
+		}
+
+		if `components'>=3 {
+			if "`mixtureof'"!="poisson" {
+				forvalues j=1/`components' {
+					_diparm ln`scale'`j', exp label(`scale'`j')
+					ereturn scalar `scale'`j'_est = r(est)
+					ereturn scalar `scale'`j'_se = r(se)
+
+				}
+			}
+			local den "1"
+			forvalues i=1/`=`components'-1' {
+				local den `"`den'+exp(@`i')"'
+				local invml `"`invml' imlogitpi`i'"'
+			}
+			forvalues i=1/`=`components'-1' {
+				local prob`i' `"_diparm `invml', func(exp(@`i')/(`den')) der("'
+				forvalues j=1/`=`components'-1' {
+					if `i'==`j' {
+						local prod `"`den'-exp(@`i')"'
+						local der`i'`j' `"+0+exp(@`i')*(`prod')/((`den')^2)"'
+					}
+					else {
+						local der`i'`j' `"-exp(@`i')*exp(@`j')/((`den')^2)"'
+					}
+					local prob`i' `"`prob`i'' `der`i'`j''"'
+				}
+				local prob`i' `" `prob`i'' ) label(pi`i') ci(logit) "'
+				`prob`i''
+				ereturn scalar pi`i'_est = r(est)
+				ereturn scalar pi`i'_se = r(se)
+
+			}
+			forvalues j=1/`=`components'-1' {
+				forvalues i=1/`=`components'-1' {
+					local sumder`j' `"`sumder`j''`der`i'`j''"'
+				}
+				local derivs `"`derivs'`sumder`j'' "'
+			}
+			_diparm `invml', func(1-(`den'-1)/(`den')) ///
+				der(`derivs') label(pi`components')
+			ereturn scalar pi`components'_est = r(est)
+			ereturn scalar pi`components'_se = r(se)
+		}
+		_diparm __bot__
+	}
+
+	if "`probability'"!="" {
+		if "`mixtureof'"!="poisson" {
+			forvalues j=1/`components' {
+				_diparm ln`scale'`j', exp label(`scale'`j')
+				ereturn scalar `scale'`j'_est = r(est)
+				ereturn scalar `scale'`j'_se = r(se)
+			}
+			_diparm __bot__
+		}
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm.hlp

@@ -0,0 +1,240 @@
+{smcl}
+{* documented: June 12, 2007}{...}
+{* revised: February 12, 2012}{...}
+{cmd:help fmm} {right:also see:  {helpb fmm postestimation}}
+
+{hline}
+
+{title:Title}
+
+{cmd :fmm} {hline 2} Finite mixture models
+
+
+{title:Syntax}
+
+{phang}
+Finite mixture models
+
+{p 8 14 2}
+{cmd:fmm} {depvar} [{indepvars}] {ifin} {weight}{cmd:,} {opt comp:onents(#)}
+{opth mix:tureof(fmm##density:density)} [{it:{help fmm##fmm_options:fmm_options}}]
+
+{synoptset 28 tabbed}{...}
+{marker fmm_options}{...}
+{synopthdr :fmm_options}
+{synoptline}
+{syntab :Model}
+{synopt :{opt comp:onents(#)}}specifies the number of mixture components.  It is 
+required.{p_end}
+{synopt :{opth mix:tureof(fmm##density:density)}}specifies the component density.  
+It is required.{p_end}
+
+{syntab :Model 2}
+{synopt :{opth prob:ability(varlist)}}specifies the variables used to model the component probabilities.{p_end}
+{synopt :{opt df(#)}}specifies the degrees of freedom of the Student-t density.  The default is 5.{p_end}
+{synopt :{opt nocons:tant}}suppress constant term{p_end}
+{synopt :{opth exp:osure(varname)}}include ln({it:varname}) in model with
+coefficient constrained to 1.{p_end}
+{synopt :{opth off:set(varname)}}include {it:varname} in model with coefficient
+constrained to 1.{p_end}
+{synopt :{opth cons:traint(constraint)}}apply specified linear constraints.{p_end}
+
+{syntab :SE/Robust}
+{synopt :{opth vce(vcetype)}}{it:vcetype} may be {opt oim}, {opt r:obust}, {opt opg}, {opt boot:strap}, or {opt jack:knife}{p_end}
+{synopt :{opt r:obust}}synonym for {cmd:vce(robust)}{p_end}
+{synopt :{opth cl:uster(varname)}}adjust standard errors for intragroup correlation{p_end}
+
+{syntab :Max options}
+{synopt :{it:{help fmm##fmm_maximize:maximize_options}}}control the maximization process; some options may be useful{p_end}
+{synoptline}
+{p2colreset}{...}
+{p 4 6 2} {it:depvar}, {it:indepvars}, {it:varname_e}, and {it:varname_o} may
+contain time-series operators; see {help tsvarlist}.{p_end}
+
+{p 4 6 2}  {cmd:fweight}s, {cmd:pweight}s, {cmd:iweight}s, and {cmd:aweight}s 
+are allowed; see {help weight}.{p_end}
+{p 4 6 2} See {help postestimation commands} for features available after estimation.
+
+{marker density}{...}
+{synoptset 23}{...}
+{synopthdr :density}
+{synoptline}
+{synopt :{opt gamma}}Gamma{p_end}
+{synopt :{opt lognormal}}Lognormal{p_end}
+{synopt :{opt negbin1}}Negative Binomial-1 (constant dispersion){p_end}
+{synopt :{opt negbin2}}Negative Binomial-2 (mean dispersion){p_end}
+{synopt :{opt normal}}Normal or Gaussian{p_end}
+{synopt :{opt poisson}}Poisson{p_end}
+{synopt :{opt studentt}}Student-t with {opt df} degrees of freedom{p_end}
+{synoptline}
+{p2colreset}{...}
+
+
+{title:Description}
+
+{pstd}
+{cmd:fmm} fits a finite mixture regression model of {it:depvar} on {it:indepvars} 
+using maximum likelihood estimation.  The model is a {it:J}-component finite mixture 
+of densities, with the density within a component (j) allowed to vary in location 
+and scale.  Optionally, the mixing probabilities may be specified with covariates.
+
+
+{title:Options for fmm}
+
+{dlgtab:Model}
+
+{phang}
+{opt comp:onents(#)} specifies the number of mixing components.  It is an 
+integral part of specifying the finite mixture model and is not optional.  
+{it:#} should be an integer between 2 and 9.
+
+{phang}
+{opt mix:tureof(density)} specifies the component density in the 
+mixture model.  It is not optional.  For more on the available choices of 
+component densities and associated specifications of conditional means, see 
+{opt Remarks} below.
+
+{dlgtab:Model 2}
+
+{phang}
+{opt prob:ability(varlist)} specifies the variables used to model 
+the component probabilities.  The probabilities are specified using a 
+multinomial logit parameterization.
+
+{phang}
+{opt df(#)} specifies the degrees of freedom if a Student-t component density 
+is specified.  The default value is 5.
+
+{phang}
+{opt nocons:tant}, {opth exp:osure(varname)}, {opt off:set(varname)},
+{opt cons:traints(constraints)}; see {help estimation options}.
+
+{dlgtab:SE/Robust}
+
+{phang}
+{opt vce(vcetype)}; see {it:{help vce_option}}.
+
+{phang}
+{opt r:obust}, {opt cl:uster(varname)}; see {help estimation options}.
+{opt cl:uster()} can be used with {help pweight}s to produce estimates for
+unstratified cluster-sampled data.
+
+{dlgtab:Reporting}
+
+{phang}
+{opt level(#)}; see {help estimation options}.
+
+{marker fmm_maximize}{...}
+{dlgtab:Max options}
+
+{phang}
+{it:maximize_options}: {opt dif:ficult}, {opt tech:nique(algorithm_spec)},
+{opt iter:ate(#)}, [{cmdab:no:}]{opt lo:g}, {opt tr:ace},
+{opt grad:ient}, {opt showstep}, {opt hess:ian},
+{opt shownr:tolerance}, {opt tol:erance(#)}, {opt ltol:erance(#)},
+{opt gtol:erance(#)}, {opt nrtol:erance(#)}, {opt nonrtol:erance},
+{opt fr:om(init_specs)}; see {help maximize} are standard {help ml} options.{p_end}
+
+
+{phang}
+{opt sh:ift(#)} generates alternative starting values by systematically 
+shifting some values from the default algorithm by the proportion {opt #}.{p_end}
+
+
+{phang}
+{opt se:arch(spec)} {it:spec} may be {opt on} or {opt off} and specifies whether
+{help ml}'s initial search algorithm is used.  The default is {opt off}.{p_end}
+
+{phang}
+Because finite mixture models have complicated likelihood functions, 
+{opt shift(#)}, {opt search(spec)}, {opt dif:ficult} and {opt from(init_specs)} 
+may be useful choices if the default setup fails. The other options are seldom 
+used.{p_end}
+
+
+{title:Remarks}
+
+{pstd}
+If {opt components(2)} is specified, default starting values are specified using 
+the parameters from the associate degenerate mixture model.  In order to take 
+advantage of the built-in algorithms for specifying starting values for models 
+with {it #} components, ({it #}>2), the user must estimate models sequentially 
+{it #}=2.  This is the preferred estimation approach.  But {cmd:fmm} will not 
+check for reasonableness of the prior {cmd:fmm} estimates, so proceed 
+carefully.  Otherwise, {cmd:fmm} expects the user to specify starting values 
+using the {opt from(init_specs)} option.{p_end}
+
+{pstd}
+The available component densities and the associated conditional means are
+
+{tab}Density {col 30} {cmd:fmm} option {col 50} cond. mean
+{tab}{hline 70}
+{tab}Gamma {col 30} {cmd:density(gamma)} {col 50} alpha_j exp(xb_j)
+{tab}Lognormal {col 30} {cmd:density(lognormal)} {col 50} exp(xb_j + 0.5 sigma_j^2)
+{tab}Negative Binomial-1 {col 30} {cmd:density(negbin1)} {col 50} exp(xb_j)
+{tab}Negative Binomial-2 {col 30} {cmd:density(negbin2)} {col 50} exp(xb_j)
+{tab}Normal(Gaussian) {col 30} {cmd:density(normal)} {col 50} xb_j
+{tab}Poisson {col 30} {cmd:density(poisson)} {col 50} exp(xb_j)
+{tab}Student-t {col 30} {cmd:density(studentt)}	 {col 50} xb_j
+
+{pstd}
+Note that {cmd:fmm} has not been updated to accommodate factor variables.
+
+
+{title:Saved results}
+
+{pstd}In addition to standard results saved by maximum likelihood procedures
+in {opt e()}, {cmd:fmm} saves the following scalars:
+
+{tab}{opt e(parname_est)} parameter estimate
+{tab}{opt e(parname_se)} standard error of estimate
+
+{pstd}where {it:parname} denotes either a scale parameter or a mixing 
+probability parameter.
+ 
+
+{title:Examples}
+
+{pstd}Mixture of normals
+
+{phang}{stata "webuse womenwk, clear" : . webuse womenwk, clear}
+
+{phang}{stata "fmm wagefull educ age married, mix(normal) comp(2)" : . fmm wagefull educ age married, mix(normal) comp(2)}
+
+
+{pstd}Mixture of Negative Binomials (Type 2)
+
+{phang}{stata "webuse medpar, clear" : . webuse medpar, clear}
+
+{phang}{stata "gen los0 = los - 1" : . gen los0 = los - 1}
+
+{phang}{stata "fmm los0 died hmo type2-type3, mix(negbin2) comp(2)" : . fmm exlos died hmo type2-type3, mix(negbin2) comp(2) comp(2)}
+
+
+{title:References}
+
+{p 4 8 2}Conway, K. and P. Deb, (2005), Is Prenatal Care Really Ineffective? 
+Or, is the 'Devil' in the Distribution?, {it:Journal of Health Economics}, 
+24, 489-513.
+
+{p 4 8 2}Deb, P. and P. K. Trivedi (1997), Demand for Medical Care by 
+the Elderly: A Finite Mixture Approach, {it:Journal of Applied Econometrics}, 
+12, 313-326.
+
+{p 4 8 2}McLachlan, G.J., and D. Peel (2000), {it:Finite Mixture Models}, 
+New York: John Wiley.
+
+{p 4 8 2}Titterington, D.M., A.F.M. Smith and U.E. Makow (1985), 
+{it:Statistical Analysis of Finite Mixture Distributions}, New York: John Wiley, 1985.
+
+
+{title:Author}
+
+{phang}Partha Deb, Hunter College and the Graduate Center, City University of New York, USA{p_end}
+{phang}[email protected]{p_end}
+
+
+{title:Also see}
+
+{psee}
+Online:  {help fmm postestimation}{p_end}

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_gamma_lf.ado

@@ -0,0 +1,243 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.0.1  24apr2007
+* version 1.0.0 06mar2007
+
+program fmm_gamma_lf
+	version 9.2
+
+	forvalues i = 1/$fmm_components {
+		local L_xb `"`L_xb' xb`i'"'
+		local L_exb `"`L_exb' exb`i'"'
+		local L_fxb `"`L_fxb' fxb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_lalp `"`L_lalp' lnalpha`i'"'
+		local L_alp `"`L_alp' alpha`i'"'
+		local L_gb `"`L_gb' gb`i'"'
+		local L_gs `"`L_gs' gs`i'"'
+	}
+
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local L_gL `"`L_gL' gL`i'"'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			local L_h `"`L_h' h`i'`j'"'
+			local L_nh `"`L_nh' nh`i'`j'"'
+		}
+	}
+
+	forvalues i = 1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+		forvalues j = 1/`=$fmm_components-1' {
+			local L_ga `"`L_ga' ga`i'`j'"'
+		}
+	}
+
+	// model arguments and temporary variables
+	args todo b lnf g negH `L_gL'
+	tempname `L_xb' `L_exb' `L_fxb' `L_lalp' `L_alp' `L_lpr' `L_pr' ///
+						den prob gi `L_gb' `L_ga' `L_gs' hij `L_h' `L_nh'
+
+	// set up equations
+	forvalues i=1/$fmm_components {
+		mleval `xb`i'' = `b', eq(`i')
+		qui gen double `exb`i'' = exp(`xb`i'')
+		mleval `lnalpha`i'' = `b', eq(`=2*$fmm_components-1+`i'')
+		qui gen double `alpha`i'' = exp(`lnalpha`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		mleval `lpr`i'' = `b', eq(`=$fmm_components+`i'')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+
+	// calculate the likelihood function
+	qui gen double `prob' = 0
+	forvalues i=1/$fmm_components {
+		qui gen double `fxb`i'' = gammaden(`alpha`i'',`exb`i'',0,$ML_y)
+		qui replace `prob' = `prob' + `pr`i''*`fxb`i''
+	}
+
+	mlsum `lnf' = ln(`prob')
+
+
+	// CALCULATE GRADIENT TERMS
+	// gradient bi
+	forvalues i = 1/$fmm_components {
+		qui gen double `gb`i'' = -`alpha`i'' + $ML_y/`exb`i''	// density specific
+		qui replace `gL`i'' = (`pr`i'' * `fxb`i'' * `gb`i'')/`prob'
+	}
+
+	// gradient prj
+	forvalues j = 1/`=$fmm_components-1' {
+		local m = `=$fmm_components+`j''
+		qui replace `gL`m'' = 0
+		forvalues k = 1/`=$fmm_components-1' {
+			qui gen double `ga`k'`j'' = ((`j'==`k') - `pr`j'')
+			qui replace `gL`m'' = `gL`m'' + `pr`k''*`ga`k'`j'' ///
+											*(`fxb`k'' - `fxb$fmm_components')/`prob'
+		}
+	}
+
+	// gradient alphai
+	forvalues i=1/$fmm_components {
+		local k = `=2*$fmm_components-1+`i''
+		qui gen double `gs`i'' = (-digamma(`alpha`i'') - `xb`i'' ///
+															+ log($ML_y))*`alpha`i''	// density specific
+		qui replace `gL`k'' = (`pr`i'' * `fxb`i'' * `gs`i'')/`prob'
+	}
+
+	// collect gradient terms into vector
+	local np = colsof(`b')
+	local c 1
+	matrix `g' = J(1,`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		mlvecsum `lnf' `gi' = `gL`i'', eq(`i')
+		matrix `g'[1,`c'] = `gi'
+		local c = `c' + colsof(`gi')
+	}
+
+
+	// CALCULATE HESSIAN TERMS
+	// hessian - b terms
+	local c 1
+	qui gen double `hij' = .
+	forvalues i = 1/$fmm_components {
+		// hessian (bi,bi)
+		qui replace `hij' = -$ML_y/`exb`i''					// density specific
+		qui gen double `h`i'`i'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`i''*`gb`i'' + `gb`i''^2 + `hij')
+		mlmatsum `lnf' `nh`i'`i'' = -`h`i'`i'', eq(`i',`i')
+		// hessian (bi,bj)
+		if (`i'<$fmm_components) {
+			forvalues j = `=`i'+1'/$fmm_components {
+				qui gen double `h`i'`j'' = `pr`i''/`prob'*(-`gL`j''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`j'' = -`h`i'`j'', eq(`i',`j')
+			}
+		}
+
+		// hessian (bi,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' ///
+						+ 1/`prob'*`fxb`i''*`gb`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`i'`m'' = `h`i'`m'' ///
+							- 1/`prob'*`fxb`i''*`gb`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+
+		// hessian (bi,alpha)
+		forvalues j = 1/$fmm_components {
+			local k = `=2*$fmm_components-1+`j''
+			// hessian (bi,alphai)
+			if (`i'==`j') {
+				qui replace `hij' = -`alpha`j''			// density specific
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*`fxb`i'' ///
+					*(-`gL`k''*`gb`i'' + `gs`j''*`gb`i'' + `hij')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+			else {
+			// hessian (bi,alphaj)
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*(-`gL`k''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+		}
+	}
+
+	// hessian - pr terms
+	// hessian (prj,pri)
+	forvalues i = 1/`=$fmm_components-1' {
+		forvalues j = `i'/`=$fmm_components-1' {
+			local m = `=$fmm_components+`i''
+			local n = `=$fmm_components+`j''
+			qui gen double `h`m'`n'' = -`gL`m''*`gL`n''
+			qui replace `hij' = -`pr`i''*((`i'==`j') - `pr`j'')
+			forvalues k = 1/`=$fmm_components-1' {
+				qui replace `h`m'`n'' = `h`m'`n'' ///
+						+ 1/`prob'*`pr`k''*(`fxb`k'' - `fxb$fmm_components') ///
+						*(`ga`k'`i''*`ga`k'`j'' + `hij')
+			}
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+	}
+
+	// hessian - alpha terms
+	forvalues i = 1/$fmm_components {
+		// hessian w.r.t. alphai
+		local m = `=2*$fmm_components-1+`i''
+		qui replace `hij' = (-digamma(`alpha`i'') - `xb`i'' + log($ML_y) ///
+								- trigamma(`alpha`i'')*`alpha`i'')*`alpha`i''	// density specific
+		qui gen double `h`m'`m'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`m''*`gs`i'' + `gs`i''^2 + `hij')
+		mlmatsum `lnf' `nh`m'`m'' = -`h`m'`m'', eq(`m',`m')
+		// hessian w.r.t. alphaj (cross partials)
+		forvalues j = `=`i'+1'/$fmm_components {
+			local n = `=2*$fmm_components-1+`j''
+			qui gen double `h`m'`n'' = `pr`i''/`prob'*(-`gL`n''*`fxb`i''*`gs`i'')
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+
+	// hessian (alphai,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' ///
+						+ 1/`prob'*`fxb`i''*`gs`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`m'`n'' = `h`m'`n'' ///
+							- 1/`prob'*`fxb`i''*`gs`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+	}
+
+	// collect hessian terms into matrix
+	local np = colsof(`b')
+	local r 1
+	matrix `negH' = J(`np',`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local c = `r'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			matrix `negH'[`r',`c'] = `nh`i'`j''
+			if (`j'>`i') {
+				matrix `negH'[`c',`r'] = `nh`i'`j'''
+			}
+			local c = `c' + colsof(`nh`i'`j'')
+		}
+		local r = `r' + rowsof(`nh`i'`i'')
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_gamma_p.ado

@@ -0,0 +1,93 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 2.0.1 29jul2011
+* version 2.0.0 27aug2008
+* version 1.1.0  12jul2007
+* version 1.0.0 06mar2007
+
+program fmm_gamma_p
+	version 9.2
+
+	syntax anything(id="newvarname") [if] [in] [, MEan PRIor POSterior EQuation(string) ]
+
+	syntax newvarname [if] [in] [, * ]
+
+	forvalues i=1/$fmm_components {
+		local L_exb `"`L_exb' exb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_lod `"`L_lod' lnalpha`i'"'
+		local L_od `"`L_od' alpha`i'"'
+	}
+	forvalues i=1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+	}
+
+	tempvar `L_exb' `L_lpr' `L_pr' `L_lod' `L_od' den
+
+	forvalues i=1/$fmm_components {
+		qui _predict `typlist' `exb`i'' `if' `in', equation(component`i')
+		qui replace `exb`i'' = exp(`exb`i'')
+		qui _predict double `lnalpha`i'' `if' `in', equation(lnalpha`i')
+		qui gen double `alpha`i'' = exp(`lnalpha`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui _predict `typlist' `lpr`i'' `if' `in', equation(imlogitpi`i')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+	if "`equation'" != "" & "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		local i = substr("`equation'",-1,1)
+		qui replace `varlist' = `alpha`i'' * `exb`i''
+		label variable `varlist' "predicted mean: `equation'"
+		exit
+	}
+
+	if "`equation'" == "" & "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `varlist' = `varlist' + `pr`i'' * `alpha`i'' * `exb`i''
+		}
+		label variable `varlist' "predicted mean"
+		exit
+	}
+
+	if "`prior'" == "prior" {
+		local i = substr("`equation'",-1,1)
+		gen `typlist' `varlist' = `pr`i'' `if' `in'
+		label variable `varlist' "prior probability: `equation'"
+		exit
+	}
+
+
+	if "`posterior'" == "posterior" {
+		tempvar prob probcomponent
+
+		local fmm_y = e(depvar)
+		qui gen double `prob' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `prob' = `prob' + `pr`i'' ///
+				* gammaden(`alpha`i'',`exb`i'',0,`fmm_y') 
+			if "`equation'"=="component`i'" {
+				qui gen double `probcomponent' = `pr`i'' ///
+				* gammaden(`alpha`i'',`exb`i'',0,`fmm_y') 
+			}
+		}
+		gen `typlist' `varlist' = `probcomponent' / `prob'
+		label variable `varlist' "posterior probability: `equation'"
+		exit
+	}
+
+end
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_lognormal_lf.ado

@@ -0,0 +1,243 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.0.0  05sep2011
+
+program fmm_lognormal_lf
+	version 9.2
+
+	forvalues i = 1/$fmm_components {
+		local L_xb `"`L_xb' xb`i'"'
+		local L_fxb `"`L_fxb' fxb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_z `"`L_z' z`i'"'
+		local L_lsig `"`L_lsig' lnsigma`i'"'
+		local L_sig `"`L_sig' sigma`i'"'
+		local L_gb `"`L_gb' gb`i'"'
+		local L_gs `"`L_gs' gs`i'"'
+	}
+
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local L_gL `"`L_gL' gL`i'"'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			local L_h `"`L_h' h`i'`j'"'
+			local L_nh `"`L_nh' nh`i'`j'"'
+		}
+	}
+
+	forvalues i = 1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+		forvalues j = 1/`=$fmm_components-1' {
+			local L_ga `"`L_ga' ga`i'`j'"'
+		}
+	}
+
+	// model arguments and temporary variables
+	args todo b lnf g negH `L_gL'
+	tempname `L_xb' `L_fxb' `L_lsig' `L_sig' `L_lpr' `L_pr' `L_z' ///
+						den prob gi `L_gb'  `L_ga' `L_gs' hij `L_h' `L_nh'
+
+	// set up equations
+	forvalues i=1/$fmm_components {
+		mleval `xb`i'' = `b', eq(`i')
+		mleval `lnsigma`i'' = `b', eq(`=2*$fmm_components-1+`i'')
+		qui gen double `sigma`i'' = exp(`lnsigma`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		mleval `lpr`i'' = `b', eq(`=$fmm_components+`i'')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+
+	// calculate the likelihood function
+	qui gen double `prob' = 0
+	forvalues i=1/$fmm_components {
+		qui gen double `z`i'' = .
+		qui gen double `fxb`i'' = normalden(ln($ML_y),`xb`i'',`sigma`i'') / $ML_y
+		qui replace `prob' = `prob' + `pr`i''*`fxb`i''
+	}
+
+	mlsum `lnf' = ln(`prob')
+
+
+	// CALCULATE GRADIENT TERMS
+	// gradient bi
+	forvalues i = 1/$fmm_components {
+		qui replace `z`i'' = (ln($ML_y)-`xb`i'')/`sigma`i''
+		qui gen double `gb`i'' = `z`i''/`sigma`i''				// density specific
+		qui replace `gL`i'' = (`pr`i'' * `fxb`i'' * `gb`i'')/`prob'
+	}
+
+	// gradient prj
+	forvalues j = 1/`=$fmm_components-1' {
+		local m = `=$fmm_components+`j''
+		qui replace `gL`m'' = 0
+		forvalues k = 1/`=$fmm_components-1' {
+			qui gen double `ga`k'`j'' = ((`j'==`k') - `pr`j'')
+			qui replace `gL`m'' = `gL`m'' + `pr`k''*`ga`k'`j'' ///
+											*(`fxb`k'' - `fxb$fmm_components')/`prob'
+		}
+	}
+
+	// gradient sigmai
+	forvalues i=1/$fmm_components {
+		local k = `=2*$fmm_components-1+`i''
+		qui gen double `gs`i'' = `z`i''*`z`i''-1					// density specific
+		qui replace `gL`k'' = (`pr`i'' * `fxb`i'' * `gs`i'')/`prob'
+	}
+
+	// collect gradient terms into vector
+	local np = colsof(`b')
+	local c 1
+	matrix `g' = J(1,`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		mlvecsum `lnf' `gi' = `gL`i'', eq(`i')
+		matrix `g'[1,`c'] = `gi'
+		local c = `c' + colsof(`gi')
+	}
+
+
+	// CALCULATE HESSIAN TERMS
+	// hessian - b terms
+	local c 1
+	qui gen double `hij' = .
+	forvalues i = 1/$fmm_components {
+		// hessian (bi,bi)
+		qui replace `hij' = -1/(`sigma`i''^2)							// density specific
+		qui gen double `h`i'`i'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`i''*`gb`i'' + `gb`i''^2 + `hij')
+		mlmatsum `lnf' `nh`i'`i'' = -`h`i'`i'', eq(`i',`i')
+		// hessian (bi,bj)
+		if (`i'<$fmm_components) {
+			forvalues j = `=`i'+1'/$fmm_components {
+				qui gen double `h`i'`j'' = `pr`i''/`prob'*(-`gL`j''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`j'' = -`h`i'`j'', eq(`i',`j')
+			}
+		}
+
+		// hessian (bi,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' ///
+						+ 1/`prob'*`fxb`i''*`gb`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`i'`m'' = `h`i'`m'' ///
+							- 1/`prob'*`fxb`i''*`gb`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+
+
+		// hessian (bi,sigma)
+		forvalues j = 1/$fmm_components {
+			local k = `=2*$fmm_components-1+`j''
+			// hessian (bi,sigmai)
+			if (`i'==`j') {
+				qui replace `hij' = -2*`z`j''/`sigma`j''			// density specific
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*`fxb`i'' ///
+					*(-`gL`k''*`gb`i'' + `gs`j''*`gb`i'' + `hij')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+			else {
+			// hessian (bi,sigmaj)
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*(-`gL`k''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+		}
+	}
+
+	// hessian - pr terms
+	// hessian (prj,pri)
+	forvalues i = 1/`=$fmm_components-1' {
+		forvalues j = `i'/`=$fmm_components-1' {
+			local m = `=$fmm_components+`i''
+			local n = `=$fmm_components+`j''
+			qui gen double `h`m'`n'' = -`gL`m''*`gL`n''
+			qui replace `hij' = -`pr`i''*((`i'==`j') - `pr`j'')
+			forvalues k = 1/`=$fmm_components-1' {
+				qui replace `h`m'`n'' = `h`m'`n'' ///
+						+ 1/`prob'*`pr`k''*(`fxb`k'' - `fxb$fmm_components') ///
+						*(`ga`k'`i''*`ga`k'`j'' + `hij')
+			}
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+	}
+
+
+	// hessian - sigma terms
+	forvalues i = 1/$fmm_components {
+		// hessian w.r.t. sigmai
+		local m = `=2*$fmm_components-1+`i''
+		qui replace `hij' = -2*(`z`i''^2)									// density specific
+		qui gen double `h`m'`m'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`m''*`gs`i'' + `gs`i''^2 + `hij')
+		mlmatsum `lnf' `nh`m'`m'' = -`h`m'`m'', eq(`m',`m')
+		// hessian w.r.t. sigmaj (cross partials)
+		forvalues j = `=`i'+1'/$fmm_components {
+			local n = `=2*$fmm_components-1+`j''
+			qui gen double `h`m'`n'' = `pr`i''/`prob'*(-`gL`n''*`fxb`i''*`gs`i'')
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+
+	// hessian (sigmai,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' ///
+						+ 1/`prob'*`fxb`i''*`gs`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`m'`n'' = `h`m'`n'' ///
+							- 1/`prob'*`fxb`i''*`gs`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+	}
+
+	// collect hessian terms into matrix
+	local np = colsof(`b')
+	local r 1
+	matrix `negH' = J(`np',`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local c = `r'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			matrix `negH'[`r',`c'] = `nh`i'`j''
+			if (`j'>`i') {
+				matrix `negH'[`c',`r'] = `nh`i'`j'''
+			}
+			local c = `c' + colsof(`nh`i'`j'')
+		}
+		local r = `r' + rowsof(`nh`i'`i'')
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_lognormal_p.ado

@@ -0,0 +1,89 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.0.0 05sep2011
+
+program fmm_lognormal_p
+	version 9.2
+
+	syntax anything(id="newvarname") [if] [in] [, MEan PRIor POSterior EQuation(string) ]
+
+	syntax newvarname [if] [in] [, * ]
+
+	forvalues i=1/$fmm_components {
+		local L_xb `"`L_xb' xb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_lod `"`L_lod' lnsigma`i'"'
+		local L_od `"`L_od' sigma`i'"'
+	}
+	forvalues i=1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+	}
+
+	tempvar `L_xb' `L_lpr' `L_pr' `L_lod' `L_od' den
+
+	forvalues i=1/$fmm_components {
+		qui _predict `typlist' `xb`i'' `if' `in', equation(component`i')
+		qui _predict `typlist' `lnsigma`i'' `if' `in', equation(lnsigma`i')
+		qui gen double `sigma`i'' = exp(`lnsigma`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui _predict `typlist' `lpr`i'' `if' `in', equation(imlogitpi`i')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+	if "`equation'" != "" & "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		local i = substr("`equation'",-1,1)
+		qui replace `varlist' = exp(`xb`i'' + 0.5*(`sigma`i'')^2) 
+		label variable `varlist' "predicted mean: `equation'"
+		exit
+	}
+
+	if "`equation'" == "" & "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `varlist' = `varlist' + `pr`i'' * ///
+					exp(`xb`i'' + 0.5*(`sigma`i'')^2)
+		}
+		label variable `varlist' "predicted mean"
+		exit
+	}
+
+	if "`prior'" == "prior" {
+		local i = substr("`equation'",-1,1)
+		gen `typlist' `varlist' = `pr`i'' `if' `in'
+		label variable `varlist' "prior probability: `equation'"
+		exit
+	}
+
+	if "`posterior'" == "posterior" {
+		tempvar prob probcomponent
+
+		local fmm_y = e(depvar)
+		qui gen double `prob' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `prob' = `prob' + `pr`i'' ///
+					* normalden(ln(`fmm_y'),`xb`i'',`sigma`i'') / `fmm_y' 
+			if "`equation'"=="component`i'" {
+				qui gen double `probcomponent' = `pr`i'' ///
+					* normalden(ln(`fmm_y'),`xb`i'',`sigma`i'') / `fmm_y'
+			}
+		}
+		gen `typlist' `varlist' = `probcomponent' / `prob'
+		label variable `varlist' "posterior probability: `equation'"
+		exit
+	}
+
+end
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_negbin1_lf.ado

@@ -0,0 +1,255 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.0.1  24apr2007
+* version 1.0.0 06mar2007
+
+program fmm_negbin1_lf
+	version 9.2
+
+	forvalues i = 1/$fmm_components {
+		local L_xb `"`L_xb' xb`i'"'
+		local L_exb `"`L_exb' exb`i'"'
+		local L_fxb `"`L_fxb' fxb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_ldel `"`L_ldel' lndelta`i'"'
+		local L_del `"`L_del' delta`i'"'
+		local L_psi `"`L_psi' psi`i'"'
+		local L_phi `"`L_phi' phi`i'"'
+		local L_gb `"`L_gb' gb`i'"'
+		local L_gs `"`L_gs' gs`i'"'
+		local L_hterm `"`L_hterm' hterm`i'"'
+	}
+
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local L_gL `"`L_gL' gL`i'"'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			local L_h `"`L_h' h`i'`j'"'
+			local L_nh `"`L_nh' nh`i'`j'"'
+		}
+	}
+
+	forvalues i = 1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+		forvalues j = 1/`=$fmm_components-1' {
+			local L_ga `"`L_ga' ga`i'`j'"'
+		}
+	}
+
+	// model arguments and temporary variables
+	args todo b lnf g negH `L_gL'
+	tempname `L_xb' `L_exb' `L_fxb' `L_ldel' `L_del' `L_psi' `L_lpr' `L_pr' ///
+						den prob `L_phi' gi `L_gb' `L_ga' `L_gs' hterm hij `L_h' `L_nh' ///
+						`L_hterm'
+
+	// set up equations
+	forvalues i=1/$fmm_components {
+		mleval `xb`i'' = `b', eq(`i')
+		qui gen double `exb`i'' = exp(`xb`i'')
+		mleval `lndelta`i'' = `b', eq(`=2*$fmm_components-1+`i'')
+		qui gen double `delta`i'' = exp(`lndelta`i'')
+		qui gen double `psi`i'' = `exb`i'' / `delta`i''
+		qui gen double `phi`i'' = ln(1+`delta`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		mleval `lpr`i'' = `b', eq(`=$fmm_components+`i'')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+
+	// calculate the likelihood function
+	qui gen double `prob' = 0
+	forvalues i=1/$fmm_components {
+		qui gen double `fxb`i'' = exp(lngamma($ML_y+`psi`i'') ///
+					- lngamma($ML_y+1) - lngamma(`psi`i'') + `lndelta`i''*$ML_y ///
+					- ($ML_y+`psi`i'')*`phi`i'')
+		qui replace `prob' = `prob' + `pr`i''*`fxb`i''
+	}
+
+	mlsum `lnf' = ln(`prob')
+
+
+	// CALCULATE GRADIENT TERMS
+	// gradient bi
+	forvalues i = 1/$fmm_components {
+		qui gen double `gb`i'' = `psi`i''*(digamma($ML_y+`psi`i'') ///
+				- digamma(`psi`i'') - `phi`i'')				 	// density specific
+		qui replace `gL`i'' = (`pr`i'' * `fxb`i'' * `gb`i'')/`prob'
+	}
+
+	// gradient prj
+	forvalues j = 1/`=$fmm_components-1' {
+		local m = `=$fmm_components+`j''
+		qui replace `gL`m'' = 0
+		forvalues k = 1/`=$fmm_components-1' {
+			qui gen double `ga`k'`j'' = ((`j'==`k') - `pr`j'')
+			qui replace `gL`m'' = `gL`m'' + `pr`k''*`ga`k'`j'' ///
+											*(`fxb`k'' - `fxb$fmm_components')/`prob'
+		}
+	}
+
+	// gradient deltai
+	forvalues i=1/$fmm_components {
+		local k = `=2*$fmm_components-1+`i''
+		qui gen double `gs`i'' = -($ML_y+`psi`i'')*`delta`i''/(1+`delta`i'') ///
+						+ $ML_y - `gb`i''   	// density specific
+		qui replace `gL`k'' = (`pr`i'' * `fxb`i'' * `gs`i'')/`prob'
+	}
+
+	// collect gradient terms into vector
+	local np = colsof(`b')
+	local c 1
+	matrix `g' = J(1,`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		mlvecsum `lnf' `gi' = `gL`i'', eq(`i')
+		matrix `g'[1,`c'] = `gi'
+		local c = `c' + colsof(`gi')
+	}
+
+
+	// CALCULATE HESSIAN TERMS
+	// hessian - b terms
+	local c 1
+	qui gen double `hij' = .
+	forvalues i = 1/$fmm_components {
+		// hessian (bi,bi)
+		qui gen double `hterm`i'' =  `psi`i''*(digamma($ML_y+`psi`i'') ///
+					- digamma(`psi`i'') + `psi`i''*(trigamma($ML_y+`psi`i'') ///
+					- trigamma(`psi`i'')) - `phi`i'')		// density specific
+		qui replace `hij' = `hterm`i''
+		qui gen double `h`i'`i'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`i''*`gb`i'' + `gb`i''^2 + `hij')
+		mlmatsum `lnf' `nh`i'`i'' = -`h`i'`i'', eq(`i',`i')
+		// hessian (bi,bj)
+		if (`i'<$fmm_components) {
+			forvalues j = `=`i'+1'/$fmm_components {
+				qui gen double `h`i'`j'' = `pr`i''/`prob'*(-`gL`j''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`j'' = -`h`i'`j'', eq(`i',`j')
+			}
+		}
+
+		// hessian (bi,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' ///
+						+ 1/`prob'*`fxb`i''*`gb`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`i'`m'' = `h`i'`m'' ///
+							- 1/`prob'*`fxb`i''*`gb`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+
+		// hessian (bi,delta)
+		forvalues j = 1/$fmm_components {
+			local k = `=2*$fmm_components-1+`j''
+			// hessian (bi,deltai)
+			if (`i'==`j') {
+				qui replace `hij' = -`psi`i''*`delta`i''/(1+`delta`i'') - `hterm`i''	// density specific
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*`fxb`i'' ///
+					*(-`gL`k''*`gb`i'' + `gs`j''*`gb`i'' + `hij')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+			else {
+			// hessian (bi,deltaj)
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*(-`gL`k''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+		}
+	}
+
+	// hessian - pr terms
+	// hessian (prj,pri)
+	forvalues i = 1/`=$fmm_components-1' {
+		forvalues j = `i'/`=$fmm_components-1' {
+			local m = `=$fmm_components+`i''
+			local n = `=$fmm_components+`j''
+			qui gen double `h`m'`n'' = -`gL`m''*`gL`n''
+			qui replace `hij' = -`pr`i''*((`i'==`j') - `pr`j'')
+			forvalues k = 1/`=$fmm_components-1' {
+				qui replace `h`m'`n'' = `h`m'`n'' ///
+						+ 1/`prob'*`pr`k''*(`fxb`k'' - `fxb$fmm_components') ///
+						*(`ga`k'`i''*`ga`k'`j'' + `hij')
+			}
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+	}
+
+	// hessian - delta terms
+	forvalues i = 1/$fmm_components {
+		// hessian w.r.t. deltai
+		local m = `=2*$fmm_components-1+`i''
+		qui replace `hij' = -`delta`i''*($ML_y-`psi`i''*(1+2*`delta`i'')) ///
+											/(1+`delta`i'')^2 + `hterm`i'' 	// density specific
+		qui gen double `h`m'`m'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`m''*`gs`i'' + `gs`i''^2 + `hij')
+		mlmatsum `lnf' `nh`m'`m'' = -`h`m'`m'', eq(`m',`m')
+		// hessian w.r.t. deltaj (cross partials)
+		forvalues j = `=`i'+1'/$fmm_components {
+			local n = `=2*$fmm_components-1+`j''
+			qui gen double `h`m'`n'' = `pr`i''/`prob'*(-`gL`n''*`fxb`i''*`gs`i'')
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+
+	// hessian (deltai,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' ///
+						+ 1/`prob'*`fxb`i''*`gs`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`m'`n'' = `h`m'`n'' ///
+							- 1/`prob'*`fxb`i''*`gs`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+	}
+
+	// collect hessian terms into matrix
+	local np = colsof(`b')
+	local r 1
+	matrix `negH' = J(`np',`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local c = `r'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			matrix `negH'[`r',`c'] = `nh`i'`j''
+			if (`j'>`i') {
+				matrix `negH'[`c',`r'] = `nh`i'`j'''
+			}
+			local c = `c' + colsof(`nh`i'`j'')
+		}
+		local r = `r' + rowsof(`nh`i'`i'')
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_negbin1_p.ado

@@ -0,0 +1,104 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 2.0.0 27aug2008
+* version 1.1.0  12jul2007
+* version 1.0.0 06mar2007
+
+program fmm_negbin1_p
+	version 9.2
+
+	syntax anything(id="newvarname") [if] [in] [, MEan PRIor POSterior EQuation(string) ]
+
+	syntax newvarname [if] [in] [, * ]
+
+	if "`equation'" != "" & "`prior'" == "" & "`posterior'" == "" {
+		_predict `typlist' `varlist' `if' `in', equation(`equation')
+		qui replace `varlist' = exp(`varlist')
+		label variable `varlist' "predicted mean: `equation'"
+		exit
+	}
+
+	if "`equation'" == "" | "`prior'" == "prior" | "`posterior'" == "posterior" {
+
+		forvalues i=1/$fmm_components {
+			local L_xb `"`L_xb' xb`i'"'
+			local L_exb `"`L_exb' exb`i'"'
+			local L_pr `"`L_pr' pr`i'"'
+			local L_lod `"`L_lod' lndelta`i'"'
+			local L_od `"`L_od' delta`i'"'
+			local L_psi `"`L_psi' psi`i'"'
+			local L_phi `"`L_phi' phi`i'"'
+		}
+		forvalues i=1/`=$fmm_components-1' {
+			local L_lpr `"`L_lpr' lpr`i'"'
+		}
+
+		tempvar `L_xb' `L_exb' `L_lpr' `L_pr' `L_lod' `L_od' `L_psi' `L_phi' den
+
+		forvalues i=1/$fmm_components {
+			qui _predict `typlist' `xb`i'' `if' `in', equation(component`i')
+			qui gen double `exb`i'' = exp(`xb`i'')
+			qui _predict `typlist' `lndelta`i'' `if' `in', equation(lndelta`i')
+			qui gen double `delta`i'' = exp(`lndelta`i'')
+			qui gen double `psi`i'' = `exb`i'' / `delta`i''
+			qui gen double `phi`i'' = ln(1+`delta`i'')
+
+		}
+
+		qui gen double `den' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			_predict `typlist' `lpr`i'' `if' `in', equation(imlogitpi`i')
+			qui replace `den' = `den' + exp(`lpr`i'')
+		}
+
+		forvalues i=1/`=$fmm_components-1' {
+			qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+		}
+
+		qui gen double `pr$fmm_components' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+		}
+	}
+
+	if "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `varlist' = `varlist' + `pr`i'' * `exb`i''
+		}
+		label variable `varlist' "predicted mean"
+		exit
+	}
+
+	if "`prior'" == "prior" {
+		local i = substr("`equation'",-1,1)
+		gen `typlist' `varlist' = `pr`i'' `if' `in'
+		label variable `varlist' "prior probability: `equation'"
+		exit
+	}
+
+
+	if "`posterior'" == "posterior" {
+		tempvar prob probcomponent
+
+		local fmm_y = e(depvar)
+		qui gen double `prob' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `prob' = `prob' + `pr`i'' ///
+						* exp(lngamma(`fmm_y'+`psi`i'') ///
+					- lngamma(`fmm_y'+1) - lngamma(`psi`i'') + `lndelta`i''*`fmm_y' ///
+					- (`fmm_y'+`psi`i'')*`phi`i'')
+			if "`equation'"=="component`i'" {
+				qui gen double `probcomponent' = `pr`i'' ///
+						* exp(lngamma(`fmm_y'+`psi`i'') ///
+					- lngamma(`fmm_y'+1) - lngamma(`psi`i'') + `lndelta`i''*`fmm_y' ///
+					- (`fmm_y'+`psi`i'')*`phi`i'')
+			}
+		}
+		gen `typlist' `varlist' = `probcomponent' / `prob'
+		label variable `varlist' "posterior probability: `equation'"
+		exit
+	}
+
+end
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_negbin2_lf.ado

@@ -0,0 +1,253 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.0.1  24apr2007
+* version 1.0.0 06mar2007
+
+program fmm_negbin2_lf
+	version 9.2
+
+	forvalues i = 1/$fmm_components {
+		local L_xb `"`L_xb' xb`i'"'
+		local L_exb `"`L_exb' exb`i'"'
+		local L_fxb `"`L_fxb' fxb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_lalp `"`L_lalp' lnalpha`i'"'
+		local L_alp `"`L_alp' alpha`i'"'
+		local L_psi `"`L_psi' psi`i'"'
+		local L_phi `"`L_phi' phi`i'"'
+		local L_gb `"`L_gb' gb`i'"'
+		local L_gs `"`L_gs' gs`i'"'
+	}
+
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local L_gL `"`L_gL' gL`i'"'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			local L_h `"`L_h' h`i'`j'"'
+			local L_nh `"`L_nh' nh`i'`j'"'
+		}
+	}
+
+	forvalues i = 1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+		forvalues j = 1/`=$fmm_components-1' {
+			local L_ga `"`L_ga' ga`i'`j'"'
+		}
+	}
+
+	// model arguments and temporary variables
+	args todo b lnf g negH `L_gL'
+	tempname `L_xb' `L_exb' `L_fxb' `L_lalp' `L_alp' `L_psi' `L_lpr' `L_pr' ///
+						den prob `L_phi' gi `L_gb' `L_ga' `L_gs' hij `L_h' `L_nh'
+
+	// set up equations
+	forvalues i=1/$fmm_components {
+		mleval `xb`i'' = `b', eq(`i')
+		qui gen double `exb`i'' = exp(`xb`i'')
+		mleval `lnalpha`i'' = `b', eq(`=2*$fmm_components-1+`i'')
+		qui gen double `alpha`i'' = exp(`lnalpha`i'')
+		qui gen double `psi`i'' = 1 / `alpha`i''
+		qui gen double `phi`i'' = 1 / (1 + `alpha`i''*`exb`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		mleval `lpr`i'' = `b', eq(`=$fmm_components+`i'')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+
+	// calculate the likelihood function
+	qui gen double `prob' = 0
+	forvalues i=1/$fmm_components {
+		qui gen double `fxb`i'' = exp(lngamma(`psi`i''+$ML_y) - lngamma($ML_y+1) ///
+						- lngamma(`psi`i'') - `psi`i''*ln(1+exp(`xb`i''+`lnalpha`i'')) ///
+						- $ML_y*ln(1+exp(-`xb`i''-`lnalpha`i'')))
+		qui replace `prob' = `prob' + `pr`i''*`fxb`i''
+	}
+
+	mlsum `lnf' = ln(`prob')
+
+
+	// CALCULATE GRADIENT TERMS
+	// gradient bi
+	forvalues i = 1/$fmm_components {
+		qui gen double `gb`i'' = ($ML_y-`exb`i'')*`phi`i''	 	// density specific
+		qui replace `gL`i'' = (`pr`i'' * `fxb`i'' * `gb`i'')/`prob'
+	}
+
+	// gradient prj
+	forvalues j = 1/`=$fmm_components-1' {
+		local m = `=$fmm_components+`j''
+		qui replace `gL`m'' = 0
+		forvalues k = 1/`=$fmm_components-1' {
+			qui gen double `ga`k'`j'' = ((`j'==`k') - `pr`j'')
+			qui replace `gL`m'' = `gL`m'' + `pr`k''*`ga`k'`j'' ///
+											*(`fxb`k'' - `fxb$fmm_components')/`prob'
+		}
+	}
+
+	// gradient alphai
+	forvalues i=1/$fmm_components {
+		local k = `=2*$fmm_components-1+`i''
+		qui gen double `gs`i'' = `psi`i''*(digamma(`psi`i'') - digamma($ML_y+`psi`i'') ///
+									- ln(`phi`i'')) + `phi`i''*($ML_y-`exb`i'')   	// density specific
+		qui replace `gL`k'' = (`pr`i'' * `fxb`i'' * `gs`i'')/`prob'
+	}
+
+	// collect gradient terms into vector
+	local np = colsof(`b')
+	local c 1
+	matrix `g' = J(1,`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		mlvecsum `lnf' `gi' = `gL`i'', eq(`i')
+		matrix `g'[1,`c'] = `gi'
+		local c = `c' + colsof(`gi')
+	}
+
+
+	// CALCULATE HESSIAN TERMS
+	// hessian - b terms
+	local c 1
+	qui gen double `hij' = .
+	forvalues i = 1/$fmm_components {
+		// hessian (bi,bi)
+		qui replace `hij' = -`exb`i'' * `phi`i'' ///
+								*(`alpha`i''*`phi`i''*($ML_y-`exb`i'')+1)		// density specific
+		qui gen double `h`i'`i'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`i''*`gb`i'' + `gb`i''^2 + `hij')
+		mlmatsum `lnf' `nh`i'`i'' = -`h`i'`i'', eq(`i',`i')
+		// hessian (bi,bj)
+		if (`i'<$fmm_components) {
+			forvalues j = `=`i'+1'/$fmm_components {
+				qui gen double `h`i'`j'' = `pr`i''/`prob'*(-`gL`j''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`j'' = -`h`i'`j'', eq(`i',`j')
+			}
+		}
+
+		// hessian (bi,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' ///
+						+ 1/`prob'*`fxb`i''*`gb`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`i'`m'' = `h`i'`m'' ///
+							- 1/`prob'*`fxb`i''*`gb`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+
+		// hessian (bi,alpha)
+		forvalues j = 1/$fmm_components {
+			local k = `=2*$fmm_components-1+`j''
+			// hessian (bi,alphai)
+			if (`i'==`j') {
+				qui replace `hij' = -`alpha`j'' * `exb`j'' * `phi`j''^2 ///
+													* ($ML_y-`exb`j'')		// density specific
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*`fxb`i'' ///
+					*(-`gL`k''*`gb`i'' + `gs`j''*`gb`i'' + `hij')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+			else {
+			// hessian (bi,alphaj)
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*(-`gL`k''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+		}
+	}
+
+	// hessian - pr terms
+	// hessian (prj,pri)
+	forvalues i = 1/`=$fmm_components-1' {
+		forvalues j = `i'/`=$fmm_components-1' {
+			local m = `=$fmm_components+`i''
+			local n = `=$fmm_components+`j''
+			qui gen double `h`m'`n'' = -`gL`m''*`gL`n''
+			qui replace `hij' = -`pr`i''*((`i'==`j') - `pr`j'')
+			forvalues k = 1/`=$fmm_components-1' {
+				qui replace `h`m'`n'' = `h`m'`n'' ///
+						+ 1/`prob'*`pr`k''*(`fxb`k'' - `fxb$fmm_components') ///
+						*(`ga`k'`i''*`ga`k'`j'' + `hij')
+			}
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+	}
+
+	// hessian - alpha terms
+	forvalues i = 1/$fmm_components {
+		// hessian w.r.t. alphai
+		local m = `=2*$fmm_components-1+`i''
+		qui replace `hij' = -(`psi`i''*(digamma(`psi`i'') ///
+				- digamma($ML_y+`psi`i'') - ln(`phi`i'') ///
+				- `psi`i''*(trigamma($ML_y+`psi`i'') - trigamma(`psi`i''))) ///
+				+ `exb`i''*`phi`i''*(`alpha`i''*`phi`i''*($ML_y-`exb`i'')- 1)) 	// density specific
+		qui gen double `h`m'`m'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`m''*`gs`i'' + `gs`i''^2 + `hij')
+		mlmatsum `lnf' `nh`m'`m'' = -`h`m'`m'', eq(`m',`m')
+		// hessian w.r.t. alphaj (cross partials)
+		forvalues j = `=`i'+1'/$fmm_components {
+			local n = `=2*$fmm_components-1+`j''
+			qui gen double `h`m'`n'' = `pr`i''/`prob'*(-`gL`n''*`fxb`i''*`gs`i'')
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+
+	// hessian (alphai,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' ///
+						+ 1/`prob'*`fxb`i''*`gs`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`m'`n'' = `h`m'`n'' ///
+							- 1/`prob'*`fxb`i''*`gs`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+	}
+
+	// collect hessian terms into matrix
+	local np = colsof(`b')
+	local r 1
+	matrix `negH' = J(`np',`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local c = `r'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			matrix `negH'[`r',`c'] = `nh`i'`j''
+			if (`j'>`i') {
+				matrix `negH'[`c',`r'] = `nh`i'`j'''
+			}
+			local c = `c' + colsof(`nh`i'`j'')
+		}
+		local r = `r' + rowsof(`nh`i'`i'')
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_negbin2_p.ado

@@ -0,0 +1,104 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 2.0.0 27aug2008
+* version 1.1.0  12jul2007
+* version 1.0.0 06mar2007
+
+program fmm_negbin2_p
+	version 9.2
+
+	syntax anything(id="newvarname") [if] [in] [, MEan PRIor POSterior EQuation(string) ]
+
+	syntax newvarname [if] [in] [, * ]
+
+	if "`equation'" != "" & "`prior'" == "" & "`posterior'" == "" {
+		_predict `typlist' `varlist' `if' `in', equation(`equation')
+		qui replace `varlist' = exp(`varlist')
+		label variable `varlist' "predicted mean: `equation'"
+		exit
+	}
+
+	if "`equation'" == "" | "`prior'" == "prior" | "`posterior'" == "posterior" {
+
+		forvalues i=1/$fmm_components {
+			local L_xb `"`L_xb' xb`i'"'
+			local L_exb `"`L_exb' exb`i'"'
+			local L_pr `"`L_pr' pr`i'"'
+			local L_lod `"`L_lod' lnalpha`i'"'
+			local L_od `"`L_od' alpha`i'"'
+			local L_psi `"`L_psi' psi`i'"'
+			local L_phi `"`L_phi' phi`i'"'
+		}
+		forvalues i=1/`=$fmm_components-1' {
+			local L_lpr `"`L_lpr' lpr`i'"'
+		}
+
+		tempvar `L_xb' `L_exb' `L_lpr' `L_pr' `L_lod' `L_od' `L_psi' `L_phi' den
+
+		forvalues i=1/$fmm_components {
+			qui _predict `typlist' `xb`i'' `if' `in', equation(component`i')
+			qui gen double `exb`i'' = exp(`xb`i'')
+			qui _predict `typlist' `lnalpha`i'' `if' `in', equation(lnalpha`i')
+			qui gen double `alpha`i'' = exp(`lnalpha`i'')
+			qui gen double `psi`i'' = 1 / `alpha`i''
+			qui gen double `phi`i'' = 1 / (1 + `alpha`i''*`exb`i'')
+
+		}
+
+		qui gen double `den' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui _predict `typlist' `lpr`i'' `if' `in', equation(imlogitpi`i')
+			qui replace `den' = `den' + exp(`lpr`i'')
+		}
+
+		forvalues i=1/`=$fmm_components-1' {
+			qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+		}
+
+		qui gen double `pr$fmm_components' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+		}
+	}
+
+	if "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `varlist' = `varlist' + `pr`i'' * `exb`i''
+		}
+		label variable `varlist' "predicted mean"
+		exit
+	}
+
+	if "`prior'" == "prior" {
+		local i = substr("`equation'",-1,1)
+		gen `typlist' `varlist' = `pr`i'' `if' `in'
+		label variable `varlist' "prior probability: `equation'"
+		exit
+	}
+
+
+	if "`posterior'" == "posterior" {
+		tempvar prob probcomponent
+
+		local fmm_y = e(depvar)
+		qui gen double `prob' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `prob' = `prob' + `pr`i'' ///
+						* exp(lngamma(`psi`i''+`fmm_y') - lngamma(`fmm_y'+1) ///
+						- lngamma(`psi`i'') - `psi`i''*ln(1+exp(`xb`i''+`lnalpha`i'')) ///
+						- `fmm_y'*ln(1+exp(-`xb`i''-`lnalpha`i'')))
+			if "`equation'"=="component`i'" {
+				qui gen double `probcomponent' = `pr`i'' ///
+						* exp(lngamma(`psi`i''+`fmm_y') - lngamma(`fmm_y'+1) ///
+						- lngamma(`psi`i'') - `psi`i''*ln(1+exp(`xb`i''+`lnalpha`i'')) ///
+						- `fmm_y'*ln(1+exp(-`xb`i''-`lnalpha`i'')))
+			}
+		}
+		gen `typlist' `varlist' = `probcomponent' / `prob'
+		label variable `varlist' "posterior probability: `equation'"
+		exit
+	}
+
+end
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_normal_lf.ado

@@ -0,0 +1,244 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.0.1  24apr2007
+* version 1.0.0 06mar2007
+
+program fmm_normal_lf
+	version 9.2
+
+	forvalues i = 1/$fmm_components {
+		local L_xb `"`L_xb' xb`i'"'
+		local L_fxb `"`L_fxb' fxb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_z `"`L_z' z`i'"'
+		local L_lsig `"`L_lsig' lnsigma`i'"'
+		local L_sig `"`L_sig' sigma`i'"'
+		local L_gb `"`L_gb' gb`i'"'
+		local L_gs `"`L_gs' gs`i'"'
+	}
+
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local L_gL `"`L_gL' gL`i'"'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			local L_h `"`L_h' h`i'`j'"'
+			local L_nh `"`L_nh' nh`i'`j'"'
+		}
+	}
+
+	forvalues i = 1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+		forvalues j = 1/`=$fmm_components-1' {
+			local L_ga `"`L_ga' ga`i'`j'"'
+		}
+	}
+
+	// model arguments and temporary variables
+	args todo b lnf g negH `L_gL'
+	tempname `L_xb' `L_fxb' `L_lsig' `L_sig' `L_lpr' `L_pr' `L_z' ///
+						den prob gi `L_gb'  `L_ga' `L_gs' hij `L_h' `L_nh'
+
+	// set up equations
+	forvalues i=1/$fmm_components {
+		mleval `xb`i'' = `b', eq(`i')
+		mleval `lnsigma`i'' = `b', eq(`=2*$fmm_components-1+`i'')
+		qui gen double `sigma`i'' = exp(`lnsigma`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		mleval `lpr`i'' = `b', eq(`=$fmm_components+`i'')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+
+	// calculate the likelihood function
+	qui gen double `prob' = 0
+	forvalues i=1/$fmm_components {
+		qui gen double `z`i'' = .
+		qui gen double `fxb`i'' = normalden($ML_y,`xb`i'',`sigma`i'')
+		qui replace `prob' = `prob' + `pr`i''*`fxb`i''
+	}
+
+	mlsum `lnf' = ln(`prob')
+
+
+	// CALCULATE GRADIENT TERMS
+	// gradient bi
+	forvalues i = 1/$fmm_components {
+		qui replace `z`i'' = ($ML_y-`xb`i'')/`sigma`i''
+		qui gen double `gb`i'' = `z`i''/`sigma`i''				// density specific
+		qui replace `gL`i'' = (`pr`i'' * `fxb`i'' * `gb`i'')/`prob'
+	}
+
+	// gradient prj
+	forvalues j = 1/`=$fmm_components-1' {
+		local m = `=$fmm_components+`j''
+		qui replace `gL`m'' = 0
+		forvalues k = 1/`=$fmm_components-1' {
+			qui gen double `ga`k'`j'' = ((`j'==`k') - `pr`j'')
+			qui replace `gL`m'' = `gL`m'' + `pr`k''*`ga`k'`j'' ///
+											*(`fxb`k'' - `fxb$fmm_components')/`prob'
+		}
+	}
+
+	// gradient sigmai
+	forvalues i=1/$fmm_components {
+		local k = `=2*$fmm_components-1+`i''
+		qui gen double `gs`i'' = `z`i''*`z`i''-1					// density specific
+		qui replace `gL`k'' = (`pr`i'' * `fxb`i'' * `gs`i'')/`prob'
+	}
+
+	// collect gradient terms into vector
+	local np = colsof(`b')
+	local c 1
+	matrix `g' = J(1,`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		mlvecsum `lnf' `gi' = `gL`i'', eq(`i')
+		matrix `g'[1,`c'] = `gi'
+		local c = `c' + colsof(`gi')
+	}
+
+
+	// CALCULATE HESSIAN TERMS
+	// hessian - b terms
+	local c 1
+	qui gen double `hij' = .
+	forvalues i = 1/$fmm_components {
+		// hessian (bi,bi)
+		qui replace `hij' = -1/(`sigma`i''^2)							// density specific
+		qui gen double `h`i'`i'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`i''*`gb`i'' + `gb`i''^2 + `hij')
+		mlmatsum `lnf' `nh`i'`i'' = -`h`i'`i'', eq(`i',`i')
+		// hessian (bi,bj)
+		if (`i'<$fmm_components) {
+			forvalues j = `=`i'+1'/$fmm_components {
+				qui gen double `h`i'`j'' = `pr`i''/`prob'*(-`gL`j''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`j'' = -`h`i'`j'', eq(`i',`j')
+			}
+		}
+
+		// hessian (bi,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' ///
+						+ 1/`prob'*`fxb`i''*`gb`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`i'`m'' = `h`i'`m'' ///
+							- 1/`prob'*`fxb`i''*`gb`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+
+
+		// hessian (bi,sigma)
+		forvalues j = 1/$fmm_components {
+			local k = `=2*$fmm_components-1+`j''
+			// hessian (bi,sigmai)
+			if (`i'==`j') {
+				qui replace `hij' = -2*`z`j''/`sigma`j''			// density specific
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*`fxb`i'' ///
+					*(-`gL`k''*`gb`i'' + `gs`j''*`gb`i'' + `hij')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+			else {
+			// hessian (bi,sigmaj)
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*(-`gL`k''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+		}
+	}
+
+	// hessian - pr terms
+	// hessian (prj,pri)
+	forvalues i = 1/`=$fmm_components-1' {
+		forvalues j = `i'/`=$fmm_components-1' {
+			local m = `=$fmm_components+`i''
+			local n = `=$fmm_components+`j''
+			qui gen double `h`m'`n'' = -`gL`m''*`gL`n''
+			qui replace `hij' = -`pr`i''*((`i'==`j') - `pr`j'')
+			forvalues k = 1/`=$fmm_components-1' {
+				qui replace `h`m'`n'' = `h`m'`n'' ///
+						+ 1/`prob'*`pr`k''*(`fxb`k'' - `fxb$fmm_components') ///
+						*(`ga`k'`i''*`ga`k'`j'' + `hij')
+			}
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+	}
+
+
+	// hessian - sigma terms
+	forvalues i = 1/$fmm_components {
+		// hessian w.r.t. sigmai
+		local m = `=2*$fmm_components-1+`i''
+		qui replace `hij' = -2*(`z`i''^2)									// density specific
+		qui gen double `h`m'`m'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`m''*`gs`i'' + `gs`i''^2 + `hij')
+		mlmatsum `lnf' `nh`m'`m'' = -`h`m'`m'', eq(`m',`m')
+		// hessian w.r.t. sigmaj (cross partials)
+		forvalues j = `=`i'+1'/$fmm_components {
+			local n = `=2*$fmm_components-1+`j''
+			qui gen double `h`m'`n'' = `pr`i''/`prob'*(-`gL`n''*`fxb`i''*`gs`i'')
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+
+	// hessian (sigmai,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' ///
+						+ 1/`prob'*`fxb`i''*`gs`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`m'`n'' = `h`m'`n'' ///
+							- 1/`prob'*`fxb`i''*`gs`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+	}
+
+	// collect hessian terms into matrix
+	local np = colsof(`b')
+	local r 1
+	matrix `negH' = J(`np',`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local c = `r'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			matrix `negH'[`r',`c'] = `nh`i'`j''
+			if (`j'>`i') {
+				matrix `negH'[`c',`r'] = `nh`i'`j'''
+			}
+			local c = `c' + colsof(`nh`i'`j'')
+		}
+		local r = `r' + rowsof(`nh`i'`i'')
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_normal_p.ado

@@ -0,0 +1,92 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 2.0.0 27aug2008
+* version 1.1.0  12jul2007
+* version 1.0.0 06mar2007
+
+program fmm_normal_p
+	version 9.2
+
+	syntax anything(id="newvarname") [if] [in] [, MEan PRIor POSterior EQuation(string) ]
+
+	syntax newvarname [if] [in] [, * ]
+
+	if "`equation'" != "" & "`prior'" == "" & "`posterior'" == "" {
+		_predict `typlist' `varlist' `if' `in', equation(`equation')
+		label variable `varlist' "predicted mean: `equation'"
+		exit
+	}
+
+	if "`equation'" == "" | "`prior'" == "prior" | "`posterior'" == "posterior" {
+
+		forvalues i=1/$fmm_components {
+			local L_xb `"`L_xb' xb`i'"'
+			local L_pr `"`L_pr' pr`i'"'
+			local L_lod `"`L_lod' lnsigma`i'"'
+			local L_od `"`L_od' sigma`i'"'
+		}
+		forvalues i=1/`=$fmm_components-1' {
+			local L_lpr `"`L_lpr' lpr`i'"'
+		}
+
+		tempvar `L_xb' `L_lpr' `L_pr' `L_lod' `L_od' den
+
+		forvalues i=1/$fmm_components {
+			qui _predict `typlist' `xb`i'' `if' `in', equation(component`i')
+			qui _predict `typlist' `lnsigma`i'' `if' `in', equation(lnsigma`i')
+			qui gen double `sigma`i'' = exp(`lnsigma`i'')
+		}
+
+		qui gen double `den' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui _predict `typlist' `lpr`i'' `if' `in', equation(imlogitpi`i')
+			qui replace `den' = `den' + exp(`lpr`i'')
+		}
+
+		forvalues i=1/`=$fmm_components-1' {
+			qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+		}
+
+		qui gen double `pr$fmm_components' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+		}
+	}
+
+	if "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `varlist' = `varlist' + `pr`i'' * `xb`i''
+		}
+		label variable `varlist' "predicted mean"
+		exit
+	}
+
+	if "`prior'" == "prior" {
+		local i = substr("`equation'",-1,1)
+		gen `typlist' `varlist' = `pr`i'' `if' `in'
+		label variable `varlist' "prior probability: `equation'"
+		exit
+	}
+
+
+	if "`posterior'" == "posterior" {
+		tempvar prob probcomponent
+
+		local fmm_y = e(depvar)
+		qui gen double `prob' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `prob' = `prob' + `pr`i'' ///
+												* normalden(`fmm_y',`xb`i'',`sigma`i'') 
+			if "`equation'"=="component`i'" {
+				qui gen double `probcomponent' = `pr`i'' ///
+												* normalden(`fmm_y',`xb`i'',`sigma`i'') 
+			}
+		}
+		gen `typlist' `varlist' = `probcomponent' / `prob'
+		label variable `varlist' "posterior probability: `equation'"
+		exit
+	}
+
+end
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_poisson_lf.ado

@@ -0,0 +1,174 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.0.1  24apr2007
+* version 1.0.0 06mar2007
+
+program fmm_poisson_lf
+	version 9.2
+
+	forvalues i = 1/$fmm_components {
+		local L_xb `"`L_xb' xb`i'"'
+		local L_exb `"`L_exb' exb`i'"'
+		local L_fxb `"`L_fxb' fxb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_gb `"`L_gb' gb`i'"'
+	}
+
+	forvalues i = 1/`=2*$fmm_components-1' {
+		local L_gL `"`L_gL' gL`i'"'
+		forvalues j = `i'/`=2*$fmm_components-1' {
+			local L_h `"`L_h' h`i'`j'"'
+			local L_nh `"`L_nh' nh`i'`j'"'
+		}
+	}
+
+	forvalues i = 1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+		forvalues j = 1/`=$fmm_components-1' {
+			local L_ga `"`L_ga' ga`i'`j'"'
+		}
+	}
+
+	// model arguments and temporary variables
+	args todo b lnf g negH `L_gL'
+	tempname `L_xb' `L_exb' `L_fxb' `L_lpr' `L_pr' ///
+						den prob gi `L_gb' `L_ga' hij `L_h' `L_nh'
+
+	// set up equations
+	forvalues i=1/$fmm_components {
+		mleval `xb`i'' = `b', eq(`i')
+		qui gen double `exb`i'' = exp(`xb`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		mleval `lpr`i'' = `b', eq(`=$fmm_components+`i'')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+
+	// calculate the likelihood function
+	qui gen double `prob' = 0
+	forvalues i=1/$fmm_components {
+		qui gen double `fxb`i'' = exp($ML_y*`xb`i'' - `exb`i'' ///
+																- lngamma($ML_y+1))
+		qui replace `prob' = `prob' + `pr`i''*`fxb`i''
+	}
+
+	mlsum `lnf' = ln(`prob')
+
+
+	// CALCULATE GRADIENT TERMS
+	// gradient bi
+	forvalues i = 1/$fmm_components {
+		qui gen double `gb`i'' = $ML_y-`exb`i'' 	// density specific
+		qui replace `gL`i'' = (`pr`i'' * `fxb`i'' * `gb`i'')/`prob'
+	}
+
+	// gradient prj
+	forvalues j = 1/`=$fmm_components-1' {
+		local m = `=$fmm_components+`j''
+		qui replace `gL`m'' = 0
+		forvalues k = 1/`=$fmm_components-1' {
+			qui gen double `ga`k'`j'' = ((`j'==`k') - `pr`j'')
+			qui replace `gL`m'' = `gL`m'' + `pr`k''*`ga`k'`j'' ///
+											*(`fxb`k'' - `fxb$fmm_components')/`prob'
+		}
+	}
+
+	// collect gradient terms into vector
+	local np = colsof(`b')
+	local c 1
+	matrix `g' = J(1,`np',0)
+	
+	forvalues i = 1/`=2*$fmm_components-1' {
+		mlvecsum `lnf' `gi' = `gL`i'', eq(`i')
+		matrix `g'[1,`c'] = `gi'
+		local c = `c' + colsof(`gi')
+	}
+
+
+	// CALCULATE HESSIAN TERMS
+	// hessian - b terms
+	local c 1
+	qui gen double `hij' = .
+	forvalues i = 1/$fmm_components {
+		// hessian (bi,bi)
+		qui replace `hij' = -`exb`i''					// density specific
+		qui gen double `h`i'`i'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`i''*`gb`i'' + `gb`i''^2 + `hij')
+		mlmatsum `lnf' `nh`i'`i'' = -`h`i'`i'', eq(`i',`i')
+		// hessian (bi,bj)
+		if (`i'<$fmm_components) {
+			forvalues j = `=`i'+1'/$fmm_components {
+				qui gen double `h`i'`j'' = `pr`i''/`prob'*(-`gL`j''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`j'' = -`h`i'`j'', eq(`i',`j')
+			}
+		}
+
+		// hessian (bi,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' ///
+						+ 1/`prob'*`fxb`i''*`gb`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`i'`m'' = `h`i'`m'' ///
+							- 1/`prob'*`fxb`i''*`gb`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+	}
+
+	// hessian - pr terms
+	// hessian (prj,pri)
+	forvalues i = 1/`=$fmm_components-1' {
+		forvalues j = `i'/`=$fmm_components-1' {
+			local m = `=$fmm_components+`i''
+			local n = `=$fmm_components+`j''
+			qui gen double `h`m'`n'' = -`gL`m''*`gL`n''
+			qui replace `hij' = -`pr`i''*((`i'==`j') - `pr`j'')
+			forvalues k = 1/`=$fmm_components-1' {
+				qui replace `h`m'`n'' = `h`m'`n'' ///
+						+ 1/`prob'*`pr`k''*(`fxb`k'' - `fxb$fmm_components') ///
+						*(`ga`k'`i''*`ga`k'`j'' + `hij')
+			}
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+	}
+
+	// collect hessian terms into matrix
+	local np = colsof(`b')
+	local r 1
+	matrix `negH' = J(`np',`np',0)
+	
+	forvalues i = 1/`=2*$fmm_components-1' {
+		local c = `r'
+		forvalues j = `i'/`=2*$fmm_components-1' {
+			matrix `negH'[`r',`c'] = `nh`i'`j''
+			if (`j'>`i') {
+				matrix `negH'[`c',`r'] = `nh`i'`j'''
+			}
+			local c = `c' + colsof(`nh`i'`j'')
+		}
+		local r = `r' + rowsof(`nh`i'`i'')
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_poisson_p.ado

@@ -0,0 +1,91 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 2.0.0 27aug2008
+* version 1.1.0  12jul2007
+* version 1.0.0 06mar2007
+
+program fmm_poisson_p
+	version 9.2
+
+	syntax anything(id="newvarname") [if] [in] [, MEan PRIor POSterior EQuation(string) ]
+
+	syntax newvarname [if] [in] [, * ]
+
+	if "`equation'" != "" & "`prior'" == "" & "`posterior'" == "" {
+		_predict `typlist' `varlist' `if' `in', equation(`equation')
+		qui replace `varlist' = exp(`varlist')
+		label variable `varlist' "predicted mean: `equation'"
+		exit
+	}
+
+	if "`equation'" == "" | "`prior'" == "prior" | "`posterior'" == "posterior" {
+
+		forvalues i=1/$fmm_components {
+			local L_xb `"`L_xb' xb`i'"'
+			local L_exb `"`L_exb' exb`i'"'
+			local L_pr `"`L_pr' pr`i'"'
+		}
+		forvalues i=1/`=$fmm_components-1' {
+			local L_lpr `"`L_lpr' lpr`i'"'
+		}
+
+		tempvar `L_xb' `L_exb' `L_lpr' `L_pr' den
+
+		forvalues i=1/$fmm_components {
+			qui _predict `typlist' `xb`i'' `if' `in', equation(component`i')
+			qui gen double `exb`i'' = exp(`xb`i'')
+		}
+
+		qui gen double `den' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui _predict `typlist' `lpr`i'' `if' `in', equation(imlogitpi`i')
+			qui replace `den' = `den' + exp(`lpr`i'')
+		}
+
+		forvalues i=1/`=$fmm_components-1' {
+			qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+		}
+
+		qui gen double `pr$fmm_components' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+		}
+	}
+
+	if "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `varlist' = `varlist' + `pr`i'' * `exb`i''
+		}
+		label variable `varlist' "predicted mean"
+		exit
+	}
+
+	if "`prior'" == "prior" {
+		local i = substr("`equation'",-1,1)
+		gen `typlist' `varlist' = `pr`i'' `if' `in'
+		label variable `varlist' "prior probability: `equation'"
+		exit
+	}
+
+
+	if "`posterior'" == "posterior" {
+		tempvar prob probcomponent
+
+		local fmm_y = e(depvar)
+		qui gen double `prob' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `prob' = `prob' + `pr`i'' * exp(`fmm_y'*`xb`i'' ///
+															- `exb`i'' - lngamma(`fmm_y'+1)) 
+			if "`equation'"=="component`i'" {
+				qui gen double `probcomponent' = `pr`i'' * exp(`fmm_y'*`xb`i'' ///
+																					- `exb`i'' - lngamma(`fmm_y'+1)) 
+			}
+		}
+		gen `typlist' `varlist' = `probcomponent' / `prob'
+		label variable `varlist' "posterior probability: `equation'"
+		exit
+	}
+
+end
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_postestimation.hlp

@@ -0,0 +1,149 @@
+{smcl}
+{* documented: June 12, 2007}{...}
+{* revised: February 12, 2012}{...}
+{cmd:help fmm postestimation} {right:also see:  {helpb fmm} }
+{hline}
+
+{title:Title}
+
+{hi:fmm postestimation} {hline 2} Postestimation tools for {cmd:fmm}
+
+
+{title:Description}
+
+{pstd}
+The following postestimation commands are available for {opt fmm}:
+
+{synoptset 11}{...}
+{p2coldent :command}description{p_end}
+{synoptline}
+INCLUDE help post_estat
+INCLUDE help post_estimates
+INCLUDE help post_lincom
+INCLUDE help post_lrtest
+INCLUDE help post_margins
+INCLUDE help post_nlcom
+{synopt :{helpb fmm postestimation##predict:predict}}predictions including component 
+probabilities{p_end}
+INCLUDE help post_test
+INCLUDE help post_testnl
+{synoptline}
+{p2colreset}{...}
+
+
+{marker predict}{...}
+{title:Syntax for predict}
+
+{p 8 16 2}
+{cmd:predict} {dtype} {newvar} {ifin} [{cmd:,} {it:statistic}
+{opt eq:uation(component#)}]
+
+{synoptset 11 tabbed}{...}
+{synopthdr :statistic}
+{synoptline}
+{syntab :Main}
+{synopt :{opt me:an}}predicted mean; the default{p_end}
+{synopt :{opt pri:or}}prior component probability{p_end}
+{synopt :{opt pos:terior}}posterior component probability{p_end}
+{synoptline}
+{p2colreset}{...}
+{p 4 6 2}
+Option {opt eq:uation(component#)} is required for {opt pri:or} and {opt pos:terior}.  
+It is also required for {opt me:an} if predicted within-component means are desired.
+{p_end}
+
+INCLUDE help esample
+
+
+{title:Options for predict}
+
+{phang}
+{opt me:an}, the default, calculates the predicted mean.
+
+{pmore}
+To obtain within component means, specify the {opt eq:uation(component#)} option.
+
+{phang}
+{opt pri:or} calculates the prior component probabilities.  With {opt prior}, 
+{opt eq:uation(component#)} must also be specified.
+
+{phang}
+{opt pos:terior} calculates the posterior component probabilities.  With 
+{opt posterior}, {opt eq:uation(component#)} must also be specified.
+
+
+{title:Marginal effects}
+
+{pstd}
+Marginal effects can be calculated separately for the overall conditional mean 
+as well as for within-component means, prior and posterior probabilities.  To calculate 
+marginal effects for within-component means, prior and posterior probabilities, run 
+{cmd:margins} separately for each component, as shown in the examples below. Note that {cmd:fmm} has not been updated to accommodate factor variables.
+
+
+{title:Examples}
+
+{pstd}Mixture of normals
+
+{phang}{stata "webuse womenwk, clear" : . webuse womenwk, clear}
+
+{phang}{stata "fmm wagefull educ age married, mix(normal) comp(2)" : . fmm wagefull educ age married, mix(normal) comp(2)}
+
+{phang}{stata "predict wfhat" : . predict wfhat}
+
+{phang}{stata "predict wfhat1, eq(component1)" : . predict wfhat1, eq(component1)}
+
+{phang}{stata "predict wfhat2, eq(component2)" : . predict wfhat2, eq(component2)}
+
+{phang}{stata "predict wfhatpri, prior eq(component1)" : . predict wfhatpri, prior eq(component1)}
+
+{phang}{stata "predict wfhatpos, posterior eq(component1)" : . predict wfhatpos, posterior eq(component1)}
+
+{phang}{stata "sum wagefull wfhat*" : . sum wagefull wfhat*}
+
+{phang}{stata "drop wfhat*" : . drop wfhat*}
+
+
+{pstd}Mixture of Negative Binomials (Type 2)
+
+{phang}{stata "webuse medpar, clear" : . webuse medpar, clear}
+
+{phang}{stata "gen los0 = los - 1" : . gen los0 = los - 1}
+
+{phang}{stata "fmm los0 died hmo type2-type3, mix(negbin2) comp(2)" : . fmm exlos died hmo type2-type3, mix(negbin2) comp(2) comp(2)}
+
+{phang}{stata "predict wfhat" : . predict wfhat}
+
+{phang}{stata "predict l0hat1, eq(component1)" : . predict l0hat1, eq(component1)}
+
+{phang}{stata "predict l0hat2, eq(component2)" : . predict l0hat2, eq(component2)}
+
+{phang}{stata "predict l0hatpri, prior eq(component1)" : . predict l0hatpri, prior eq(component1)}
+
+{phang}{stata "predict l0hatpos, posterior eq(component1)" : . predict l0hatpos, posterior eq(component1)}
+
+{phang}{stata "sum los0 l0hat*" : . sum los0 l0hat*}
+
+{phang}{stata "drop l0hat*" : . drop l0hat*}
+
+{phang}{stata "margins, dydx(*) predict(eq(component1))" : . margins, dydx(*) predict(eq(component1))}
+
+{phang}{stata "margins, dydx(*) predict(eq(component2))" : . margins, dydx(*) predict(eq(component2))}
+
+{phang}{stata "margins, dydx(*)" : . margins, dydx(*)}
+
+
+{title:Also see}
+
+{psee}
+{helpb fmm};
+{helpb estimates},
+{helpb lincom},
+{helpb lrtest},
+{helpb margins},
+{helpb nlcom},
+{helpb predictnl},
+{helpb suest},
+{helpb test},
+{helpb testnl}
+{p_end}

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_studentt_lf.ado

@@ -0,0 +1,255 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.1.0  12jul2007
+* version 1.1.0  12jul2007
+
+program fmm_studentt_lf
+	version 9.2
+
+	forvalues i = 1/$fmm_components {
+		local L_xb `"`L_xb' xb`i'"'
+		local L_fxb `"`L_fxb' fxb`i'"'
+		local L_pr `"`L_pr' pr`i'"'
+		local L_z `"`L_z' z`i'"'
+		local L_lsig `"`L_lsig' lnsigma`i'"'
+		local L_sig `"`L_sig' sigma`i'"'
+		local L_gb `"`L_gb' gb`i'"'
+		local L_gs `"`L_gs' gs`i'"'
+		local L_z2bydf `"`L_z2bydf' z2bydf`i'"'
+		local L_inv1plz2bydf `"`L_inv1plz2bydf' inv1plz2bydf`i'"'
+	}
+
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local L_gL `"`L_gL' gL`i'"'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			local L_h `"`L_h' h`i'`j'"'
+			local L_nh `"`L_nh' nh`i'`j'"'
+		}
+	}
+
+	forvalues i = 1/`=$fmm_components-1' {
+		local L_lpr `"`L_lpr' lpr`i'"'
+		forvalues j = 1/`=$fmm_components-1' {
+			local L_ga `"`L_ga' ga`i'`j'"'
+		}
+	}
+
+	// model arguments and temporary variables
+	args todo b lnf g negH `L_gL'
+	tempname `L_xb' `L_fxb' `L_lsig' `L_sig' `L_lpr' `L_pr' `L_z' ///
+						den prob gi `L_gb'  `L_ga' `L_gs' hij `L_h' `L_nh' ///
+						dfpl1 `L_z2bydf' `L_inv1plz2bydf'
+
+	// set up equations
+	forvalues i=1/$fmm_components {
+		mleval `xb`i'' = `b', eq(`i')
+		mleval `lnsigma`i'' = `b', eq(`=2*$fmm_components-1+`i'')
+		qui gen double `sigma`i'' = exp(`lnsigma`i'')
+	}
+
+	qui gen double `den' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		mleval `lpr`i'' = `b', eq(`=$fmm_components+`i'')
+		qui replace `den' = `den' + exp(`lpr`i'')
+	}
+
+	forvalues i=1/`=$fmm_components-1' {
+		qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+	}
+
+	qui gen double `pr$fmm_components' = 1
+	forvalues i=1/`=$fmm_components-1' {
+		qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+	}
+
+
+	// calculate the likelihood function
+	qui gen double `prob' = 0
+	forvalues i=1/$fmm_components {
+		qui gen double `z`i'' = ($ML_y-`xb`i'')/`sigma`i''
+		qui gen double `z2bydf`i'' = (`z`i''^2)/$fmm_tdf
+		qui gen double `inv1plz2bydf`i'' = 1/(1 + `z2bydf`i'')
+		qui gen double `fxb`i'' = tden($fmm_tdf,`z`i'')/`sigma`i''
+		qui replace `prob' = `prob' + `pr`i''*`fxb`i''
+	}
+
+	mlsum `lnf' = ln(`prob')
+
+
+	// CALCULATE GRADIENT TERMS
+	qui gen double `dfpl1' = $fmm_tdf + 1
+	// gradient bi
+	forvalues i = 1/$fmm_components {
+		qui gen double `gb`i'' = `dfpl1' * `inv1plz2bydf`i'' ///
+													* `z`i'' / ($fmm_tdf*`sigma`i'') // density specific
+		qui replace `gL`i'' = (`pr`i'' * `fxb`i'' * `gb`i'')/`prob'
+	}
+
+	// gradient prj
+	forvalues j = 1/`=$fmm_components-1' {
+		local m = `=$fmm_components+`j''
+		qui replace `gL`m'' = 0
+		forvalues k = 1/`=$fmm_components-1' {
+			qui gen double `ga`k'`j'' = ((`j'==`k') - `pr`j'')
+			qui replace `gL`m'' = `gL`m'' + `pr`k''*`ga`k'`j'' ///
+											*(`fxb`k'' - `fxb$fmm_components')/`prob'
+		}
+	}
+
+	// gradient sigmai
+	forvalues i=1/$fmm_components {
+		local k = `=2*$fmm_components-1+`i''
+		qui gen double `gs`i'' = `dfpl1' * `inv1plz2bydf`i'' ///
+															* `z2bydf`i'' - 1 // density specific
+		qui replace `gL`k'' = (`pr`i'' * `fxb`i'' * `gs`i'')/`prob'
+	}
+
+	// collect gradient terms into vector
+	local np = colsof(`b')
+	local c 1
+	matrix `g' = J(1,`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		mlvecsum `lnf' `gi' = `gL`i'', eq(`i')
+		matrix `g'[1,`c'] = `gi'
+		local c = `c' + colsof(`gi')
+	}
+
+
+	// CALCULATE HESSIAN TERMS
+	// hessian - b terms
+	local c 1
+	qui gen double `hij' = .
+	forvalues i = 1/$fmm_components {
+		// hessian (bi,bi)
+		qui replace `hij' = `dfpl1' * `inv1plz2bydf`i'' / ($fmm_tdf*(`sigma`i''^2)) ///
+							* (`inv1plz2bydf`i'' * 2 * `z2bydf`i'' - 1) 		// density specific
+		qui gen double `h`i'`i'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`i''*`gb`i'' + `gb`i''^2 + `hij')
+		mlmatsum `lnf' `nh`i'`i'' = -`h`i'`i'', eq(`i',`i')
+		// hessian (bi,bj)
+		if (`i'<$fmm_components) {
+			forvalues j = `=`i'+1'/$fmm_components {
+				qui gen double `h`i'`j'' = `pr`i''/`prob'*(-`gL`j''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`j'' = -`h`i'`j'', eq(`i',`j')
+			}
+		}
+
+		// hessian (bi,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' ///
+						+ 1/`prob'*`fxb`i''*`gb`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local m = `=$fmm_components+`j''
+				qui gen double `h`i'`m'' = -`gL`m''*`gL`i'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`i'`m'' = `h`i'`m'' ///
+							- 1/`prob'*`fxb`i''*`gb`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`i'`m'' = -`h`i'`m'', eq(`i',`m')
+			}
+		}
+
+
+		// hessian (bi,sigma)
+		forvalues j = 1/$fmm_components {
+			local k = `=2*$fmm_components-1+`j''
+			// hessian (bi,sigmai)
+			if (`i'==`j') {
+				qui replace `hij' = -2 * `dfpl1' * `inv1plz2bydf`i'' * `z`i'' ///
+														/ ($fmm_tdf*`sigma`i'')           ///
+														* (1 - `inv1plz2bydf`i'' * `z2bydf`i'')	// density specific
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*`fxb`i'' ///
+					*(-`gL`k''*`gb`i'' + `gs`j''*`gb`i'' + `hij')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+			else {
+			// hessian (bi,sigmaj)
+				qui gen double `h`i'`k'' = `pr`i''/`prob'*(-`gL`k''*`fxb`i''*`gb`i'')
+				mlmatsum `lnf' `nh`i'`k'' = -`h`i'`k'', eq(`i',`k')
+			}
+		}
+	}
+
+	// hessian - pr terms
+	// hessian (prj,pri)
+	forvalues i = 1/`=$fmm_components-1' {
+		forvalues j = `i'/`=$fmm_components-1' {
+			local m = `=$fmm_components+`i''
+			local n = `=$fmm_components+`j''
+			qui gen double `h`m'`n'' = -`gL`m''*`gL`n''
+			qui replace `hij' = -`pr`i''*((`i'==`j') - `pr`j'')
+			forvalues k = 1/`=$fmm_components-1' {
+				qui replace `h`m'`n'' = `h`m'`n'' ///
+						+ 1/`prob'*`pr`k''*(`fxb`k'' - `fxb$fmm_components') ///
+						*(`ga`k'`i''*`ga`k'`j'' + `hij')
+			}
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+	}
+
+
+	// hessian - sigma terms
+	forvalues i = 1/$fmm_components {
+		// hessian w.r.t. sigmai
+		local m = `=2*$fmm_components-1+`i''
+		qui replace `hij' = 2 * `dfpl1' * `inv1plz2bydf`i'' * `z2bydf`i''	///
+												* (`inv1plz2bydf`i'' * `z2bydf`i'' - 1)		  // density specific
+		qui gen double `h`m'`m'' = `pr`i''/`prob'*`fxb`i'' ///
+			*(-`gL`m''*`gs`i'' + `gs`i''^2 + `hij')
+		mlmatsum `lnf' `nh`m'`m'' = -`h`m'`m'', eq(`m',`m')
+		// hessian w.r.t. sigmaj (cross partials)
+		forvalues j = `=`i'+1'/$fmm_components {
+			local n = `=2*$fmm_components-1+`j''
+			qui gen double `h`m'`n'' = `pr`i''/`prob'*(-`gL`n''*`fxb`i''*`gs`i'')
+			mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+		}
+
+	// hessian (sigmai,prj)
+		if (`i'<$fmm_components) {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' ///
+						+ 1/`prob'*`fxb`i''*`gs`i''*`pr`i''*`ga`i'`j''
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+		else {
+			forvalues j = 1/`=$fmm_components-1' {
+				local n = `=2*$fmm_components-1+`i''
+				local m = `=$fmm_components+`j''
+				qui gen double `h`m'`n'' = -`gL`m''*`gL`n'' 
+					forvalues k = 1/`=$fmm_components-1' {
+						qui replace `h`m'`n'' = `h`m'`n'' ///
+							- 1/`prob'*`fxb`i''*`gs`i''*`pr`k''*`ga`k'`j''
+					}
+				mlmatsum `lnf' `nh`m'`n'' = -`h`m'`n'', eq(`m',`n')
+			}
+		}
+	}
+
+	// collect hessian terms into matrix
+	local np = colsof(`b')
+	local r 1
+	matrix `negH' = J(`np',`np',0)
+	
+	forvalues i = 1/`=3*$fmm_components-1' {
+		local c = `r'
+		forvalues j = `i'/`=3*$fmm_components-1' {
+			matrix `negH'[`r',`c'] = `nh`i'`j''
+			if (`j'>`i') {
+				matrix `negH'[`c',`r'] = `nh`i'`j'''
+			}
+			local c = `c' + colsof(`nh`i'`j'')
+		}
+		local r = `r' + rowsof(`nh`i'`i'')
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/f/fmm_studentt_p.ado

@@ -0,0 +1,91 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.1.0 12jul2007
+* version 1.0.0 12jul2007
+
+program fmm_studentt_p
+	version 9.2
+
+	syntax anything(id="newvarname") [if] [in] [, MEan PRior POsterior EQuation(string) ]
+
+	syntax newvarname [if] [in] [, * ]
+
+	if "`equation'" != "" & "`prior'" == "" & "`posterior'" == "" {
+		_predict `typlist' `varlist' `if' `in', equation(`equation')
+		label variable `varlist' "predicted mean: `equation'"
+		exit
+	}
+
+	if "`equation'" == "" | "`prior'" == "prior" | "`posterior'" == "posterior" {
+
+		forvalues i=1/$fmm_components {
+			local L_xb `"`L_xb' xb`i'"'
+			local L_pr `"`L_pr' pr`i'"'
+			local L_lod `"`L_lod' lnsigma`i'"'
+			local L_od `"`L_od' sigma`i'"'
+		}
+		forvalues i=1/`=$fmm_components-1' {
+			local L_lpr `"`L_lpr' lpr`i'"'
+		}
+
+		tempvar `L_xb' `L_lpr' `L_pr' `L_lod' `L_od' den
+
+		forvalues i=1/$fmm_components {
+			qui _predict `typlist' `xb`i'' `if' `in', equation(component`i')
+			qui _predict `typlist' `lnsigma`i'' `if' `in', equation(lnsigma`i')
+			qui gen double `sigma`i'' = exp(`lnsigma`i'')
+		}
+
+		qui gen double `den' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui _predict `typlist' `lpr`i'' `if' `in', equation(imlogitpi`i')
+			qui replace `den' = `den' + exp(`lpr`i'')
+		}
+
+		forvalues i=1/`=$fmm_components-1' {
+			qui gen double `pr`i'' = exp(`lpr`i'')/`den'
+		}
+
+		qui gen double `pr$fmm_components' = 1
+		forvalues i=1/`=$fmm_components-1' {
+			qui replace `pr$fmm_components' = `pr$fmm_components' - `pr`i''
+		}
+	}
+
+	if "`prior'" == "" & "`posterior'" == "" {
+		gen `typlist' `varlist' `if' `in' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `varlist' = `varlist' + `pr`i'' * `xb`i''
+		}
+		label variable `varlist' "predicted mean"
+		exit
+	}
+
+	if "`prior'" == "prior" {
+		local i = substr("`equation'",-1,1)
+		gen `typlist' `varlist' = `pr`i'' `if' `in'
+		label variable `varlist' "prior probability: `equation'"
+		exit
+	}
+
+
+	if "`posterior'" == "posterior" {
+		tempvar prob probcomponent
+
+		local fmm_y = e(depvar)
+		qui gen double `prob' = 0
+		forvalues i=1/$fmm_components {
+			qui replace `prob' = `prob' + `pr`i'' ///
+												* tden($fmm_tdf,(`fmm_y'-`xb`i'')/`sigma`i'')/`sigma`i'' 
+			if "`equation'"=="component`i'" {
+				qui gen double `probcomponent' = `pr`i'' ///
+												* tden($fmm_tdf,(`fmm_y'-`xb`i'')/`sigma`i'')/`sigma`i'' 
+			}
+		}
+		gen `typlist' `varlist' = `probcomponent' / `prob'
+		label variable `varlist' "posterior probability: `equation'"
+		exit
+	}
+
+end
+

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/g/gammareg_lf.ado

@@ -0,0 +1,41 @@
+*! version 2.1.0 12feb2012
+*! author: Partha Deb
+* version 1.1.0 12jul2007
+* version 1.0.0 21dec2006
+
+program gammareg_lf
+	version 9.2
+
+	args todo b lnf g negH g1 g2
+
+	tempname xb exb lnalpha alpha G1 G2 h11 h21 h22 H11 H21 H22 
+
+	mleval `xb' = `b', eq(1)
+	mleval `lnalpha' = `b', eq(2)
+
+	quietly {
+		gen double `exb' = exp(`xb')
+		gen double `alpha' = exp(`lnalpha')
+
+		mlsum `lnf' = ln(gammaden(`alpha',`exb',0,$ML_y))
+
+		replace `g1' = -`alpha' + $ML_y/`exb'
+		replace `g2' = (-digamma(`alpha') - `xb' + log($ML_y))*`alpha'
+
+		mlvecsum `lnf' `G1' = `g1', eq(1)
+		mlvecsum `lnf' `G2' = `g2', eq(2)
+		matrix `g' = (`G1', `G2')
+
+		gen double `h11' = - $ML_y/`exb'
+		gen double `h21' = -`alpha'
+		gen double `h22' = (-digamma(`alpha') - `xb' + log($ML_y) ///
+			- trigamma(`alpha')*`alpha')*`alpha'
+
+		mlmatsum `lnf' `H11' = -`h11', eq(1,1)
+		mlmatsum `lnf' `H21' = -`h21', eq(2,1)
+		mlmatsum `lnf' `H22' = -`h22', eq(2,2)
+		matrix `negH' = (`H11',`H21'' \	///
+										 `H21',`H22')
+	}
+
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/g/glcurve.ado

@@ -0,0 +1,203 @@
+*! 3.2.0 Philippe Van Kerm - Stephen P. Jenkins 07 February 2007
+*  - Concentration curves with ties in ranking variable do not depend on initial sort order anymore: 'maximal concentration' now imposed
+* 3.1.0 Philippe Van Kerm - Stephen P. Jenkins 24 August 2006
+*  - fix for TIP curves with varying (observation-specific) poverty lines (cumulation was not incorrect)
+*  - minor fix for -replace- options with non existing pvar and glvar
+*  - revision of labels (more meaningful labels, identification of TIP curves, etc.)
+* 3.0.2 Philippe Van Kerm - Stephen P. Jenkins 15 May 2006
+*  -one fix: sort stability issue with ties in weights and sort variable
+*  -minor change to help file (label specification)
+* 3.0.0 Philippe Van Kerm - Stephen P. Jenkins 26 October 2004 (SJ 4-4: gr0001_1)
+* touched by NJC 24 October 2004
+* 2.0 Philippe Van Kerm - Stephen P. Jenkins, 19 Feb 2001 (TSJ-1: gr0001)
+* 1.2 Stephen P. Jenkins - Philippe Van Kerm, Apr 1999 STB-49 sg107.1
+* Syntax: glcurve y [fw aw] [if in], [GLvar(x1) Pvar(x2) SOrtvar(svar)
+*            Lorenz RTIP(string) ATIP(string)
+*            BY(gvar) SPlit GRaph REPLACE plot(plot) graph_options]
+
+program glcurve, sort
+	version 8.0
+	syntax varname [if] [in] [fweight aweight] ///
+		[, GLvar(string) Pvar(string) SOrtvar(varname) ///
+		Lorenz RTIP(string) ATIP(string) ///
+		BY(varname numeric) SPlit NOGRaph REPLACE PLOT(string asis) * ]
+
+	tempvar inc cumwy cumw maxw badinc wi gl p
+	tempname byname
+
+	local graph = cond("`nograph'" != "", "", "graph")
+
+	if "`by'" != "" {
+		if "`graph'" != "" & "`split'" == "" {
+			di as err "{p}split must be used to combine by()" ///
+			" with a graph; nograph option assumed{p_end}"
+			local graph
+		}
+	}
+	else {
+		if "`split'" != "" {
+			di as err "{p}split must be combined with by(); " ///
+			" split ignored{p_end}"
+			local split
+		}
+	}
+
+	/* this code modified in v3.0.3 to avoid problems with non-existing variables */
+	if "`replace'" != "" {
+		cap confirm new variable `pvar'
+		if (_rc!=0) {
+			drop `pvar'
+		}
+		if "`split'" != "" & "`by'" != "" {
+			local prefix "`glvar'"
+			cap drop `prefix'_*
+		}
+		else {
+			cap confirm new variable `glvar'
+			if (_rc!=0) {
+				drop `glvar'
+			}
+		}
+	}
+
+	if "`weight'" == "" qui gen byte `wi' = 1
+	else qui gen `wi' `exp'
+
+	marksample touse
+	markout `touse' `sortvar' `by'
+
+	if "`split'" == "" {
+		if "`glvar'" != "" {
+			confirm new variable `glvar'
+			di as txt "new variable `glvar' created"
+		}
+		else tempvar glvar
+	}
+	else qui {
+		if "`glvar'" == "" {
+			tab `by' `by' if  `touse', matrow(`byname')
+			local nv = rowsof(`byname')
+			forval i = 1/`nv' {
+				tempvar newvar`i'
+			}
+		}
+		else {
+			tab `by' `by' if  `touse', matrow(`byname')
+			local prefix "`glvar'"
+			local nv = rowsof(`byname')
+			forval i = 1/`nv' {
+				local suffix = `byname'[`i',1]
+				local newvar`i' "`prefix'_`suffix'"
+				confirm new variable `newvar`i''
+   				noi di as txt "new variable `newvar`i'' created"
+			}
+		}
+	}
+
+	if "`pvar'" != "" {
+		confirm new variable `pvar'
+		di as txt "new variable `pvar' created"
+	}
+	else tempvar pvar
+
+	qui gen `inc' = `varlist' if `touse'
+
+	qui if "`atip'" != "" {
+		if "`rtip'" != "" {
+			di as err "cannot use options atip() and rtip() together"
+			exit 198
+		}
+		if "`lorenz'" != ""{
+			di as err "cannot use option atip() with lorenz"
+			exit 198
+		}
+		replace `inc' = max(0,`atip' - `varlist') if `touse'
+		/* if "`sortvar'" == "" local sortvar "`varlist'" : incorrect if obs.-specific atip */
+		tempvar incratio
+		gen double `incratio' = (`varlist'/`atip')
+		if "`sortvar'" == "" local sortvar "`incratio'"
+	}
+
+	qui if "`rtip'" != "" {
+		if "`lorenz'" != ""{
+			di as err "cannot use option rtip() with lorenz"
+			exit 198
+		}
+		replace `inc' = max(0,(`rtip' - `varlist')/`rtip') if `touse'
+		/* if "`sortvar'" == "" local sortvar "`varlist'" : incorrect if obs.-specific rtip */
+		tempvar incratio
+		gen double `incratio' = (`varlist'/`rtip')
+		if "`sortvar'" == "" local sortvar "`incratio'"
+	}
+
+	quietly {
+		count if `inc' < 0 & `touse'
+		if r(N) > 0 {
+			noi di as txt _n "warning: `inc' has `r(N)' values < 0;" ///
+			"used in calculations"
+		}
+
+		if "`by'" == "" {
+			tempvar placebo
+			gen byte `placebo' = 1
+			local by "`placebo'"
+		}
+
+		if "`sortvar'" == "" local sortvar `inc'
+		sort `by' `sortvar' `inc' , stable /* `inc' included in v3.2.0 to stabilize concentration curves */
+		by `by' : gen double `cumwy' = sum(`wi' * `inc') if `touse'
+		by `by' : gen double `cumw' = sum(`wi') if `touse'
+*		by `by': gen double `cumw' = sum(`wi') if `touse'
+		egen `maxw' = max(`cumw'), by(`by')
+		gen double `pvar' = `cumw'/`maxw' if `touse'
+		label variable `pvar' "Cumulative population proportion"
+
+		/* get the appropriate curve label */
+		if "`lorenz'" != "" loc curvelabel "Lorenz"
+		else if "`atip'" != ""  loc curvelabel "Absolute TIP"
+		else if "`rtip'" != ""  loc curvelabel "Relative TIP"
+		else loc curvelabel "Gen. Lorenz"
+
+		if "`split'" == "" {
+			gen `glvar' = `cumwy'/`maxw' if `touse'
+			label var `glvar' "`curvelabel' (`varlist')"
+			if "`lorenz'" != ""{
+				su `inc' [`weight' `exp'] if `touse', meanonly
+				replace `glvar' = `glvar' / r(mean)
+			}
+			if "`graph'" != "" {
+				twoway scatter `glvar' `pvar' if `touse', ///
+				ms(i i) c(l l) `options'  || `plot'
+			}
+		}
+		else {
+			local lname : value label `by'
+			forval i = 1/`nv' {
+				local bylevel = `byname'[`i',1]
+				bysort `by' (`sortvar'): ge `newvar`i'' = `cumwy'/`maxw' ///
+					if `touse' & `by' ==  `byname'[`i',1]
+				if ("`lname'" != "") {
+				 label var `newvar`i'' "`curvelabel' (`varlist') [`by'==`: label `lname' `= `byname'[`i',1]'']"
+				}
+				else label var `newvar`i'' "`curvelabel' (`varlist') [`by'==`= `byname'[`i',1]']"
+				if "`lorenz'" != "" {
+					su `inc' [`weight' `exp'] if `touse' & `by' == `byname'[`i',1], meanonly
+					replace `newvar`i'' = `newvar`i'' / r(mean)
+				}
+				local listvar "`listvar' `newvar`i''"
+				/*local legtext `"`legtext' `i' "`varlist'[`= `byname'[`i',1]']" "' */
+				if ("`lname'" != "") {
+				  local legtext `"`legtext' `i' "`: label `lname' `= `byname'[`i',1]''" "'
+				  }
+				else local legtext `"`legtext' `i' "`by'==`= `byname'[`i',1]'" "'
+			}
+			if "`graph'" != "" {
+				if `nv' > 1 {
+					local yti `"yti("`curvelabel' `varlist' (by `by')")"'
+				}
+				twoway scatter `listvar' `pvar' if `touse', ///
+				ms(i ..) c(l ..) `yti' legend(order(`legtext')) `options'  || `plot'
+			}
+		}
+	}
+end

40/replication_package/EmpiricalAnalysis/library/stata/ado_ext/plus/g/glcurve.hlp

@@ -0,0 +1,242 @@
+{smcl}
+{* *! 3.2.0 07feb2007}{...}
+{hline}
+help for {hi:glcurve}{right:(SJ7-2: gr0001_3; SJ6-4: gr0001_2; SJ4-4: gr0001_1;}
+{right:SJ1-1: gr0001; STB-49: sg107_1; STB-48: sg107)}
+{hline}
+
+{title:Deriving generalized Lorenz curve ordinates with unit record data}
+
+{p 8 17 2}{cmd:glcurve}
+{it:varname}
+{weight}
+{ifin}
+[{cmd:,}
+{cmdab:p:var}{cmd:(}{it:newvarname}{cmd:)}
+{cmdab:gl:var}{cmd:(}{it:newvarname}{cmd:)}
+{cmdab:so:rtvar}{cmd:(}{it:varname}{cmd:)}
+{cmd:by}{cmd:(}{it:varname}{cmd:)}
+{cmdab:sp:lit}
+{cmdab:nogr:aph}
+{cmd:replace}
+{cmdab:l:orenz}
+{cmd:atip}{cmd:(}{it:string}{cmd:)}
+{cmd:rtip}{cmd:(}{it:string}{cmd:)}
+{cmd:plot}{cmd:(}{it:plot}{cmd:)}
+{it:graph_options}]
+
+{p 4 4 2}{cmd:aweight}s and {cmd:fweight}s are allowed; see {help weight}.
+
+
+{title:Description}
+
+{p 4 4 2}Given a variable {it:varname}, call it x with c.d.f. F(x),
+{cmd:glcurve} draws its generalized Lorenz curve and/or generates two new
+variables containing the generalized Lorenz ordinates for x; i.e., GL(p) at
+each p = F(x).  For a population ordered in ascending order of x, a graph of
+GL(p) against p plots the cumulative total of x divided by population size
+against cumulative population share GL(1) = mean(x). {cmd:glcurve} can also be
+used to derive many other related concepts such as Lorenz curves, concentration
+curves, and "three is of poverty" (TIP) curves, with appropriate definition of
+{it:varname}, order of cumulation (set with the {cmd:sortvar} option), and
+normalization (e.g., by means of {it:varname}). {cmd:glcurve}
+with the {cmd:lorenz}, {cmd:atip}, or {cmd:rtip} option can also be used
+directly to draw the related Lorenz, concentration, and TIP curves.
+
+{p 4 4 2}Comparisons of pairs of distributions (and dominance checks) can be
+undertaken by using the {cmd:by()} (with or without the {cmd:split}) option.
+It can also be made manually by "stacking" the data (see {helpb stack}).
+
+{p 4 4 2}The graphs drawn by {cmd:glcurve} are relatively basic. For graphs
+with full user control over formatting and labeling, users should 
+use {cmd:glcurve} to generate the ordinates of the graph required using the
+{cmd:pvar(}{it:newvarname}{cmd:)} and {cmd:glvar(}{it:newvarname}{cmd:)}
+options and then should draw the graph by using {helpb graph twoway}.
+
+
+{title:Options}
+
+{p 4 8 2}{cmd:pvar(}{it:pvarname}{cmd:)} generates the variable {it:pvarname}
+containing the x coordinates of the created curve.
+
+{p 4 8 2}{cmd:glvar(}{it:glvarname}{cmd:)} generates the variable
+{it:glvarname} containing the y coordinates of the created curve.
+
+{p 4 8 2}{cmd:sortvar(}{it:sname}{cmd:)} specifies the sort variable.  By
+default, the data are sorted (and cumulated) in ascending order of
+{it:varname}. If the {cmd:sortvar} option is specified, sorting and cumulation
+is in ascending order of variable {it:sname}. Within tied values of {it:sname}, 
+data are sorted in ascending order of {it:varname}.
+
+{p 4 8 2}{cmd:by(}{it:groupvar}{cmd:)} specifies that the coordinates are to be
+computed separately for each subgroup defined by {it:groupvar}. {it:groupvar}
+must be an integer variable.
+
+{p 4 8 2}{cmd:split} specifies that a series of new variables be created,
+containing the coordinates for each subgroup specified by
+{cmd:by(}{it:groupvar}{cmd:)}. {cmd:split} cannot be used without {cmd:by()}.
+If {cmd:split} is specified, then the string {it:glname} in
+{cmd:glvar(}{it:glname}{cmd:)} is used as a prefix to create new variables
+{it:glname_X1}, {it:glname_X2}, ... (where X1, X2, ... are the values taken by
+{it:groupvar}).
+
+{p 4 8 2}{cmd:nograph} avoids the automatic display of a crude graph made from
+the created variables. {cmd:nograph} is assumed if {cmd:by()} is specified
+without {cmd:split}.
+
+{p 4 8 2}{cmd:replace} allows the variables specified in
+{cmd:glvar(}{it:glvarname}{cmd:)} and {cmd:pvar(}{it:pvarname}{cmd:)} to be
+overwritten if they already exist. Otherwise {it:glvarname} and
+{it:pvarname} must be new variable names.
+
+{p 4 8 2}{cmd:lorenz} requires that the ordinates of the Lorenz curve be 
+computed instead of generalized Lorenz ordinates. The Lorenz ordinates of
+variable x, L(p), are GL(p)/mean(x).
+
+{p 4 8 2}{cmd:rtip(}{it:povline}{cmd:)} and {cmd:atip(}{it:povline}{cmd:)}
+require that the ordinates of TIP curves be computed instead of generalized
+Lorenz ordinates.  {it:povline} specifies the value of the poverty line: it can
+be either a numeric value taken as the poverty line for all observations or a
+variable name containing the value of the poverty line for each observation.
+{cmd:atip()} draws absolute TIP curves (by cumulating max(z-x,0)) and
+{cmd:rtip()} draws relative TIP curves (by cumulating max(1-(x/z),0)).
+
+{p 4 8 2}{cmd:plot(}{it:plot}{cmd:)} provides a way to add other plots to the
+generated graph; see {it:{help addplot_option}}.
+
+{p 4 8 2}{it:graph_options} are standard {helpb twoway scatter} options.
+Modifications to the legend labels should be made with the
+{cmd:legend(order(}...{cmd:)} options instead of
+{cmd:legend(label(}...{cmd:)} (see {it:{help legend_option}}).
+
+
+{title:Examples}
+
+{p 4 4 2}Many {cmd:glcurve} examples are provided in the downloadable
+materials provided by
+{browse "http://econpapers.repec.org/paper/bocasug06/16.htm":Jenkins (2006)}.
+
+{p 4 8 2}{cmd:. * Generalized Lorenz curve ordinates; plot using -graph twoway- }
+
+{p 4 8 2}{cmd:. glcurve x, gl(gl1) p(p1) nograph}{p_end}
+
+{p 4 8 2}{cmd:. twoway line gl1 p1}
+
+{p 4 8 2}{cmd:. * Lorenz curve ordinates; plot using -glcurve- }
+
+{p 4 8 2}{cmd:. glcurve x, lorenz plot(function equality = x)}
+
+{p 4 8 2}{cmd:. * Lorenz curve ordinates; plot using -glcurve-; options }
+
+{p 4 8 2}{cmd:. glcurve x [fw=wgt] if x > 0, gl(gl2) p(p2) lorenz}
+
+{p 4 8 2}{cmd:. * Generalized Lorenz curve ordinates and graphs, by state }
+
+{p 4 8 2}{cmd:. glcurve x, gl(gl2) p(p2) replace sort(y) by(state) split}
+
+{p 4 8 2}{cmd:. * TIP curve ordinates with graph }
+
+{p 4 8 2}{cmd:. glcurve x, gl(gl3) p(p3) atip(10000)}
+
+{p 4 8 2}{cmd:. glcurve x, gl(gl3) p(p3) atip(plinevar)}
+
+{p 4 8 2}{cmd:. * Lorenz curve ordinates; plot using -graph twoway- }
+
+{p 4 8 2}{cmd:. glcurve x, gl(gl) p(p) lorenz nograph}{p_end}
+
+{p 4 8 2}{cmd:. twoway line gl p , sort || line p p ,{space 1}/// }{p_end}
+{p}{space 8}{cmd:xlabel(0(.1)1) ylabel(0(.1)1){space 6}///}{p_end}
+{p}{space 8}{cmd:xline(0(.2)1)  yline(0(.2)1){space 8}/// }{p_end}
+{p}{space 8}{cmd:title("Lorenz curve") subtitle("Example with custom formatting"){space 4}/// }{p_end}
+{p}{space 8}{cmd:legend(label(1 "Lorenz curve") label(2 "Line of perfect equality")) /// }{p_end}
+{p}{space 8}{cmd:plotregion(margin(zero)) aspectratio(1) scheme(economist)}{p_end}
+
+
+{title:Notes}
+
+{p 4 4 2}{cmd:glcurve} is designed to be used with individual-level,
+unit-record data.  Although {cmd:glcurve} can also be applied mechanically to
+grouped (banded) income data by using {cmd:fweight}s, the
+resulting curve is a potentially poor estimate, because within-income-band
+inequality is not taken into account.  On the estimation of Lorenz curves and
+inequality indices with grouped data, see, e.g., Gastwirth and Glaubermann
+(1976) or Cowell and Mehta (1982).
+
+{p 4 4 2}One must also be careful in using the ordinates returned from the
+option {it:pvar} for subsequent computation of the Gini or concentration
+coefficient by using the "convenient covariance" formulas described by, e.g.,
+Lerman and Yitzhaki (1984, 1989) or Jenkins (1988). The ordinates returned in
+{it:pvar} are the curve ordinates (and are equal to estimates obtained from
+{cmd:cumul}), and these are not necessarily the fractional ranks required in
+the covariance formula. The difference is generally negligible with continuous
+unit-record data but is larger if there are many ties in the ranking variable
+(as for the concentration coefficient based on an ordinal
+categorical variable or when dealing with grouped data). 
+
+
+{title:Acknowledgments}
+
+{p 4 4 2}Nicholas J. Cox helped with updating the code for our program from
+Stata 7 ({helpb glcurve7}) to Stata 8. David Demery and Owen O'Donnell made
+useful bug reports. Comments by Zhuo (Adam) Chen led to introduction of 
+"sort stable" estimation for concentration curves.  
+
+
+{title:Authors}
+
+{p 4 4 2}Philippe Van Kerm, CEPS/INSTEAD, Differdange, G.-D. Luxembourg{break}
+[email protected]
+
+{p 4 4 2}Stephen P. Jenkins, ISER, University of Essex{break}
+[email protected]
+
+
+{title:References}
+
+{p 4 8 2}Cowell, F. A. 1995. {it:Measuring Inequality}. 2nd ed.
+Hemel Hempstead: Prentice-Hall/Harvester-Wheatsheaf.
+
+{p 4 8 2}Cowell, F. A., and F. Mehta. 1982.
+The estimation and interpolation of inequality measures.
+{it:Review of Economic Studies} 49(2): 273-290. 
+
+{p 4 8 2}Gastwirth, J. L., and M. Glauberman. 1976.
+The interpolation of the Lorenz curve and Gini index from grouped data.
+{it:Econometrica} 44(3): 479-483. 
+
+{p 4 8 2}Jenkins, S. P. 1988.
+Calculating income distribution indices from microdata.
+{it:National Tax Journal} 61: 139-142.
+
+{p 4 8 2}Jenkins, S. P. 2006.
+Estimation and interpretation of measures of inequality,
+poverty, and social welfare using Stata. Presentation at North American
+Stata Users Group meeting 2006, Boston.
+{browse "http://econpapers.repec.org/paper/bocasug06/16.htm"}.
+
+{p 4 8 2}Jenkins, S. P., and P. J. Lambert. 1997.
+Three 'I's of poverty curves, with an analysis of UK poverty trends.
+{it:Oxford Economic Papers} 49: 317-327.
+
+{p 4 8 2}Lambert, P. J. 2001.
+{it:The Distribution and Redistribution of Income}. 3rd ed.
+Manchester: Manchester University Press.
+
+{p 4 8 2}Lerman, R. I., and S. Yitzhaki. 1984.
+A note on the calculation and interpretation of the Gini index.
+{it:Economics Letters} 15: 363-368.
+
+{p 4 8 2}------. 1989.
+Improving the accuracy of estimates of Gini coefficients.
+{it:Journal of Econometrics} 42: 43-47.
+
+{p 4 8 2}Shorrocks, A. F. 1983. Ranking income distributions.
+{it:Economica} 197: 3-17.
+
+
+{title:Also see}
+
+{psee} Manual:  {hi:[R] lorenz}{p_end}
+
+{psee}Online:  {helpb sumdist}, {helpb svylorenz} (if installed)
+{p_end}