add 110

110/paper.pdf

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:07d13bb63519a2b71d947cad77a7fdce405a8fe8149948a912d60ec73311c0f7
+size 1047016

110/replication_package/README.pdf

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:78a718f187ebdc73405e2c0fd25b19f5f355ddebff74865072cbb606f9ad750e
+size 83852

110/replication_package/replication/Data/Raw/allcity_info.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:12a4cb5b0d282c620703079f8249182f5be48ba77acc8dccdcbd91201b396f30
+size 26619

110/replication_package/replication/Data/Raw/baidu.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:1592c3d50dfd55c71dc6e941b060ad427988755640cd8dd629e5ceb10a616e9d
+size 1610593

110/replication_package/replication/Data/Raw/city_info.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:3a82a01813262f00682801f8d1b6cc82495ab1b91d5b0cad81c45617fa5ecf32
+size 157347

110/replication_package/replication/Data/Raw/daily_monitor_api.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:601b057fbd7bb156dc6c09ac76944951b5f5fda616e716f150389a656325790f
+size 73326101

110/replication_package/replication/Data/Raw/enf_info.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:725cfabc1df243f8581550753f1dc4ca837a9b3cfadc91cdbee5334da91884a7
+size 125241117

110/replication_package/replication/Data/Raw/firm_info.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:219e4405db12a981ae0968460f46759c4ca55ac25bae511a7452ecaab33ecf55
+size 48410992

110/replication_package/replication/Data/Raw/lights.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:660809efe234fe8cce30755a42884a612c898be7f84e58d442fd630fd2a3f7cb
+size 590633

110/replication_package/replication/Data/Raw/mayor.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:049e787aab43af46ed8d7c119813ddbd24aa6f3d520b83a47572ef1e1cbf22b3
+size 158452

110/replication_package/replication/Data/Raw/monitor_city_long.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:9a62866ac354457cc8d873bc4ee89eb50ccdc662d93700bba83c8ad61265cd4c
+size 398439

110/replication_package/replication/Data/Raw/monitor_info.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:72f23e3fbfa4045e19762601b67364054560599b0229375e6bace842a2d9cd9a
+size 17207

110/replication_package/replication/Data/Raw/non-asif.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:c2dae2c0e50bb65703d9f7b7adb60708170aa9b95451792a5a756b87b26401b5
+size 145814

110/replication_package/replication/Data/Raw/pm.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:b48d012c21a4b6d2640315da680593a4984956da648010306a5aff782c8a06c6
+size 402981

110/replication_package/replication/Data/Raw/pm_pix.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:161a1cd39bba8a13dd987fe56cb957571ceb1570f536957524550a3723c6951d
+size 296456487

110/replication_package/replication/Data/Raw/weather_daily.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:4ec43c966d187b8e8bf642914cdd514a0b67907ceceaf830a86567d77f1f16e5
+size 356358846

110/replication_package/replication/Data/age_2017.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:075f53223d92b3ec57941b91f325a70b5a61f8097336d9a98ef72b83d2e83526
+size 9971

110/replication_package/replication/Data/age_year.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:cbacc1ada89b49d026131d50dc255fefa6a1302d9f4577dc1ea9aaa4fa7dfbe2
+size 17228

110/replication_package/replication/Data/city_enf.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:7736abea6375079aa347b33c17db4eb6616fa420b53834820fdcff4c7805f225
+size 5212280

110/replication_package/replication/Data/city_enf_rd.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:26c6b8b5d881fa88d1312b4206033bd85a1181741cc116a23ef11f9b739cd0bd
+size 10401144

110/replication_package/replication/Data/city_pm.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:b40fbf0c7ac82654fd5d45a40fcd4490a79a566cdf5d84e7eb301d7d57e35e84
+size 14746346

110/replication_package/replication/Data/city_pm_rd.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:5e449b5afef866304b825c89830b1c1e2afc13a8f59a921c5d29a5a73f6bd2d0
+size 29496042

110/replication_package/replication/Data/enf.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:e2607fee216a4488bf52da3a9833a0b9e86a8da4066af5ea57f0ebb3efd53540
+size 447505

110/replication_package/replication/Data/firm_enf.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:c057d3ef97271990288ae4773bdc26d1be58b65e269c61b958b1319c41a7c257
+size 1790795729

110/replication_package/replication/Data/mayor_panel.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:943e087105600af41c4686d6b327678a454fa3ccf6b0a955203eaf7690781fac
+size 5591041

110/replication_package/replication/Data/monitor_api.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:ee5a6f082c4897a3f25a001b9a89559c5e54fdf64016ac6b445732163f01142b
+size 1165784

110/replication_package/replication/Data/monitor_pix.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:b480cdfd1bb7de424b67048ebc5e42a5418a2d44eb1dd336e3342f6df9dfb51c
+size 967587

110/replication_package/replication/Data/monthly_api.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:9e581d51abea4737c85604861f62fc370e6908c8ca28442b2891ae063bf5d6fc
+size 1930462

110/replication_package/replication/Data/pix.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:a307757e58c7bc113f829f0494542ee98f1d00a5795469b2d4e78e782117b234
+size 221127

110/replication_package/replication/Data/share.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:e01d6591a4efbed529daf66bd71fec07bbda9093a022bb874f9613f493f2eca4
+size 11366

110/replication_package/replication/Data/weather_monthly.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:25ccb314e369ee87ed719872313ea3ed2b91d493f8bdd2ca2e44b619a579656f
+size 297844

110/replication_package/replication/Data/weather_quarterly.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:f93b8adcffe878426f1c004bbda5d36daa347fbc78c8c7651a55bd12232d32b4
+size 122260

110/replication_package/replication/Data/wind_quarterly.dta

@@ -0,0 +1,3 @@
+version https://git-lfs.github.com/spec/v1
+oid sha256:9c1a0b439edc00aa35d7b8a42cdada8c415b15774c026e396a4bdd6f699697e9
+size 59316

110/replication_package/replication/Do-file/Appendix.do

@@ -0,0 +1,1564 @@
+* Set Directory
+clear
+set more off
+set scheme s1mono
+
+cd "$path"
+global data_files "$path/Data"
+global out_files "$path/output"
+
+**==============================================================================
+* Table A1
+use "$data_files/Raw/allcity_info", clear
+
+label variable pm25 "AOD"
+label variable number "\# Monitors"
+label variable area "Size of Built-up Area (km2)"
+label variable pop "Urban Population (10,000)"
+
+eststo clear
+estpost tabstat pm25 number area pop, by(mainsample) statistics(mean sd) columns(statistics) listwise nototal
+esttab using "$out_files/TableA1.tex", replace tex main(mean) aux(sd) nogaps nodepvar compress fragment nostar noobs unstack nonote nomtitle label
+
+**==============================================================================
+* Table C1
+use "$data_files/firm_enf.dta", clear
+keep if min_dist<50 & starty<=2010
+drop if revenue == .
+drop if key == .
+
+label variable any_air "Any Air Pollution Enforcement"
+label variable any_air_shutdown "\quad Suspension"
+label variable any_air_fine "\quad Fine"
+label variable any_air_renovate "\quad Upgrading"
+label variable any_air_warning "\quad Warning"
+label variable air "\# Air Pollution Enforcement"
+label variable any_water "Any Water Pollu. Enforc."
+label variable any_waste "Any Solid Waste Pollu. Enforc."
+label variable any_proc "Any Procedure Pollu. Enforc."
+
+label variable min_dist_10 "Monitor within 10 km"
+label variable min_dist "Distance to Monitor (km)"
+label variable starty "Year Started"
+label variable employment "Employment"
+label variable revenue "Revenue"
+label variable up "Upwind Firms"
+
+eststo clear
+estpost summarize any_air* air any_water any_waste any_proc up
+esttab using "$out_files/TableC1a1.tex", replace cells("mean(fmt(a2)) sd(fmt(a2)) count") noobs nolines nogaps nodepvar compress fragment nonumbers label mlabels(none) tex
+display "Periods: "
+display "Frequency: "
+
+keep if year==2010 & quarter==1
+
+gen state = (ownership==1 | ownership==2)
+gen private = (ownership==3)
+gen foreign = (ownership==9)
+gen rest = (ownership==4|ownership==5)
+
+label variable state "Owner: SOEs"
+label variable private "Owner: Private"
+label variable foreign "Owner: Foreign"
+label variable rest "Owner: Other"
+
+eststo clear
+estpost summarize min_dist_10 min_dist starty state private foreign rest employment revenue
+esttab using "$out_files/TableC1a2.tex", replace cells("mean(fmt(a2)) sd(fmt(a2)) count") noobs nolines nogaps nodepvar compress fragment nonumbers label mlabels(none) tex
+display "Periods: "
+display "Frequency: "
+
+use "$data_files/city_pm.dta", clear
+drop if pm25 == .
+
+label variable number "\# Monitors"
+label variable area "Size of Built-up Area (km2)"
+label variable pop "Urban Population (10,000)"
+label variable age_year "Age of the Mayor"
+label variable pre "Precipitation (mm)"
+label variable tem_mean "Mean Temperature"
+label variable pm25 "Aerosol Optical Depth"
+
+eststo clear
+estpost summarize number area pop age_year pre tem_mean pm25
+esttab using "$out_files/TableC1b1.tex", replace cells("mean(fmt(a2)) sd(fmt(a2)) count") noobs nolines nogaps nodepvar compress fragment nonumbers label mlabels(none) tex
+display "Periods: "
+display "Frequency: "
+
+use "$data_files/city_pm.dta", clear
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+merge 1:1 city_cn year month using "$data_files/Raw/baidu.dta" 
+keep if _merge == 3
+drop _merge
+
+label variable sear_freq_w1 "Search Index: air pollution"
+label variable sear_freq_w2 "Search Index: haze/smoke"
+label variable sear_freq_w3 "Search Index: PM25"
+label variable sear_freq_w4 "Search Index: air mask"
+label variable sear_freq_w5 "Search Index: air purifier"
+
+eststo clear
+estpost summarize sear* 
+esttab using "$out_files/TableC1b3.tex", replace cells("mean(fmt(a2)) sd(fmt(a2)) count") noobs nolines nogaps nodepvar compress fragment nonumbers label mlabels(none) tex
+display "Periods: "
+display "Frequency: "
+
+use "$data_files/city_enf.dta", clear
+
+gen any_air_total = any_air+any_air_rest
+label variable any_air_total "\# Firms Any Air Pollu. Enfor. (incl non-ASIF)"
+label variable any_air "\# Firms Any Air Pollu. Enfor."
+
+eststo clear
+estpost summarize any_air any_air_total 
+esttab using "$out_files/TableC1b2.tex", replace cells("mean(fmt(a2)) sd(fmt(a2)) count") noobs nolines nogaps nodepvar compress fragment nonumbers label mlabels(none) tex
+display "Periods: "
+display "Frequency: "
+
+use "$data_files/monitor_api.dta", clear
+
+label variable pm25api "Particulate Matter 2.5 (PM$\_2.5$)"
+label variable pm10api "Particulate Matter 10 (PM$\_10$))"
+label variable AQI "Air Quality Index (AQI) "
+
+eststo clear
+estpost summarize pm25api pm10api AQI
+esttab using "$out_files/TableC1c.tex", replace cells("mean(fmt(a2)) sd(fmt(a2)) count") noobs nolines nogaps nodepvar compress fragment nonumbers label mlabels(none) substitute(\_ _) tex
+
+**==============================================================================
+* Table C4
+use "$data_files/monitor_api.dta", clear
+
+gen log_pm25api = log(pm25api)
+gen log_pm10api = log(pm10api) 
+gen log_aqi = log(AQI) 
+replace log_aqi = . if log_pm25api == .
+
+rename pm25 AOD
+label variable AOD "AOD"
+
+eststo clear
+reghdfe log_pm25api AOD pre tem_mean, a(monitor_id year#month) cl(city_id)
+eststo A
+estadd ysumm, mean
+reghdfe log_pm10api AOD pre tem_mean, a(monitor_id year#month) cl(city_id)
+eststo B
+estadd ysumm, mean
+reghdfe log_aqi AOD pre tem_mean, a(monitor_id year#month) cl(city_id)
+eststo C
+estadd ysumm, mean
+esttab A B C using "$out_files/TableC4.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep(AOD) drop() stats(ymean N, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+**==============================================================================
+* Table C5
+use "$data_files/firm_enf.dta", clear
+drop if revenue == .
+drop if key == .
+keep if min_dist<50 & starty<=2010 & time==1
+
+gen twodigit = int(industry/100)
+
+lab def twodigit_lb 6 "Mining and Washing of Coal & 6" ///
+ 7 "Extraction of Petroleum and Natural Gas & 7" ///
+ 8 "Mining and Processing of Ferrous Metal Ores & 8" ///
+ 9 "Mining and Processing of Non-Ferrous Metal Ores & 9" ///
+ 10 "Mining and Processing of Nonmetallic Mineral & 10" ///
+ 11 "Mining Support & 11" ///
+ 12 "Other Mining & 12" ///
+ 13 "Agricultural and Sideline Food Processing & 13" ///
+ 14 "Fermentation & 14" ///
+ 15 "Beverage Manufacturing & 15" ///
+ 16 "Tobacco Manufacturing & 16" ///
+ 17 "Textile Mills & 17" ///
+ 18 "Wearing Apparel and Clothing Accessories Manufacturing & 18" ///
+ 19 "Leather, Fur and Related Products Manufacturing & 19" ///
+ 20 "Wood and Bamboo Products Manufacturing & 20" ///
+ 21 "Furniture Manufacturing & 21" ///
+ 22 "Products Manufacturing & 22" ///
+ 23 "Printing and Reproduction of Recorded Media & 23" ///
+ 24 "Education and Entertainment Articles Manufacturing & 24" ///
+ 25 "Petrochemicals Manufacturing & 25" ///
+ 26 "Chemical Products Manufacturing& 26" ///
+ 27 "Medicine Manufacturing & 27" ///
+ 28 "Chemical Fibers Manufacturing & 28" ///
+ 29 "Rubber Products Manufacturing & 29" ///
+ 30 "Plastic Products Manufacturing & 30" ///
+ 31 "Non-Metallic Mineral Products Manufacturing & 31" ///
+ 32 "Iron and Steel Smelting & 32" ///
+ 33 "Non-Ferrous Metal Smelting & 33" ///
+ 34 "Fabricated Metal Products Manufacturing & 34" ///
+ 35 "General Purpose Machinery Manufacturing & 35" ///
+ 36 "Special Purpose Machinery Manufacturing & 36" ///
+ 37 "Transport Equipment Manufacturing & 37" ///
+ 38 "Electrical machinery and equipment Manufacturing & 38" ///
+ 39 "Electrical Equipment Manufacturing & 39" ///
+ 40 "Computers and Electronic Products Manufacturing & 40" ///
+ 41 "General Instruments and Other Equipment Manufacturing & 41" ///
+ 42 "Craft-works Manufacturing  & 42" ///
+ 43 "Renewable Materials Recovery & 43" ///
+ 44 "Electricity and Heat Supply & 44" ///
+ 45 "Gas Production and Supply & 45" ///
+ 46 "Water Production and Supply & 46", add
+ 
+label values twodigit twodigit_lb
+
+eststo clear
+
+estpost tabulate twodigit
+esttab using "$out_files/TableC5.tex", replace tex cells("b(label(freq)) pct(fmt(2))") varlabels(`e(labels)', blist(Total)) nolines nogaps compress fragment label
+
+
+**==============================================================================
+* Table C6
+use "$data_files/Raw/daily_monitor_api.dta", clear
+
+* Construct daily indicators
+gen above_100=0 & AQI!=.
+replace above_100=1 if AQI>=100 & AQI!=.
+gen above_200=0 & AQImax!=.
+replace above_200=1 if AQImax>=200 & AQImax!=.
+
+* Collapse data to monthly level
+collapse (mean) above_200 pm25api pm10api AQI, by(year month city_id)
+
+* Merge with weather data
+merge 1:1 city_id year month using "$data_files/weather_monthly.dta"
+keep if _merge == 3
+drop _merge
+
+gen quarter = int((month-1)/3)+1
+collapse (mean) above_200 pm25api pm10api AQI pre tem_mean, by(year quarter city_id)
+
+* Construct monthly variables
+egen time=group(year quarter)
+replace pre=. if pre==-9999
+
+bysort city_id: egen med_pre=median(pre) 
+gen high_pre=0 if pre!=.
+replace high_pre=1 if pre>med_pre & pre!=.
+label var high_pre "\$Rain_{>\tilde{x}}$"
+
+gen log_pre=log(pre)
+gen log_api25=log(pm25api)
+gen log_aqi=log(AQI)
+gen log_api10=log(pm10api)
+
+gen tem_meand = int(tem_mean)
+
+* Monthly pollution regressions
+reghdfe log_api25 high_pre, absorb(time city_id tem_meand) cluster(city_id)
+eststo A
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe log_api10 high_pre, absorb(time city_id  tem_meand) cluster(city_id)
+eststo B
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe log_aqi high_pre, absorb(time city_id  tem_meand) cluster(city_id)
+eststo C
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe above_200 high_pre if AQI!=., absorb(time city_id  tem_meand) cluster(city_id)
+eststo D
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+
+esttab A B C D using "$out_files/TableC6.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() drop(_cons) stats(ymean EN, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+**==============================================================================
+* Table C7
+use "$data_files/firm_enf.dta", clear
+drop if revenue == .
+drop if key == .
+
+label var min_dist_10 "Mon\$\_{<10km}\$"
+label var any_air "Any Enforcement (0/1)"
+label var post "Post"
+label var key "High Pollution"
+
+* Table 
+eststo clear
+reghdfe any_air c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo A
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local FirmFE = "Yes"
+estadd local ITFE = "Yes"
+estadd local PTFE = "Yes"
+reghdfe any_water c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo B
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local FirmFE = "Yes"
+estadd local ITFE = "Yes"
+estadd local PTFE = "Yes"
+reghdfe any_waste c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo C
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local FirmFE = "Yes"
+estadd local ITFE = "Yes"
+estadd local PTFE = "Yes"
+reghdfe any_proc c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo D
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local FirmFE = "Yes"
+estadd local ITFE = "Yes"
+estadd local PTFE = "Yes"
+esttab A B C D using "$out_files/TableC7a.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep(c.min_dist_10*) stats(ymean EN FirmFE ITFE PTFE, labels("Mean Outcome" "Observations" "Firm FE" "Industry-Time FE" "Province-Time FE")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+merge m:1 city_id using "$data_files/Raw/city_info.dta", keepusing(disttocoast)
+keep if _merge == 3
+drop _merge
+
+eststo clear
+reghdfe any_air c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo A
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local FirmFE = "Yes"
+estadd local ITFE = "Yes"
+estadd local PTFE = "Yes"
+estadd local DTFE = "No"
+estadd local FCTFE = "No"
+estadd local CTFE = "No"
+reghdfe any_air c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time c.disttocoast#time) cluster(city_id)
+eststo B
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local FirmFE = "Yes"
+estadd local ITFE = "Yes"
+estadd local PTFE = "Yes"
+estadd local DTFE = "Yes"
+estadd local FCTFE = "No"
+estadd local CTFE = "No"
+reghdfe any_air c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time c.disttocoast#time c.employment#time) cluster(city_id)
+eststo C
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local FirmFE = "Yes"
+estadd local ITFE = "Yes"
+estadd local PTFE = "Yes"
+estadd local DTFE = "Yes"
+estadd local FCTFE = "Yes"
+estadd local CTFE = "No"
+reghdfe any_air c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time city_id#time) cluster(city_id)
+eststo D
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local FirmFE = "Yes"
+estadd local ITFE = "Yes"
+estadd local PTFE = "No"
+estadd local DTFE = "No"
+estadd local FCTFE = "Yes"
+estadd local CTFE = "Yes"
+esttab A B C D using "$out_files/TableC7b.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep(c.min_dist_10*) stats(ymean EN DTFE FCTFE CTFE FirmFE ITFE PTFE, labels("Mean Outcome" "Observations" "Distance to coast-Time FE" "Firm characteristics-Time FE" "City-Time FE" "Firm FE" "Industry-Time FE" "Province-Time FE" )) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+**==============================================================================
+* Table C8
+use "$data_files/Raw/city_info.dta", clear
+merge 1:1 city_id using "$data_files/share.dta"
+drop if _merge == 2
+drop _merge
+
+label variable number "\# Monitors"
+label variable number_iv "Min \# Monitors"
+
+regress share_rev_10 number, r
+eststo A
+estadd ysumm, mean
+regress share_emp_10 number, r
+eststo B
+estadd ysumm, mean
+regress share_rev_5 number, r
+eststo C
+estadd ysumm, mean
+regress share_emp_5 number, r
+eststo D
+estadd ysumm, mean
+esttab A B C D using "$out_files/TableC8a.tex", replace b(a2) noconstant se(a2) label nolines nogaps compress fragment nonumbers mlabels(none) collabels() drop(_cons) stats(ymean N, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+ivregress 2sls share_rev_10 (number = number_iv), r
+eststo A
+estadd ysumm, mean
+ivregress 2sls share_emp_10 (number = number_iv), r
+eststo B
+estadd ysumm, mean
+ivregress 2sls share_rev_5 (number = number_iv), r
+eststo C
+estadd ysumm, mean
+ivregress 2sls share_emp_5 (number = number_iv), r
+eststo D
+estadd ysumm, mean
+esttab A B C D using "$out_files/TableC8b.tex", replace b(a2) noconstant se(a2) label nolines nogaps compress fragment nonumbers mlabels(none) collabels() drop(_cons) stats(ymean N, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+**==============================================================================
+* Table C9
+* Robustness: additional controls
+use "$data_files/city_pm.dta", clear
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+eststo clear
+reghdfe pm25 RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe pm25 c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo B
+reghdfe pm25 RD_Estimate i.time#c.area i.time#c.pop, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo C
+ivreghdfe pm25 i.time#c.area i.time#c.pop i.time#c.background (RD_Estimate=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo D
+reghdfe pm25 RD_Estimate i.time#c.area i.time#c.pop i.time#c.background i.time#c.GDP, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo E
+ivreghdfe pm25 i.time#c.area i.time#c.pop i.time#c.background i.time#c.GDP (RD_Estimate=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo F
+esttab A B C D E F using "$out_files/TableC9a.tex", tex keep(RD_Estimate) transform(@/1, pattern(0 0 0 0)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN, labels( "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+use "$data_files/city_enf.dta", clear
+
+label variable post1 "Post"
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+eststo clear
+reghdfe log_any_air RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+estadd local CFE = "Yes"
+estadd local TTFE = "Yes"
+estadd local CSPost = "Yes"
+estadd local CSTFE = "No"
+estadd local CCTFE = "No"
+estadd local Weather = "Yes"
+eststo A
+ivreghdfe log_any_air c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+estadd local CFE = "Yes"
+estadd local TTFE = "Yes"
+estadd local CSPost = "Yes"
+estadd local CSTFE = "No"
+estadd local CCTFE = "No"
+estadd local Weather = "Yes"
+eststo B
+reghdfe log_any_air RD_Estimate i.time#c.area i.time#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+estadd local CFE = "Yes"
+estadd local TTFE = "Yes"
+estadd local CSPost = "No"
+estadd local CSTFE = "Yes"
+estadd local CCTFE = "No"
+estadd local Weather = "Yes"
+eststo C
+ivreghdfe log_any_air i.time#c.area i.time#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+estadd local CFE = "Yes"
+estadd local TTFE = "Yes"
+estadd local CSPost = "No"
+estadd local CSTFE = "Yes"
+estadd local CCTFE = "No"
+estadd local Weather = "Yes"
+eststo D
+reghdfe log_any_air RD_Estimate i.time#c.area i.time#c.pop i.time#c.background i.time#c.GDP, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+estadd local CFE = "Yes"
+estadd local TTFE = "Yes"
+estadd local CSPost = "No"
+estadd local CSTFE = "Yes"
+estadd local CCTFE = "Yes"
+estadd local Weather = "Yes"
+eststo E
+ivreghdfe log_any_air i.time#c.area i.time#c.pop i.time#c.background i.time#c.GDP (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+estadd local CFE = "Yes"
+estadd local TTFE = "Yes"
+estadd local CSPost = "No"
+estadd local CSTFE = "Yes"
+estadd local CCTFE = "Yes"
+estadd local Weather = "Yes"
+eststo F
+esttab A B C D E F using "$out_files/TableC9b.tex", tex keep(RD_Estimate) transform(@/1, pattern(0 0 0 0)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN CFE TTFE CSPost CSTFE CCTFE Weather, labels("Observations" "City FE" "Target-Time FE" "City size $\times$ Post" "City size-Time FE" "City char.-Time FE" "Weather")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+**==============================================================================
+* Table C10
+* Robustness: Sample Restriction
+use "$data_files/city_pm.dta", clear
+
+gen prov_id = int(city_id/100)
+drop if prov_id == 54 | prov_id == 65
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+reghdfe pm25 RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe pm25 c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo B  
+
+use "$data_files/city_pm_rd.dta", clear
+
+gen prov_id = int(city_id/100)
+drop if prov_id == 54 | prov_id == 65
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = pm25 if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust pm25 dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench year month) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe pm25 RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N_full)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/TableC10a.tex", tex keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN, labels( "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+use "$data_files/city_enf.dta", clear
+
+gen prov_id = int(city_id/100)
+drop if prov_id == 54 | prov_id == 65
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+reghdfe log_any_air RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe log_any_air c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo B
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen prov_id = int(city_id/100)
+drop if prov_id == 54 | prov_id == 65
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = log_any_air if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+estadd local kern = "Uniform"
+eststo C
+reghdfe log_any_air RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N_full)
+estadd scalar band = 11.3
+estadd local kern = "Uniform"
+eststo D
+esttab A B C D using "$out_files/TableC10b.tex", tex keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN kern band, labels("Observations" "Kernel" "Bandwidth")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+
+**==============================================================================
+* Table C11
+* asif vs all
+use "$data_files/city_enf.dta", clear
+
+gen log_any_air_total = log(any_air+any_air_rest+1)
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+reghdfe log_any_air_total RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe log_any_air_total c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo B
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen log_any_air_total = log(any_air+any_air_rest+1)
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = log_any_air_total if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air_total dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench year quarter) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe log_any_air_total RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N_full)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/TableC11a.tex", tex keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN, labels("Observations")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+
+use "$data_files/city_enf.dta", clear
+
+gen log_any_air_rest = log(any_air_rest+1)
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+reghdfe log_any_air_rest RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe log_any_air_rest c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo B
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen log_any_air_rest = log(any_air_rest+1)
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = log_any_air_rest if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air_rest dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench year quarter) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe log_any_air_rest RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N_full)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/TableC11b.tex", tex keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN, labels("Observations")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+
+**==============================================================================
+* Table C12
+* kernel and covs
+use "$data_files/city_pm_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = pm25 if year < 2012
+bys city_id: egen mean_bench = mean(bench)
+
+eststo clear
+rdrobust pm25 dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench year month) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo A
+rdrobust pm25 dist1 if year>=2015, fuzzy(number) p(1) covs(cutoff mean_bench year month) kernel(tri) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo B
+rdrobust pm25 dist1 if year>=2015, fuzzy(number) p(1) covs(cutoff mean_bench year month) kernel(epa) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+rdrobust pm25 dist1 if year>=2015, fuzzy(number) p(1) covs() kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo D
+esttab A B C D using "$out_files/TableC12a1.tex", tex keep(RD_Estimate) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN band, labels("Observations" "Bandwidth")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+eststo clear
+rdrobust number dist1 if year>=2015, p(1) h(11.3) covs(cutoff) kernel(uni) vce(cluster city_id)
+eststo A
+rdrobust number dist1 if year>=2015, p(1) h(12.3) covs(cutoff) kernel(tri) vce(cluster city_id)
+eststo B
+rdrobust number dist1 if year>=2015, p(1) h(12.5) covs(cutoff) kernel(epa) vce(cluster city_id)
+eststo C
+rdrobust number dist1 if year>=2015, p(1) h(13.8) covs() kernel(uni) vce(cluster city_id)
+eststo D
+esttab A B C D using "$out_files/TableC12a2.tex", tex replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers noobs mlabels(none) keep(RD_Estimate) coeflabels(RD_Estimate "First stage") starlevels(* 0.10 ** 0.05 *** 0.01)
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen dist2 = pop - 25 if cutoff == 1
+replace dist2 = pop - 50 if cutoff == 2
+
+gen bench = log_any_air if year < 2012
+bys city_id: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+eststo clear
+rdrobust log_any_air dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench year quarter) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo A
+rdrobust log_any_air dist1 if year>=2015, fuzzy(number) p(1) covs(cutoff mean_bench year quarter) kernel(tri) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo B
+rdrobust log_any_air dist1 if year>=2015, fuzzy(number) p(1) covs(cutoff mean_bench year quarter) kernel(epa) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+rdrobust log_any_air dist1 if year>=2015, fuzzy(number) p(1) covs() kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo D
+esttab A B C D using "$out_files/TableC12b1.tex", tex keep(RD_Estimate) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN band, labels("Observations" "Bandwidth")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+eststo clear
+rdrobust number dist1 if year>=2015, p(1) h(11.3) covs(cutoff) kernel(uni) vce(cluster city_id)
+eststo A
+estadd local kern = "Uniform"
+estadd local cov = "Yes"
+rdrobust number dist1 if year>=2015, p(1) h(13.1) covs(cutoff) kernel(tri) vce(cluster city_id)
+eststo B
+estadd local kern = "Epanechnikov"
+estadd local cov = "Yes"
+rdrobust number dist1 if year>=2015, p(1) h(12.5) covs(cutoff) kernel(epa) vce(cluster city_id)
+eststo C
+estadd local kern = "Triangle"
+estadd local cov = "Yes"
+rdrobust number dist1 if year>=2015, p(1) h(11.4) covs() kernel(uni) vce(cluster city_id)
+eststo D
+estadd local kern = "Uniform"
+estadd local cov = "No"
+esttab A B C D using "$out_files/TableC12b2.tex", tex replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers noobs mlabels(none) keep(RD_Estimate) coeflabels(RD_Estimate "First stage") stats(kern cov, labels("Kernel" "Covariates")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+
+**==============================================================================
+* Table C13
+* Cutoff 1
+use "$data_files/city_pm.dta", clear
+
+gen dist1 = area - 20
+
+gen bench = pm25 if year < 2012
+bys city_id: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+eststo clear
+rdrobust pm25 dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(mean_bench year quarter) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo A
+reghdfe pm25 RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post#c.above#c.dist1 if abs(dist1) < 11.3, a(year#month) cl(city_id)
+estadd scalar EN = e(N_full)
+estadd scalar band = 11.3
+eststo B
+
+use "$data_files/city_enf.dta", clear
+
+gen dist1 = area - 20
+
+gen bench = log_any_air if year < 2012
+bys city_id: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(mean_bench year quarter) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe log_any_air RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N_full)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/TableC13a1.tex", tex keep(RD_Estimate) transform(@/0.79 1/0.79, pattern(0 1 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN band, labels("Observations" "Bandwidth")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+eststo clear
+rdrobust number dist1 if year>=2015, p(1) h(11.3) kernel(uni) vce(cluster city_id)
+eststo A
+rdrobust number dist1 if year>=2015, p(1) h(11.3) kernel(uni) vce(cluster city_id)
+eststo B
+rdrobust number dist1 if year>=2015, p(1) h(11.3) kernel(uni) vce(cluster city_id)
+eststo C
+rdrobust number dist1 if year>=2015, p(1) h(11.3) covs() kernel(uni) vce(cluster city_id)
+eststo D
+esttab A B C D using "$out_files/TableC13a2.tex", tex replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers noobs mlabels(none) keep(RD_Estimate) coeflabels(RD_Estimate "First stage") starlevels(* 0.10 ** 0.05 *** 0.01)
+
+* Cutoff 2
+use "$data_files/city_pm.dta", clear
+
+gen dist1 = area - 50
+
+gen bench = pm25 if year < 2012
+bys city_id: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+eststo clear
+rdrobust pm25 dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(mean_bench year month) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo A
+reghdfe pm25 RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post#c.above#c.dist1 if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N_full)
+estadd scalar band = 11.3
+eststo B
+
+use "$data_files/city_enf.dta", clear
+
+gen dist1 = area - 50
+
+gen bench = log_any_air if year < 2012
+bys city_id: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(mean_bench year quarter) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe log_any_air RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N_full)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/TableC13b1.tex", tex keep(RD_Estimate) transform(@/1.76 1/1.76, pattern(0 1 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN band, labels("Observations" "Bandwidth")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+eststo clear
+rdrobust number dist1 if year>=2015, p(1) h(11.3) kernel(uni) vce(cluster city_id)
+eststo A
+estadd local kern = "Uniform"
+estadd scalar band = 11.3
+rdrobust number dist1 if year>=2015, p(1) h(11.3) kernel(uni) vce(cluster city_id)
+eststo B
+estadd local kern = "Uniform"
+estadd scalar band = 11.3
+rdrobust number dist1 if year>=2015, p(1) h(11.3) kernel(uni) vce(cluster city_id)
+eststo C
+estadd local kern = "Uniform"
+estadd scalar band = 11.3
+rdrobust number dist1 if year>=2015, p(1) h(11.3) covs() kernel(uni) vce(cluster city_id)
+eststo D
+estadd local kern = "Uniform"
+estadd local band = 11.3
+esttab A B C D using "$out_files/TableC13b2.tex", tex replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers noobs mlabels(none) keep(RD_Estimate) coeflabels(RD_Estimate "First stage") stats(kern band, labels("Kernel" "Bandwidth")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+
+**==============================================================================
+* Table C14
+* Spillover in aod
+use "$data_files/city_pm_rd.dta", clear
+
+rename pm pm_monitor
+drop if pm_monitor == .
+drop if pm_direct == .
+drop if pm_indirect == .
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench_monitor = pm_monitor if year < 2012
+bys city_id cutoff: egen mean_bench_monitor = mean(bench_monitor)
+
+gen RD_Estimate = .
+gen above = dist1 > 0
+
+replace RD_Estimate = c.post1#c.number
+eststo clear
+reghdfe pm_monitor RD_Estimate c.post1#c.area c.post1#c.pop if cutoff == 1, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo A
+summ pm_monitor
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+ivreghdfe pm_monitor c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv) if cutoff == 1, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo B
+summ pm_monitor
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+rdrobust pm_monitor dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench_monitor year month) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+summ pm_monitor if abs(dist1)<11.3
+estadd scalar ysumm = r(mean)
+eststo C
+replace RD_Estimate = c.post1#c.above
+reghdfe pm_monitor RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N)
+summ pm_monitor if abs(dist1)<11.3
+estadd scalar ysumm = r(mean)
+eststo D
+esttab A B C D using "$out_files/TableC14a.tex", keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN ysumm, labels("Observations" "Mean Outcome")) starlevels(* 0.10 ** 0.05 *** 0.01) tex
+
+use "$data_files/city_pm_rd.dta", clear
+
+rename pm pm_monitor
+drop if pm_monitor == .
+drop if pm_direct == .
+drop if pm_indirect == .
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench_dir = pm_direct if year < 2012
+bys city_id cutoff: egen mean_bench_dir = mean(bench_dir)
+
+gen bench_in = pm_indirect if year < 2012
+bys city_id cutoff: egen mean_bench_in = mean(bench_in)
+
+gen RD_Estimate = .
+gen above = dist1 > 0
+
+replace RD_Estimate = c.post1#c.number
+eststo clear
+reghdfe pm_direct RD_Estimate c.post1#c.area c.post1#c.pop if cutoff == 1, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo A
+summ pm_direct
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+ivreghdfe pm_direct c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv) if cutoff == 1, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo B
+summ pm_direct
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+rdrobust pm_direct dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench_dir year month) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+summ pm_direct if abs(dist1) < 11.3
+estadd scalar ysumm = r(mean)
+eststo C
+replace RD_Estimate = c.post1#c.above
+reghdfe pm_direct RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N)
+summ pm_direct if abs(dist1) < 11.3
+estadd scalar ysumm = r(mean)
+eststo D
+esttab A B C D using "$out_files/TableC14b.tex", keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN ysumm, labels("Observations" "Mean Outcome")) starlevels(* 0.10 ** 0.05 *** 0.01) tex
+
+replace RD_Estimate = c.post1#c.number
+eststo clear
+reghdfe pm_indirect RD_Estimate c.post1#c.area c.post1#c.pop if cutoff == 1, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo A
+summ pm_indirect
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+ivreghdfe pm_indirect c.post1#c.area c.post1#c.pop pre tem_mean (RD_Estimate=c.post1#c.number_iv) if cutoff == 1, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo B
+summ pm_indirect
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+rdrobust pm_indirect dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench_in year month) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+summ pm_indirect if abs(dist1) < 11.3
+estadd scalar ysumm = r(mean)
+eststo C
+replace RD_Estimate = c.post1#c.above
+reghdfe pm_indirect RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+summ pm_indirect if abs(dist1) < 11.3
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N)
+eststo D
+esttab A B C D using "$out_files/TableC14c.tex", keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN ysumm, labels("Observations" "Mean Outcome")) starlevels(* 0.10 ** 0.05 *** 0.01) tex
+
+* Spillover in enf
+use "$data_files/city_enf.dta", clear
+
+label variable post1 "Post"
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+eststo clear
+reghdfe log_any_air_10 RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+summ log_any_air_10
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe log_any_air_10 c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+summ log_any_air_10
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+eststo B
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench_10 = log_any_air_10 if year < 2012
+bys city_id cutoff: egen mean_bench_10 = mean(bench_10)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air_10 dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench_10 year quarter) kernel(uni) vce(cluster city_id)
+summ log_any_air_10 if abs(dist1)<11.3
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe log_any_air_10 RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+summ log_any_air_10 if abs(dist1)<11.3
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/TableC14d.tex", keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN ysumm, labels("Observations" "Mean Outcome")) starlevels(* 0.10 ** 0.05 *** 0.01) tex
+
+
+use "$data_files/city_enf.dta", clear
+
+label variable post1 "Post"
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+eststo clear
+reghdfe log_any_air_20 RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+summ log_any_air_20
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe log_any_air_20 c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+summ log_any_air_20
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+eststo B
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench_20 = log_any_air_20 if year < 2012
+bys city_id cutoff: egen mean_bench_20 = mean(bench_20)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air_20 dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench_20 year quarter) kernel(uni) vce(cluster city_id)
+summ log_any_air_20 if abs(dist1)<11.3
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe log_any_air_20 RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+summ log_any_air_20 if abs(dist1)<11.3
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/TableC14e.tex", keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN ysumm, labels("Observations" "Mean Outcome")) starlevels(* 0.10 ** 0.05 *** 0.01) tex
+
+use "$data_files/city_enf.dta", clear
+
+label variable post1 "Post"
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+eststo clear
+reghdfe log_any_air_50 RD_Estimate c.post1#c.area c.post1#c.pop, a(city_id pred tem_meand age_year incentive2#time) cluster(city_id)
+summ log_any_air_50
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe log_any_air_50 c.post1#c.area c.post1#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id pred tem_meand age_year incentive2#time) cluster(city_id)
+summ log_any_air_50
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_full)
+eststo B
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench_50 = log_any_air_50 if year < 2012
+bys city_id cutoff: egen mean_bench_50 = mean(bench_50)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air_50 dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench_50 year quarter) kernel(uni) vce(cluster city_id)
+summ log_any_air_50 if abs(dist1)<11.3
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd local kern = "Uniform"
+estadd scalar band = 11.3
+eststo C
+reghdfe log_any_air_50 RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+summ log_any_air_50 if abs(dist1)<11.3
+estadd scalar ysumm = r(mean)
+estadd scalar EN = e(N)
+estadd local kern = "Uniform"
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/TableC14f.tex", keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN ysumm kern band, labels("Observations" "Mean Outcome" "Kernel" "Bandwidth")) starlevels(* 0.10 ** 0.05 *** 0.01) tex
+
+
+**==============================================================================
+* Table C15
+* Promotion
+use "$data_files/city_pm.dta", clear
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen above57 = age<=57
+gen RD_Estimate = c.post1#c.number
+label variable above57 "Below 58"
+
+eststo clear
+reghdfe pm25 RD_Estimate c.post1#c.area c.post1#c.pop c.RD_Estimate#c.above57, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo A
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe pm25 RD_Estimate c.post1#c.area c.post1#c.pop c.RD_Estimate#c.above57 if age >= 51 & age <= 62, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo B
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe pm25 RD_Estimate c.post1#c.area c.post1#c.pop c.RD_Estimate#c.above57 if age >= 53 & age <= 62, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo C
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe pm25 RD_Estimate c.post1#c.area c.post1#c.pop c.RD_Estimate#c.above57 if age >= 55 & age <= 60, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo D
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+esttab A B C D  using "$out_files/TableC15a.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep(RD_Estimate c.RD_Estimate#c.above57) coeflabels(RD_Estimate "\# Monitors" c.RD_Estimate#c.above57 "\# Monitors $\times$ Below 58") stats(ymean EN, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+use "$data_files/city_enf.dta", clear
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen above57 = age <= 57
+gen RD_Estimate = c.post1#c.number
+label variable above57 "Below 58"
+
+eststo clear
+reghdfe log_any_air RD_Estimate c.post1#c.area c.post1#c.pop c.RD_Estimate#c.above57, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo A
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe log_any_air RD_Estimate c.post1#c.area c.post1#c.pop c.RD_Estimate#c.above57 if age >= 51 & age <= 62, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo B
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe log_any_air RD_Estimate c.post1#c.area c.post1#c.pop c.RD_Estimate#c.above57 if age >= 53 & age <= 62, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo C
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe log_any_air RD_Estimate c.post1#c.area c.post1#c.pop c.RD_Estimate#c.above57 if age >= 55 & age <= 60, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo D
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+esttab A B C D using "$out_files/TableC15b.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep(RD_Estimate c.RD_Estimate#c.above57) coeflabels(RD_Estimate "\# Monitors" c.RD_Estimate#c.above57 "\# Monitors $\times$ Below 58") stats(ymean EN, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+
+**==============================================================================
+* Table C16
+* Balance
+use "$data_files/city_pm.dta", clear
+keep if year < 2015
+
+replace light = log(light)
+gen log_any_air = log(any_air+1)
+
+collapse (mean) pm25 light log_any_air number area pop age city_id, by(city_cn)
+gen above57 = age > 57
+
+label variable number "\# Monitors"
+label variable area "Size of buildup area"
+label variable pop "Urban population"
+label variable pm25 "AOD before 2015"
+label variable light "Night light before 2015"
+label variable log_any_air "log(\# Firms) before 2015"
+
+regress above57 number area pop pm25 light log_any_air
+test number area pop pm25 light log_any_air
+regress above57 number area pop pm25 light log_any_air if age >= 51 & age <= 62
+test number area pop pm25 light log_any_air
+regress above57 number area pop pm25 light log_any_air if age >= 53 & age <= 62
+test number area pop pm25 light log_any_air
+regress above57 number area pop pm25 light log_any_air if age >= 55 & age <= 60
+test number area pop pm25 light log_any_air
+
+eststo clear
+eststo tot: estpost summarize number area pop pm25 light log_any_air
+eststo treat1: estpost summarize number area pop pm25 light log_any_air if above57==1
+eststo control1: estpost summarize number area pop pm25 light log_any_air if above57==0
+eststo diff1: estpost ttest number area pop pm25 light log_any_air, by(above57)
+eststo diff1: estadd scalar pvalue = 0.19
+eststo diff2: estpost ttest number area pop pm25 light log_any_air if age >= 51 & age <= 62, by(above57)
+eststo diff2: estadd scalar pvalue = 0.15
+eststo diff3: estpost ttest number area pop pm25 light log_any_air if age >= 53 & age <= 62, by(above57)
+eststo diff3: estadd scalar pvalue = 0.29
+eststo diff4: estpost ttest number area pop pm25 light log_any_air if age >= 55 & age <= 60, by(above57)
+eststo diff4: estadd scalar pvalue = 0.37
+esttab tot treat1 control1 diff1 diff2 diff3 diff4 using "$out_files/TableC16.tex", tex label noconstant nolines nogaps compress fragment nonumbers mlabels(,none) collabels(,none) cells(mean(pattern(1 1 1 0 0 0 0) fmt(a2)) & b(star pattern(0 0 0 1 1 1 1) fmt(a2)) sd(pattern(1 1 1 0 0 0 0) fmt(a2) par) & se(pattern(0 0 0 1 1 1 1) fmt(a2) par)) stats(N pvalue, labels("Observations" "Joint Test (p-value)")) starlevels(* 0.10 ** 0.05 *** 0.01) replace
+
+
+**==============================================================================
+* Table C17
+
+use "$data_files/city_pm.dta", clear
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+merge 1:1 city_cn year month using "$data_files/Raw/baidu.dta" 
+keep if _merge == 3
+drop _merge
+
+replace sear_freq_w1 = sear_freq_w1/pop
+replace sear_freq_w2 = sear_freq_w2/pop
+replace sear_freq_w3 = sear_freq_w3/pop
+replace sear_freq_w4 = sear_freq_w4/pop
+replace sear_freq_w5 = sear_freq_w5/pop
+
+foreach x of varlist sear_freq_w* {
+	egen m_`x' = mean(`x')
+	egen sd_`x' = sd(`x')
+	gen std_`x' = (`x'- m_`x')/sd_`x'
+}
+
+forvalues i=1/5 {
+replace sear_freq_w`i'=0 if sear_freq_w`i'==.
+gen log_w`i'=log(sear_freq_w`i'+1)
+gen any_w`i'=0
+replace any_w`i'=1 if sear_freq_w`i'>0 & sear_freq_w`i'!=.
+}
+
+eststo clear 
+ivreghdfe log_w1 i.time#c.area i.time#c.pop (c.post1#c.number=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo A
+summ log_w1
+estadd scalar ymean = r(mean)
+ivreghdfe log_w2 i.time#c.area i.time#c.pop (c.post1#c.number=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo B
+summ log_w2
+estadd scalar ymean = r(mean)
+ivreghdfe log_w3 i.time#c.area i.time#c.pop (c.post1#c.number=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo C
+summ log_w3
+estadd scalar ymean = r(mean)
+ivreghdfe log_w4 i.time#c.area i.time#c.pop (c.post1#c.number=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo D
+summ log_w4
+estadd scalar ymean = r(mean)
+ivreghdfe log_w5 i.time#c.area i.time#c.pop (c.post1#c.number=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo E
+summ log_w5
+estadd scalar ymean = r(mean)
+estfe A B C D E, labels(city_id "City FE" time "Time FE")
+return list
+esttab A B C D E using "$out_files/TableC17.tex", replace b(a2) se(a2) keep(c.post1#c.number) coeflabels(c.post1#c.number "\# Monitors") label noconstant nolines nogaps compress fragment nonumbers mlabels(none) collabels() stats(ymean N, labels( "Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+
+**==============================================================================
+** Figures
+
+**==============================================================================
+* Figure D3
+use "$data_files/firm_enf.dta", clear
+
+fvset base 4 min_d_d4
+
+reghdfe any_air i.post##i.min_d_d4 if min_dist<50 & starty<=2010, absorb(id time industry#time prov_id#time) cluster(city_id) poolsize(1) compact
+coefplot, baselevels omitted vert yline(0, lc(cranberry)) keep(1.post1#*) coeflabels(1.post1#0.min_d_d4 = "0-5km" 1.post1#1.min_d_d4 = "5-10km" 1.post1#2.min_d_d4 = "10-15km" 1.post1#3.min_d_d4 = "15-20km" 1.post1#4.min_d_d4 = "20-50km") drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle() le(95)
+graph export "$out_files/any_air_gradient_50_ci.pdf", replace
+
+
+**==============================================================================
+* Figure D5
+use "$data_files/firm_enf.dta", clear
+
+merge m:1 city_id using "$data_files/Raw/city_info.dta", keepusing(env_lat env_lon centroid_lat centroid_lon)
+keep if _merge == 3
+drop _merge
+
+geodist env_lat env_lon lat lon, gen(env_dist)
+gen min_env_d4 = int(env_dist/5)
+replace min_env_d4 = 4 if min_env_d4 > 4
+
+* set base level
+fvset base 20 time
+fvset base 4 min_env_d4
+
+geodist centroid_lat centroid_lon lat lon, gen(cen_dist)
+gen min_cen_d4 = int(cen_dist/5)
+replace min_cen_d4 = 4 if min_cen_d4 > 4
+
+* set base level
+fvset base 20 time
+fvset base 4 min_cen_d4
+
+reghdfe any_air i.time##i.min_env_d4 i.post##i.min_d_d4 i.post##i.min_cen_d4 if env_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id) poolsize(1) compact
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#0.min_env_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_5_) replace
+
+twoway (rarea enf_5_ul1 enf_5_ll1 enf_5_at, color(gs6%20)) (scatter enf_5_b enf_5_at, msymbol(p) mc(black%60)) (line enf_5_b enf_5_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.01 0.01)) ylab(-0.01(0.005)0.01)
+graph export "$out_files/any_air_env_event_5.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#1.min_env_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_10_) replace
+
+twoway (rarea enf_10_ul1 enf_10_ll1 enf_10_at, color(gs6%20)) (scatter enf_10_b enf_10_at, msymbol(p) mc(black%60)) (line enf_10_b enf_10_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.01 0.01)) ylab(-0.01(0.005)0.01)
+graph export "$out_files/any_air_env_event_10.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#2.min_env_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_15_) replace
+
+twoway (rarea enf_15_ul1 enf_15_ll1 enf_15_at, color(gs6%20)) (scatter enf_15_b enf_10_at, msymbol(p) mc(black%60)) (line enf_15_b enf_15_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.01 0.01)) ylab(-0.01(0.005)0.01)
+graph export "$out_files/any_air_env_event_15.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#3.min_env_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_20_) replace
+
+twoway (rarea enf_20_ul1 enf_20_ll1 enf_20_at, color(gs6%20)) (scatter enf_20_b enf_20_at, msymbol(p) mc(black%60)) (line enf_20_b enf_20_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.01 0.01)) ylab(-0.01(0.005)0.01)
+graph export "$out_files/any_air_env_event_20.pdf", replace
+
+
+
+reghdfe any_air i.time##i.min_cen_d4 i.post##i.min_d_d4 i.post##i.min_env_d4 if cen_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id) poolsize(1) compact
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#0.min_cen_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_5_) replace
+
+twoway (rarea enf_5_ul1 enf_5_ll1 enf_5_at, color(gs6%20)) (scatter enf_5_b enf_5_at, msymbol(p) mc(black%60)) (line enf_5_b enf_5_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.01 0.01)) ylab(-0.01(0.005)0.01)
+graph export "$out_files/any_air_cen_event_5.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#1.min_cen_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_10_) replace
+
+twoway (rarea enf_10_ul1 enf_10_ll1 enf_10_at, color(gs6%20)) (scatter enf_10_b enf_10_at, msymbol(p) mc(black%60)) (line enf_10_b enf_10_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.01 0.01)) ylab(-0.01(0.005)0.01)
+graph export "$out_files/any_air_cen_event_10.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#2.min_cen_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_15_) replace
+
+twoway (rarea enf_15_ul1 enf_15_ll1 enf_15_at, color(gs6%20)) (scatter enf_15_b enf_10_at, msymbol(p) mc(black%60)) (line enf_15_b enf_15_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.01 0.01)) ylab(-0.01(0.005)0.01)
+graph export "$out_files/any_air_cen_event_15.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#3.min_cen_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_20_) replace
+
+twoway (rarea enf_20_ul1 enf_20_ll1 enf_20_at, color(gs6%20)) (scatter enf_20_b enf_20_at, msymbol(p) mc(black%60)) (line enf_20_b enf_20_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.01 0.01)) ylab(-0.01(0.005)0.01)
+graph export "$out_files/any_air_cen_event_20.pdf", replace
+
+
+**==============================================================================
+* Figure D5
+use "$data_files/city_enf.dta", clear
+set scheme s1mono
+
+fvset base 2014 year
+fvset base 20 time
+
+reghdfe log_any_air i.time##c.number i.post1##c.area i.post1##c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id) poolsize(1) compact
+coefplot, baselevels omitted vert yline(-0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) keep(*me#c.number) coeflabels() drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) le(95) mc(black) gen(pm1_) replace
+
+regress number number_iv
+predict num_hat
+
+reghdfe log_any_air i.time##c.num_hat i.post1##c.area i.post1##c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id) poolsize(1) compact
+coefplot, baselevels omitted vert yline(-0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) keep(*me#c.num_hat) coeflabels() drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) le(95) mc(black) gen(pm2_) replace
+
+twoway (rarea pm1_ul1 pm1_ll1 pm1_at, color(gs6%20)) (line pm1_b pm1_at, lwidth(medthick) lp(dash) lc(blackblack%70)) (rarea pm2_ul1 pm2_ll1 pm2_at, color(gs6%20)) (line pm2_b pm2_at, lp(dash) lc(blackblack%40)), yline(-0, lc(black)) xline(20.5, lp(dash) lc(cranberry))  graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.2 0.6)) ylabel(-0.2(0.2)0.6)  legend(order(2 "DiD" 4 "DiD+IV") pos(2) ring(0) rows(2))
+
+graph export "$out_files/eventenf.pdf", replace
+
+
+**==============================================================================
+* Figure D11
+* balance
+use "$data_files/city_pm.dta", clear
+keep if year < 2015
+
+replace light = log(light)
+gen log_any_air = log(any_air+1)
+
+collapse (mean) pm25 light log_any_air number area pop age city_id GDP, by(city_cn)
+gen above57 = age > 57
+
+label variable number "\# Monitors"
+label variable area "Size of buildup area"
+label variable pop "Urban population"
+label variable pm25 "AOD before 2015"
+label variable light "Night light before 2015"
+label variable log_any_air "log(\# Firms) before 2015"
+
+fvset base 58 age
+regress number i.age if age>=50 & age<=60
+coefplot, baselevels omitted vert drop(_cons) keep(*.age) yline(0, lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("Age of Mayor")coeflabels(50.age = "50" 51.age = "51" 52.age = "52" 53.age = "53" 54.age = "54" 55.age = "55" 56.age = "56" 57.age = "57" 58.age = "58" 59.age = "59" 60.age = "60") le(95)
+graph export "$out_files/number_age.pdf", replace
+
+regress area i.age if age>=50 & age<=60
+coefplot, baselevels omitted vert drop(_cons) keep(*.age) yline(0, lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("Age of Mayor")coeflabels(50.age = "50" 51.age = "51" 52.age = "52" 53.age = "53" 54.age = "54" 55.age = "55" 56.age = "56" 57.age = "57" 58.age = "58" 59.age = "59" 60.age = "60") le(95)
+graph export "$out_files/area_age.pdf", replace
+
+regress pop i.age if age>=50 & age<=60
+coefplot, baselevels omitted vert drop(_cons) keep(*.age) yline(0, lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("Age of Mayor")coeflabels(50.age = "50" 51.age = "51" 52.age = "52" 53.age = "53" 54.age = "54" 55.age = "55" 56.age = "56" 57.age = "57" 58.age = "58" 59.age = "59" 60.age = "60") le(95)
+graph export "$out_files/pop_age.pdf", replace
+
+regress pm25 i.age if age>=50 & age<=60
+coefplot, baselevels omitted vert drop(_cons) keep(*.age) yline(0, lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("Age of Mayor")coeflabels(50.age = "50" 51.age = "51" 52.age = "52" 53.age = "53" 54.age = "54" 55.age = "55" 56.age = "56" 57.age = "57" 58.age = "58" 59.age = "59" 60.age = "60") le(95)
+graph export "$out_files/pm_age.pdf", replace
+
+regress light i.age if age>=50 & age<=60
+coefplot, baselevels omitted vert drop(_cons) keep(*.age) yline(0, lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("Age of Mayor")coeflabels(50.age = "50" 51.age = "51" 52.age = "52" 53.age = "53" 54.age = "54" 55.age = "55" 56.age = "56" 57.age = "57" 58.age = "58" 59.age = "59" 60.age = "60") le(95)
+graph export "$out_files/light_age.pdf", replace
+
+regress log_any_air i.age if age>=50 & age<=60
+coefplot, baselevels omitted vert drop(_cons) keep(*.age) yline(0, lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("Age of Mayor")coeflabels(50.age = "50" 51.age = "51" 52.age = "52" 53.age = "53" 54.age = "54" 55.age = "55" 56.age = "56" 57.age = "57" 58.age = "58" 59.age = "59" 60.age = "60") le(95)
+graph export "$out_files/enf_age.pdf", replace
+
+
+**==============================================================================
+* Figure D7
+* Bandwidths
+use "$data_files/city_pm_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+frame create fs fs_b fs_var
+quietly{
+	forvalues x = 4(2)20 {
+		qui rdrobust number dist1, p(1) h(`x') kernel(uni) covs(cutoff) vce(cluster city_id)
+		frame post fs (e(tau_cl)) (e(se_tau_cl))
+	}
+}
+
+frame fs: gen fs_ul = fs_b + 1.96*fs_var
+frame fs: gen fs_ll = fs_b - 1.96*fs_var
+frame fs: gen fs_at = 2 + 2*_n
+
+frame fs: twoway (connected fs_b fs_at, sort msymbol(S) color(black)) (line fs_ul fs_at, sort lpattern(dash) lcolor(gs9)) /*
+*/ (line fs_ll fs_at, sort lpattern(dash) lcolor(gs9)), ytitle(Number of monitors) yline(0, lc(cranberry)) /*
+*/ xtitle(Bandwidth) xline(11.3, lcolor(blue) lpattern(dash) lwidth(thin)) /*
+*/ graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ysc(r(0 2)) ylabel(0(0.5)2) xlabel(4(2)20) 
+graph export "$out_files/band_fs.pdf", replace
+
+gen bench = pm25 if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+frame create rd rd_b rd_var
+quietly{
+	forvalues x = 4(2)20 {
+		qui rdrobust pm25 dist1 if year >= 2015, fuzzy(number) covs(cutoff mean_bench year) p(1) h(`x') vce(cluster city_id) kernel(uni)
+		frame post rd (e(tau_cl)) (e(se_tau_cl))
+	}
+}
+
+frame rd: gen rd_ul = rd_b + 1.96*rd_var
+frame rd: gen rd_ll = rd_b - 1.96*rd_var
+frame rd: gen rd_at = 2 + 2*_n
+
+frame rd: twoway (connected rd_b rd_at, sort msymbol(S) color(black)) (line rd_ul rd_at, sort lpattern(dash) lcolor(gs9)) /*
+*/ (line rd_ll rd_at, sort lpattern(dash) lcolor(gs9)), ytitle(Number of monitors) yline(0, lc(cranberry)) /*
+*/ xtitle(Bandwidth) xline(11.3, lcolor(blue) lpattern(dash) lwidth(thin)) /*
+*/ graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ysc(r(-0.075 0.05)) ylabel(-0.075(0.025)0.05) xlabel(4(2)20) 
+graph export "$out_files/band_rd.pdf", replace
+
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = log_any_air if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+frame drop rd
+frame create rd rd_b rd_var
+quietly{
+	forvalues x = 4(2)20 {
+		qui rdrobust log_any_air dist1 if year >= 2015, fuzzy(number) covs(cutoff mean_bench year) p(1) h(`x') vce(cluster city_id) kernel(uni)
+		frame post rd (e(tau_cl)) (e(se_tau_cl))
+	}
+}
+
+frame rd: gen rd_ul = rd_b + 1.96*rd_var
+frame rd: gen rd_ll = rd_b - 1.96*rd_var
+frame rd: gen rd_at = 2 + 2*_n
+
+frame rd: twoway (connected rd_b rd_at, sort msymbol(S) color(black)) (line rd_ul rd_at, sort lpattern(dash) lcolor(gs9)) /*
+*/ (line rd_ll rd_at, sort lpattern(dash) lcolor(gs9)), ytitle(Number of monitors) yline(0, lc(cranberry)) /*
+*/ xtitle(Bandwidth) xline(11.3, lcolor(blue) lpattern(dash) lwidth(thin)) /*
+*/ graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ysc(r(-0.2 0.6)) ylabel(-0.2(0.2)0.6) xlabel(4(2)20) 
+graph export "$out_files/band_rd_enf.pdf", replace
+
+
+**==============================================================================
+* Figure D7
+use "$data_files/city_pm_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+hist dist1 if cutoff == 1 & year == 2015 & month == 1, /*
+*/ start(-24) width(12) xline(0, lc(cranberry)) ysc(r(0 0.025)) /*
+*/ ylabel(0(0.005)0.025) xtitle("Size of the Build-up Area") /*
+*/ graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) /*
+*/ plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) /*
+*/ legend(nobox region(fcolor(white) margin(zero) lcolor(white)))
+graph export "$out_files/Cutoff1Score1.pdf", replace
+
+hist dist1 if cutoff == 2 & year == 2015 & month == 1, /*
+*/ start(-60) width(12) xline(0, lc(cranberry)) ysc(r(0 0.025)) /*
+*/ ylabel(0(0.005)0.025) xtitle("Size of the Build-up Area") /*
+*/ graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) /*
+*/ plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) /*
+*/ legend(nobox region(fcolor(white) margin(zero) lcolor(white)))
+graph export "$out_files/Cutoff2Score1.pdf", replace
+
+rddensity dist1 if year==2015 & month==1 & dist1<40 & dist1>-40, all plot plot_range(-20 20) nohist graph_opt(legend(off) xtitle("Size of the Buildup Area") ytitle("Density") graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)))
+graph export "$out_files/DensityTest1.pdf", as(pdf) replace
+
+
+**==============================================================================
+* Figure D9
+* hist
+use "$data_files/Raw/firm_info.dta", clear
+
+hist min_dist if min_dist < 50, xtitle("Distance to the closest monitor (km)") /* 
+*/ graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) /*
+*/ plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) /*
+*/ legend(nobox region(fcolor(white) margin(zero) lcolor(white)))
+graph export "$out_files/hist_min_dist.pdf", as(pdf) replace
+
+
+
+
+

110/replication_package/replication/Do-file/Figure.do

@@ -0,0 +1,177 @@
+* Set Directory
+clear
+set more off
+set scheme s1mono
+
+cd "$path"
+global data_files "$path/Data"
+global out_files "$path/output"
+
+**==============================================================================
+* Figure 1
+use "$data_files/firm_enf.dta", clear
+
+fvset base 2014 year
+
+* Binscatter plot
+binscatter any_air min_dist if min_dist<50 & starty<=2010, by(post) line(none) ytitle(Any Air Pollution Related Enforcement) xtitle(Distance to the Closest Monitor(km)) legend(region(lwidth(none)) pos(12) ring(0) lab(1 pre-policy (2010-2014)) lab(2 post-policy (2015-2017))) mc(black cranberry) lc(black cranberry) ysc(r(0.001 0.013)) ylab(0.001(0.002)0.013) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) 
+graph export "$out_files/any_air_gradient_50.pdf", replace
+
+binscatter any_air year if min_dist<50 & starty<=2010, by(min_dist_10) ytitle(Any Air Pollution Related Enforcement) xtitle(Year) legend(region(lwidth(none)) pos(12) ring(0) order(2 1) lab(1 10-50km) lab(2 0-10km)) mc(black cranberry) line(none) xtick(2010(1)2017) xlabel(2010 "2010" 2011 "2011" 2012 "2012" 2013 "2013" 2014 "2014" 2015 "2015" 2016 "2016" 2017 "2017") ysc(r(0.001 0.013)) ylab(0.001(0.002)0.013) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) 
+graph export "$out_files/any_air_trend.pdf", replace
+
+use "$data_files/Raw/pm.dta", clear
+drop pm25 
+
+rename pm_indirect pm3
+rename pm_direct pm2
+
+reshape long pm, i(city_id year month) j(group)
+
+append using "$data_files/pix.dta"
+replace group = 1 if group == .
+
+egen time = group(year month)
+
+binscatter pm year, by(group) line(none) legend(region(lwidth(none)) pos(12) ring(0) cols(3) lab(1 Monitor (≤ 10km)) lab(2 City Center (10-50km)) lab(3 Surrounding Area (> 50km))) ysc(r(0.33 0.47)) ylab(0.30(0.02)0.48) mc(cranberry black gray) m(D O S) ytitle("Aerosol Optical Depth") xtitle("Year") xtick(2010(1)2017) xlabel(2010 "2010" 2011 "2011" 2012 "2012" 2013 "2013" 2014 "2014" 2015 "2015" 2016 "2016" 2017 "2017") ysc(r(0.24 0.48)) ylab(0.24(0.04)0.48) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white))
+graph export "$out_files/monitors_trend.pdf", replace
+
+**==============================================================================
+* Figure 2
+use "$data_files/firm_enf.dta", clear
+
+* set base level
+fvset base 20 time
+fvset base 4 min_d_d4
+
+* Event Study Specification
+reghdfe any_air i.time##i.min_d_d4 if min_dist<50 & starty<=2010, absorb(id time industry#time prov_id#time) cluster(city_id)
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#0.min_d_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_5_) replace
+
+twoway (rarea enf_5_ul1 enf_5_ll1 enf_5_at, color(gs6%20)) (scatter enf_5_b enf_5_at, msymbol(p) mc(black%60)) (line enf_5_b enf_5_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.006 0.012)) ylab(-0.006(0.006)0.012)
+graph export "$out_files/event_enf_min_dist5.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#1.min_d_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_10_) replace
+
+twoway (rarea enf_10_ul1 enf_10_ll1 enf_10_at, color(gs6%20)) (scatter enf_10_b enf_10_at, msymbol(p) mc(black%60)) (line enf_10_b enf_10_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.006 0.012)) ylab(-0.006(0.006)0.012)
+graph export "$out_files/event_enf_min_dist10.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#2.min_d_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_15_) replace
+
+twoway (rarea enf_15_ul1 enf_15_ll1 enf_15_at, color(gs6%20)) (scatter enf_15_b enf_10_at, msymbol(p) mc(black%60)) (line enf_15_b enf_15_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.006 0.012)) ylab(-0.006(0.006)0.012)
+graph export "$out_files/event_enf_min_dist15.pdf", replace
+
+qui coefplot, baselevels omitted vert yline(0, lc(black)) xline(20.5, lc(cranberry) lp(dash)) keep(*.time#3.min_d_d4) drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) xtitle(Year) le(95) mc(black) ciopts(recast(rcap) lwidth(0.3) lpattern(dash)) gen(enf_20_) replace
+
+twoway (rarea enf_20_ul1 enf_20_ll1 enf_20_at, color(gs6%20)) (scatter enf_20_b enf_20_at, msymbol(p) mc(black%60)) (line enf_20_b enf_20_at, lp(dash) lc(blackblack%60)), yline(0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.006 0.012)) ylab(-0.006(0.006)0.012)
+graph export "$out_files/event_enf_min_dist20.pdf", replace
+
+**==============================================================================
+* Figure 3
+use "$data_files/Raw/city_info.dta", clear
+merge 1:1 city_id using "$data_files/share.dta"
+drop if _merge == 2
+drop _merge
+
+binsreg share_rev_10 number, ci(95) graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(% of High-Pollution Activity <10km from Monitor) xtitle(# Monitors)
+graph export "$out_files/revenue_share.pdf", replace
+
+**==============================================================================
+* Figure 4
+use "$data_files/city_pm.dta", clear
+
+reghdfe pm25, a(city_id) residuals(pm_res) 
+
+collapse (mean) pm_res, by(number_iv year)
+twoway (line pm_res year if number==1, lc(navy)) (line pm_res year if number==2, lc(maroon)) /*
+*/ (line pm_res year if number==4, lc(forest_green)) (line pm_res year if number==6, lc(dkorange)), /*
+*/ yline(0, lc(black)) xline(2014.5, lp(dash) lc(cranberry))  graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle("Aerosol Optical Depth") xtitle("Year") xtick(2010(1)2017) xsc(r(2010 2017)) xlabel(2010 "2010" 2011 "2011" 2012 "2012" 2013 "2013" 2014 "2014" 2015 "2015" 2016 "2016" 2017 "2017") legend(off) text(-0.008 2016.8 "One" -0.05 2016.8 "Two" -0.085 2016.8 "Four" -0.097 2016.8 "Six")
+graph export "$out_files/number_iv_trend.pdf", replace
+
+use "$data_files/city_pm.dta", clear
+
+fvset base 2014 year
+fvset base 20 time
+drop if year==2014 & month==12
+
+reghdfe pm25 i.time##c.number i.post1##i.quarter##c.area i.post1##i.quarter##c.pop i.quarter##c.area i.quarter##c.pop, a(city_id year#month pred tem_meand age_year year#incentive2) cluster(city_id)
+coefplot, baselevels omitted vert yline(-0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) keep(*me#c.number) coeflabels() drop() ysc(r(-0.08 0.04)) ylabel(-0.08(0.04)0.04) graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) le(95) mc(black) gen(pm1_) replace
+
+regress number number_iv area pop
+predict num_hat
+
+reghdfe pm25 i.time##c.num_hat i.post1##i.quarter##c.area i.post1##i.quarter##c.pop i.quarter##c.area i.quarter##c.pop, a(city_id year#month pred tem_meand age_year year#incentive2) cluster(city_id)
+coefplot, baselevels omitted vert yline(-0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) keep(*me#c.num_hat) coeflabels() drop() graphregion(color(white) fcolor(white)) plotregion(color(white)) ytitle(Parameter Estimate) le(95) mc(black) gen(pm2_) replace
+
+twoway (rarea pm1_ul1 pm1_ll1 pm1_at, color(gs6%20)) (line pm1_b pm1_at, lwidth(medthick) lp(dash) lc(blackblack%70)) (rarea pm2_ul1 pm2_ll1 pm2_at, color(gs6%20)) (line pm2_b pm2_at, lp(dash) lc(blackblack%40)), yline(-0, lc(black)) xline(20.5, lp(dash) lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) ytitle("") xtitle("") xtick(1(1)32) xlabel(1 "2010" 5 "2011" 9 "2012" 13 "2013" 17 "2014" 21 "2015" 25 "2016" 29 "2017") ysc(r(-0.08 0.08)) ylabel(-0.08(0.04)0.08) legend(order(2 "DiD" 4 "DiD+IV") pos(2) ring(0) rows(2))
+graph export "$out_files/eventpm.pdf", replace
+
+**==============================================================================
+* Figure 5
+use "$data_files/city_pm_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = pm25 if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+regress number cutoff if abs(dist1)<22
+predict res_num, residuals
+rdplot res_num dist1 if abs(dist1)<15 & year==2015 & month==1, p(2) h(15) nbins(5) kernel(uni) ci(95) vce(cluster city_id) graph_options(ytitle(Residualized # of Monitors) xtitle(Distance to the Closest Geographical Size Cutoff) legend(off) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(nobox region(fcolor(white) margin(zero) lcolor(white))) ysc(r(-1.5 1.5)) ylabel(-1.5(0.5)1.5) xsc(r(-15 15)) xlabel(-15(5)15))
+graph export "$out_files/fs_ci.pdf", replace
+
+regress incentive2 cutoff if abs(dist1)<22
+predict res_inc2, residuals
+rdplot res_inc2 dist1 if abs(dist1)<15 & year==2015 & month==1, p(2) h(15) nbins(5) kernel(uni) ci(95) vce(cluster city_id) graph_options(ytitle(Residualized Reduction Goal(%)) xtitle(Distance to the Closest Geographical Size Cutoff) legend(off) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(nobox region(fcolor(white) margin(zero) lcolor(white))) ysc(r(-10 10)) ylabel(-10(5)10) xsc(r(-15 15)) xlabel(-15(5)15))
+graph export "$out_files/inc2_ci.pdf", replace
+
+regress pm25 cutoff mean_bench if abs(dist1)<22 & year>=2015
+predict res_pm, residuals
+rdplot res_pm dist1 if abs(dist1)<15 & year>=2015 & year>2011, p(2) h(15) nbins(5) covs() kernel(uni) ci(95) vce(cluster city_id) graph_options(ytitle(Residualized AOD) xtitle(Distance to the Closest Geographical Size Cutoff) legend(off) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(nobox region(fcolor(white) margin(zero) lcolor(white))) ysc(r(-0.06 0.06)) ylabel(-0.06(0.03)0.06) xsc(r(-15 15)) xlabel(-15(5)15))
+graph export "$out_files/rd_ci.pdf", replace
+
+regress pm25 cutoff mean_bench if abs(dist1)<22 & year<2015 & year>2010
+predict res_pm_pre, residuals
+rdplot res_pm_pre dist1 if abs(dist1)<15 & year<2015 & year>2011, p(2) h(15) nbins(5) covs() kernel(uni) ci(95) vce(cluster city_id) graph_options(ytitle(Residualized AOD) xtitle(Distance to the Closest Geographical Size Cutoff) legend(off) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(nobox region(fcolor(white) margin(zero) lcolor(white))) ysc(r(-0.06 0.06)) ylabel(-0.06(0.03)0.06) xsc(r(-15 15)) xlabel(-15(5)15))
+graph export "$out_files/rd_ci_pre.pdf", replace
+
+**==============================================================================
+use "$data_files/city_enf_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = log_any_air if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+regress log_any_air cutoff mean_bench if abs(dist1)<22 & year>=2015
+predict res_air, residuals
+rdplot res_air dist1 if abs(dist1)<16 & year>=2015 & year>2011, p(2) h(15) nbins(5) covs() kernel(uni) ci(95) vce(cluster city_id) graph_options(ytitle(Residualized log(# Any Enf)) xtitle(Distance to the Closest Geographical Size Cutoff) legend(off) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(nobox region(fcolor(white) margin(zero) lcolor(white))) ysc(r(-0.5 0.5)) ylabel(-0.5(0.25)0.5) xsc(r(-15 15)) xlabel(-15(5)15))
+graph export "$out_files/rd_ci_enf.pdf", replace
+
+regress log_any_air cutoff if abs(dist1)<22 & year<2015 & year>2011
+predict res_air_pre, residuals
+rdplot res_air_pre dist1 if abs(dist1)<16 & year<2015 & year>2011, p(2) h(15) nbins(5) covs() kernel(uni) ci(95) vce(cluster city_id) graph_options(ytitle(Residualized log(# Any Enf)) xtitle(Distance to the Closest Geographical Size Cutoff) legend(off) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(nobox region(fcolor(white) margin(zero) lcolor(white)))  ysc(r(-0.5 0.5)) ylabel(-0.5(0.25)0.5) xsc(r(-15 15)) xlabel(-15(5)15))
+graph export "$out_files/rd_ci_enf_pre.pdf", replace
+
+**==============================================================================
+* Figure 6
+use "$data_files/city_pm.dta", clear
+
+fvset base 58 age
+reghdfe pm25 c.post1#c.number c.post1#c.area c.post1#c.pop i.age#c.post1#c.number if age >= 50 & age <= 60, a(city_id year#month pred tem_meand incentive2#i.year) cluster(city_id)
+coefplot, baselevels omitted vert keep(*age#c.post1#c.number) drop(_cons c.post1#c.number  c.post1#c.area c.post1#c.pop) yline(0, lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("Age of Mayor") coeflabels(50.age#c.post1#c.number = "50" 51.age#c.post1#c.number = "51" 52.age#c.post1#c.number = "52" 53.age#c.post1#c.number = "53" 54.age#c.post1#c.number = "54" 55.age#c.post1#c.number = "55" 56.age#c.post1#c.number = "56" 57.age#c.post1#c.number = "57" 58.age#c.post1#c.number = "58" 59.age#c.post1#c.number = "59" 60.age#c.post1#c.number = "60") le(95) ysc(r(-0.04 0.02)) ylab(-0.04(0.02)0.02)
+graph export "$out_files/promotion_age.pdf", replace
+
+use "$data_files/city_enf.dta", clear
+
+fvset base 58 age
+reghdfe log_any_air c.post1#c.number i.age#c.post1#c.number c.post1#c.area c.post1#c.pop if age >= 50 & age <= 60, a(city_id year#quarter incentive2#i.year) cluster(city_id)
+coefplot, baselevels omitted vert keep(*age#c.post1#c.number) drop(_cons c.post1#c.number c.post1#c.area c.post1#c.pop) yline(0, lc(cranberry)) graphregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white) ilpattern(blank)) plotregion(fcolor(white) lcolor(none) ifcolor(white) ilcolor(white)) legend(off) ytitle("") xtitle("Age of Mayor") coeflabels(50.age#c.post1#c.number = "50" 51.age#c.post1#c.number = "51" 52.age#c.post1#c.number = "52" 53.age#c.post1#c.number = "53" 54.age#c.post1#c.number = "54" 55.age#c.post1#c.number = "55" 56.age#c.post1#c.number = "56" 57.age#c.post1#c.number = "57" 58.age#c.post1#c.number = "58" 59.age#c.post1#c.number = "59" 60.age#c.post1#c.number = "60") le(95) ysc(r(-0.12 0.24)) ylab(-0.12(0.12)0.24)
+graph export "$out_files/promotion_age_enf.pdf", replace
+
+
+
+

110/replication_package/replication/Do-file/Install.do

@@ -0,0 +1,39 @@
+*** Install all the programs in the ado/plus-folder from internet
+
+ssc install geodist, replace
+ssc install binscatter, replace
+ssc install ivreg2, replace
+ssc install ranktest, replace
+ssc install estout, replace
+ssc install erepost, replace
+ssc install coefplot, replace
+ssc install tmpdir, replace
+ssc install reg2hdfe, replace
+
+cap ado uninstall rdrobust
+net install rdrobust, from("https://raw.githubusercontent.com/rdpackages/rdrobust/master/stata") replace
+
+cap ado uninstall binsreg
+net install binsreg, from("https://raw.githubusercontent.com/nppackages/binsreg/master/stata") replace
+
+cap ado uninstall ftools
+net install ftools, from("https://raw.githubusercontent.com/sergiocorreia/ftools/master/src/") replace
+
+cap ado uninstall reghdfe
+net install reghdfe, from("https://raw.githubusercontent.com/sergiocorreia/reghdfe/master/src/") replace
+
+cap ado uninstall ivreghdfe
+net install ivreghdfe, from("https://raw.githubusercontent.com/sergiocorreia/ivreghdfe/master/src/") replace
+
+cap ado uninstall lpdensity
+net install lpdensity, from("https://raw.githubusercontent.com/nppackages/lpdensity/master/stata") replace
+
+cap ado uninstall rddensity
+net install rddensity, from("https://raw.githubusercontent.com/rdpackages/rddensity/master/stata") replace */
+
+
+***The End
+
+
+
+

110/replication_package/replication/Do-file/MakeData.do

@@ -0,0 +1,351 @@
+* Set Directory
+clear
+set more off
+set scheme s1mono
+
+cd "$path"
+global data_files "$path/Data"
+global out_files "$path/output"
+
+**==============================================================================
+* Weather data
+use "$data_files/Raw/weather_daily.dta", clear
+
+collapse (sum) pre (mean) tem_mean, by(city_id year month)
+save "$data_files/weather_monthly.dta", replace
+
+use "$data_files/Raw/weather_daily.dta", clear
+gen quarter = int((month-1)/3)+1
+
+collapse (sum) pre (mean) tem_mean, by(city_id year quarter)
+save "$data_files/weather_quarterly.dta", replace
+
+use "$data_files/Raw/weather_daily.dta", clear
+gen quarter = int((month-1)/3)+1
+
+bys city_id year quarter: egen wd = mode(wdmax), max
+keep city_id year quarter wd
+duplicates drop
+save "$data_files/wind_quarterly.dta", replace
+
+**==============================================================================
+* Firm-level: enforcement data
+use "$data_files/Raw/firm_info.dta", clear
+
+merge 1:m id using "$data_files/Raw/enf_info.dta"
+keep if _merge == 3
+drop _merge
+
+merge m:1 city_id year quarter using "$data_files/weather_quarterly.dta"
+keep if _merge == 3
+drop _merge
+
+merge m:1 city_id year quarter using "$data_files/wind_quarterly.dta"
+keep if _merge == 3
+drop _merge
+
+capture drop ibear
+program ibear
+   
+    args lat1 lon1 lat2 lon2 newvar
+   
+    tempname d2r r2d
+    scalar `d2r' = _pi / 180
+    scalar `r2d' = 180 / _pi
+
+    gen `newvar' = atan2(sin((`lon2'-`lon1') * `d2r') * cos(`lat2' * `d2r') , ///
+                            cos(`lat1' * `d2r') * sin(`lat2' * `d2r') - ///
+                            sin(`lat1' * `d2r') * cos(`lat2' * `d2r') * ///
+                            cos((`lon2'-`lon1') * `d2r'))
+   
+    // normalize atan2 results (-pi to pi) to range from 0 to 360 degrees
+    replace `newvar' = mod((`newvar' * `r2d') + 360,3 60)
+	
+end
+
+ibear monitor_lat monitor_lon lat lon angle
+replace wd = 22.5*(wd-1)
+
+gen upwd = 1 if angle - wd < 45 & angle - wd > -45
+replace upwd = 1 if (angle - wd < 45 | angle - 360 - wd > -45) & wd <= 45
+replace upwd = 1 if (angle + 360 - wd < 45 | angle - wd > -45) & wd >= 315
+replace upwd = 0 if upwd == .
+
+egen time = group(year quarter)
+gen min_dist_10 = min_dist < 10
+gen post1 = year >= 2015
+
+gen air_1 = air==1
+gen air_2 = air>=2
+
+gen leni = (any_air_shutdown + any_air_fine + any_air_renovate == 1)
+gen stri = (any_air_shutdown + any_air_fine + any_air_renovate == 3)
+
+gen min_d_d4 = int(min_dist/5)
+replace min_d_d4 = 4 if min_d_d4 > 4
+
+bysort city_id: egen med_pre=median(pre)
+gen high_pre=0 if pre!=.
+replace high_pre=1 if pre!=. & pre>med_pre
+
+save "$data_files/firm_enf.dta", replace
+
+**==============================================================================
+use "$data_files/firm_enf.dta", clear
+
+gen any_air_10 = any_air & min_dist < 10
+gen any_air_20 = any_air & min_dist < 50 & min_dist > 10
+gen any_air_50 = any_air & min_dist > 50
+
+collapse (sum) any_air any_air_*, by(city_id year quarter)
+save "$data_files/enf.dta", replace
+
+**==============================================================================
+* Mayor data
+use "$data_files/Raw/mayor.dta", clear
+format %td start_date
+format %td end_date
+format %td birthdate
+
+bysort city_cn city_id (start_date end_date): gen next_start=start_date[_n+1]
+replace next_start=end_date if next_start==.
+format %td next_start
+
+foreach v of varlist start_date next_start end_date {
+    gen `v'_m = mofd(`v')
+	format %tm `v'_m
+}
+
+bysort city_cn city_id (start_date next_start_m): replace next_start_m=next_start_m-1 if _n!=_N
+expand next_start_m-start_date_m + 1
+
+by city_cn city_id name start_date (next_start_m), sort: gen month_date = start_date_m + _n - 1
+format month_date %tm
+gen month=month(dofm(month_date))
+gen year=year(dofm(month_date))
+
+sort city_cn city_id month_date name
+
+destring city_id, replace
+drop if city_id==.
+save "$data_files/mayor_panel.dta", replace
+
+keep if year==2015
+format %td birthdate
+gen birth_year=year(birthdate)
+gen birth_month=month(birthdate)
+gen age_2017=2018-birth_year
+bysort city_id: egen age = mode(age_2017), maxmode
+bysort city_id: egen age_month = mode(birth_month), maxmode
+
+keep city_id city_cn age age_month
+duplicates drop
+
+replace age = age+1 if age_month==1 & age==57
+drop age_month
+
+save "$data_files/age_2017.dta", replace
+
+use "$data_files/mayor_panel.dta", clear
+format %td birthdate
+gen birth_year=year(birthdate)
+gen birth_month=month(birthdate)
+
+gen age = year-birth_year
+bys city_id year: egen age_year = mode(age)
+
+keep if year >= 2010 & year <= 2017
+keep city_id year age_year
+duplicates drop
+
+bys city_id (year): replace age_year = age_year[_n-1]+1 if age_year == .
+bys city_id (year): replace age_year = age_year[_n+1]-1 if age_year == .
+bys city_id (year): replace age_year = age_year[_n-1]+1 if age_year == .
+bys city_id (year): replace age_year = age_year[_n+1]-1 if age_year == .
+
+save "$data_files/age_year.dta", replace
+
+**==============================================================================
+* Monitor data
+use "$data_files/raw/pm_pix.dta", clear
+
+keep city_id p_id p_lon p_lat
+duplicates drop
+
+rename city_id city_id2
+joinby city_id2 using "$data_files/Raw/monitor_city_long.dta"
+
+geodist p_lat p_lon monitor_lat monitor_lon, gen(dist)
+keep if dist < 20
+
+expand 8
+bys city_id monitor_id p_id: gen year = 2009 + _n
+expand 12
+bys city_id monitor_id p_id year: gen month = _n
+
+merge m:1 p_id year month using "$data_files/raw/pm_pix.dta"
+keep if _merge == 3
+drop _merge
+
+drop if pm25 == .
+bys monitor_id year month (dist): keep if _n == 1
+
+keep monitor_id city_id year month pm25 compare
+save "$data_files/monitor_pix.dta", replace
+
+keep if compare == 0
+collapse (mean) pm25, by(city_id year month)
+rename pm25 pm
+
+save "$data_files/pix.dta", replace
+
+**==============================================================================
+* City-level: AOD data
+use "$data_files/Raw/city_info.dta", clear
+
+merge 1:m city_id using "$data_files/raw/pm.dta"
+keep if _merge == 3
+drop _merge
+
+merge 1:1 city_id year month using "$data_files/weather_monthly.dta"
+keep if _merge == 3
+drop _merge
+
+merge m:1 city_id using "$data_files/age_2017.dta"
+keep if _merge == 3
+drop _merge
+
+merge m:1 city_id year using "$data_files/age_year.dta"
+keep if _merge == 3
+drop _merge
+
+merge 1:1 city_id year month using "$data_files/Raw/lights.dta"
+keep if _merge == 3
+drop _merge
+
+gen pred = int(pre/20)
+gen tem_meand = int(tem_mean)
+
+sort city_id year month
+gen quarter = int((month-1)/3)+1
+egen time = group(year quarter)
+
+merge m:1 city_id year quarter using "$data_files/enf.dta", keepusing(any_air)
+replace any_air = 0 if _merge == 1
+drop _merge
+
+gen post1 = year >= 2015
+
+merge 1:1 city_id year month using "$data_files/pix.dta"
+drop _merge
+
+save "$data_files/city_pm.dta", replace
+
+expand 2, gen(cutoff)
+replace cutoff = cutoff + 1
+save "$data_files/city_pm_rd.dta", replace
+
+**==============================================================================
+* City-level: Enforcement data
+use "$data_files/Raw/city_info.dta", clear
+expand 8
+bys city_id: gen year = _n + 2009
+expand 4
+bys city_id year: gen quarter = _n
+
+merge 1:1 city_id year quarter using "$data_files/weather_quarterly.dta"
+drop _merge
+
+merge 1:1 city_id year quarter using "$data_files/enf.dta"
+drop _merge
+
+merge m:1 city_id using "$data_files/age_2017.dta"
+keep if _merge == 3
+drop _merge
+
+merge m:1 city_id year using "$data_files/age_year.dta"
+keep if _merge == 3
+drop _merge
+
+gen pred = int(pre/20)
+gen tem_meand = int(tem_mean)
+
+sort city_id year quarter
+egen time = group(year quarter)
+
+replace any_air = 0 if any_air == .
+gen log_any_air = log(any_air+1)
+
+replace any_air_10 = 0 if any_air_10 == .
+gen log_any_air_10 = log(any_air_10+1)
+replace any_air_20 = 0 if any_air_20 == .
+gen log_any_air_20 = log(any_air_20+1)
+
+replace any_air_50 = 0 if any_air_50 == .
+gen log_any_air_50 = log(any_air_50+1)
+
+gen post1 = year >= 2015
+
+merge 1:1 city_id year quarter using "$data_files/Raw/non-asif.dta"
+drop _merge
+
+save "$data_files/city_enf.dta", replace
+
+expand 2, gen(cutoff)
+replace cutoff = cutoff + 1
+save "$data_files/city_enf_rd.dta", replace
+
+**==============================================================================
+use "$data_files/Raw/daily_monitor_api.dta", clear
+
+collapse (mean) pm25api pm10api AQI, by(city_id monitor_id year month)
+save "$data_files/monthly_api.dta", replace
+
+**==============================================================================
+use "$data_files/Raw/monitor_info.dta", clear
+
+merge 1:m monitor_id using "$data_files/monitor_pix"
+keep if _merge == 3
+drop _merge
+
+keep if year>=2015 & year<=2017
+
+merge 1:1 monitor_id year month using "$data_files/monthly_api.dta"
+keep if _merge == 3
+drop _merge
+
+merge m:1 city_id year month using "$data_files/weather_monthly.dta"
+keep if _merge == 3
+drop _merge
+
+merge m:1 city_id year using "$data_files/age_year.dta"
+keep if _merge == 3
+drop _merge
+
+save "$data_files/monitor_api.dta", replace
+
+**==============================================================================
+use "$data_files/Raw/firm_info.dta", clear
+
+keep if key == 1
+gen revenue_5 = revenue if min_dist < 5
+gen revenue_10 = revenue if min_dist < 10
+
+gen employment_5 = employment if min_dist < 5
+gen employment_10 = employment if min_dist < 10
+
+collapse (sum) revenue* employment*, by(city_id)
+
+gen share_rev_10 = revenue_10/revenue
+gen share_rev_5 = revenue_5/revenue
+
+gen share_emp_10 = employment_10/employment
+gen share_emp_5 = employment_5/employment
+
+keep share* city_id
+save "$data_files/share.dta", replace
+
+
+
+
+

110/replication_package/replication/Do-file/Master.do

@@ -0,0 +1,19 @@
+*** Master file for set path. Then run master file to produce all output.
+
+global path "C:/Users/s14756/Desktop/replication"
+cd "$path/Do-file"
+
+sysdir set PLUS "$path/ado/plus"
+sysdir set PERSONAL "$path/ado/personal"
+
+do "$path/Do-file/MakeData.do"
+do "$path/Do-file/Figure.do"
+do "$path/Do-file/Table.do"
+do "$path/Do-file/Appendix.do"
+
+
+***The End
+
+
+
+

110/replication_package/replication/Do-file/Table.do

@@ -0,0 +1,284 @@
+* Set Directory
+clear
+set more off
+set scheme s1mono
+
+cd "$path"
+global data_files "$path/Data"
+global out_files "$path/output"
+
+**==============================================================================
+* Table 1-2
+// Conley
+use "$data_files/firm_enf.dta", clear
+keep if min_dist<50 & starty<=2010
+drop if revenue == .
+drop if key == .
+
+label var min_dist_10 "Mon\$\_{<10km}\$"
+label var any_air "Any Enforcement (0/1)"
+label var post "Post"
+label var key "High Pollution"
+
+gen min_dist_10_post1 = c.min_dist_10#c.post1
+egen ind_time = group(industry prov_id time)
+
+reg2hdfespatial any_air min_dist_10_post1, lat(lat) lon(lon) timevar(time) panelvar(id) altfetime(ind_time) distcutoff(100) lagcutoff(20)
+scalar Conley1 = _se[min_dist_10_post1]
+
+reg2hdfespatial any_air_shutdown min_dist_10_post1, lat(lat) lon(lon) timevar(time) panelvar(id) altfetime(ind_time) distcutoff(100) lagcutoff(20) 
+scalar Conley2 = _se[min_dist_10_post1]
+
+reg2hdfespatial any_air_renovate min_dist_10_post1, lat(lat) lon(lon) timevar(time) panelvar(id) altfetime(ind_time) distcutoff(100) lagcutoff(20) 
+scalar Conley3 = _se[min_dist_10_post1]
+
+reg2hdfespatial any_air_fine min_dist_10_post1, lat(lat) lon(lon) timevar(time) panelvar(id) altfetime(ind_time) distcutoff(100) lagcutoff(20) 
+scalar Conley4 = _se[min_dist_10_post1]
+
+reg2hdfespatial any_air_warning min_dist_10_post1, lat(lat) lon(lon) timevar(time) panelvar(id) altfetime(ind_time) distcutoff(100) lagcutoff(20) 
+scalar Conley5 = _se[min_dist_10_post1]
+
+use "$data_files/firm_enf.dta", clear
+drop if revenue == .
+drop if key == .
+
+label var min_dist_10 "Mon\$\_{<10km}\$"
+label var any_air "Any Enforcement (0/1)"
+label var post "Post"
+label var key "High Pollution"
+
+eststo clear
+reghdfe any_air c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo A
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local Conley =  "[`: di %9.5f Conley1']"
+reghdfe any_air_shutdown c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo B
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local Conley = "[`: di %9.5f Conley2']"
+reghdfe any_air_renovate c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo C
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local Conley = "[`: di %9.5f Conley3']"
+reghdfe any_air_fine c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo D
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local Conley = "[`:di %9.5f Conley4']"
+reghdfe any_air_warning c.min_dist_10#c.post1 if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo E
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+estadd local Conley = "[`:di %9.5f Conley5']"
+esttab A B C D E using "$out_files/Table1a.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep(c.min_dist_10*) stats(ymean EN Conley, labels("Mean Outcome" "Observations" "Conley SE")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+* Table 1b
+use "$data_files/firm_enf.dta", clear
+drop if revenue == .
+drop if key == .
+
+label var min_dist_10 "Mon\$\_{<10km}\$"
+label var any_air "Any Enforcement (0/1)"
+label var post "Post"
+label var key "High Pollution"
+
+eststo clear
+reghdfe air c.min_dist_10#c.post1##c.key if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo A
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe air_1 c.min_dist_10#c.post1##c.key if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo B
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe air_2 c.min_dist_10#c.post1##c.key if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo C
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe leni c.min_dist_10#c.post1##c.key if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo D
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe stri c.min_dist_10#c.post1##c.key if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo E
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+esttab A B C D E using "$out_files/Table1b.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep(c.min_dist_10*) stats(ymean EN, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+* Table 2
+gen Shock = high_pre
+eststo clear
+reghdfe any_air c.min_dist_10#c.post1##c.Shock tem_mean if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo A
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe any_air c.min_dist_10##c.post1##c.Shock tem_mean if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo B
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+replace Shock = upwd
+reghdfe any_air c.min_dist_10#c.post1##c.Shock tem_mean if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo C
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+reghdfe any_air c.min_dist_10##c.post1##c.Shock tem_mean if min_dist<50 & starty<=2010, absorb(time id industry#time prov_id#time) cluster(city_id)
+eststo D
+estadd ysumm, mean
+estadd scalar EN = e(N_full)
+esttab A B C D using "$out_files/Table2.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep() drop(_cons tem_mean post1 min_dist_10) order(Shock c.min_dist_10#c.post1 c.min_dist_10#c.Shock c.min_dist_10#c.post1#c.Shock) stats(ymean EN, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+**==============================================================================
+* Table 3
+use "$data_files/city_pm.dta", clear
+label variable post1 "Post" 
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+eststo clear
+reghdfe pm25 RD_Estimate c.post#c.area c.post#c.pop, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe pm25 c.post#c.area c.post#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo B
+
+use "$data_files/city_pm_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = pm25 if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust pm25 dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench year month) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe pm25 RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/Table3a.tex", keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN, labels( "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) tex
+
+use "$data_files/city_enf.dta", clear
+
+label variable post1 "Post"
+label variable number "\# Mon"
+label variable number_iv "Min \# Mon"
+
+gen RD_Estimate = c.post1#c.number
+
+eststo clear
+reghdfe log_any_air RD_Estimate c.post#c.area c.post#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo A
+ivreghdfe log_any_air c.post#c.area c.post#c.pop (RD_Estimate=c.post1#c.number_iv), a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+estadd scalar EN = e(N_full)
+eststo B
+
+use "$data_files/city_enf_rd.dta", clear
+
+gen dist1 = area - 20 if cutoff == 1
+replace dist1 = area - 50 if cutoff == 2
+
+gen bench = log_any_air if year < 2012
+bys city_id cutoff: egen mean_bench = mean(bench)
+
+gen above = dist1 > 0
+gen RD_Estimate = c.post1#c.above
+
+rdrobust log_any_air dist1 if year>=2015, fuzzy(number) p(1) h(11.3) covs(cutoff mean_bench year quarter) kernel(uni) vce(cluster city_id)
+estadd scalar EN = e(N_h_l) + e(N_h_r)
+estadd scalar band = e(h_l)
+eststo C
+reghdfe log_any_air RD_Estimate post1 above dist1 c.post1#c.dist1 c.above#c.dist1 c.post1#c.above#c.dist1 cutoff if abs(dist1) < 11.3, a(time) cl(city_id)
+estadd scalar EN = e(N)
+estadd scalar band = 11.3
+eststo D
+esttab A B C D using "$out_files/Table3b.tex", tex keep(RD_Estimate) transform(@/1.21 1/1.21, pattern(0 0 0 1)) replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers mlabels(none) coeflabels(RD_Estimate "\# Monitors") stats(EN, labels("Observations")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+replace RD_Estimate = number_iv
+
+eststo clear
+regress number number_iv if year>=2015, vce(cluster city_id)
+eststo A
+regress number RD_Estimate pop area if year>=2015, vce(cluster city_id)
+eststo B
+rdrobust number dist1 if year>=2015, p(1) h(11.3) covs(cutoff) kernel(uni) vce(cluster city_id)
+eststo C
+estadd local kern = "Uniform"
+estadd scalar band = 11.3
+rdrobust number dist1 if year>=2015, p(1) h(11.3) covs(cutoff) kernel(uni) vce(cluster city_id)
+eststo D
+estadd local kern = "Uniform"
+estadd scalar band = 11.3
+esttab A B C D using "$out_files/Table3c.tex", tex replace b(a2) se(a2) label noconstant nolines nogaps compress fragment nonumbers noobs mlabels(none) keep(RD_Estimate) coeflabels(RD_Estimate "Estimate") stats(kern band, labels("Kernel" "Bandwidth")) starlevels(* 0.10 ** 0.05 *** 0.01)
+
+
+**==============================================================================
+* Table 4
+use "$data_files/monitor_api.dta", clear
+
+gen log_pm25api = log(pm25api)
+gen log_pm10api = log(pm10api)
+
+gen reassign = (year == 2017)
+replace reassign = 1 if year == 2016 & month >= 11
+
+rename pm25 AOD
+label variable AOD "AOD"
+label variable reassign "Reassigned"
+
+eststo clear
+reghdfe log_pm25api AOD pre tem_mean, a(monitor_id year#month) cl(city_id)
+eststo A
+estadd ysumm, mean
+reghdfe log_pm25api AOD pre tem_mean if ~compare, a(monitor_id year#month) cl(city_id)
+eststo B
+estadd ysumm, mean
+reghdfe log_pm25api AOD c.AOD#c.reassign pre tem_mean if ~compare, a(monitor_id year#month) cl(city_id)
+eststo C
+estadd ysumm, mean
+reghdfe log_pm25api AOD pre tem_mean if compare, a(monitor_id year#month) cl(city_id)
+eststo D
+estadd ysumm, mean
+reghdfe log_pm25api AOD c.AOD#c.reassign pre tem_mean if compare, a(monitor_id year#month) cl(city_id)
+eststo E
+estadd ysumm, mean
+
+use "$data_files/city_pm.dta", clear
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+
+gen reassign = (year == 2017)
+replace reassign = 1 if year == 2016 & month >= 10
+label variable reassign "Reassigned"
+
+reghdfe pm25 c.post1#c.number c.post1#c.number#c.reassign c.post1#c.area c.post1#c.pop, a(city_id year#month pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo F
+estadd ysumm, mean
+
+use "$data_files/city_enf.dta", clear
+
+label variable post1 "Post" 
+label variable number "\# Mon"
+
+gen reassign = (year == 2017)
+replace reassign = 1 if year == 2016 & quarter == 4
+label variable reassign "Reassigned"
+
+reghdfe log_any_air c.post1#c.number c.post1#c.number#c.reassign c.post1#c.area c.post1#c.pop, a(city_id year#quarter pred tem_meand age_year incentive2#time) cluster(city_id)
+eststo G
+estadd ysumm, mean
+esttab A B C D E F G using "$out_files/Table4.tex", replace b(a2) noconstant se(a2) nolines nogaps compress fragment nonumbers label mlabels(none) collabels() keep(AOD c.AOD#c.reassign c.post1#c.number c.post1#c.number#c.reassign) drop() coeflabels(c.AOD#c.reassign "AOD $\times$ Reassigned" c.post1#c.number "\# Monitors" c.post1#c.number#c.reassign "\# Monitors $\times$ Reassigned") stats(ymean N, labels("Mean Outcome" "Observations")) starlevels(* 0.10 ** 0.05 *** 0.01) substitute(\_ _) tex
+
+

110/replication_package/replication/Do-file/classify.py

@@ -0,0 +1,110 @@
+import time
+import csv
+import os
+import re
+from bs4 import BeautifulSoup
+
+def FindKey(RecordText, KeyWords):
+
+    if any(word in RecordText for word in KeyWords):
+        output = 1
+    else:
+        output = 0
+
+    return output
+
+
+KeyWords1 = ['气','烟','尘','二氧化硫','颗粒','脱硝','脱硫','炉','焚烧','NO','PM']
+KeyWords2 = ['污水','水污染','沉淀','沟','渠','COD']
+KeyWords3 = ['固体']
+KeyWords4 = ['未批先建','批建不符','未验先投','清理明细表','开工','环评','手续','三同时','未经验收']
+KeyWords5 = ['罚款','经济处罚','万元']
+KeyWords6 = ['停']
+KeyWords7 = ['改','维修']
+
+htfile = "output.txt"
+fo = open(htfile, "w", encoding='utf_8_sig')
+
+
+with open('records.csv', 'r') as f:
+    reader = csv.reader(f)
+    records_list = list(reader)
+
+
+for record in records_list:
+    dir_path = '/Volumes/forMac/list/'+str(record[0])
+    address = dir_path+'/'+str(record[1])
+    print(address)
+
+    fo.write(str(record[1]))
+    soup = BeautifulSoup(open(address).read(), "html.parser")
+    
+    output1=0
+    output2=0
+    output3=0
+    output4=0
+    output5=0
+    output6=0
+    output7=0
+
+    tables = soup.find_all('table')
+    cells = soup.find_all(style="color:#eeeeee;background-color:#3399FF")
+
+    if len(cells)==0:
+        output1=0
+        output2=0
+        output3=0
+    else:
+        if len(tables)==0:
+            text = soup.get_text()
+        else:
+            try:
+                block = cells[-1].find_parents('tr')[-1]
+                row = block.find_all('td')
+                if len(row)<4:
+                    text = soup.get_text()
+                else:
+                    text = block.get_text()
+            except:
+                text = soup.get_text()
+
+        output1 = FindKey(text, KeyWords1)
+        output2 = FindKey(text, KeyWords2)
+        output3 = FindKey(text, KeyWords3)
+        output4 = FindKey(text, KeyWords4)
+        output5 = FindKey(text, KeyWords5)
+        output6 = FindKey(text, KeyWords6)
+        output7 = FindKey(text, KeyWords7)
+
+    total=output1+output2+output3+output4
+
+    if total==0:
+        text = soup.get_text()
+        output4 = FindKey(text, KeyWords4)
+    
+    fo.write(",")
+    fo.write(str(output1))
+    fo.write(",")
+    fo.write(str(output2))
+    fo.write(",")
+    fo.write(str(output3))
+    fo.write(",")
+    fo.write(str(output4))
+    fo.write(",")
+    fo.write(str(output5))
+    fo.write(",")
+    fo.write(str(output6))
+    fo.write(",")
+    fo.write(str(output7))
+    fo.write("\n")
+
+fo.close()
+
+
+
+
+
+
+
+
+

110/replication_package/replication/ado/personal/ols_spatial_HAC.ado

@@ -0,0 +1,408 @@
+program ols_spatial_HAC, eclass byable(recall)
+version 11
+syntax varlist(ts fv min=2) [if] [in], ///
+                lat(varname numeric) lon(varname numeric) ///
+                Timevar(varname numeric) Panelvar(varname numeric) [LAGcutoff(integer 0) DISTcutoff(real 1) ///
+                DISPlay star bartlett dropvar]
+                
+/*--------PARSING COMMANDS AND SETUP-------*/
+
+capture drop touse
+marksample touse                // indicator for inclusion in the sample
+gen touse = `touse'
+
+//parsing variables
+loc Y = word("`varlist'",1)        
+
+loc listing "`varlist'"
+
+loc X ""
+scalar k = 0
+
+//make sure that Y is not included in the other_var list
+foreach i of loc listing {
+    if "`i'" ~= "`Y'"{
+        loc X "`X' `i'"
+        scalar k = k + 1 // # indep variables
+        
+    }
+}
+
+
+//Kyle Meng's code to drop omitted variables that Stata would drop due to collinearity
+
+if "`dropvar'" == "dropvar"{
+    
+    quietly reg `Y' `X' if `touse', nocons
+    
+    mat omittedMat=e(b)
+    local newVarList=""
+    local i=1
+    scalar k = 0 //replace the old k if this option is selected
+    
+    foreach var of varlist `X'{
+        if omittedMat[1,`i']!=0{
+            loc newVarList "`newVarList' `var'"
+            scalar k = k + 1
+        }
+        local i=`i'+1
+    }
+    
+    loc X "`newVarList'"
+}
+
+//generating a function of the included obs
+quietly count if `touse'        
+scalar n = r(N)                    // # obs
+scalar n_obs = r(N)
+
+/*--------FIRST DO OLS, STORE RESULTS-------*/
+
+
+quietly: reg `Y' `X' if `touse', nocons
+estimates store OLS
+
+//est tab OLS, stats(N r2)
+
+/*--------SECOND, IMPORT ALL VALUES INTO MATA-------*/
+
+mata{
+
+Y_var = st_local("Y") //importing variable assignments to mata
+X_var = st_local("X")
+lat_var = st_local("lat")
+lon_var = st_local("lon")
+time_var = st_local("timevar")
+panel_var = st_local("panelvar")
+
+//NOTE: values are all imported as "views" instead of being copied and pasted as Mata data because it is faster, however none of the matrices are changed in any way, so it should not permanently affect the data.
+
+st_view(Y=.,.,tokens(Y_var),"touse") //importing variables vectors to mata
+st_view(X=.,.,tokens(X_var),"touse")
+st_view(lat=.,.,tokens(lat_var),"touse")
+st_view(lon=.,.,tokens(lon_var),"touse")
+st_view(time=.,.,tokens(time_var),"touse")
+st_view(panel=.,.,tokens(panel_var),"touse")
+
+k = st_numscalar("k")                //importing other parameters
+n = st_numscalar("n")
+b = st_matrix("e(b)")                // (estimated coefficients, row vector)
+lag_var = st_local("lagcutoff")
+lag_cutoff = strtoreal(lag_var)
+dist_var = st_local("distcutoff")
+dist_cutoff = strtoreal(dist_var)
+
+XeeX = J(k, k, 0)                 //set variance-covariance matrix equal to zeros
+
+
+/*--------THIRD, CORRECT VCE FOR SPATIAL CORR-------*/
+
+timeUnique = uniqrows(time)
+Ntime = rows(timeUnique)         // # of obs. periods
+
+for (ti = 1; ti <= Ntime; ti++){
+    
+    
+
+    // 1 if in year ti, 0 otherwise:
+
+    rows_ti = time:==timeUnique[ti,1]     
+
+    //get subsets of variables for time ti (without changing original matrix)
+    
+    Y1 = select(Y, rows_ti)
+    X1 = select(X, rows_ti)
+    lat1 = select(lat, rows_ti)
+    lon1 = select(lon, rows_ti)
+    e1 = Y1 - X1*b'
+    
+    n1 = length(Y1)             // # obs for period ti
+    
+    //loop over all observations in period ti
+
+    for (i = 1; i <=n1; i++){
+        
+
+        //----------------------------------------------------------------
+        // step a: get non-parametric weight
+    
+        //This is a Euclidean distance scale IN KILOMETERS specific to i
+        
+        lon_scale = cos(lat1[i,1]*pi()/180)*111
+        lat_scale = 111
+        
+
+        // Distance scales lat and lon degrees differently depending on
+        // latitude.  The distance here assumes a distortion of Euclidean
+        // space around the location of 'i' that is approximately correct for
+        // displacements around the location of 'i'
+        //
+        //    Note:     1 deg lat = 111 km
+        //             1 deg lon = 111 km * cos(lat)
+        
+        distance_i = ((lat_scale*(lat1[i,1]:-lat1)):^2 + ///     
+                      (lon_scale*(lon1[i,1]:-lon1)):^2):^0.5
+
+
+        
+        // this sets all observations beyon dist_cutoff to zero, and weights all nearby observations equally [this kernal is isotropic]
+        
+        window_i = distance_i :<= dist_cutoff
+
+        //----------------------------------------------------------------
+        // adjustment for the weights if a "bartlett" kernal is selected as an option
+ 
+        if ("`bartlett'"=="bartlett"){
+        
+            // this weights observations as a linear function of distance
+            // that is zero at the cutoff distance
+            
+            weight_i = 1:- distance_i:/dist_cutoff
+
+            window_i = window_i:*weight_i
+        }
+
+ 
+        //----------------------------------------------------------------
+        // step b: construct X'e'eX for the given observation
+ 
+         XeeXh = ((X1[i,.]'*J(1,n1,1)*e1[i,1]):*(J(k,1,1)*e1':*window_i'))*X1
+
+        //add each new k x k matrix onto the existing matrix (will be symmetric)
+    
+        XeeX = XeeX + XeeXh     
+    
+    } //i
+} // ti
+
+
+
+// -----------------------------------------------------------------
+// generate the VCE for only cross-sectional spatial correlation,
+// return it for comparison
+
+invXX = luinv(X'*X) * n
+
+XeeX_spatial = XeeX / n
+
+V = invXX * XeeX_spatial * invXX / n
+
+// Ensures that the matrix is symmetric
+// in theory, it should be already, but it may not be due to rounding errors for large datasets
+V = (V+V')/2
+
+st_matrix("V_spatial", V)
+
+} // mata
+
+
+//------------------------------------------------------------------
+// storing old statistics about the estimate so postestimation can be used
+
+matrix beta = e(b)
+scalar r2_old = e(r2)
+scalar df_m_old = e(df_m)
+scalar df_r_old = e(df_r)
+scalar rmse_old = e(rmse)
+scalar mss_old = e(mss)
+scalar rss_old = e(rss)
+scalar r2_a_old = e(r2_a)
+
+// the row and column names of the new VCE must match the vector b
+
+matrix colnames V_spatial = `X'
+matrix rownames V_spatial = `X'
+ 
+// this sets the new estimates as the most recent model
+
+ereturn post beta V_spatial, esample(`touse')
+
+// then filling back in all the parameters for postestimation
+
+ereturn local cmd = "ols_spatial"
+
+ereturn scalar N = n_obs
+
+ereturn scalar r2 = r2_old
+ereturn scalar df_m = df_m_old
+ereturn scalar df_r = df_r_old
+ereturn scalar rmse = rmse_old
+ereturn scalar mss = mss_old
+ereturn scalar rss = rss_old
+ereturn scalar r2_a = r2_a_old
+
+ereturn local title = "Linear regression"
+ereturn local depvar = "`Y'"
+ereturn local predict = "regres_p"
+ereturn local model = "ols"
+ereturn local estat_cmd = "regress_estat"
+
+//storing these estimates for comparison to OLS and the HAC estimates
+
+estimates store spatial
+
+
+
+/*--------FOURTH, CORRECT VCE FOR SERIAL CORR-------*/
+
+mata{
+
+panelUnique = uniqrows(panel)
+Npanel = rows(panelUnique)         // # of panels
+
+for (pi = 1; pi <= Npanel; pi++){
+    
+    // 1 if in panel pi, 0 otherwise:
+
+    rows_pi = panel:==panelUnique[pi,1]     
+
+    //get subsets of variables for panel pi (without changing original matrix)
+    
+    Y1 = select(Y, rows_pi)
+    X1 = select(X, rows_pi)
+    time1 = select(time, rows_pi)
+    e1 = Y1 - X1*b'
+
+    n1 = length(Y1)             // # obs for panel pi
+    
+    //loop over all observations in panel pi
+
+    for (t = 1; t <=n1; t++){
+
+           // ----------------------------------------------------------------
+        // step a: get non-parametric weight
+        
+        // this is the weight for Newey-West with a Bartlett kernal
+        
+        //weight = (1:-abs(time1[t,1] :- time1))/(lag_cutoff+1) // correction: need to removing parentheses to compute inter-temporal  (6/10/18)
+        weight = 1:-abs(time1[t,1] :- time1)/(lag_cutoff+1)
+
+        
+        // obs var far enough apart in time are prescribed to have no estimated
+        // correlation (Greene recomments lag_cutoff >= T^0.25 {pg 546})
+        
+        window_t = (abs(time1[t,1]:- time1) :<= lag_cutoff) :* weight
+        
+        //this is required so diagonal terms in var-covar matrix are not
+        //double counted (since they were counted once above for the spatial
+        //correlation estimates:
+        
+        window_t = window_t :* (time1[t,1] :!= time1)                   
+            
+          // ----------------------------------------------------------------
+        // step b: construct X'e'eX for given observation
+         
+           XeeXh = ((X1[t,.]'*J(1,n1,1)*e1[t,1]):*(J(k,1,1)*e1':*window_t'))*X1
+
+        //add each new k x k matrix onto the existing matrix (will be symmetric)
+                
+        XeeX = XeeX + XeeXh
+
+    } // t
+} // pi
+
+
+
+
+// -----------------------------------------------------------------
+// generate the VCE for x-sectional spatial correlation and serial correlation
+
+XeeX_spatial_HAC = XeeX / n
+
+V = invXX * XeeX_spatial_HAC * invXX / n
+
+// Ensures that the matrix is symmetric
+// in theory, it should be already, but it may not be due to rounding errors for large datasets
+V = (V+V')/2
+
+st_matrix("V_spatial_HAC", V)
+
+} // mata
+
+//------------------------------------------------------------------
+//storing results
+
+matrix beta = e(b)
+
+// the row and column names of the new VCE must match the vector b
+
+matrix colnames V_spatial_HAC = `X'
+matrix rownames V_spatial_HAC = `X'
+
+// this sets the new estimates as the most recent model
+
+marksample touse                // indicator for inclusion in the sample
+
+ereturn post beta V_spatial_HAC, esample(`touse')
+
+// then filling back in all the parameters for postestimation
+
+ereturn local cmd = "ols_spatial_HAC"
+
+ereturn scalar N = n_obs
+ereturn scalar r2 = r2_old
+ereturn scalar df_m = df_m_old
+ereturn scalar df_r = df_r_old
+ereturn scalar rmse = rmse_old
+ereturn scalar mss = mss_old
+ereturn scalar rss = rss_old
+ereturn scalar r2_a = r2_a_old
+
+ereturn local title = "Linear regression"
+ereturn local depvar = "`Y'"
+ereturn local predict = "regres_p"
+ereturn local model = "ols"
+ereturn local estat_cmd = "regress_estat"
+
+//storing these estimates for comparison to OLS and the HAC estimates
+
+estimates store spatHAC
+
+//------------------------------------------------------------------
+//displaying results
+
+disp as txt " "
+disp as txt "OLS REGRESSION"
+disp as txt " "
+disp as txt "SE CORRECTED FOR CROSS-SECTIONAL SPATIAL DEPENDANCE"
+disp as txt "             AND PANEL-SPECIFIC SERIAL CORRELATION"
+disp as txt " "
+disp as txt "DEPENDANT VARIABLE: `Y'"
+disp as txt "INDEPENDANT VARIABLES: `X'"
+disp as txt " "
+disp as txt "SPATIAL CORRELATION KERNAL CUTOFF: `distcutoff' KM"
+
+if "`bartlett'" == "bartlett" {
+    disp as txt "(NOTE: LINEAR BARTLETT WINDOW USED FOR SPATIAL KERNAL)"
+}
+    
+disp as txt "SERIAL CORRELATION KERNAL CUTOFF: `lagcutoff' PERIODS"
+
+ereturn display // standard Stata regression table format
+
+// displaying different SE if option selected
+
+if "`display'" == "display"{
+    disp as txt " "
+    disp as txt "STANDARD ERRORS UNDER OLS, WITH SPATIAL CORRECTION AND WITH SPATIAL AND SERIAL CORRECTION:"
+    estimates table OLS spatial spatHAC, b(%7.3f) se(%7.3f) t(%7.3f) stats(N r2)     
+}
+
+if "`star'" == "star"{
+    disp as txt " "
+    disp as txt "STANDARD ERRORS UNDER OLS, WITH SPATIAL CORRECTION AND WITH SPATIAL AND SERIAL CORRECTION:"
+    estimates table OLS spatial spatHAC, b(%7.3f) star(0.10 0.05 0.01)
+}
+
+//------------------------------------------------------------------
+// cleaning up Mata environment
+
+capture mata mata drop V invXX  XeeX XeeXh XeeX_spatial_HAC window_t window_i weight t i ti pi X1 Y1 e1 time1 n1 lat lon lat1 lon1 lat_scale lon_scale rows_ti rows_pi timeUnique panelUnique Ntime Npanel X X_var XeeX_spatial Y Y_var b dist_cutoff dist_var distance_i k lag_cutoff lag_var lat_var lon_var n panel panel_var time time_var weight_i
+
+/*
+if "`bartlett'" == "bartlett" {
+    capture mata mata drop weight_i            
+}
+*/
+
+end

110/replication_package/replication/ado/personal/reg2hdfespatial.ado

@@ -0,0 +1,202 @@
+capture program drop reg2hdfespatial 
+*! Thiemo Fetzer 4/2015: WRAPPER PROGRAM TO ESTIMATE SPATIAL HAC FOR OLS REGRESSION MODELS WITH HIGH DIMENSIONAL FIXED EFFECTS
+*! The function uses the reg2hdfe procedure to demean the data by the time- and panel-variable you specify
+*! This ensures that you do not compute large variance covariance matrices to compute
+*! Spatial HAC errors for coefficients you do not actually care about.
+*! Updates available on http://www.trfetzer.com
+*! Please email me in case you find any bugs or have suggestions for improvement.
+*! Please cite: Fetzer, T. (2014) "Can Workfare Programs Moderate Violence? Evidence from India", STICERD Working Paper.
+*! Also credit Sol Hsiang.
+*! Hsiang, S. M. (2010). Temperatures and cyclones strongly associated with economic production in the Caribbean and Central America. PNAS, 107(35), 15367–72.
+*! The Use of the function is simple
+*!  reg2hdfespatial Yvar Xvarlist, lat(latvar) lon(lonvar) Timevar(tvar) Panelvar(pvar) [DISTcutoff(#) LAGcutoff(#) bartlett DISPlay star dropvar demean altfetime(varname) altfepanel(varname)]
+*!
+*!
+*! You can also specify other fixed effects:
+*! reg2hdfespatial Yvar     Xvarlist   ,timevar(year) panelvar(district) altfetime(regionyear)  lat(y) lon(x) distcutoff(500) lagcutoff(20) 
+*!
+*! here I specify the time variable as the year, but I demean the data first
+*! by region x year fixed effects.
+*! This turns out to matter as the OLS_Spatial_HAC for the autocorrelation correction which you may want
+*! to be done at a level different from the level at which you have the time fixed effects specified.
+/*-----------------------------------------------------------------------------
+
+ Syntax:
+ 
+ reg2hdfespatial Yvar Xvarlist, lat(latvar) lon(lonvar) Timevar(tvar) Panelvar(pvar) [DISTcutoff(#) LAGcutoff(#) bartlett DISPlay star dropvar demean altfetime(varname) altfepanel(varname)]
+
+ -----------------------------------------------------------------------------*/
+
+program reg2hdfespatial, eclass byable(recall)
+//version 9.2
+version 11
+syntax varlist(ts fv min=2) [if] [in], ///
+				lat(varname numeric) lon(varname numeric) ///
+				Timevar(varname numeric) Panelvar(varname numeric) [LAGcutoff(integer 0) DISTcutoff(real 1) ///
+				DISPlay star bartlett dropvar altfetime(varname) altfepanel(varname) ]
+				
+/*--------PARSING COMMANDS AND SETUP-------*/
+
+preserve
+if "`if'"~="" {
+	qui keep `if' 
+}
+
+
+capture drop touse
+marksample touse				// indicator for inclusion in the sample
+gen touse = `touse'
+
+*keep if touse
+//parsing variables
+loc Y = word("`varlist'",1)		
+
+loc listing "`varlist'"
+
+
+loc X ""
+scalar k_variables = 0
+
+//make sure that Y is not included in the other_var list
+foreach i of loc listing {
+	if "`i'" ~= "`Y'"{
+		loc X "`X' `i'"
+		scalar k_variables = k_variables + 1 // # indep variables
+		
+	}
+}
+local wdir `c(pwd)'
+
+tmpdir returns r(tmpdir):
+local tdir  `r(tmpdir)'
+
+
+**clear temp folder of existing files
+qui cd "`tdir'"
+local tempfiles : dir . files "*.dta"
+foreach f in `tempfiles' {
+	erase `f'
+}
+
+quietly {
+if("`altfepanel'" !="" & "`altfetime'" !="") {
+di "CASE 1"
+reg2hdfe `Y' `X' `lat' `lon' `timevar' `panelvar' ,  id1(`altfepanel') id2(`altfetime') out("`tdir'") noregress 
+loc iteratevarlist "`Y' `X' `lat' `lon' `timevar' `panelvar'" 
+reg2hdfe `Y' `X' , id1(`altfepanel') id2(`altfetime')
+}
+if("`altfepanel'" =="" & "`altfetime'" !="") {
+di "CASE 2"
+
+reg2hdfe `Y' `X' `lat' `lon' `timevar' ,  id1(`panelvar') id2(`altfetime') out("`tdir'") noregress 
+loc iteratevarlist "`Y' `X' `lat' `lon' `timevar' " 
+
+reg2hdfe `Y' `X' , id1(`panelvar') id2(`altfetime')
+}
+if("`altfepanel'" !="" & "`altfetime'" =="") {
+di "CASE 3"
+
+reg2hdfe `Y' `X' `lat' `lon' `panelvar' ,  id1(`altfepanel') id2(`timevar') out("`tdir'") noregress 
+reg2hdfe `Y' `X' , id1(`altfepanel') id2(`timevar') 
+loc iteratevarlist "`Y' `X' `lat' `lon' `panelvar'"
+}
+if("`altfepanel'" =="" & "`altfetime'" =="") {
+di "CASE 4"
+reg2hdfe `Y' `X' `lat' `lon' ,  id1(`panelvar') id2(`timevar') out("`tdir'") noregress 
+loc iteratevarlist "`Y' `X' `lat' `lon'" 
+reg2hdfe `Y' `X' ,  id1(`panelvar') id2(`timevar')
+}
+
+	foreach var of varlist `X' {
+		lincom `var'		
+		if `r(se)' != 0 {
+			loc newVarList "`newVarList' `var'"
+			scalar k_variables = k_variables + 1
+		}
+	}
+	
+	loc XX "`newVarList'"
+
+
+/* From reg2hdfe.ado */
+tempfile tmp1 tmp2 tmp3 readdata
+
+	use _ids, clear
+	sort __uid
+	qui save "`tmp1'", replace
+	if "`cluster'"!="" {
+		merge __uid using _clustervar
+		if r(min)<r(max) { 
+			di "Fatal Error"
+			error 198
+		}
+		drop _merge
+		sort __uid
+		rename __clustervar `clustervar'
+		qui save "`tmp1'", replace
+		}
+	
+
+* Now read the original variables
+	foreach var in `iteratevarlist'  {
+		merge __uid using _`var'
+		sum _merge, meanonly
+		if r(min)<r(max) { 
+			di "Fatal Error"
+			error 198
+		}
+		tab _merge
+		drop _merge
+		drop __fe2*
+		drop __t_*
+		sort __uid
+		qui save "`tmp2'", replace
+	}
+	foreach var in  `iteratevarlist'  {
+		rename __o_`var' `var'
+	}
+	
+	
+ 	tempvar yy sy
+	gen double `yy'=(`depvar'-r(mean))^2
+	gen double `sy'=sum(`yy')
+	local tss=`sy'[_N]
+	drop `yy' `sy'
+	qui save "`readdata'", replace
+	use `tmp1', clear
+	foreach var in  `iteratevarlist'  {
+		merge 1:1 __uid using _`var'
+		sum _merge, meanonly
+		if r(min)<r(max) { 
+			di "Fatal Error."
+			error 198
+		}
+		
+	drop _merge
+	}
+
+		drop __fe2*
+		rename __o_`lon' `lon'
+		rename __o_`lat' `lat'
+		if("`altfepanel'" !="" ) {
+ 		rename __o_`panelvar' `panelvar'
+ 		}
+ 		if("`altfetime'" !="" ) {
+ 		rename __o_`timevar' `timevar'
+ 		}
+ 			
+		drop __o_*
+		sort __uid
+		qui save "`tmp3'", replace
+        
+	foreach var in `Y' `X'  {
+		rename __t_`var' `var'
+	}
+
+}
+ols_spatial_HAC `Y' `XX', lat(`lat') lon(`lon') timevar(`timevar') panelvar(`panelvar') lagcutoff(`lagcutoff') distcutoff(`distcutoff') bartlett
+
+cd "`wdir'"
+end
+
+

110/replication_package/replication/ado/plus/_/_eststo.ado

@@ -0,0 +1,28 @@
+*! version 1.0.4  09nov2007  Ben Jann
+
+program define _eststo, byable(onecall)
+    local caller : di _caller()
+    version 8.2
+    if "`_byvars'"!="" local by "by `_byvars'`_byrc0' : "
+    if inlist(`"`1'"',"clear","dir","drop") {
+        version `caller': `by'eststo `0'
+    }
+    else {
+        capt _on_colon_parse `0'
+        if !_rc {
+            local command `"`s(after)'"'
+            if `"`command'"'!="" {
+                local command `":`command'"'
+            }
+            local 0 `"`s(before)'"'
+        }
+        syntax [anything] [, Esample * ]
+        if `"`esample'"'=="" {
+            local options `"noesample `options'"'
+        }
+        if `"`options'"'!="" {
+            local options `", `options'"'
+        }
+        version `caller': `by'eststo `anything'`options' `command'
+    }
+end

110/replication_package/replication/ado/plus/_/_eststo.hlp

@@ -0,0 +1 @@
+.h eststo

110/replication_package/replication/ado/plus/b/binscatter.ado

@@ -0,0 +1,1048 @@
+*! version 7.02  24nov2013  Michael Stepner, [email protected]
+
+/* CC0 license information:
+To the extent possible under law, the author has dedicated all copyright and related and neighboring rights
+to this software to the public domain worldwide. This software is distributed without any warranty.
+
+This code is licensed under the CC0 1.0 Universal license.  The full legal text as well as a
+human-readable summary can be accessed at http://creativecommons.org/publicdomain/zero/1.0/
+*/
+
+* Why did I include a formal license? Jeff Atwood gives good reasons: http://www.codinghorror.com/blog/2007/04/pick-a-license-any-license.html
+
+
+program define binscatter, eclass sortpreserve
+	version 12.1
+	
+	syntax varlist(min=2 numeric) [if] [in] [aweight fweight], [by(varname) ///
+		Nquantiles(integer 20) GENxq(name) discrete xq(varname numeric) MEDians ///
+		CONTROLs(varlist numeric ts fv) absorb(varname) noAddmean ///
+		LINEtype(string) rd(numlist ascending) reportreg ///
+		COLors(string) MColors(string) LColors(string) Msymbols(string) ///
+		savegraph(string) savedata(string) replace ///
+		nofastxtile randvar(varname numeric) randcut(real 1) randn(integer -1) ///
+		/* LEGACY OPTIONS */ nbins(integer 20) create_xq x_q(varname numeric) symbols(string) method(string) unique(string) ///
+		*]
+
+	set more off
+
+	* Create convenient weight local
+	if ("`weight'"!="") local wt [`weight'`exp']
+	
+	***** Begin legacy option compatibility code
+	
+	if (`nbins'!=20) {
+		if (`nquantiles'!=20) {
+			di as error "Cannot specify both nquantiles() and nbins(): both are the same option, nbins is supported only for backward compatibility."
+			exit
+		}
+		di as text "NOTE: legacy option nbins() has been renamed nquantiles(), and is supported only for backward compatibility."
+		local nquantiles=`nbins'
+	}
+	
+	if ("`create_xq'"!="") {
+		if ("`genxq'"!="") {
+			di as error "Cannot specify both genxq() and create_xq: both are the same option, create_xq is supported only for backward compatibility."
+			exit
+		}
+		di as text "NOTE: legacy option create_xq has been renamed genxq(), and is supported only for backward compatibility."
+		local genxq="q_"+word("`varlist'",-1)
+	}
+	
+	if ("`x_q'"!="") {
+		if ("`xq'"!="") {
+			di as error "Cannot specify both xq() and x_q(): both are the same option, x_q() is supported only for backward compatibility."
+			exit
+		}
+		di as text "NOTE: legacy option x_q() has been renamed xq(), and is supported only for backward compatibility."
+		local xq `x_q'
+	}
+	
+	if ("`symbols'"!="") {
+		if ("`msymbols'"!="") {
+			di as error "Cannot specify both msymbols() and symbols(): both are the same option, symbols() is supported only for backward compatibility."
+			exit
+		}
+		di as text "NOTE: legacy option symbols() has been renamed msymbols(), and is supported only for backward compatibility."
+		local msymbols `symbols'
+	}
+	
+	if ("`linetype'"=="noline") {
+		di as text "NOTE: legacy line type 'noline' has been renamed 'none', and is supported only for backward compatibility."
+		local linetype none
+	}
+	
+	if ("`method'"!="") {
+		di as text "NOTE: method() is no longer a recognized option, and will be ignored. binscatter now always uses the fastest method without a need for two instances"
+	}
+	
+	if ("`unique'"!="") {
+		di as text "NOTE: unique() is no longer a recognized option, and will be ignored. binscatter now considers the x-variable discrete if it has fewer unique values than nquantiles()"
+	}
+		
+	***** End legacy option capatibility code
+
+	*** Perform checks
+
+	* Set default linetype and check valid
+	if ("`linetype'"=="") local linetype lfit
+	else if !inlist("`linetype'","connect","lfit","qfit","none") {
+		di as error "linetype() must either be connect, lfit, qfit, or none"
+		exit
+	}
+	
+	* Check that nofastxtile isn't combined with fastxtile-only options
+	if "`fastxtile'"=="nofastxtile" & ("`randvar'"!="" | `randcut'!=1 | `randn'!=-1) {
+		di as error "Cannot combine randvar, randcut or randn with nofastxtile"
+		exit
+	}
+
+	* Misc checks
+	if ("`genxq'"!="" & ("`xq'"!="" | "`discrete'"!="")) | ("`xq'"!="" & "`discrete'"!="") {
+		di as error "Cannot specify more than one of genxq(), xq(), and discrete simultaneously."
+		exit
+	}
+	if ("`genxq'"!="") confirm new variable `genxq'
+	if ("`xq'"!="") {
+		capture assert `xq'==int(`xq') & `xq'>0
+		if _rc!=0 {
+			di as error "xq() must contain only positive integers."
+			exit
+		}
+		
+		if ("`controls'`absorb'"!="") di as text "warning: xq() is specified in combination with controls() or absorb(). note that binning takes places after residualization, so the xq variable should contain bins of the residuals."
+	}
+	if `nquantiles'!=20 & ("`xq'"!="" | "`discrete'"!="") {
+		di as error "Cannot specify nquantiles in combination with discrete or an xq variable."
+		exit
+	}
+	if "`reportreg'"!="" & !inlist("`linetype'","lfit","qfit") {
+		di as error "Cannot specify 'reportreg' when no fit line is being created."
+		exit
+	}
+	if "`replace'"=="" {
+		if `"`savegraph'"'!="" {
+			if regexm(`"`savegraph'"',"\.[a-zA-Z0-9]+$") confirm new file `"`savegraph'"'
+			else confirm new file `"`savegraph'.gph"'
+		}
+		if `"`savedata'"'!="" {
+			confirm new file `"`savedata'.csv"'
+			confirm new file `"`savedata'.do"'
+		}
+	}
+
+	* Mark sample (reflects the if/in conditions, and includes only nonmissing observations)
+	marksample touse
+	markout `touse' `by' `xq' `controls' `absorb', strok
+	qui count if `touse'
+	local samplesize=r(N)
+	local touse_first=_N-`samplesize'+1
+	local touse_last=_N
+
+	* Parse varlist into y-vars and x-var
+	local x_var=word("`varlist'",-1)
+	local y_vars=regexr("`varlist'"," `x_var'$","")
+	local ynum=wordcount("`y_vars'")
+
+	* Check number of unique byvals & create local storing byvals
+	if "`by'"!="" {
+		local byvarname `by'
+	
+		capture confirm numeric variable `by'
+		if _rc {
+			* by-variable is string => generate a numeric version
+			tempvar by
+			tempname bylabel
+			egen `by'=group(`byvarname'), lname(`bylabel')
+		}
+		
+		local bylabel `:value label `by'' /*catch value labels for numeric by-vars too*/ 
+		
+		tempname byvalmatrix
+		qui tab `by' if `touse', nofreq matrow(`byvalmatrix')
+		
+		local bynum=r(r)
+		forvalues i=1/`bynum' {
+			local byvals `byvals' `=`byvalmatrix'[`i',1]'
+		}
+	}
+	else local bynum=1
+	
+
+	****** Create residuals  ******
+	
+	if (`"`controls'`absorb'"'!="") quietly {
+	
+		* Parse absorb to define the type of regression to be used
+		if `"`absorb'"'!="" {
+			local regtype "areg"
+			local absorb "absorb(`absorb')"
+		}
+		else {
+			local regtype "reg"
+		}
+	
+		* Generate residuals
+		
+		local firstloop=1
+		foreach var of varlist `x_var' `y_vars' {
+			tempvar residvar
+			`regtype' `var' `controls' `wt' if `touse', `absorb'
+			predict `residvar' if e(sample), residuals
+			if ("`addmean'"!="noaddmean") {
+				summarize `var' `wt' if `touse', meanonly
+				replace `residvar'=`residvar'+r(mean)
+			}
+			
+			label variable `residvar' "`var'"
+			if `firstloop'==1 {
+				local x_r `residvar'
+				local firstloop=0
+			}
+			else local y_vars_r `y_vars_r' `residvar'
+		}
+		
+	}
+	else { 	/*absorb and controls both empty, no need for regression*/
+		local x_r `x_var'
+		local y_vars_r `y_vars'
+	}
+
+
+	****** Regressions for fit lines ******
+	
+	if ("`reportreg'"=="") local reg_verbosity "quietly"
+
+	if inlist("`linetype'","lfit","qfit") `reg_verbosity' {
+
+		* If doing a quadratic fit, generate a quadratic term in x
+		if "`linetype'"=="qfit" {
+			tempvar x_r2
+			gen `x_r2'=`x_r'^2
+		}
+		
+		* Create matrices to hold regression results
+		tempname e_b_temp
+		forvalues i=1/`ynum' {
+			tempname y`i'_coefs
+		}
+		
+		* LOOP over by-vars
+		local counter_by=1
+		if ("`by'"=="") local noby="noby"
+		foreach byval in `byvals' `noby' {
+		
+			* LOOP over rd intervals
+			tokenize  "`rd'"
+			local counter_rd=1	
+				
+			while ("`1'"!="" | `counter_rd'==1) {
+			
+				* display text headers
+				if "`reportreg'"!="" {
+					di "{txt}{hline}"
+					if ("`by'"!="") {
+						if ("`bylabel'"=="") di "-> `byvarname' = `byval'"
+						else {
+							di "-> `byvarname' = `: label `bylabel' `byval''"
+						}
+					}
+					if ("`rd'"!="") {
+						if (`counter_rd'==1) di "RD: `x_var'<=`1'"
+						else if ("`2'"!="") di "RD: `x_var'>`1' & `x_var'<=`2'"
+						else di "RD: `x_var'>`1'"
+					}
+				}
+				
+				* set conditions on reg
+				local conds `touse'
+				
+				if ("`by'"!="" ) local conds `conds' & `by'==`byval'
+				
+				if ("`rd'"!="") {
+					if (`counter_rd'==1) local conds `conds' & `x_r'<=`1'
+					else if ("`2'"!="") local conds `conds' & `x_r'>`1' & `x_r'<=`2'
+					else local conds `conds' & `x_r'>`1'
+				}
+
+				* LOOP over y-vars
+				local counter_depvar=1
+				foreach depvar of varlist `y_vars_r' {
+				
+					* display text headers
+					if (`ynum'>1) {
+						if ("`controls'`absorb'"!="") local depvar_name : var label `depvar'
+						else local depvar_name `depvar'
+						di as text "{bf:y_var = `depvar_name'}"
+					}
+					
+					* perform regression
+					if ("`reg_verbosity'"=="quietly") capture reg `depvar' `x_r2' `x_r' `wt' if `conds'
+					else capture noisily reg `depvar' `x_r2' `x_r' `wt' if `conds'
+					
+					* store results
+					if (_rc==0) matrix e_b_temp=e(b)
+					else if (_rc==2000) {
+						if ("`reg_verbosity'"=="quietly") di as error "no observations for one of the fit lines. add 'reportreg' for more info."
+						
+						if ("`linetype'"=="lfit") matrix e_b_temp=.,.
+						else /*("`linetype'"=="qfit")*/ matrix e_b_temp=.,.,.
+					}
+					else {
+						error _rc
+						exit _rc
+					}
+					
+					* relabel matrix row			
+					if ("`by'"!="") matrix roweq e_b_temp = "by`counter_by'"
+					if ("`rd'"!="") matrix rownames e_b_temp = "rd`counter_rd'"
+					else matrix rownames e_b_temp = "="
+					
+					* save to y_var matrix
+					if (`counter_by'==1 & `counter_rd'==1) matrix `y`counter_depvar'_coefs'=e_b_temp
+					else matrix `y`counter_depvar'_coefs'=`y`counter_depvar'_coefs' \ e_b_temp
+					
+					* increment depvar counter
+					local ++counter_depvar
+				}
+			
+				* increment rd counter
+				if (`counter_rd'!=1) mac shift
+				local ++counter_rd
+				
+			}
+			
+			* increment by counter
+			local ++counter_by
+			
+		}
+	
+		* relabel matrix column names
+		forvalues i=1/`ynum' {
+			if ("`linetype'"=="lfit") matrix colnames `y`i'_coefs' = "`x_var'" "_cons"
+			else if ("`linetype'"=="qfit") matrix colnames `y`i'_coefs' = "`x_var'^2" "`x_var'" "_cons"
+		}
+	
+	}
+
+	******* Define the bins *******
+	
+	* Specify and/or create the xq var, as necessary
+	if "`xq'"=="" {
+
+		if !(`touse_first'==1 & word("`:sortedby'",1)=="`x_r'") sort `touse' `x_r'
+	
+		if "`discrete'"=="" { /* xq() and discrete are not specified */
+			
+			* Check whether the number of unique values > nquantiles, or <= nquantiles
+			capture mata: characterize_unique_vals_sorted("`x_r'",`touse_first',`touse_last',`nquantiles')
+			
+			if (_rc==0) { /* number of unique values <= nquantiles, set to discrete */
+				local discrete discrete
+				if ("`genxq'"!="") di as text `"note: the x-variable has fewer unique values than the number of bins specified (`nquantiles').  It will therefore be treated as discrete, and genxq() will be ignored"'
+
+				local xq `x_r'
+				local nquantiles=r(r)
+				if ("`by'"=="") {
+					tempname xq_boundaries xq_values
+					matrix `xq_boundaries'=r(boundaries)		
+					matrix `xq_values'=r(values)
+				}
+			}
+			else if (_rc==134) { /* number of unique values > nquantiles, perform binning */
+				if ("`genxq'"!="") local xq `genxq'
+				else tempvar xq
+	
+				if ("`fastxtile'"!="nofastxtile") fastxtile `xq' = `x_r' `wt' in `touse_first'/`touse_last', nq(`nquantiles') randvar(`randvar') randcut(`randcut') randn(`randn')
+				else xtile `xq' = `x_r' `wt' in `touse_first'/`touse_last', nq(`nquantiles')
+
+				if ("`by'"=="") {
+					mata: characterize_unique_vals_sorted("`xq'",`touse_first',`touse_last',`nquantiles')
+
+					if (r(r)!=`nquantiles') {
+						di as text "warning: nquantiles(`nquantiles') was specified, but only `r(r)' were generated. see help file under nquantiles() for explanation."
+						local nquantiles=r(r)
+					}
+
+					tempname xq_boundaries xq_values
+					matrix `xq_boundaries'=r(boundaries)		
+					matrix `xq_values'=r(values)
+				}
+			}
+			else {
+				error _rc
+			}
+
+		}
+		
+		else { /* discrete is specified, xq() & genxq() are not */
+		
+			if ("`controls'`absorb'"!="") di as text "warning: discrete is specified in combination with controls() or absorb(). note that binning takes places after residualization, so the residualized x-variable may contain many more unique values."
+
+			capture mata: characterize_unique_vals_sorted("`x_r'",`touse_first',`touse_last',`=`samplesize'/2')
+		
+			if (_rc==0) {
+				local xq `x_r'
+				local nquantiles=r(r)
+				if ("`by'"=="") {
+					tempname xq_boundaries xq_values
+					matrix `xq_boundaries'=r(boundaries)		
+					matrix `xq_values'=r(values)
+				}
+			}
+			else if (_rc==134) {
+				di as error "discrete specified, but number of unique values is > (sample size/2)"
+				exit 134
+			}
+			else {
+				error _rc
+			}
+		}
+	}
+	else {
+
+		if !(`touse_first'==1 & word("`:sortedby'",1)=="`xq'") sort `touse' `xq'
+		
+		* set nquantiles & boundaries
+		mata: characterize_unique_vals_sorted("`xq'",`touse_first',`touse_last',`=`samplesize'/2')
+		
+		if (_rc==0) {
+			local nquantiles=r(r)
+			if ("`by'"=="") {
+				tempname xq_boundaries xq_values
+				matrix `xq_boundaries'=r(boundaries)		
+				matrix `xq_values'=r(values)
+			}
+		}
+		else if (_rc==134) {
+			di as error "discrete specified, but number of unique values is > (sample size/2)"
+			exit 134
+		}
+		else {
+			error _rc
+		}
+	}
+
+	********** Compute scatter points **********
+
+	if ("`by'"!="") {
+		sort `touse' `by' `xq'
+		tempname by_boundaries
+		mata: characterize_unique_vals_sorted("`by'",`touse_first',`touse_last',`bynum')
+		matrix `by_boundaries'=r(boundaries)
+	}
+
+	forvalues b=1/`bynum' {
+		if ("`by'"!="") {
+			mata: characterize_unique_vals_sorted("`xq'",`=`by_boundaries'[`b',1]',`=`by_boundaries'[`b',2]',`nquantiles')
+			tempname xq_boundaries xq_values
+			matrix `xq_boundaries'=r(boundaries)
+			matrix `xq_values'=r(values)
+		}
+		/* otherwise xq_boundaries and xq_values are defined above in the binning code block */
+
+		* Define x-means
+		tempname xbin_means
+		if ("`discrete'"=="discrete") {
+			matrix `xbin_means'=`xq_values'
+		}
+		else {
+			means_in_boundaries `x_r' `wt', bounds(`xq_boundaries') `medians'
+			matrix `xbin_means'=r(means)
+		}
+
+		* LOOP over y-vars to define y-means
+		local counter_depvar=0
+		foreach depvar of varlist `y_vars_r' {
+			local ++counter_depvar
+
+			means_in_boundaries `depvar' `wt', bounds(`xq_boundaries') `medians'
+
+			* store to matrix
+			if (`b'==1) {
+				tempname y`counter_depvar'_scatterpts
+				matrix `y`counter_depvar'_scatterpts' = `xbin_means',r(means)
+			}
+			else {
+				* make matrices conformable before right appending			
+				local rowdiff=rowsof(`y`counter_depvar'_scatterpts')-rowsof(`xbin_means')
+				if (`rowdiff'==0) matrix `y`counter_depvar'_scatterpts' = `y`counter_depvar'_scatterpts',`xbin_means',r(means)
+				else if (`rowdiff'>0)  matrix `y`counter_depvar'_scatterpts' = `y`counter_depvar'_scatterpts', ( (`xbin_means',r(means)) \ J(`rowdiff',2,.) )
+				else /*(`rowdiff'<0)*/ matrix `y`counter_depvar'_scatterpts' = ( `y`counter_depvar'_scatterpts' \ J(-`rowdiff',colsof(`y`counter_depvar'_scatterpts'),.) ) ,`xbin_means',r(means)
+			}
+		}
+	}
+
+	*********** Perform Graphing ***********
+
+	* If rd is specified, prepare xline parameters
+	if "`rd'"!="" {
+		foreach xval in "`rd'" {
+			local xlines `xlines' xline(`xval', lpattern(dash) lcolor(gs8))
+		}
+	}
+
+	* Fill colors if missing
+	if `"`colors'"'=="" local colors ///
+		navy maroon forest_green dkorange teal cranberry lavender ///
+		khaki sienna emidblue emerald brown erose gold bluishgray ///
+		/* lime magenta cyan pink blue */
+	if `"`mcolors'"'=="" {
+		if (`ynum'==1 & `bynum'==1 & "`linetype'"!="connect") local mcolors `: word 1 of `colors''
+		else local mcolors `colors'
+	}
+	if `"`lcolors'"'=="" {
+		if (`ynum'==1 & `bynum'==1 & "`linetype'"!="connect") local lcolors `: word 2 of `colors''
+		else local lcolors `colors'
+	}
+	local num_mcolor=wordcount(`"`mcolors'"')
+	local num_lcolor=wordcount(`"`lcolors'"')
+
+
+	* Prepare connect & msymbol options
+	if ("`linetype'"=="connect") local connect "c(l)"
+	if "`msymbols'"!="" {
+		local symbol_prefix "msymbol("
+		local symbol_suffix ")"
+	}
+	
+	*** Prepare scatters
+	
+	* c indexes which color is to be used
+	local c=0
+	
+	local counter_series=0
+	
+	* LOOP over by-vars
+	local counter_by=0
+	if ("`by'"=="") local noby="noby"
+	foreach byval in `byvals' `noby' {
+		local ++counter_by
+		
+		local xind=`counter_by'*2-1
+		local yind=`counter_by'*2
+
+		* LOOP over y-vars
+		local counter_depvar=0
+		foreach depvar of varlist `y_vars' {
+			local ++counter_depvar
+			local ++c
+			
+			* LOOP over rows (each row contains a coordinate pair)
+			local row=1
+			local xval=`y`counter_depvar'_scatterpts'[`row',`xind']
+			local yval=`y`counter_depvar'_scatterpts'[`row',`yind']
+			
+			if !missing(`xval',`yval') {
+				local ++counter_series
+				local scatters `scatters' (scatteri
+				if ("`savedata'"!="") {
+					if ("`by'"=="") local savedata_scatters `savedata_scatters' (scatter `depvar' `x_var'
+					else local savedata_scatters `savedata_scatters' (scatter `depvar'_by`counter_by' `x_var'_by`counter_by'
+				}
+			}
+			else {
+				* skip the rest of this loop iteration
+				continue
+			}
+			
+			while (`xval'!=. & `yval'!=.) {
+				local scatters `scatters' `yval' `xval'
+			
+				local ++row
+				local xval=`y`counter_depvar'_scatterpts'[`row',`xind']
+				local yval=`y`counter_depvar'_scatterpts'[`row',`yind']
+			}
+			
+			* Add options
+			local scatter_options `connect' mcolor(`: word `c' of `mcolors'') lcolor(`: word `c' of `lcolors'') `symbol_prefix'`: word `c' of `msymbols''`symbol_suffix'
+			local scatters `scatters', `scatter_options')
+			if ("`savedata'"!="") local savedata_scatters `savedata_scatters', `scatter_options')
+		
+
+			* Add legend
+			if "`by'"=="" {
+				if (`ynum'==1) local legend_labels off
+				else local legend_labels `legend_labels' lab(`counter_series' `depvar')
+			}
+			else {
+				if ("`bylabel'"=="") local byvalname=`byval'
+				else {
+					local byvalname `: label `bylabel' `byval''
+				}
+			
+				if (`ynum'==1) local legend_labels `legend_labels' lab(`counter_series' `byvarname'=`byvalname')
+				else local legend_labels `legend_labels' lab(`counter_series' `depvar': `byvarname'=`byvalname')
+			}
+			if ("`by'"!="" | `ynum'>1) local order `order' `counter_series'
+			
+		}
+		
+	}
+	
+	*** Fit lines
+		
+	if inlist(`"`linetype'"',"lfit","qfit") {
+	
+		* c indexes which color is to be used
+		local c=0
+		
+		local rdnum=wordcount("`rd'")+1
+		
+		tempname fitline_bounds
+		if ("`rd'"=="") matrix `fitline_bounds'=.,.
+		else matrix `fitline_bounds'=.,`=subinstr("`rd'"," ",",",.)',.
+
+		* LOOP over by-vars
+		local counter_by=0
+		if ("`by'"=="") local noby="noby"
+		foreach byval in `byvals' `noby' {
+			local ++counter_by
+			
+			** Set the column for the x-coords in the scatterpts matrix
+			local xind=`counter_by'*2-1
+			
+			* Set the row to start seeking from
+			*     note: each time we seek a coeff, it should be from row (rd_num)(counter_by-1)+counter_rd
+			local row0=( `rdnum' ) * (`counter_by' - 1)
+			
+			
+			* LOOP over y-vars
+			local counter_depvar=0
+			foreach depvar of varlist `y_vars_r' {
+				local ++counter_depvar
+				local ++c
+				
+				* Find lower and upper bounds for the fit line
+				matrix `fitline_bounds'[1,1]=`y`counter_depvar'_scatterpts'[1,`xind']
+				
+				local fitline_ub_rindex=`nquantiles'
+				local fitline_ub=.
+				while `fitline_ub'==. {
+					local fitline_ub=`y`counter_depvar'_scatterpts'[`fitline_ub_rindex',`xind']
+					local --fitline_ub_rindex
+				}
+				matrix `fitline_bounds'[1,`rdnum'+1]=`fitline_ub'
+		
+				* LOOP over rd intervals
+				forvalues counter_rd=1/`rdnum' {
+					
+					if (`"`linetype'"'=="lfit") {
+						local coef_quad=0
+						local coef_lin=`y`counter_depvar'_coefs'[`row0'+`counter_rd',1]
+						local coef_cons=`y`counter_depvar'_coefs'[`row0'+`counter_rd',2]
+					}
+					else if (`"`linetype'"'=="qfit") {
+						local coef_quad=`y`counter_depvar'_coefs'[`row0'+`counter_rd',1]
+						local coef_lin=`y`counter_depvar'_coefs'[`row0'+`counter_rd',2]
+						local coef_cons=`y`counter_depvar'_coefs'[`row0'+`counter_rd',3]
+					}
+					
+					if !missing(`coef_quad',`coef_lin',`coef_cons') {
+						local leftbound=`fitline_bounds'[1,`counter_rd']
+						local rightbound=`fitline_bounds'[1,`counter_rd'+1]
+					
+						local fits `fits' (function `coef_quad'*x^2+`coef_lin'*x+`coef_cons', range(`leftbound' `rightbound') lcolor(`: word `c' of `lcolors''))
+					}
+				}
+			}
+		}
+	}
+	
+	* Prepare y-axis title
+	if (`ynum'==1) local ytitle `y_vars'
+	else if (`ynum'==2) local ytitle : subinstr local y_vars " " " and "
+	else local ytitle : subinstr local y_vars " " "; ", all
+
+	* Display graph
+	local graphcmd twoway `scatters' `fits', graphregion(fcolor(white)) `xlines' xtitle(`x_var') ytitle(`ytitle') legend(`legend_labels' order(`order')) `options'
+	if ("`savedata'"!="") local savedata_graphcmd twoway `savedata_scatters' `fits', graphregion(fcolor(white)) `xlines' xtitle(`x_var') ytitle(`ytitle') legend(`legend_labels' order(`order')) `options'
+	`graphcmd'
+	
+	****** Save results ******
+	
+	* Save graph
+	if `"`savegraph'"'!="" {
+		* check file extension using a regular expression
+		if regexm(`"`savegraph'"',"\.[a-zA-Z0-9]+$") local graphextension=regexs(0)
+		
+		if inlist(`"`graphextension'"',".gph","") graph save `"`savegraph'"', `replace'
+		else graph export `"`savegraph'"', `replace'
+	}
+
+	* Save data
+	if ("`savedata'"!="") {
+	
+		*** Save a CSV containing the scatter points
+		tempname savedatafile
+		file open `savedatafile' using `"`savedata'.csv"', write text `replace'
+		
+		* LOOP over rows
+		forvalues row=0/`nquantiles' {
+		
+			*** Put the x-variable at the left
+			* LOOP over by-vals
+			forvalues counter_by=1/`bynum' {
+			
+				if (`row'==0) { /* write variable names */
+					if "`by'"!="" local bynlabel _by`counter_by'
+					file write `savedatafile' "`x_var'`bynlabel',"
+				}
+				else { /* write data values */
+					if (`row'<=`=rowsof(`y1_scatterpts')') file write `savedatafile' (`y1_scatterpts'[`row',`counter_by'*2-1]) ","
+					else file write `savedatafile' ".,"
+				}
+			}
+			
+			*** Now y-variables at the right
+			
+			* LOOP over y-vars
+			local counter_depvar=0
+			foreach depvar of varlist `y_vars' {
+				local ++counter_depvar
+
+				* LOOP over by-vals
+				forvalues counter_by=1/`bynum' {
+				
+				
+					if (`row'==0) { /* write variable names */
+						if "`by'"!="" local bynlabel _by`counter_by'
+						file write `savedatafile' "`depvar'`bynlabel'"
+					}
+					else { /* write data values */
+						if (`row'<=`=rowsof(`y`counter_depvar'_scatterpts')') file write `savedatafile' (`y`counter_depvar'_scatterpts'[`row',`counter_by'*2])
+						else file write `savedatafile' "."
+					}
+					
+					* unless this is the last variable in the dataset, add a comma
+					if !(`counter_depvar'==`ynum' & `counter_by'==`bynum') file write `savedatafile' ","
+					
+				} /* end by-val loop */
+				
+			} /* end y-var loop */
+			
+			file write `savedatafile' _n
+			
+		} /* end row loop */
+
+		file close `savedatafile'
+		di as text `"(file `savedata'.csv written containing saved data)"'
+		
+		
+		
+		*** Save a do-file with the commands to generate a nicely labeled dataset and re-create the binscatter graph
+		
+		file open `savedatafile' using `"`savedata'.do"', write text `replace'
+		
+		file write `savedatafile' `"insheet using `savedata'.csv"' _n _n
+		
+		if "`by'"!="" {
+			foreach var of varlist `x_var' `y_vars' {
+				local counter_by=0
+				foreach byval in `byvals' {
+					local ++counter_by
+					if ("`bylabel'"=="") local byvalname=`byval'
+					else {
+						local byvalname `: label `bylabel' `byval''
+					}
+					file write `savedatafile' `"label variable `var'_by`counter_by' "`var'; `byvarname'==`byvalname'""' _n
+				}
+			}
+			file write `savedatafile' _n
+		}
+		
+		file write `savedatafile' `"`savedata_graphcmd'"' _n
+		
+		file close `savedatafile'
+		di as text `"(file `savedata'.do written containing commands to process saved data)"'
+		
+	}
+
+	*** Return items
+	ereturn post, esample(`touse')
+	
+	ereturn scalar N = `samplesize'
+	
+	ereturn local graphcmd `"`graphcmd'"'
+	if inlist("`linetype'","lfit","qfit") {
+		forvalues yi=`ynum'(-1)1 {
+			ereturn matrix y`yi'_coefs=`y`yi'_coefs'
+		}
+	}
+	
+	if ("`rd'"!="") {
+		tempname rdintervals
+		matrix `rdintervals' = (. \ `=subinstr("`rd'"," ","\",.)' ) , ( `=subinstr("`rd'"," ","\",.)' \ .)
+
+		forvalues i=1/`=rowsof(`rdintervals')' {
+			local rdintervals_labels `rdintervals_labels' rd`i'
+		}
+		matrix rownames `rdintervals' = `rdintervals_labels'
+		matrix colnames `rdintervals' = gt lt_eq
+		ereturn matrix rdintervals=`rdintervals'
+	}
+	
+	if ("`by'"!="" & "`by'"=="`byvarname'") { /* if a numeric by-variable was specified */
+		forvalues i=1/`=rowsof(`byvalmatrix')' {
+			local byvalmatrix_labels `byvalmatrix_labels' by`i'
+		}
+		matrix rownames `byvalmatrix' = `byvalmatrix_labels'
+		matrix colnames `byvalmatrix' = `by'
+		ereturn matrix byvalues=`byvalmatrix'
+	}
+	
+end
+
+
+**********************************
+
+* Helper programs
+
+program define means_in_boundaries, rclass
+	version 12.1
+
+	syntax varname(numeric) [aweight fweight], BOUNDsmat(name) [MEDians]
+	
+	* Create convenient weight local
+	if ("`weight'"!="") local wt [`weight'`exp']
+	
+	local r=rowsof(`boundsmat')
+	matrix means=J(`r',1,.)
+	
+	if ("`medians'"!="medians") {
+		forvalues i=1/`r' {
+			sum `varlist' in `=`boundsmat'[`i',1]'/`=`boundsmat'[`i',2]' `wt', meanonly
+			matrix means[`i',1]=r(mean)
+		}
+	}
+	else {
+		forvalues i=1/`r' {
+			_pctile `varlist' in `=`boundsmat'[`i',1]'/`=`boundsmat'[`i',2]' `wt', percentiles(50)
+			matrix means[`i',1]=r(r1)
+		}
+	}
+	
+	return clear
+	return matrix means=means
+
+end
+
+*** copy of: version 1.21  8oct2013  Michael Stepner, [email protected]
+program define fastxtile, rclass
+	version 11
+
+	* Parse weights, if any
+	_parsewt "aweight fweight pweight" `0' 
+	local 0  "`s(newcmd)'" /* command minus weight statement */
+	local wt "`s(weight)'"  /* contains [weight=exp] or nothing */
+
+	* Extract parameters
+	syntax newvarname=/exp [if] [in] [,Nquantiles(integer 2) Cutpoints(varname numeric) ALTdef ///
+		CUTValues(numlist ascending) randvar(varname numeric) randcut(real 1) randn(integer -1)]
+
+	* Mark observations which will be placed in quantiles
+	marksample touse, novarlist
+	markout `touse' `exp'
+	qui count if `touse'
+	local popsize=r(N)
+
+	if "`cutpoints'"=="" & "`cutvalues'"=="" { /***** NQUANTILES *****/
+		if `"`wt'"'!="" & "`altdef'"!="" {
+			di as error "altdef option cannot be used with weights"
+			exit 198
+		}
+		
+		if `randn'!=-1 {
+			if `randcut'!=1 {
+				di as error "cannot specify both randcut() and randn()"
+				exit 198
+			}
+			else if `randn'<1 {
+				di as error "randn() must be a positive integer"
+				exit 198
+			}
+			else if `randn'>`popsize' {
+				di as text "randn() is larger than the population. using the full population."
+				local randvar=""
+			}
+			else {
+				local randcut=`randn'/`popsize'
+				
+				if "`randvar'"!="" {
+					qui sum `randvar', meanonly
+					if r(min)<0 | r(max)>1 {
+						di as error "with randn(), the randvar specified must be in [0,1] and ought to be uniformly distributed"
+						exit 198
+					}
+				}
+			}
+		}
+
+		* Check if need to gen a temporary uniform random var
+		if "`randvar'"=="" {
+			if (`randcut'<1 & `randcut'>0) { 
+				tempvar randvar
+				gen `randvar'=runiform()
+			}
+			* randcut sanity check
+			else if `randcut'!=1 {
+				di as error "if randcut() is specified without randvar(), a uniform r.v. will be generated and randcut() must be in (0,1)"
+				exit 198
+			}
+		}
+
+		* Mark observations used to calculate quantile boundaries
+		if ("`randvar'"!="") {
+			tempvar randsample
+			mark `randsample' `wt' if `touse' & `randvar'<=`randcut'
+		}
+		else {
+			local randsample `touse'
+		}
+
+		* Error checks
+		qui count if `randsample'
+		local samplesize=r(N)
+		if (`nquantiles' > r(N) + 1) {
+			if ("`randvar'"=="") di as error "nquantiles() must be less than or equal to the number of observations [`r(N)'] plus one"
+			else di as error "nquantiles() must be less than or equal to the number of sampled observations [`r(N)'] plus one"
+			exit 198
+		}
+		else if (`nquantiles' < 2) {
+			di as error "nquantiles() must be greater than or equal to 2"
+			exit 198
+		}
+
+		* Compute quantile boundaries
+		_pctile `exp' if `randsample' `wt', nq(`nquantiles') `altdef'
+
+		* Store quantile boundaries in list
+		forvalues i=1/`=`nquantiles'-1' {
+			local cutvallist `cutvallist' r(r`i')
+		}
+	}
+	else if "`cutpoints'"!="" { /***** CUTPOINTS *****/
+	
+		* Parameter checks
+		if "`cutvalues'"!="" {
+			di as error "cannot specify both cutpoints() and cutvalues()"
+			exit 198
+		}		
+		if "`wt'"!="" | "`randvar'"!="" | "`ALTdef'"!="" | `randcut'!=1 | `nquantiles'!=2 | `randn'!=-1 {
+			di as error "cutpoints() cannot be used with nquantiles(), altdef, randvar(), randcut(), randn() or weights"
+			exit 198
+		}
+
+		tempname cutvals
+		qui tab `cutpoints', matrow(`cutvals')
+		
+		if r(r)==0 {
+			di as error "cutpoints() all missing"
+			exit 2000
+		}
+		else {
+			local nquantiles = r(r) + 1
+			
+			forvalues i=1/`r(r)' {
+				local cutvallist `cutvallist' `cutvals'[`i',1]
+			}
+		}
+	}
+	else { /***** CUTVALUES *****/
+		if "`wt'"!="" | "`randvar'"!="" | "`ALTdef'"!="" | `randcut'!=1 | `nquantiles'!=2 | `randn'!=-1 {
+			di as error "cutvalues() cannot be used with nquantiles(), altdef, randvar(), randcut(), randn() or weights"
+			exit 198
+		}
+		
+		* parse numlist
+		numlist "`cutvalues'"
+		local cutvallist `"`r(numlist)'"'
+		local nquantiles=wordcount(`"`r(numlist)'"')+1
+	}
+
+	* Pick data type for quantile variable
+	if (`nquantiles'<=100) local qtype byte
+	else if (`nquantiles'<=32,740) local qtype int
+	else local qtype long
+
+	* Create quantile variable
+	local cutvalcommalist : subinstr local cutvallist " " ",", all
+	qui gen `qtype' `varlist'=1+irecode(`exp',`cutvalcommalist') if `touse'
+	label var `varlist' "`nquantiles' quantiles of `exp'"
+	
+	* Return values
+	if ("`samplesize'"!="") return scalar n = `samplesize'
+	else return scalar n = .
+	
+	return scalar N = `popsize'
+	
+	tokenize `"`cutvallist'"'
+	forvalues i=`=`nquantiles'-1'(-1)1 {
+		return scalar r`i' = ``i''
+	}
+
+end
+
+
+version 12.1
+set matastrict on
+
+mata:
+
+void characterize_unique_vals_sorted(string scalar var, real scalar first, real scalar last, real scalar maxuq) {
+	// Inputs: a numeric variable, a starting & ending obs #, and a maximum number of unique values
+	// Requires: the data to be sorted on the specified variable within the observation boundaries given
+	//				(no check is made that this requirement is satisfied)
+	// Returns: the number of unique values found
+	//			the unique values found
+	//			the observation boundaries of each unique value in the dataset
+	
+	
+	// initialize returned results
+	real scalar Nunique
+	Nunique=0
+
+	real matrix values
+	values=J(maxuq,1,.)
+	
+	real matrix boundaries
+	boundaries=J(maxuq,2,.)
+
+	// initialize computations
+	real scalar var_index
+	var_index=st_varindex(var)
+	
+	real scalar curvalue
+	real scalar prevvalue
+	
+	// perform computations
+	real scalar obs
+	for (obs=first; obs<=last; obs++) {
+		curvalue=_st_data(obs,var_index)
+		
+		if (curvalue!=prevvalue) {
+			Nunique++
+			if (Nunique<=maxuq) {
+				prevvalue=curvalue
+				values[Nunique,1]=curvalue
+				boundaries[Nunique,1]=obs
+				if (Nunique>1) boundaries[Nunique-1,2]=obs-1
+			}
+			else {
+				exit(error(134))
+			}
+			
+		}
+	}
+	boundaries[Nunique,2]=last
+	
+	// return results
+	stata("return clear")
+	
+	st_numscalar("r(r)",Nunique)
+	st_matrix("r(values)",values[1..Nunique,.])
+	st_matrix("r(boundaries)",boundaries[1..Nunique,.])
+
+}
+
+end

110/replication_package/replication/ado/plus/b/binscatter.sthlp

@@ -0,0 +1,332 @@
+{smcl}
+{* *! version 7.02  24nov2013}{...}
+{viewerjumpto "Syntax" "binscatter##syntax"}{...}
+{viewerjumpto "Description" "binscatter##description"}{...}
+{viewerjumpto "Options" "binscatter##options"}{...}
+{viewerjumpto "Examples" "binscatter##examples"}{...}
+{viewerjumpto "Saved results" "binscatter##saved_results"}{...}
+{viewerjumpto "Author" "binscatter##author"}{...}
+{viewerjumpto "Acknowledgements" "binscatter##acknowledgements"}{...}
+{title:Title}
+
+{p2colset 5 19 21 2}{...}
+{p2col :{hi:binscatter} {hline 2}}Binned scatterplots{p_end}
+{p2colreset}{...}
+
+
+{marker syntax}{title:Syntax}
+
+{p 8 15 2}
+{cmd:binscatter}
+{varlist} {ifin}
+{weight}
+[{cmd:,} {it:options}]
+
+
+{pstd}
+where {it:varlist} is 
+{p_end}
+		{it:y_1} [{it:y_2} [...]] {it:x}
+
+{synoptset 26 tabbed}{...}
+{synopthdr :options}
+{synoptline}
+{syntab :Main}
+{synopt :{opth by(varname)}}plot separate series for each group (see {help binscatter##by_notes:important notes below}){p_end}
+{synopt :{opt med:ians}}plot within-bin medians instead of means{p_end}
+
+{syntab :Bins}
+{synopt :{opth n:quantiles(#)}}number of equal-sized bins to be created; default is {bf:20}{p_end}
+{synopt :{opth gen:xq(varname)}}generate quantile variable containing the bins{p_end}
+{synopt :{opt discrete}}each x-value to be used as a separate bin{p_end}
+{synopt :{opth xq(varname)}}variable which already contains bins; bins therefore not recomputed{p_end}
+
+{syntab :Controls}
+{synopt :{opth control:s(varlist)}}residualize the x & y variables on controls before plotting{p_end}
+{synopt :{opth absorb(varname)}}residualize the x & y variables on a categorical variable{p_end}
+{synopt :{opt noa:ddmean}}do not add the mean of each variable back to its residuals{p_end}
+
+{syntab :Fit Line}
+{synopt :{opth line:type(binscatter##linetype:linetype)}}type of fit line; default is {bf:lfit}, may also be {bf:qfit}, {bf:connect}, or {bf:none}{p_end}
+{synopt :{opth rd(numlist)}}create regression discontinuity at x-values{p_end}
+{synopt :{opt reportreg}}display the regressions used to estimate the fit lines{p_end}
+
+{syntab :Graph Style}
+{synopt :{cmdab:col:ors(}{it:{help colorstyle}list}{cmd:)}}ordered list of colors{p_end}
+{synopt :{cmdab:mc:olors(}{it:{help colorstyle}list}{cmd:)}}overriding ordered list of colors for the markers{p_end}
+{synopt :{cmdab:lc:olors(}{it:{help colorstyle}list}{cmd:)}}overriding ordered list of colors for the lines{p_end}
+{synopt :{cmdab:m:symbols(}{it:{help symbolstyle}list}{cmd:)}}ordered list of symbols{p_end}
+{synopt :{it:{help twoway_options}}}{help title options:titles}, {help legend option:legends}, {help axis options:axes}, added {help added line options:lines} and {help added text options:text},
+	{help region options:regions}, {help name option:name}, {help aspect option:aspect ratio}, etc.{p_end}
+
+{syntab :Save Output}
+{synopt :{opt savegraph(filename)}}save graph to file; format automatically detected from extension [ex: .gph .jpg .png]{p_end}
+{synopt :{opt savedata(filename)}}save {it:filename}.csv containg scatterpoint data, and {it:filename}.do to process data into graph{p_end}
+{synopt :{opt replace}}overwrite existing files{p_end}
+
+{syntab :fastxtile options}
+{synopt :{opt nofastxtile}}use xtile instead of fastxtile{p_end}
+{synopt :{opth randvar(varname)}}use {it:varname} to sample observations when computing quantile boundaries{p_end}
+{synopt :{opt randcut(#)}}upper bound on {cmd:randvar()} used to cut the sample; default is {cmd:randcut(1)}{p_end}
+{synopt :{opt randn(#)}}number of observations to sample when computing quantile boundaries{p_end}
+{synoptline}
+{p 4 6 2}
+{opt aweight}s and {opt fweight}s are allowed;
+see {help weight}.
+{p_end}
+
+
+{marker description}{...}
+{title:Description}
+
+{pstd}
+{opt binscatter} generates binned scatterplots, and is optimized for speed in large datasets.
+
+{pstd}
+Binned scatterplots provide a non-parametric way of visualizing the relationship between two variables.
+With a large number of observations, a scatterplot that plots every data point would become too crowded
+to interpret visually.  {cmd:binscatter} groups the x-axis variable into equal-sized bins, computes the
+mean of the x-axis and y-axis variables within each bin, then creates a scatterplot of these data points.
+The result is a non-parametric visualization of the conditional expectation function.
+
+{pstd}
+{opt binscatter} provides built-in options to control for covariates before plotting the relationship
+(see {help binscatter##controls:Controls}).  Additionally, {cmd:binscatter} will plot fit lines based
+on the underlying data, and can automatically handle regression discontinuities (see {help binscatter##fit_line:Fit Line}).
+
+
+{marker options}{...}
+{title:Options}
+
+{dlgtab:Main}
+
+{marker by_notes}{...}
+{phang}{opth by(varname)} plots a separate series for each by-value.  Both numeric and string by-variables
+are supported, but numeric by-variables will have faster run times.
+
+{pmore}Users should be aware of the two ways in which {cmd:binscatter} does not condition on by-values:
+
+{phang3}1) When combined with {opt controls()} or {opt absorb()}, the program residualizes using the restricted model in which each covariate
+has the same coefficient in each by-value sample.  It does not run separate regressions for each by-value.  If you wish to control for 
+covariates using a different model, you can residualize your x- and y-variables beforehand using your desired model then run {cmd:binscatter}
+on the residuals you constructed.
+
+{phang3}2) When not combined with {opt discrete} or {opt xq()}, the program constructs a single set of bins
+using the unconditional quantiles of the x-variable.  It does not bin the x-variable separately for each by-value.
+If you wish to use a different binning procedure (such as constructing equal-sized bins separately for each
+by-value), you can construct a variable containing your desired bins beforehand, then run {cmd:binscatter} with {opt xq()}.
+
+{phang}{opt med:ians} creates the binned scatterplot using the median x- and y-value within each bin, rather than the mean.
+This option only affects the scatter points; it does not, for instance, cause {opt linetype(lfit)}
+to use quantile regression instead of OLS when drawing a fit line.
+
+{dlgtab:Bins}
+
+{phang}{opth n:quantiles(#)} specifies the number of equal-sized bins to be created.  This is equivalent to the number of
+points in each series.  The default is {bf:20}. If the x-variable has fewer
+unique values than the number of bins specified, then {opt discrete} will be automatically invoked, and no
+binning will be performed.
+This option cannot be combined with {opt discrete} or {opt xq()}.
+
+{pmore}
+Binning is performed after residualization when combined with {opt controls()} or {opt absorb()}.
+Note that the binning procedure is equivalent to running xtile, which in certain cases will generate
+fewer quantile categories than specified. (e.g. {stata sysuse auto}; {stata xtile temp=mpg, nq(20)}; {stata tab temp})
+  
+{phang}{opth gen:xq(varname)} creates a categorical variable containing the computed bins.
+This option cannot be combined with {opt discrete} or {opt xq()}.
+
+{phang}{opt discrete} specifies that the x-variable is discrete and that each x-value is to be treated as
+a separate bin. {cmd:binscatter} will therefore plot the mean y-value associated with each x-value.
+This option cannot be combined with {opt nquantiles()}, {opt genxq()} or {opt xq()}.
+
+{pmore}
+In most cases, {opt discrete} should not be combined with {opt controls()} or {opt absorb()}, since residualization occurs before binning,
+and in general the residual of a discrete variable will not be discrete.
+
+{phang}{opth xq(varname)} specifies a categorical variable that contains the bins to be used, instead of {cmd:binscatter} generating them.
+This option is typically used to avoid recomputing the bins needlessly when {cmd:binscatter} is being run repeatedly on the same sample
+and with the same x-variable.
+It may be convenient to use {opt genxq(binvar)} in the first iteration, and specify {opt xq(binvar)} in subsequent iterations.
+Computing quantiles is computationally intensive in large datasets, so avoiding repetition can reduce run times considerably.
+This option cannot be combined with {opt nquantiles()}, {opt genxq()} or {opt discrete}.
+
+{pmore}
+Care should be taken when combining {opt xq()} with {opt controls()} or {opt absorb()}.  Binning takes place after residualization,
+so if the sample changes or the control variables change, the bins ought to be recomputed as well.
+
+{marker controls}{...}
+{dlgtab:Controls}
+
+{phang}{opth control:s(varlist)} residualizes the x-variable and y-variables on the specified controls before binning and plotting.
+To do so, {cmd:binscatter} runs a regression of each variable on the controls, generates the residuals, and adds the sample mean of
+each variable back to its residuals.
+
+{phang}{opth absorb(varname)} absorbs fixed effects in the categorical variable from the x-variable and y-variables before binning and plotting,
+To do so, {cmd:binscatter} runs an {helpb areg} of each variable with {it:absorb(varname)} and any {opt controls()} specified.  It then generates the
+residuals and adds the sample mean of each variable back to its residuals.
+
+{phang}{opt noa:ddmean} prevents the sample mean of each variable from being added back to its residuals, when combined with {opt controls()} or {opt absorb()}.
+
+{marker fit_line}{...}
+{dlgtab:Fit Line}
+
+{marker linetype}{...}
+{phang}{opth line:type(binscatter##linetype:linetype)} specifies the type of line plotted on each series.
+The default is {bf:lfit}, which plots a linear fit line.  Other options are {bf:qfit} for a quadratic fit line,
+{bf:connect} for connected points, and {bf:none} for no line.
+
+{pmore}Linear or quadratic fit lines are estimated using the underlying data, not the binned scatter points. When combined with
+{opt controls()} or {opt absorb()}, the fit line is estimated after the variables have been residualized.
+
+{phang}{opth rd(numlist)} draws a dashed vertical line at the specified x-values and generates regression discontinuities when combined with {opt line(lfit|qfit)}.
+Separate fit lines will be estimated below and above each discontinuity.  These estimations are performed using the underlying data, not the binned scatter points.
+
+{pmore}The regression discontinuities do not affect the binned scatter points in any way.
+Specifically, a bin may contain a discontinuity within its range, and therefore include data from both sides of the discontinuity.
+
+{phang}{opt reportreg} displays the regressions used to estimate the fit lines in the results window.
+
+{dlgtab:Graph Style}
+
+{phang}{cmdab:col:ors(}{it:{help colorstyle}list}{cmd:)} specifies an ordered list of colors for each series
+
+{phang}{cmdab:mc:olors(}{it:{help colorstyle}list}{cmd:)} specifies an ordered list of colors for the markers of each series, which overrides any list provided in {opt colors()}
+
+{phang}{cmdab:lc:olors(}{it:{help colorstyle}list}{cmd:)} specifies an ordered list of colors for the line of each series, which overrides any list provided in {opt colors()}
+
+{phang}{cmdab:m:symbols(}{it:{help symbolstyle}list}{cmd:)} specifies an ordered list of symbols for each series
+
+{phang}{it:{help twoway_options}}:
+
+{pmore}Any unrecognized options added to {cmd:binscatter} are appended to the end of the twoway command which generates the
+binned scatter plot.
+
+{pmore}These can be used to control the graph {help title options:titles},
+{help legend option:legends}, {help axis options:axes}, added {help added line options:lines} and {help added text options:text},
+{help region options:regions}, {help name option:name}, {help aspect option:aspect ratio}, etc.
+
+{dlgtab:Save Output}
+
+{phang}{opt savegraph(filename)} saves the graph to a file.  The format is automatically detected from the extension specified [ex: {bf:.gph .jpg .png}],
+and either {cmd:graph save} or {cmd:graph export} is run.  If no file extension is specified {bf:.gph} is assumed.
+
+{phang}{opt savedata(filename)} saves {it:filename}{bf:.csv} containing the binned scatterpoint data, and {it:filename}{bf:.do} which
+loads the scatterpoint data, labels the variables, and plots the binscatter graph.
+
+{pmore}Note that the saved result {bf:e(cmd)} provides an alternative way of capturing the binscatter graph and editing it.
+
+{phang}{opt replace} specifies that files be overwritten if they alredy exist
+
+{dlgtab:fastxtile options}
+
+{phang}{opt nofastxtile} forces the use of {cmd:xtile} instead of {cmd:fastxtile} to compute bins.  There is no situation where this should
+be necessary or useful.  The {cmd:fastxile} program generates identical results to {cmd:xtile}, but runs faster on large datasets, and has
+additional options for random sampling which may be useful to increase speed.
+
+{pmore}{cmd:fastxtile} is built into the {cmd:binscatter} code, but may also be installed
+separately from SSC ({stata ssc install fastxtile:click here to install}) for use outside of {cmd:binscatter}.
+
+{phang}{opth randvar(varname)} requests that {it:varname} be used to select a
+sample of observations when computing the quantile boundaries.  Sampling increases
+the speed of the binning procedure, but generates bins which are only approximately equal-sized
+due to sampling error.  It is possible to omit this option and still perform random sampling from U[0,1]
+as described below in {opt randcut()} and {opt randn()}.
+
+{phang}{opt randcut(#)} specifies the upper bound on the variable contained
+in {opt randvar(varname)}. Quantile boundaries are approximated using observations for which
+{opt randvar()} <= #.  If no variable is specified in {opt randvar()},
+a standard uniform random variable is generated. The default is {cmd:randcut(1)}.
+This option cannot be combined with {opt randn()}.
+
+{phang}{opt randn(#)} specifies an approximate number of observations to sample when
+computing the quantile boundaries. Quantile boundaries are approximated using observations
+for which a uniform random variable is <= #/N. The exact number of observations
+sampled may therefore differ from #, but it equals # in expectation. When this option is
+combined with {opth randvar(varname)}, {it:varname} ought to be distributed U[0,1].
+Otherwise, a standard uniform random variable is generated. This option cannot be combined
+with {opt randcut()}.
+
+
+{marker examples}{...}
+{title:Examples}
+
+{pstd}Load the 1988 extract of the National Longitudinal Survey of Young Women and Mature Women.{p_end}
+{phang2}. {stata sysuse nlsw88}{p_end}
+{phang2}. {stata keep if inrange(age,35,44) & inrange(race,1,2)}{p_end}
+
+{pstd}What is the relationship between job tenure and wages?{p_end}
+{phang2}. {stata scatter wage tenure}{p_end}
+{phang2}. {stata binscatter wage tenure}{p_end}
+
+{pstd}The scatter was too crowded to be easily interpetable. The binscatter is cleaner, but a linear fit looks unreasonable.{p_end}
+
+{pstd}Try a quadratic fit.{p_end}
+{phang2}. {stata binscatter wage tenure, line(qfit)}{p_end}
+
+{pstd}We can also plot a linear regression discontinuity.{p_end}
+{phang2}. {stata binscatter wage tenure, rd(2.5)}{p_end}
+
+{pstd} What is the relationship between age and wages?{p_end}
+{phang2}. {stata scatter wage age}{p_end}
+{phang2}. {stata binscatter wage age}{p_end}
+
+{pstd} The binscatter is again much easier to interpret. (Note that {cmd:binscatter} automatically
+used each age as a discrete bin, since there are fewer than 20 unique values.){p_end}
+
+{pstd}How does the relationship vary by race?{p_end}
+{phang2}. {stata binscatter wage age, by(race)}{p_end}
+
+{pstd} The relationship between age and wages is very different for whites and blacks. But what if we control for occupation?{p_end}
+{phang2}. {stata binscatter wage age, by(race) absorb(occupation)}{p_end}
+
+{pstd} A very different picture emerges.  Let's label this graph nicely.{p_end}
+{phang2}. {stata binscatter wage age, by(race) absorb(occupation) msymbols(O T) xtitle(Age) ytitle(Hourly Wage) legend(lab(1 White) lab(2 Black))}{p_end}
+
+
+{marker saved_results}{...}
+{title:Saved Results}
+
+{pstd}
+{cmd:binscatter} saves the following in {cmd:e()}:
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Scalars}{p_end}
+{synopt:{cmd:e(N)}}number of observations{p_end}
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Macros}{p_end}
+{synopt:{cmd:e(graphcmd)}}twoway command used to generate graph, which does not depend on loaded data{p_end}
+{p 30 30 2}Note: it is often important to reference this result using `"`{bf:e(graphcmd)}'"'
+rather than {bf:e(graphcmd)} in order to avoid truncation due to Stata's character limit for strings.
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Matrices}{p_end}
+{synopt:{cmd:e(byvalues)}}ordered list of by-values {it:(if numeric by-variable specified)}{p_end}
+{synopt:{cmd:e(rdintervals)}}ordered list of rd intervals {it:(if rd specified)}{p_end}
+{synopt:{cmd:e(y#_coefs)}}fit line coefficients for #th y-variable {it:(if lfit or qfit specified)}{p_end}
+
+{synoptset 20 tabbed}{...}
+{p2col 5 20 24 2: Functions}{p_end}
+{synopt:{cmd:e(sample)}}marks sample{p_end}
+{p2colreset}{...}
+
+
+{marker author}{...}
+{title:Author}
+
+{pstd}Michael Stepner{p_end}
+{pstd}[email protected]{p_end}
+
+
+{marker acknowledgements}{...}
+{title:Acknowledgements}
+
+{pstd}The present version of {cmd:binscatter} is based on a program first written by Jessica Laird.
+
+{pstd}This program was developed under the guidance and direction of Raj Chetty and John
+Friedman.  Laszlo Sandor provided suggestions which improved the program considerably, and offered abundant help
+testing it.
+
+{pstd}Thank you also to the users of early versions of the program who devoted time to reporting
+the bugs that they encountered.

110/replication_package/replication/ado/plus/b/binslogit.ado

@@ -0,0 +1,2394 @@
+*! version 1.2 09-Oct-2022 
+
+capture program drop binslogit
+program define binslogit, eclass
+     version 13
+	 
+	 syntax varlist(min=2 numeric fv ts) [if] [in] [fw pw] [, deriv(integer 0) at(string asis) nolink ///
+	        logitopt(string asis) ///
+	        dots(string) dotsgrid(string) dotsplotopt(string asis) ///
+			line(string) linegrid(integer 20) lineplotopt(string asis) ///
+			ci(string) cigrid(string) ciplotopt(string asis) /// 
+			cb(string) cbgrid(integer 20) cbplotopt(string asis) ///
+			polyreg(string) polyreggrid(integer 20) polyregcigrid(integer 0) polyregplotopt(string asis) ///
+			by(varname) bycolors(string asis) bysymbols(string asis) bylpatterns(string asis) ///
+			nbins(string) binspos(string) binsmethod(string) nbinsrot(string) ///
+			pselect(numlist integer >=0) sselect(numlist integer >=0) ///
+			samebinsby randcut(numlist max=1 >=0 <=1) ///
+			nsims(integer 500) simsgrid(integer 20) simsseed(numlist integer max=1 >=0) ///
+			dfcheck(numlist integer max=2 >=0) masspoints(string) usegtools(string) ///
+			vce(passthru) level(real 95) asyvar(string) ///
+			noplot savedata(string asis) replace ///
+			plotxrange(numlist asc max=2) plotyrange(numlist asc max=2) *]
+	 
+	 *********************************************
+	 * Regularization constant (for checking only)
+	 local qrot=2
+	 
+	 **************************************
+	 * Create weight local
+     if ("`weight'"!="") {
+	    local wt [`weight'`exp']
+		local wtype=substr("`weight'",1,1)
+	 }
+	 
+	 **********************
+	 ** Extract options ***
+	 **********************
+	 * report the results for the cond. mean model?
+	 if ("`link'"!="") local transform "F"
+	 else              local transform "T"
+	 
+	 * default vce, clustered?
+	 if ("`vce'"=="") local vce "vce(robust)"
+	 local vcetemp: subinstr local vce "vce(" "", all
+     local vcetemp: subinstr local vcetemp ")" "", all
+	 tokenize "`vcetemp'"
+	 if ("`1'"=="cl"|"`1'"=="clu"|"`1'"=="clus"|"`1'"=="clust"| /// 
+		 "`1'"=="cluste"|"`1'"=="cluster") {
+		local clusterON "T"           /* Mark cluster is specified */
+		local clustervar `2'
+	 }
+	 if ("`vce'"=="vce(oim)"|"`vce'"=="vce(opg)") local vce_select "vce(ols)"
+	 else                                         local vce_select "`vce'"
+	 
+	 if ("`asyvar'"=="") local asyvar "off"
+	 if ("`binsmethod'"=="rot") local binsmethod "ROT"
+	 if ("`binsmethod'"=="dpi") local binsmethod "DPI"
+	 if ("`binsmethod'"=="")    local binsmethod "DPI"
+	 if ("`binspos'"=="es") local binspos "ES"
+	 if ("`binspos'"=="qs") local binspos "QS"
+	 if ("`binspos'"=="")   local binspos "QS"
+
+	 
+	 * analyze options related to degrees *************
+	 if ("`dots'"!="T"&"`dots'"!="F"&"`dots'"!="") {
+	    numlist "`dots'", integer max(2) range(>=0)
+		local dots=r(numlist)
+	 }
+	 if ("`line'"!="T"&"`line'"!="F"&"`line'"!="") {
+	    numlist "`line'", integer max(2) range(>=0)
+		local line=r(numlist)
+	 }
+	 if ("`ci'"!="T"&"`ci'"!="F"&"`ci'"!="") {
+	    numlist "`ci'", integer max(2) range(>=0)
+		local ci=r(numlist)
+	 }
+	 if ("`cb'"!="T"&"`cb'"!="F"&"`cb'"!="") {
+	    numlist "`cb'", integer max(2) range(>=0)
+		local cb=r(numlist)
+	 }
+	 
+	 
+	 if ("`dots'"=="F") {                   /* shut down dots */
+	    local dots ""
+	    local dotsgrid 0
+	 }
+	 if ("`line'"=="F") local line ""
+	 if ("`ci'"=="F")   local ci ""
+	 if ("`cb'"=="F")   local cb ""
+	 
+	 
+	 ***************************************************************
+	 * 4 cases: select J, select p, user specified both, and error
+	 local selection ""
+	 
+	 * analyze nbins
+	 if ("`nbins'"=="T") local nbins=0
+	 local len_nbins=0
+	 if ("`nbins'"!=""&"`nbins'"!="F") {
+	    numlist "`nbins'", integer sort
+	    local nbins=r(numlist)
+	    local len_nbins: word count `nbins'
+	 }
+	 
+	 * analyze numlist in pselect and sselect
+	 local len_p=0
+	 local len_s=0
+	 
+	 if ("`pselect'"!="") {
+	    numlist "`pselect'", integer range(>=`deriv') sort
+		local plist=r(numlist)
+	 }
+	 
+	 if ("`sselect'"!="") {
+	    numlist "`sselect'", integer range(>=0) sort
+		local slist=r(numlist)
+	 }
+	 	 	 
+	 local len_p: word count `plist'
+	 local len_s: word count `slist'
+	 
+	 if (`len_p'==1&`len_s'==0) {
+	    local slist `plist'
+		local len_s=1
+	 }
+	 if (`len_p'==0&`len_s'==1) {
+	    local plist `slist'
+		local len_p=1
+     }
+	 
+	 if ("`binspos'"!="ES"&"`binspos'"!="QS") {
+		if ("`nbins'"!=""|"`pselect'"!=""|"`sselect'"!="") {
+		   di as error "nbins(), pselect() or sselect() incorrectly specified."
+		   exit
+		}
+	 }
+
+	 
+	 * 1st case: select J
+	 if (("`nbins'"=="0"|`len_nbins'>1|"`nbins'"=="")&("`binspos'"=="ES"|"`binspos'"=="QS")) local selection "J"
+	 if ("`selection'"=="J") {
+	 	if (`len_p'>1|`len_s'>1) {
+		   if ("`nbins'"=="") {
+		      di as error "nbins() must be specified for degree/smoothness selection."
+			  exit
+		   }
+		   else {
+			  di as error "Only one p and one s are allowed to select # of bins."
+			  exit
+		   }
+		}
+	 	if ("`plist'"=="") local plist=`deriv'
+		if ("`slist'"=="") local slist=`plist'
+		if ("`dots'"!=""&"`dots'"!="T"&"`dots'"!="F") {                         /* respect user-specified dots */
+		   local plist: word 1 of `dots'
+		   local slist: word 2 of `dots'
+		   if ("`slist'"=="") local slist `plist'
+		}
+		if ("`dots'"==""|"`dots'"=="T") local dots `plist' `slist'              /* selection is based on dots */
+		if ("`line'"=="T") local line `plist' `slist'
+		if ("`ci'"=="T") local ci `=`plist'+1' `=`slist'+1'
+		if ("`cb'"=="T") local cb `=`plist'+1' `=`slist'+1'
+		local len_p=1
+	    local len_s=1
+     }                                                                          /* e.g., binsreg y x, nbins(a b) or nbins(T) or pselect(a) nbins(T) */
+	 
+	 
+	 * 2nd case: select P (at least for one object) 
+	 if ("`selection'"!="J" & ("`dots'"==""|"`dots'"=="T"|"`line'"=="T"|"`ci'"=="T"|"`cb'"=="T")) {
+	    local pselectOK "T"                                                     /* p selection CAN be turned on as long as one of the four is T */     
+	 }
+
+	 if ("`pselectOK'"=="T" & `len_nbins'==1 & (`len_p'>1|`len_s'>1)) {
+	    local selection "P"
+	 }                                                                         /* e.g., binsreg y x, pselect(a b) or pselect() dots(T) */
+	 
+	 * 3rd case: completely user-specified J and p
+	 if ((`len_p'<=1&`len_s'<=1) & "`selection'"!="J") {
+		local selection "NA"
+		if ("`dots'"==""|"`dots'"=="T") {
+		   if (`len_p'==1&`len_s'==1) local dots `plist' `slist'
+	       else                       local dots `deriv' `deriv'                            /* e.g., binsreg y x or , dots(0 0) nbins(20) */
+		}
+		tokenize `dots'
+		if ("`2'"=="") local 2 `1'
+	    if ("`line'"=="T") {
+		   if (`len_p'==1&`len_s'==1) local line `plist' `slist'
+	       else                       local line `dots'                            
+		}
+	    if ("`ci'"=="T") {
+		   if (`len_p'==1&`len_s'==1) local ci `=`plist'+1' `=`slist'+1'
+	       else                       local ci `=`1'+1' `=`2'+1'                            
+		}
+	    if ("`cb'"=="T") {
+		   if (`len_p'==1&`len_s'==1) local cb `=`plist'+1' `=`slist'+1'
+	       else                       local cb `=`1'+1' `=`2'+1'                            
+		}
+	 }
+	 	 
+	 * exclude all other cases
+	 if ("`selection'"=="") {
+	    di as error "Degree, smoothness, or # of bins are not correctly specified."
+        exit
+	 }
+
+	 
+	 ****** Now, extract from dots, line, etc. ************ 
+	 * dots
+	 tokenize `dots'
+	 local dots_p "`1'"
+	 local dots_s "`2'"
+	 if ("`dots_p'"==""|"`dots_p'"=="T") local dots_p=.
+	 if ("`dots_s'"=="") local dots_s `dots_p'
+	 
+	 if ("`dotsgrid'"=="") local dotsgrid "mean"
+	 local dotsngrid_mean=0
+	 if (strpos("`dotsgrid'","mean")!=0) {
+	    local dotsngrid_mean=1
+		local dotsgrid: subinstr local dotsgrid "mean" "", all
+	 }
+	 if (wordcount("`dotsgrid'")==0) local dotsngrid=0
+	 else {
+	    confirm integer n `dotsgrid'
+	    local dotsngrid `dotsgrid'
+     }
+	 local dotsntot=`dotsngrid_mean'+`dotsngrid'
+	 
+	 
+	 * line
+	 tokenize `line'
+	 local line_p "`1'"
+	 local line_s "`2'"
+	 local linengrid `linegrid'
+	 if ("`line'"=="") local linengrid=0
+	 if ("`line_p'"==""|"`line_p'"=="T") local line_p=.
+	 if ("`line_s'"=="") local line_s `line_p'
+	 	 
+	 * ci
+	 if ("`cigrid'"=="") local cigrid "mean"
+	 local cingrid_mean=0
+	 if (strpos("`cigrid'","mean")!=0) {
+	    local cingrid_mean=1
+		local cigrid: subinstr local cigrid "mean" "", all
+	 }
+	 if (wordcount("`cigrid'")==0) local cingrid=0
+	 else {
+	    confirm integer n `cigrid'
+	    local cingrid `cigrid'
+	 }
+	 local cintot=`cingrid_mean'+`cingrid'
+	 
+	 tokenize `ci'
+	 local ci_p "`1'"
+	 local ci_s "`2'"
+	 if ("`ci'"=="") local cintot=0
+	 if ("`ci_p'"==""|"`ci_p'"=="T") local ci_p=.
+	 if ("`ci_s'"=="") local ci_s `ci_p'
+	 
+	 * cb
+	 tokenize `cb'
+	 local cb_p "`1'"
+	 local cb_s "`2'"
+	 local cbngrid `cbgrid'
+	 if ("`cb'"=="") local cbngrid=0
+	 if ("`cb_p'"==""|"`cb_p'"=="T") local cb_p=.
+	 if ("`cb_s'"=="") local cb_s `cb_p'
+	 
+	 * Add warnings about degrees for estimation and inference
+	 if ("`selection'"=="J") {
+	    if ("`ci_p'"!=".") {
+		   if (`ci_p'<=`dots_p') {
+		      local ci_p=`dots_p'+1
+			  local ci_s=`ci_p'
+			  di as text "Warning: Degree for ci() has been changed. It must be greater than the degree for dots()."
+		   }
+		}
+	    if ("`cb_p'"!=".") {
+		   if (`cb_p'<=`dots_p') {
+		      local cb_p=`dots_p'+1
+			  local cb_s=`cb_p'
+			  di as text "Warning: Degree for cb() has been changed. It must be greater than the degree for dots()."
+		   }
+		}
+	 }
+	 if ("`selection'"=="NA") {
+	    if ("`ci'"!=""|"`cb'"!="") {
+		   di as text "Warning: Confidence intervals/bands are valid when nbins() is much larger than IMSE-optimal choice."
+	    }
+	 }
+	 * if selection==P, compare ci_p/cb_p with P_opt later
+	 
+	 * poly fit
+	 local polyregngrid `polyreggrid'
+	 local polyregcingrid `polyregcigrid'
+	 if ("`polyreg'"!="") {
+	    confirm integer n `polyreg'
+	 }
+	 else {
+	    local polyregngrid=0
+	 }
+	 
+	 * range of x axis and y axis?
+	 tokenize `plotxrange'
+     local min_xr "`1'"
+	 local max_xr "`2'"
+	 tokenize `plotyrange'
+     local min_yr "`1'"
+	 local max_yr "`2'"
+
+	 
+	 * Simuls
+	 local simsngrid=`simsgrid'
+	 	 
+	 * Record if nbins specified by users, set default
+	 local nbins_full `nbins'              /* local save common nbins */
+	 if ("`selection'"=="NA")   local binselectmethod "User-specified"
+     else {
+	    if ("`binsmethod'"=="DPI")  local binselectmethod "IMSE-optimal plug-in choice"
+        if ("`binsmethod'"=="ROT")  local binselectmethod "IMSE-optimal rule-of-thumb choice"
+		if ("`selection'"=="J") local binselectmethod "`binselectmethod' (select # of bins)"
+		if ("`selection'"=="P") local binselectmethod "`binselectmethod' (select degree and smoothness)"
+	 }
+	 
+	 * Mass point check?
+	 if ("`masspoints'"=="") {
+	    local massadj "T"
+		local localcheck "T"	    
+	 }
+	 else if ("`masspoints'"=="off") {
+	    local massadj "F"
+		local localcheck "F"
+	 }
+	 else if ("`masspoints'"=="noadjust") {
+	    local massadj "F"
+		local localcheck "T"
+	 }
+	 else if ("`masspoints'"=="nolocalcheck") {
+	 	local massadj "T"
+		local localcheck "F"
+     }
+	 else if ("`masspoints'"=="veryfew") {
+	    local fewmasspoints "T"    /* count mass point, but turn off checks */
+	 }
+	 
+	 * extract dfcheck
+	 if ("`dfcheck'"=="") local dfcheck 20 30
+	 tokenize `dfcheck'
+	 local dfcheck_n1 "`1'"
+	 local dfcheck_n2 "`2'"
+	 
+	 * evaluate at w from another dataset?
+	 if (`"`at'"'!=`""'&`"`at'"'!=`"mean"'&`"`at'"'!=`"median"'&`"`at'"'!=`"0"') local atwout "user"
+	 
+	 * use gtools commands instead?
+	 if ("`usegtools'"=="off") local usegtools ""
+	 if ("`usegtools'"=="on")  local usegtools usegtools
+	 if ("`usegtools'"!="") {
+	    capture which gtools
+		if (_rc) {
+		   di as error "Gtools package not installed."
+		   exit
+		}
+		local localcheck "F"
+		local sel_gtools "on"
+	    * use gstats tab instead of tabstat/collapse
+		* use gquantiles instead of _pctile
+		* use gunique instead of binsreg_uniq
+		* use fasterxtile instead of irecode (within binsreg_irecode)
+		* shut down local checks & do not sort
+	 }
+	 
+	 *************************
+	 **** error checks *******
+	 *************************
+	 if (`deriv'<0) {
+	    di as error "derivative incorrectly specified."
+		exit
+	 }
+	 if (`deriv'>1&"`transform'"=="T") {
+	    di as error "deriv cannot be greater than 1 if the conditional probability is requested." 
+		exit
+	 }
+	 if (`dotsngrid'<0|`linengrid'<0|`cingrid'<0|`cbngrid'<0|`simsngrid'<0) {
+	    di as error "Number of evaluation points incorrectly specified."
+		exit
+	 }
+	 if (`level'>100|`level'<0) {
+	     di as error "Confidence level incorrectly specified."
+		 exit
+	 }
+	 if ("`dots_p'"!=".") {
+		 if (`dots_p'<`dots_s') {
+			 di as error "p cannot be smaller than s."
+			 exit
+		 }
+		 if (`dots_p'<`deriv') {
+			 di as error "p for dots cannot be less than deriv."
+			 exit
+		 }
+	 }
+	 if ("`line_p'"!=".") {
+	    if (`line_p'<`line_s') {
+		   di as error "p cannot be smaller than s."
+		   exit
+		}
+		if (`line_p'<`deriv') {
+		   di as error "p for line cannot be less than deriv."
+		   exit
+		}
+	 }
+	 if ("`ci_p'"!=".") {
+	    if (`ci_p'<`ci_s') {
+		   di as error "p cannot be smaller than s."
+		   exit
+		}
+		if (`ci_p'<`deriv') {
+		   di as error "p for CI cannot be less than deriv."
+		   exit
+		}
+	 }
+	 if ("`cb_p'"!=".") {
+	    if (`cb_p'<`cb_s') {
+		   di as error "p cannot be smaller than s."
+		   exit
+		}
+		if (`cb_p'<`deriv') {
+		   di as error "p for CB cannot be less than deriv."
+		   exit
+		}
+	 }
+	 if ("`polyreg'"!="") {
+	    if (`polyreg'<`deriv') {
+		   di as error "polyreg() cannot be less than deriv()."
+		   exit
+		}
+	 }
+     
+	 if (`"`savedata'"'!=`""') {
+	    if ("`replace'"=="") {
+		   confirm new file `"`savedata'.dta"'
+		}
+		if ("`plot'"!="") {
+		    di as error "Plot cannot be turned off if graph data are requested."
+			exit
+		}
+	 }
+	 if (`polyregcingrid'!=0&"`polyreg'"=="") {
+	    di as error "polyreg() is missing."
+		exit
+	 }
+	 if ("`binsmethod'"!="DPI"&"`binsmethod'"!="ROT") {
+	    di as error "binsmethod incorrectly specified."
+		exit
+	 }
+	 ******** END error checking ***************************
+
+	 * Mark sample
+	 preserve
+	 
+	 * Parse varlist into y_var, x_var and w_var
+	 tokenize `varlist'
+	 fvrevar `1', tsonly
+	 local y_var "`r(varlist)'"
+	 local y_varname "`1'"
+	 fvrevar `2', tsonly
+	 local x_var "`r(varlist)'"
+	 local x_varname "`2'"
+	 
+	 macro shift 2
+	 local w_var "`*'"
+	 * read eval point for w from another file
+	 if ("`atwout'"=="user") {
+	    append using `at'
+	 }
+	 
+	 fvrevar `w_var', tsonly
+	 local w_var "`r(varlist)'"
+	 local nwvar: word count `w_var'
+	 
+	 * Save the last obs in a vector and then drop it
+	 tempname wuser                  /* a vector used to keep eval for w */
+	 if ("`atwout'"=="user") {
+	    mata: st_matrix("`wuser'", st_data(`=_N', "`w_var'")) 
+	    qui drop in `=_N'
+	 }
+	 
+	 * Get positions of factor vars
+     local indexlist ""
+     local i = 1
+     foreach v in `w_var' {
+        if strpos("`v'", ".") == 0 {
+           local indexlist  `indexlist' `i'
+        }
+        local ++i
+     }
+	 
+	 * add a default for at
+	 if (`"`at'"'==""&`nwvar'>0) {
+	    local at "mean"
+	 }
+
+	 marksample touse
+	 markout `touse' `by', strok	 
+	 qui keep if `touse'
+	 local nsize=_N             /* # of rows in the original dataset */
+	 
+	 if ("`usegtools'"==""&("`masspoints'"!="off"|"`binspos'"=="QS")) {
+	    if ("`:sortedby'"!="`x_var'") {
+		  di as text in gr "Sorting dataset on `x_varname'..."
+		  di as text in gr "Note: This step is omitted if dataset already sorted by `x_varname'."
+		  sort `x_var', stable
+		}
+		local sorted "sorted"
+	 }
+	 
+	 if ("`wtype'"=="f") qui sum `x_var' `wt', meanonly
+	 else 	             qui sum `x_var', meanonly
+
+	 local xmin=r(min)
+	 local xmax=r(max)
+	 local Ntotal=r(N)  /* total sample size, with wt */
+	 * define the support of plot
+	 if ("`plotxrange'"!="") {
+	    local xsc `plotxrange'
+		if (wordcount("`xsc'")==1) local xsc `xsc' `xmax'
+	 }
+	 else local xsc `xmin' `xmax'
+	 
+	 * Effective sample size
+	 local eN=`nsize'
+	 * DO NOT check mass points and clusters outside loop unless needed
+	 
+	 * Check number of unique byvals & create local storing byvals
+	 local byvarname `by'
+     if "`by'"!="" {        
+        capture confirm numeric variable `by'
+        if _rc {
+		  local bystring "T"
+        * generate a numeric version
+          tempvar by
+          tempname bylabel
+          qui egen `by'=group(`byvarname'), lname(`bylabel')
+        }
+                
+        local bylabel `:value label `by'' /* catch value labels for numeric by-vars too */ 
+                
+        tempname byvalmatrix
+        qui tab `by', nofreq matrow(`byvalmatrix')
+                
+        local bynum=r(r)
+        forvalues i=1/`bynum' {
+           local byvals `byvals' `=`byvalmatrix'[`i',1]'
+        }
+     }
+     else local bynum=1
+	 
+	 * Default colors, symbols, linepatterns
+     if (`"`bycolors'"'==`""') local bycolors ///
+                navy maroon forest_green dkorange teal cranberry lavender ///
+                khaki sienna emidblue emerald brown erose gold bluishgray
+	 if (`"`bysymbols'"'==`""') local bysymbols ///
+	            O D T S + X A a | V o d s t x
+	 if (`"`bylpatterns'"'==`""') {
+	    forval i=1/`bynum' {
+		   local bylpatterns `bylpatterns' solid 
+		}
+	 }        
+
+	 * Temp name in MATA
+	 tempname xvec yvec byvec cluvec binedges
+	 mata: `xvec'=st_data(., "`x_var'"); `yvec'=st_data(.,"`y_var'"); `byvec'=.; `cluvec'=.
+	 
+	 *******************************************************
+	 *** Mass point counting *******************************
+	 tempname Ndistlist Nclustlist mat_imse_var_rot mat_imse_bsq_rot mat_imse_var_dpi mat_imse_bsq_dpi
+	 mat `Ndistlist'=J(`bynum',1,.)
+	 mat `Nclustlist'=J(`bynum',1,.)
+	 * Matrices saving imse
+	 mat `mat_imse_var_rot'=J(`bynum',1,.)
+	 mat `mat_imse_bsq_rot'=J(`bynum',1,.)
+	 mat `mat_imse_var_dpi'=J(`bynum',1,.)
+	 mat `mat_imse_bsq_dpi'=J(`bynum',1,.)
+	 
+	 if (`bynum'>1) mata: `byvec'=st_data(.,"`by'")
+	 if ("`clusterON'"=="T") mata: `cluvec'=st_data(.,"`clustervar'")
+	 
+	 ********************************************************
+	 ********** Bins, based on FULL sample ******************
+	 ********************************************************
+	 * knotlist: inner knot seq; knotlistON: local, knot available before loop
+	 
+	 tempname fullkmat   /* matrix name for saving knots based on the full sample */
+	 
+	 * Extract user-specified knot list
+	 if ("`binspos'"!="ES"&"`binspos'"!="QS") {
+		capture numlist "`binspos'", ascending
+		if (_rc==0) {
+		   local knotlistON "T"
+		   local knotlist `binspos'
+		   local nbins: word count `knotlist'
+		   local first: word 1 of `knotlist'
+		   local last: word `nbins' of `knotlist'
+		   if (`first'<=`xmin'|`last'>=`xmax') {
+			  di as error "Inner knots specified out of allowed range."
+			  exit
+		   }
+		   else {
+		      local nbins=`nbins'+1
+			  local nbins_full `nbins'
+              local pos "user"
+				   
+			  foreach el of local knotlist {
+		         mat `fullkmat'=(nullmat(`fullkmat') \ `el')
+		      }
+              mat `fullkmat'=(`xmin' \ `fullkmat' \ `xmax')
+		   }
+	    }
+	    else {
+		   di as error "Numeric list incorrectly specified in binspos()."
+		   exit
+		}
+	 }
+	 
+	 * Discrete x?
+	 if ("`fewmasspoints'"!="") local fullfewobs "T"
+	 
+	 * Bin selection using the whole sample if
+	 if ("`fullfewobs'"==""&"`selection'"!="NA"&(("`by'"=="")|(("`by'"!="")&("`samebinsby'"!="")))) {
+	    local selectfullON "T"
+	 }
+	 
+	 if ("`selectfullON'"=="T") {
+	    local Ndist=.
+	    if ("`massadj'"=="T") {
+	       if ("`usegtools'"=="") {
+	          mata: `binedges'=binsreg_uniq(`xvec', ., 1, "Ndist")
+		      mata: mata drop `binedges'
+		   }
+		   else {
+		      qui gunique `x_var'
+			  local Ndist=r(unique)
+		   }
+	       local eN=min(`eN', `Ndist')
+	    }
+	    * # of clusters
+	    local Nclust=.
+	    if ("`clusterON'"=="T") {
+		   if ("`usegtools'"=="") {
+		      mata: st_local("Nclust", strofreal(rows(uniqrows(`cluvec'))))
+		   }
+		   else {
+		      qui gunique `clustervar'
+			  local Nclust=r(unique)
+		   }
+		   local eN=min(`eN', `Nclust')   /* effective sample size */
+	    }
+	 
+
+		* Check effective sample size
+		if ("`dots_p'"==".") local dotspcheck=6
+		else                 local dotspcheck=`dots_p'
+		* Check effective sample size
+		if ("`nbinsrot'"==""&(`eN'<=`dfcheck_n1'+`dotspcheck'+1+`qrot')) {
+		    di as text in gr "Warning: Too small effective sample size for bin selection." ///
+			                 _newline _skip(9) "# of mass points or clusters used and by() option ignored."
+	        local by ""                 
+			local byvals ""
+			local fullfewobs "T"
+			local binspos "QS"                /* forced to be QS */
+	    }
+		else {
+		   local randcut1k `randcut'
+		   if ("`randcut'"=="" & `Ntotal'>5000) {
+	           local randcut1k=max(5000/`Ntotal', 0.01)
+		       di as text in gr "Warning: To speed up computation, bin/degree selection uses a subsample of roughly max(5,000, 0.01n) observations if the sample size n>5,000. To use the full sample, set randcut(1)."
+	       }
+		   if ("`selection'"=="J") {
+		      qui binsregselect `y_var' `x_var' `w_var' `wt', deriv(`deriv') bins(`dots_p' `dots_s') nbins(`nbins_full') ///
+				   			    absorb(`absorb') reghdfeopt(`reghdfeopt') ///
+								binsmethod(`binsmethod') binspos(`binspos') nbinsrot(`nbinsrot') ///
+								`vce' masspoints(`masspoints') dfcheck(`dfcheck_n1' `dfcheck_n2') ///
+								numdist(`Ndist') numclust(`Nclust') randcut(`randcut1k') usegtools(`sel_gtools')
+			  if (e(nbinsrot_regul)==.) {
+			      di as error "Bin selection fails."
+				  exit
+			  }
+			  if ("`binsmethod'"=="ROT") {
+				  local nbins=e(nbinsrot_regul)
+				  mat `mat_imse_var_rot'=J(`bynum',1,e(imse_var_rot))
+	              mat `mat_imse_bsq_rot'=J(`bynum',1,e(imse_bsq_rot))
+			  }
+			  else if ("`binsmethod'"=="DPI") {
+				 local nbins=e(nbinsdpi)
+				 mat `mat_imse_var_dpi'=J(`bynum',1,e(imse_var_dpi))
+	             mat `mat_imse_bsq_dpi'=J(`bynum',1,e(imse_bsq_dpi))
+				 if (`nbins'==.) {
+				    local nbins=e(nbinsrot_regul)
+ 				    mat `mat_imse_var_rot'=J(`bynum',1,e(imse_var_rot))
+	                mat `mat_imse_bsq_rot'=J(`bynum',1,e(imse_bsq_rot))
+					di as text in gr "Warning: DPI selection fails. ROT choice used."
+				 }
+			  }
+		   }
+		   else if ("`selection'"=="P") {
+		   	  qui binsregselect `y_var' `x_var' `w_var' `wt', deriv(`deriv') nbins(`nbins_full') ///
+				   			    absorb(`absorb') reghdfeopt(`reghdfeopt') ///
+								pselect(`plist') sselect(`slist') ///
+								binsmethod(`binsmethod') binspos(`binspos') nbinsrot(`nbinsrot') ///
+								`vce' masspoints(`masspoints') dfcheck(`dfcheck_n1' `dfcheck_n2') ///
+								numdist(`Ndist') numclust(`Nclust') randcut(`randcut1k') usegtools(`sel_gtools')
+			  if (e(prot_regul)==.) {
+			      di as error "bin selection fails."
+				  exit
+			  }
+			  if ("`binsmethod'"=="ROT") {
+			      local binsp=e(prot_regul)
+				  local binss=e(srot_regul)
+				  mat `mat_imse_var_rot'=J(`bynum',1,e(imse_var_rot))
+	              mat `mat_imse_bsq_rot'=J(`bynum',1,e(imse_bsq_rot))
+			  }
+			  else if ("`binsmethod'"=="DPI") {
+				 local binsp=e(pdpi)
+				 local binss=e(sdpi)
+				 mat `mat_imse_var_dpi'=J(`bynum',1,e(imse_var_dpi))
+	             mat `mat_imse_bsq_dpi'=J(`bynum',1,e(imse_bsq_dpi))
+				 if (`binsp'==.) {
+				    local binsp=e(prot_regul)
+					local binss=e(srot_regul)
+				    mat `mat_imse_var_rot'=J(`bynum',1,e(imse_var_rot))
+	                mat `mat_imse_bsq_rot'=J(`bynum',1,e(imse_bsq_rot))
+					di as text in gr "Warning: DPI selection fails. ROT choice used."
+				 }
+			  }
+			  if ("`dots'"=="T"|"`dots'"=="") {
+				 local dots_p=`binsp'
+				 local dots_s=`binss'
+			  }
+			  if ("`line'"=="T") {
+			     local line_p=`binsp'
+				 local line_s=`binss'
+			  }
+			  if ("`ci'"!="T"&"`ci'"!="") {
+			     if (`ci_p'<=`binsp') {
+				   local ci_p=`binsp'+1
+				   local ci_s=`ci_p'
+				   di as text "Warning: Degree for ci() has been changed. It must be greater than the IMSE-optimal degree."
+				 }
+			  }
+			  if ("`ci'"=="T") {
+			     local ci_p=`binsp'+1
+				 local ci_s=`binss'+1
+			  }
+			  if ("`cb'"!="T"&"`cb'"!="") {
+			     if (`cb_p'<=`binsp') {
+				   local cb_p=`binsp'+1
+				   local cb_s=`cb_p'
+				   di as text "Warning: Degree for cb() has been changed. It must be greater than the IMSE-optimal degree."
+				 }
+			  }
+			  if ("`cb'"=="T") {
+			     local cb_p=`binsp'+1
+				 local cb_s=`binss'+1
+			  }
+		   }
+		}
+	 }
+	 
+	 if (("`selectfullON'"=="T"|("`selection'"=="NA"&"`samebinsby'"!=""))&"`fullfewobs'"=="") {
+		 * Save in a knot list
+         local knotlistON "T"
+		 local nbins_full=`nbins'
+		 if ("`binspos'"=="ES") {
+	        local stepsize=(`xmax'-`xmin')/`nbins'
+	        forvalues i=1/`=`nbins'+1' {
+		       mat `fullkmat'=(nullmat(`fullkmat') \ `=`xmin'+`stepsize'*(`i'-1)')
+		    }
+	     }
+	     else if ("`binspos'"=="QS") {
+			 if (`nbins'==1)  mat `fullkmat'=(`xmin' \ `xmax')
+		     else {		
+	           binsreg_pctile `x_var' `wt', nq(`nbins') `usegtools'
+		       mat `fullkmat'=(`xmin' \ r(Q) \ `xmax')
+		     }
+	     }
+	 }
+	 
+	 *** Placement name, for display ************
+	 if ("`pos'"=="user") {
+	     local binselectmethod "User-specified"
+		 local placement "User-specified"
+	 }
+	 else if ("`binspos'"=="ES") {
+	     local placement "Evenly-spaced"
+	 }
+	 else if ("`binspos'"=="QS") {
+	     local placement "Quantile-spaced"
+	 }
+	 
+	 * NOTE: ALL checkings are put within the loop
+	 
+	 * Set seed
+	 if ("`simsseed'"!="") set seed `simsseed'
+	 
+	 * alpha quantile (for two-sided CI)
+	 local alpha=(100-(100-`level')/2)/100
+	 	 
+	 ***************************************************************************
+	 *************** Preparation before loop************************************
+	 ***************************************************************************
+	 
+	 ********** Prepare vars for plotting ********************
+	 * names for mata objects storing graph data
+	 * plotmat: final output (defined outside); 
+	 * plotmatby: output for each group
+	 tempname plotmat plotmatby xsub ysub byindex xcatsub
+	 tempname Xm Xm0 mata_fit mata_se          /* temp name for mata obj */
+	 
+	 * count the number of requested columns, record the positions
+	 local ncolplot=1                /* 1st col reserved for group */
+	 if ("`plot'"=="") {
+	    if (`dotsntot'!=0) {
+		   local dots_start=`ncolplot'+1
+		   local dots_end=`ncolplot'+4
+		   local ncolplot=`ncolplot'+4
+		}
+	    if (`linengrid'!=0&"`fullfewobs'"=="") {
+		   local line_start=`ncolplot'+1
+		   local line_end=`ncolplot'+4
+		   local ncolplot=`ncolplot'+4
+		}
+        if (`polyregngrid'!=0) {
+		   local poly_start=`ncolplot'+1
+		   local poly_end=`ncolplot'+4
+		   local ncolplot=`ncolplot'+4
+		   if (`polyregcingrid'!=0) {
+		      local polyci_start=`ncolplot'+1
+		      local polyci_end=`ncolplot'+5
+		      local ncolplot=`ncolplot'+5
+		   }
+		}
+		if (`cintot'!=0) {
+		   local ci_start=`ncolplot'+1
+		   local ci_end=`ncolplot'+5
+		   local ncolplot=`ncolplot'+5
+		}
+		if (`cbngrid'!=0&"`fullfewobs'"=="") {
+		   local cb_start=`ncolplot'+1
+		   local cb_end=`ncolplot'+5
+		   local ncolplot=`ncolplot'+5
+		}
+	 }
+	 mata: `plotmat'=J(0,`ncolplot',.)
+	 
+	 * mark the (varying) last row (for plotting)
+	 local bylast=0               
+     *******************************************************************	 
+	 * temp var: bin id
+	 tempvar xcat
+	 qui gen `xcat'=. in 1
+	 
+	 * matrix names, for returns
+	 tempname Nlist nbinslist cvallist
+	 
+	 * local vars, for plotting
+	 local counter_by=1
+	 local plotnum=0                     /* count the number of series, for legend */
+     if ("`by'"=="") local noby="noby"
+	 local byvalnamelist ""              /* save group name (value) */
+	 local plotcmd ""                    /* plotting cmd */
+	 
+	 ***************************************************************************
+	 ******************* Now, enter the loop ***********************************
+	 ***************************************************************************
+	 foreach byval in `byvals' `noby' {
+	    local conds ""
+		if ("`by'"!="") {
+		    local conds "if `by'==`byval'"     /* with "if" */
+	        if ("`bylabel'"=="") local byvalname=`byval'
+		    else {
+			   local byvalname `: label `bylabel' `byval''
+			}
+			local byvalnamelist `" `byvalnamelist' `"`byvalname'"' "'
+		}
+		if (`bynum'>1) {
+		   mata: `byindex'=`byvec':==`byval'
+		   mata: `xsub'=select(`xvec',`byindex'); `ysub'=select(`yvec', `byindex')
+		}
+		else {
+		   mata: `xsub'=`xvec'; `ysub'=`yvec'
+		}
+		
+		* Subsample size
+		if ("`wtype'"=="f") sum `x_var' `conds' `wt', meanonly
+		else                sum `x_var' `conds', meanonly
+		
+		local xmin=r(min)
+	    local xmax=r(max)
+	    local N=r(N)
+		mat `Nlist'=(nullmat(`Nlist') \ `N')
+		
+	    * Effective sample size
+		if (`bynum'==1) local eN=`nsize'
+		else {
+		   if ("`wtype'"!="f") local eN=r(N)
+		   else {
+		      qui count `conds'
+	          local eN=r(N)
+		   }
+		}
+	    
+	    local Ndist=.
+	    if ("`massadj'"=="T") {
+		   if ("`usegtools'"=="") {
+		      mata: `binedges'=binsreg_uniq(`xsub', ., 1, "Ndist")
+		      mata: mata drop `binedges'
+		   }
+		   else {
+		      qui gunique `x_var' `conds'
+			  local Ndist=r(unique)
+		   }
+		   local eN=min(`eN', `Ndist')
+		   mat `Ndistlist'[`counter_by',1]=`Ndist'
+	    }
+		
+	    * # of clusters
+	    local Nclust=.
+	    if ("`clusterON'"=="T") {
+		   if (`bynum'==1) {
+		   	  if ("`usegtools'"=="") {
+			     mata: st_local("Nclust", strofreal(rows(uniqrows(`cluvec'))))
+		      }
+			  else {
+			     qui gunique `clustervar'
+				 local Nclust=r(unique)
+			  }
+		   }
+		   else {
+		      if ("`usegtools'"=="") {
+		         mata: st_local("Nclust", strofreal(rows(uniqrows(select(`cluvec', `byindex')))))
+		      }
+			  else {
+			     qui gunique `clustervar' `conds'
+				 local Nclust=r(unique)
+			  }
+		   }
+		   local eN=min(`eN', `Nclust')   /* effective SUBsample size */
+		   mat `Nclustlist'[`counter_by',1]=`Nclust'
+	    }
+	    
+		*********************************************************
+		************** Prepare bins, within loop ****************
+		*********************************************************
+		if ("`pos'"!="user") local pos `binspos'              /* initialize pos */
+		* Selection?
+	    if ("`selection'"!="NA"&"`knotlistON'"!="T"&"`fullfewobs'"=="") {
+		   * Check effective sample size
+		   if ("`dots_p'"==".") local dotspcheck=6
+		   else                 local dotspcheck=`dots_p'
+		   if ("`nbinsrot'"==""&(`eN'<=`dfcheck_n1'+`dotspcheck'+1+`qrot')) {
+		      di as text in gr "Warning: Too small effective sample size for bin selection." ///
+			                   _newline _skip(9) "# of mass points or clusters used."
+	          local fewobs "T"
+			  local nbins=`eN'
+			  local pos "QS"                /* forced to be QS */
+	       }
+		   else {
+		   	  local randcut1k `randcut'
+		      if ("`randcut'"=="" & `N'>5000) {
+			     local randcut1k=max(5000/`N', 0.01)
+				 di as text in gr "Warning: To speed up computation, bin/degree selection uses a subsample of roughly max(5,000, 0.01n) observations if the sample size n>5,000. To use the full sample, set randcut(1)."
+		      }
+		      if ("`selection'"=="J") {
+			     qui binsregselect `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+				                   bins(`dots_p' `dots_s') nbins(`nbins_full') ///
+		                           absorb(`absorb') reghdfeopt(`reghdfeopt') /// 
+					   			   binsmethod(`binsmethod') binspos(`pos') nbinsrot(`nbinsrot') ///
+							       `vce' masspoints(`masspoints') dfcheck(`dfcheck_n1' `dfcheck_n2') ///
+							       numdist(`Ndist') numclust(`Nclust') randcut(`randcut1k') usegtools(`sel_gtools')
+			     if (e(nbinsrot_regul)==.) {
+			        di as error "Bin selection fails."
+			        exit
+			     }
+			     if ("`binsmethod'"=="ROT") {
+		            local nbins=e(nbinsrot_regul)
+				    mat `mat_imse_bsq_rot'[`counter_by',1]=e(imse_bsq_rot)
+				    mat `mat_imse_var_rot'[`counter_by',1]=e(imse_var_rot)
+		         }
+		         else if ("`binsmethod'"=="DPI") {
+			        local nbins=e(nbinsdpi)
+					mat `mat_imse_bsq_dpi'[`counter_by',1]=e(imse_bsq_dpi)
+				    mat `mat_imse_var_dpi'[`counter_by',1]=e(imse_var_dpi)
+			        if (`nbins'==.) {
+			           local nbins=e(nbinsrot_regul)
+					   mat `mat_imse_bsq_rot'[`counter_by',1]=e(imse_bsq_rot)
+				       mat `mat_imse_var_rot'[`counter_by',1]=e(imse_var_rot)
+			           di as text in gr "Warning: DPI selection fails. ROT choice used."
+			        }
+		         }
+			  }
+		      else if ("`selection'"=="P") {
+		   	     qui binsregselect `y_var' `x_var' `w_var' `wt', deriv(`deriv') nbins(`nbins_full') ///
+				     			    absorb(`absorb') reghdfeopt(`reghdfeopt') ///
+					  			    pselect(`plist') sselect(`slist') ///
+								    binsmethod(`binsmethod') binspos(`binspos') nbinsrot(`nbinsrot') ///
+								    `vce' masspoints(`masspoints') dfcheck(`dfcheck_n1' `dfcheck_n2') ///
+								    numdist(`Ndist') numclust(`Nclust') randcut(`randcut1k') usegtools(`sel_gtools')
+			     if (e(prot_regul)==.) {
+			        di as error "Bin selection fails."
+				    exit
+			     }
+			     if ("`binsmethod'"=="ROT") {
+				    local binsp=e(prot_regul)
+				    local binss=e(srot_regul)
+					mat `mat_imse_bsq_rot'[`counter_by',1]=e(imse_bsq_rot)
+				    mat `mat_imse_var_rot'[`counter_by',1]=e(imse_var_rot)
+			     }
+			     else if ("`binsmethod'"=="DPI") {
+				    local binsp=e(pdpi)
+				    local binss=e(sdpi)
+					mat `mat_imse_bsq_dpi'[`counter_by',1]=e(imse_bsq_dpi)
+				    mat `mat_imse_var_dpi'[`counter_by',1]=e(imse_var_dpi)
+				    if (`binsp'==.) {
+				       local binsp=e(prot_regul)
+					   local binss=e(srot_regul)
+					   mat `mat_imse_bsq_rot'[`counter_by',1]=e(imse_bsq_rot)
+				       mat `mat_imse_var_rot'[`counter_by',1]=e(imse_var_rot)
+					   di as text in gr "Warning: DPI selection fails. ROT choice used."
+				    }
+			     }
+				 if ("`dots'"=="T"|"`dots'"=="") {
+				    local dots_p=`binsp'
+					local dots_s=`binss'
+				 }
+				 if ("`line'"=="T") {
+				    local line_p=`binsp'
+					local line_s=`binss'
+				 }
+				 if ("`ci'"!="T"&"`ci'"!="") {
+					if (`ci_p'<=`binsp') {
+					   local ci_p=`binsp'+1
+					   local ci_s=`ci_p'
+				       di as text "Warning: Degree for ci() has been changed. It must be greater than the IMSE-optimal degree."
+				    }
+			     }
+				 if ("`ci'"=="T") {
+					local ci_p=`binsp'+1
+					local ci_s=`binss'+1
+				 }
+				 if ("`cb'"!="T"&"`cb'"!="") {
+			        if (`cb_p'<=`binsp') {
+				      local cb_p=`binsp'+1
+					  local cb_s=`cb_p'
+				      di as text "Warning: Degree for cb() has been changed. It must be greater than the IMSE-optimal degree."
+				    }
+			     }
+				 if ("`cb'"=="T") {
+				    local cb_p=`binsp'+1
+					local cb_s=`binss'+1
+				 }
+		      }		   
+		   }
+	    }
+		
+		if ("`selection'"=="NA"|"`knotlistON'"=="T") local nbins=`nbins_full'    /* add the universal nbins */
+		*if ("`knotlistON'"=="T") local nbins=`nbins_full'
+		if ("`fullfewobs'"!="") {
+		   local fewobs "T"
+		   local nbins=`eN'
+		}
+		
+	    ******************************************************
+	    * Check effective sample size for each case **********
+		******************************************************
+	    if ("`fewobs'"!="T") {
+		   if ((`nbins'-1)*(`dots_p'-`dots_s'+1)+`dots_p'+1+`dfcheck_n2'>=`eN') {
+		      local fewobs "T"           /* even though ROT available, treat it as few obs case */
+		      local nbins=`eN'
+		      local pos "QS"
+		      di as text in gr "Warning: Too small effective sample size for dots. # of mass points or clusters used."
+	       }
+		   if ("`line_p'"!=".") {
+	          if ((`nbins'-1)*(`line_p'-`line_s'+1)+`line_p'+1+`dfcheck_n2'>=`eN') {
+	             local line_fewobs "T"
+		         di as text in gr "Warning: Too small effective sample size for line."
+	          }
+		   }
+		   if ("`ci_p'"!=".") {
+	          if ((`nbins'-1)*(`ci_p'-`ci_s'+1)+`ci_p'+1+`dfcheck_n2'>=`eN') {
+	             local ci_fewobs "T"
+		         di as text in gr "Warning: Too small effective sample size for CI."
+	          }
+		   }
+		   if ("`cb_p'"!=".") {
+	          if ((`nbins'-1)*(`cb_p'-`cb_s'+1)+`cb_p'+1+`dfcheck_n2'>=`eN') {
+	             local cb_fewobs "T"
+		         di as text in gr "Warning: Too small effective sample size for CB."
+	          }
+		   }
+	    }
+		
+	    if ("`polyreg'"!="") {
+	       if (`polyreg'+1>=`eN') {
+	          local polyreg_fewobs "T"
+		      di as text in gr "Warning: Too small effective sample size for polynomial fit."
+	       }
+	    }
+ 
+	    * Generate category variable for data and save knot in matrix
+		tempname kmat
+	    
+		if ("`knotlistON'"=="T") {
+		   mat `kmat'=`fullkmat'
+		   if ("`fewobs'"=="T"&"`eN'"!="`Ndist'") {
+		      if (`nbins'==1)  mat `kmat'=(`xmin' \ `xmax')
+		      else {		
+	            binsreg_pctile `x_var' `conds' `wt', nq(`nbins') `usegtools'
+		        mat `kmat'=(`xmin' \ r(Q) \ `xmax')
+		      }
+		   }
+		}
+		else {
+		   if ("`fewmasspoints'"==""&("`fewobs'"!="T"|"`eN'"!="`Ndist'")) {
+             if ("`pos'"=="ES") {
+	            local stepsize=(`xmax'-`xmin')/`nbins'
+	            forvalues i=1/`=`nbins'+1' {
+		           mat `kmat'=(nullmat(`kmat') \ `=`xmin'+`stepsize'*(`i'-1)')
+		        }
+		     }
+	         else {		
+		        if (`nbins'==1)  mat `kmat'=(`xmin' \ `xmax')
+		        else {		
+	              binsreg_pctile `x_var' `conds' `wt', nq(`nbins') `usegtools'
+		          mat `kmat'=(`xmin' \ r(Q) \ `xmax')
+		        }
+		     }
+		   }
+		}
+	
+		* Renew knot list if few mass points
+		if (("`fewobs'"=="T"&"`eN'"=="`Ndist'")|"`fewmasspoints'"!="") {
+		   qui tab `x_var' `conds', matrow(`kmat')
+		   if ("`fewmasspoints'"!="") {
+		      local nbins=rowsof(`kmat')
+			  local Ndist=`nbins'
+			  local eN=`Ndist'
+		   }
+		}
+		else {
+		   mata: st_matrix("`kmat'", (`xmin' \ uniqrows(st_matrix("`kmat'")[|2 \ `=`nbins'+1'|])))
+	       if (`nbins'!=rowsof(`kmat')-1) {
+	          di as text in gr "Warning: Repeated knots. Some bins dropped."
+		      local nbins=rowsof(`kmat')-1
+	       }
+		   
+		   binsreg_irecode `x_var' `conds', knotmat(`kmat') bin(`xcat') ///
+		                                   `usegtools' nbins(`nbins') pos(`pos') knotliston(`knotlistON')
+		   
+		   mata: `xcatsub'=st_data(., "`xcat'")
+		   if (`bynum'>1) {
+		      mata: `xcatsub'=select(`xcatsub', `byindex')
+		   }
+        }
+
+	    *************************************************
+	    **** Check for empty bins ***********************
+		*************************************************
+		mata: `binedges'=.               /* initialize */
+		if ("`fewobs'"!="T"&"`localcheck'"=="T") {
+		   mata: st_local("Ncat", strofreal(rows(uniqrows(`xcatsub'))))
+		   if (`nbins'==`Ncat') {
+		      mata: `binedges'=binsreg_uniq(`xsub', `xcatsub', `nbins', "uniqmin")
+		   }
+		   else {
+		      local uniqmin=0
+			  di as text in gr "Warning: There are empty bins. Specify a smaller number in nbins()."
+		   }
+		   
+		   if ("`dots_p'"!=".") {
+		      if (`uniqmin'<`dots_p'+1) {
+		         local dots_fewobs "T"
+		         di as text in gr "Warning: Some bins have too few distinct x-values for dots."
+		      }
+	       }
+	       if ("`line_p'"!=".") {
+		      if (`uniqmin'<`line_p'+1) {
+		         local line_fewobs "T"
+		         di as text in gr "Warning: Some bins have too few distinct x-values for line."
+		      }
+	       }
+	       if ("`ci_p'"!=".") {
+		      if (`uniqmin'<`ci_p'+1) {
+		         local ci_fewobs "T"
+		         di as text in gr "Warning: Some bins have too few distinct x-values for CI."
+		      }
+	       }
+	       if ("`cb_p'"!=".") {
+		      if (`uniqmin'<`cb_p'+1) {
+		         local cb_fewobs "T"
+		         di as text in gr "Warning: Some bins have too few distinct x-values for CB."
+		      }
+	       }
+		}
+		
+		* Now, save nbins in a list !!!
+		mat `nbinslist'=(nullmat(`nbinslist') \ `nbins')
+		
+		**********************************************************
+	    **** Count the number of rows needed (within loop!) ******
+		**********************************************************
+		local byfirst=`bylast'+1
+		local byrange=0
+		if ("`fewobs'"!="T") {
+		   local dots_nr=`dotsngrid_mean'*`nbins'
+		   if (`dotsngrid'!=0) local dots_nr=`dots_nr'+`dotsngrid'*`nbins'+`nbins'-1
+		   local ci_nr=`cingrid_mean'*`nbins'
+		   if (`cingrid'!=0)   local ci_nr=`ci_nr'+`cingrid'*`nbins'+`nbins'-1
+		   if (`linengrid'!=0) local line_nr=`linengrid'*`nbins'+`nbins'-1
+		   if (`cbngrid'!=0)   local cb_nr=`cbngrid'*`nbins'+`nbins'-1
+		   if (`polyregngrid'!=0) {
+		      local poly_nr=`polyregngrid'*`nbins'+`nbins'-1
+		      if (`polyregcingrid'!=0) local polyci_nr=`polyregcingrid'*`nbins'+`nbins'-1
+		   }	   
+		   local byrange=max(`dots_nr'+0,`line_nr'+0,`ci_nr'+0,`cb_nr'+0, `poly_nr'+0, `polyci_nr'+0)
+		}
+		else {
+		   if ("`eN'"=="`Ndist'") {
+		      if (`polyregngrid'!=0) {
+			     local poly_nr=`polyregngrid'*(`nbins'-1)+`nbins'-1-1
+				 if (`polyregcingrid'!=0) local polyci_nr=`polyregcingrid'*(`nbins'-1)+`nbins'-1-1
+			  }
+		   }
+		   else {
+		      if (`polyregngrid'!=0) {
+		         local poly_nr=`polyregngrid'*`nbins'+`nbins'-1
+			     if (`polyregcingrid'!=0) local polyci_nr=`polyregcingrid'*`nbins'+`nbins'-1
+			  }
+		   }
+		   local byrange=max(`nbins', `poly_nr'+0, `polyci_nr'+0)
+		}
+		local bylast=`bylast'+`byrange'
+		mata: `plotmatby'=J(`byrange',`ncolplot',.)
+		if ("`byval'"!="noby") {
+		   mata: `plotmatby'[.,1]=J(`byrange',1,`byval')
+		}
+ 
+		************************************************
+	    **** START: prepare data for plotting***********
+	    ************************************************
+		local plotcmdby ""
+		
+		********************************
+		* adjust w vars
+		tempname wval
+		if (`nwvar'>0) {
+		   if (`"`at'"'==`"mean"'|`"`at'"'==`"median"') {
+		     matrix `wval'=J(1, `nwvar', 0)
+			 tempname wvaltemp mataobj
+			 mata: `mataobj'=.
+			 foreach wpos in `indexlist' {
+			    local wname: word `wpos' of `w_var'
+		        if ("`usegtools'"=="") {
+		           if ("`wtype'"!="") qui tabstat `wname' `conds' [aw`exp'], stat(`at') save
+			       else               qui tabstat `wname' `conds', stat(`at') save
+				   mat `wvaltemp'=r(StatTotal)
+				}
+				else {
+				   qui gstats tabstat `wname' `conds' `wt', stat(`at') matasave("`mataobj'")
+				   mata: st_matrix("`wvaltemp'", `mataobj'.getOutputCol(1))
+				}
+				mat `wval'[1,`wpos']=`wvaltemp'[1,1]
+		     }
+			 mata: mata drop `mataobj'
+		   }
+		   else if (`"`at'"'==`"0"') {
+   		     matrix `wval'=J(1,`nwvar',0)
+		   }
+		   else if ("`atwout'"=="user") {
+		     matrix `wval'=`wuser'
+		   }
+		}
+
+		
+		*************************************************
+	    ********** dots and ci for few obs. case ********
+	    *************************************************
+	    if (`dotsntot'!=0&"`plot'"==""&"`fewobs'"=="T") {
+		   di as text in gr "Warning: dots(0 0) is used."
+		   if (`deriv'>0) di as text in gr "Warning: deriv(0 0) is used."
+		   
+		   local dots_first=`byfirst'
+		   local dots_last=`byfirst'-1+`nbins'
+	       
+		   mata: `plotmatby'[|1,`dots_start'+2 \ `nbins',`dots_start'+2|]=range(1,`nbins',1)
+		
+		   if ("`eN'"=="`Ndist'") {
+		      mata: `plotmatby'[|1,`dots_start' \ `nbins',`dots_start'|]=st_matrix("`kmat'"); ///
+			        `plotmatby'[|1,`dots_start'+1 \ `nbins',`dots_start'+1|]=J(`nbins',1,1)
+			  
+			  * Renew knot commalist, each value forms a group
+		      local xknot ""
+		      forvalues i=1/`nbins' {
+		         local xknot `xknot' `kmat'[`i',1]
+		      }
+		      local xknotcommalist : subinstr local xknot " " ",", all
+		      qui replace `xcat'=1+irecode(`x_var',`xknotcommalist') `conds'
+		   }
+		   else {
+		      tempname grid
+		      mat `grid'=(`kmat'[1..`nbins',1]+`kmat'[2..`nbins'+1,1])/2
+		      mata: `plotmatby'[|1,`dots_start' \ `nbins',`dots_start'|]=st_matrix("`grid'"); ///
+			        `plotmatby'[|1,`dots_start'+1 \ `nbins',`dots_start'+1|]=J(`nbins',1,0)
+		   }
+		   
+	       local nseries=`nbins'
+	       capture logit `y_var' ibn.`xcat' `w_var' `conds' `wt', nocon `vce' `logitopt'
+		   tempname fewobs_b fewobs_V
+		   if (_rc==0) {
+		      mat `fewobs_b'=e(b)
+		      mat `fewobs_V'=e(V)
+		      mata: binsreg_checkdrop("`fewobs_b'", "`fewobs_V'", `nseries')
+			  if (`nwvar'>0) {
+			     mat `fewobs_b'=`fewobs_b'[1,1..`nseries']+(`fewobs_b'[1,`=`nseries'+1'..`=`nseries'+`nwvar'']*`wval'')*J(1,`nseries',1)
+		      }
+			  else {
+			     mat `fewobs_b'=`fewobs_b'[1,1..`nseries']
+		      }
+		   }
+		   else {
+		      error _rc
+		      exit _rc
+		   }
+		
+		   if ("`transform'"=="T") {
+		      mata: `plotmatby'[|1,`dots_start'+3 \ `nbins',`dots_start'+3|]=logistic(st_matrix("`fewobs_b'"))'
+           }
+		   else {
+		      mata: `plotmatby'[|1,`dots_start'+3 \ `nbins',`dots_start'+3|]=st_matrix("`fewobs_b'")'
+		   }
+		   
+		   local plotnum=`plotnum'+1
+		   local legendnum `legendnum' `plotnum' 
+		   local col: word `counter_by' of `bycolors'
+		   local sym: word `counter_by' of `bysymbols'
+		   local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond `plotcond' if 
+			  if ("`plotxrange'"!="") {
+		         local plotcond `plotcond' dots_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &dots_x<=`max_xr' 
+		      }
+		      if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' dots_fit>=`min_yr'
+				 else                    local plotcond `plotcond' &dots_fit>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &dots_fit<=`max_yr' 
+		      }
+		   }
+
+		   local plotcmdby `plotcmdby' (scatter dots_fit dots_x ///
+		                   `plotcond' in `dots_first'/`dots_last', ///
+						   mcolor(`col') msymbol(`sym') `dotsplotopt')
+		   
+		   if (`cintot'!=0) {
+		      di as text in gr "Warning: ci(0 0) is used."
+		   
+		   	  if (`nwvar'>0) {
+			     mata: `mata_se'=(I(`nseries'), J(`nseries',1,1)#st_matrix("`wval'"))
+			  }
+			  else {
+			     mata: `mata_se'=I(`nseries')
+			  }
+
+		      mata: `plotmatby'[|1,`ci_start'+1 \ `nbins',`ci_start'+2|]=`plotmatby'[|1,`dots_start'+1 \ `nbins',`dots_start'+2|]; ///
+			        `mata_se'=sqrt(rowsum((`mata_se'*st_matrix("`fewobs_V'")):*`mata_se'))
+			  if ("`transform'"=="T") {
+			     mata: `mata_se'=`mata_se':*(logisticden(st_matrix("`fewobs_b'"))')
+			  }
+			  mata: `plotmatby'[|1,`ci_start'+3 \ `nbins',`ci_start'+3|]=`plotmatby'[|1,`dots_start'+3 \ `nbins',`dots_start'+3|]-`mata_se'*invnormal(`alpha'); ///
+			        `plotmatby'[|1,`ci_start'+4 \ `nbins',`ci_start'+4|]=`plotmatby'[|1,`dots_start'+3 \ `nbins',`dots_start'+3|]+`mata_se'*invnormal(`alpha')
+			  mata: mata drop `mata_se'
+			  
+			  local plotnum=`plotnum'+1
+			  local lty: word `counter_by' of `bylpatterns'
+		      local plotcmdby `plotcmdby' (rcap CI_l CI_r dots_x ///
+			                  `plotcond' in `dots_first'/`dots_last', ///
+							  sort lcolor(`col') lpattern(`lty') `ciplotopt')
+		   }
+	    } 
+	 
+	    *********************************************
+	    **** The following handles the usual case ***
+	    *********************************************
+		* Turn on or off?
+		local dotsON ""
+		local lineON ""
+		local polyON ""
+		local ciON   ""
+		local cbON   ""
+	    if (`dotsntot'!=0&"`plot'"==""&"`fewobs'"!="T"&"`dots_fewobs'"!="T") {
+	       local dotsON "T"
+	    }	    
+		if (`linengrid'!=0&"`plot'"==""&"`line_fewobs'"!="T"&"`fewobs'"!="T") {
+	       local lineON "T"
+	    }
+	    if (`polyregngrid'!=0&"`plot'"==""&"`polyreg_fewobs'"!="T") {
+	       local polyON "T"
+	    }
+	    if (`cintot'!=0&"`plot'"==""&"`ci_fewobs'"!="T"&"`fewobs'"!="T") {
+	       local ciON "T"
+	    }
+		if (`cbngrid'!=0&"`plot'"==""&"`cb_fewobs'"!="T"&"`fewobs'"!="T") {
+	       local cbON "T"
+	    }
+				
+		
+	    ************************
+	    ****** Dots ************
+	    ************************
+		tempname xmean
+
+	    if ("`dotsON'"=="T") {
+		   local dots_first=`byfirst'
+		   local dots_last=`byfirst'+`dots_nr'-1
+		   
+		   * fitting
+		   tempname dots_b dots_V
+		   if (("`dots_p'"=="`ci_p'"&"`dots_s'"=="`ci_s'"&"`ciON'"=="T")| ///
+		       ("`dots_p'"=="`cb_p'"&"`dots_s'"=="`cb_s'"&"`cbON'"=="T")) {
+			  binslogit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                    p(`dots_p') s(`dots_s') type(dots) `vce' ///
+			            xcat(`xcat') kmat(`kmat') dotsmean(`dotsngrid_mean') /// 
+			            xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						usereg `sorted' `usegtools' logitopt(`logitopt')
+		   }
+		   else {
+		      binslogit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                    p(`dots_p') s(`dots_s') type(dots) `vce' ///
+			            xcat(`xcat') kmat(`kmat') dotsmean(`dotsngrid_mean') /// 
+			            xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						`sorted' `usegtools' logitopt(`logitopt')
+		   }
+		   
+		   mat `dots_b'=e(bmat)
+		   mat `dots_V'=e(Vmat)
+		   if (`dotsngrid_mean'!=0) mat `xmean'=e(xmat)
+		   
+		   * prediction
+		   if (`dotsngrid_mean'==0) {
+		      mata: `plotmatby'[|1,`dots_start' \ `dots_nr',`dots_end'|] = ///
+			                  binslogit_plotmat("`dots_b'", "`dots_V'", ., "`kmat'", ///
+		                                       `nbins', `dots_p', `dots_s', `deriv', ///
+							                   "dots", `dotsngrid', "`wval'", `nwvar', ///
+											   "`transform'", "`asyvar'")
+		   }
+		   else {
+		      mata: `plotmatby'[|1,`dots_start' \ `dots_nr',`dots_end'|] = ///
+			                  binslogit_plotmat("`dots_b'", "`dots_V'", ., "`kmat'", ///
+		                                        `nbins', `dots_p', `dots_s', `deriv', ///
+							                    "dots", `dotsngrid', "`wval'", `nwvar', ///
+												"`transform'", "`asyvar'", "`xmean'")
+		   }		  
+		  
+		   * dots
+		   local plotnum=`plotnum'+1
+		   if ("`cbON'"=="T") local legendnum `legendnum' `=`plotnum'+1'
+		   else {
+		      local legendnum `legendnum' `plotnum'
+		   }
+		   local col: word `counter_by' of `bycolors'
+		   local sym: word `counter_by' of `bysymbols'
+		   local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+		         local plotcond `plotcond' dots_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &dots_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' dots_fit>=`min_yr'
+				 else                    local plotcond `plotcond' &dots_fit>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &dots_fit<=`max_yr' 
+		      }
+		   }
+		   
+	       local plotcmdby `plotcmdby' (scatter dots_fit dots_x ///
+		                   `plotcond' in `dots_first'/`dots_last', ///
+						   mcolor(`col') msymbol(`sym') `dotsplotopt')
+	    }
+
+	    **********************************************
+	    ********************* Line *******************
+	    **********************************************
+	    if ("`lineON'"=="T") {
+		   local line_first=`byfirst'
+		   local line_last=`byfirst'-1+`line_nr'
+
+		   * fitting
+		   tempname line_b line_V
+		   capture confirm matrix `dots_b' `dots_V'
+		   if ("`line_p'"=="`dots_p'"& "`line_s'"=="`dots_s'" & _rc==0) {
+		      matrix `line_b'=`dots_b'
+		      matrix `line_V'=`dots_V'
+		   }
+		   else {
+		      if (("`line_p'"=="`ci_p'"&"`line_s'"=="`ci_s'"&"`ciON'"=="T")| ///
+		          ("`line_p'"=="`cb_p'"&"`line_s'"=="`cb_s'"&"`cbON'"=="T")) {
+				 binslogit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                      p(`line_p') s(`line_s') type(line) `vce' ///
+			              xcat(`xcat') kmat(`kmat') dotsmean(0) /// 
+			              xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						  usereg `sorted' `usegtools' logitopt(`logitopt')
+			  }
+			  else {
+		         binslogit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                      p(`line_p') s(`line_s') type(line) `vce' ///
+			              xcat(`xcat') kmat(`kmat') dotsmean(0) /// 
+			              xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') /// 
+						  `sorted' `usegtools' logitopt(`logitopt')
+			  }
+		      mat `line_b'=e(bmat)
+		      mat `line_V'=e(Vmat)
+		   }
+
+		   * prediction
+		   mata: `plotmatby'[|1,`line_start' \ `line_nr',`line_end'|] = ///
+			              binslogit_plotmat("`line_b'", "`line_V'", ., "`kmat'", ///
+		                      `nbins', `line_p', `line_s', `deriv', ///
+							  "line", `linengrid', "`wval'", `nwvar', "`transform'", "`asyvar'")
+		   
+		   * line
+		   local plotnum=`plotnum'+1
+		   local col: word `counter_by' of `bycolors'
+		   local lty: word `counter_by' of `bylpatterns'
+		   local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+		         local plotcond `plotcond' line_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &line_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' line_fit>=`min_yr'
+				 else                    local plotcond `plotcond' &line_fit>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &(line_fit<=`max_yr'|line_fit==.) 
+		      }
+		   }
+		   
+	       local plotcmdby `plotcmdby' (line line_fit line_x ///
+		                   `plotcond' in `line_first'/`line_last', sort cmissing(n) ///
+						   lcolor(`col') lpattern(`lty') `lineplotopt')
+	
+	    }
+	 
+	    ***********************************
+	    ******* Polynomial fit ************
+	    ***********************************
+	    if ("`polyON'"=="T") {
+		   if (`nwvar'>0) {
+		      di as text "Note: When additional covariates w are included, the polynomial fit may not always be close to the binscatter fit."
+		   }
+
+	       local poly_first=`byfirst'
+		   local poly_last=`byfirst'-1+`poly_nr'
+
+	       mata:`plotmatby'[|1,`poly_start' \ `poly_nr',`poly_start'+2|]=binsreg_grids("`kmat'",`polyregngrid')
+		   
+	       local poly_series ""
+	       forval i=0/`polyreg' {
+		      tempvar x_var_`i'
+			  qui gen `x_var_`i''=`x_var'^`i' `conds'
+	          local poly_series `poly_series' `x_var_`i''
+		   }
+		 
+		   capture logit `y_var' `poly_series' `w_var' `conds' `wt', nocon `vce' `logitopt'
+		   * store results
+		   tempname poly_b poly_V poly_adjw
+	       if (_rc==0) {
+	 	      matrix `poly_b'=e(b)
+			  matrix `poly_V'=e(V)
+	       }
+	       else {
+	          error  _rc
+	   	      exit _rc
+           }
+		 
+		   * Data for derivative
+		   mata: `Xm'=J(`poly_nr',0,.); `Xm0'=J(`poly_nr',0,.)   
+	       forval i=`deriv'/`polyreg' {
+		      mata: `Xm'=(`Xm', ///
+				      `plotmatby'[|1,`poly_start' \ `poly_nr',`poly_start'|]:^(`i'-`deriv')* ///
+					  factorial(`i')/factorial(`i'-`deriv'))	
+	       }
+		   mata: `Xm'=(J(`poly_nr', `deriv',0), `Xm')
+		   if (`nwvar'>0) {
+		      if (`deriv'==0) mata: `Xm'=(`Xm', J(`poly_nr',1,1)#st_matrix("`wval'"))
+			  else            mata: `Xm'=(`Xm', J(`poly_nr',`nwvar',0))
+		   }
+		   
+		   if ("`transform'"=="T") {
+		      if (`deriv'==0) {
+			     mata:`plotmatby'[|1,`poly_start'+3 \ `poly_nr',`poly_start'+3|]=logistic(`Xm'*st_matrix("`poly_b'")')
+			  }
+			  else if (`deriv'==1) {
+			     forval i=0/`polyreg' {
+		            mata: `Xm0'=(`Xm0', `plotmatby'[|1,`poly_start' \ `poly_nr',`poly_start'|]:^`i')	
+	             }
+				 if (`nwvar'>0) mata: `Xm0'=(`Xm0', J(`poly_nr',1,1)#st_matrix("`wval'"))
+			     mata:`plotmatby'[|1,`poly_start'+3 \ `poly_nr',`poly_start'+3|]=logisticden(`Xm0'*st_matrix("`poly_b'")'):* ///
+				                                                                 (`Xm'*st_matrix("`poly_b'")')
+			  }
+		   }
+		   else {
+		      mata:`plotmatby'[|1,`poly_start'+3 \ `poly_nr',`poly_start'+3|]=`Xm'*st_matrix("`poly_b'")'
+		   }
+		   
+		   mata: mata drop `Xm' `Xm0'
+		   
+		   local plotnum=`plotnum'+1
+		   local col: word `counter_by' of `bycolors'
+		   local lty: word `counter_by' of `bylpatterns'
+		   local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+		         local plotcond `plotcond' poly_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &poly_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' poly_fit>=`min_yr'
+				 else                    local plotcond `plotcond' &poly_fit>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &poly_fit<=`max_yr' 
+		      }
+		   }
+
+		   local plotcmdby `plotcmdby' (line poly_fit poly_x ///
+		                   `plotcond' in `poly_first'/`poly_last', ///
+						   sort lcolor(`col') lpattern(`lty') `polyregplotopt')
+		
+		   * add CI for global poly?
+		   if (`polyregcingrid'!=0) {
+	          local polyci_first=`byfirst'
+			  local polyci_last=`byfirst'-1+`polyci_nr'
+	          
+	          mata: `plotmatby'[|1,`polyci_start' \ `polyci_nr',`polyci_start'+2|]=binsreg_grids("`kmat'", `polyregcingrid')
+		   
+		      mata: `Xm'=J(`polyci_nr',0,.); `Xm0'=J(`polyci_nr',0,.)
+	          forval i=`deriv'/`polyreg' {
+		         mata:`Xm'=(`Xm', ///
+				      `plotmatby'[|1,`polyci_start' \ `polyci_nr',`polyci_start'|]:^(`i'-`deriv')* ///
+					  factorial(`i')/factorial(`i'-`deriv'))	
+	          }
+ 		      mata: `Xm'=(J(`polyci_nr', `deriv',0), `Xm')
+		      if (`nwvar'>0) {
+		         if (`deriv'==0) mata: `Xm'=(`Xm', J(`polyci_nr',1,1)#st_matrix("`wval'"))
+			     else            mata: `Xm'=(`Xm', J(`polyci_nr',`nwvar',0))
+		      }
+			  
+			  if ("`transform'"=="T") {
+		         if (`deriv'==0) {
+				    mata: `mata_fit'=logistic(`Xm'*st_matrix("`poly_b'")')
+					mata: `mata_se'=logisticden(`Xm'*st_matrix("`poly_b'")'):* ///
+					                sqrt(rowsum((`Xm'*st_matrix("`poly_V'")):*`Xm'))
+				 }
+				 else if (`deriv'==1) {
+				    forval i=0/`polyreg' {
+		               mata: `Xm0'=(`Xm0', `plotmatby'[|1,`polyci_start' \ `polyci_nr',`polyci_start'|]:^`i')	
+	                }
+					if (`nwvar'>0) mata: `Xm0'=(`Xm0', J(`polyci_nr',1,1)#st_matrix("`wval'"))
+			        mata:`mata_fit'=logisticden(`Xm0'*st_matrix("`poly_b'")'):* ///
+				                    (`Xm'*st_matrix("`poly_b'")')
+									
+					tempname tempobj
+					mata: `tempobj'=`Xm0'*st_matrix("`poly_b'")'; ///
+					      `tempobj'=logisticden(`tempobj'):*(1:-2*logistic(`tempobj')):*(`Xm'*st_matrix("`poly_b'")'):*`Xm0' + ///
+					                logisticden(`tempobj'):*`Xm'; ///
+						  `mata_se'=sqrt(rowsum((`tempobj'*st_matrix("`poly_V'")):*`tempobj'))
+					mata: mata drop `tempobj'
+				 }
+			  }
+			  else {
+		         mata: `mata_fit'=`Xm'*st_matrix("`poly_b'")';	///			 
+			           `mata_se'=sqrt(rowsum((`Xm'*st_matrix("`poly_V'")):*`Xm')) 
+			  }
+
+			  mata:`plotmatby'[|1,`polyci_start'+3 \ `polyci_nr',`polyci_start'+3|]=`mata_fit'-`mata_se'*invnormal(`alpha'); ///
+				   `plotmatby'[|1,`polyci_start'+4 \ `polyci_nr',`polyci_start'+4|]=`mata_fit'+`mata_se'*invnormal(`alpha'); ///
+				   `plotmatby'[selectindex(`plotmatby'[,`=`polyci_start'+1']:==1),(`=`polyci_start'+3',`=`polyci_start'+4')]=J(`=`nbins'-1',2,.)
+		      
+		      mata: mata drop `Xm' `Xm0' `mata_fit' `mata_se'
+		
+		      * poly ci
+			  local plotnum=`plotnum'+1
+			  local plotcond ""
+		      if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		         local plotcond if
+		         if ("`plotxrange'"!="") {
+		            local plotcond `plotcond' polyCI_x>=`min_xr'
+			        if ("`max_xr'"!="") local plotcond `plotcond' &polyCI_x<=`max_xr' 
+		         }
+			     if ("`plotyrange'"!="") {
+		            if ("`plotxrange'"=="") local plotcond `plotcond' polyCI_l>=`min_yr'
+				    else                    local plotcond `plotcond' &polyCI_l>=`min_yr'
+			        if ("`max_yr'"!="") local plotcond `plotcond' &polyCI_r<=`max_yr' 
+		         }
+		      }
+
+	          local plotcmdby `plotcmdby' (rcap polyCI_l polyCI_r polyCI_x ///
+			                  `plotcond' in `polyci_first'/`polyci_last', ///
+							  sort lcolor(`col') lpattern(`lty') `ciplotopt')
+		   }
+	    }
+	  
+	 
+	    **********************************
+	    ******* Confidence Interval ******
+	    **********************************
+	    if ("`ciON'"=="T") {
+	       local ci_first=`byfirst'
+		   local ci_last=`byfirst'-1+`ci_nr'
+		   
+		   * fitting
+		   tempname ci_b ci_V
+		   capture confirm matrix `line_b' `line_V'
+		   if ("`ci_p'"=="`line_p'"& "`ci_s'"=="`line_s'" & _rc==0) {
+		         matrix `ci_b'=`line_b'
+		         matrix `ci_V'=`line_V'
+		   }
+		   else {
+		      capture confirm matrix `dots_b' `dots_V'
+		      if ("`ci_p'"=="`dots_p'"& "`ci_s'"=="`dots_s'" & _rc==0) {
+		         matrix `ci_b'=`dots_b'
+		         matrix `ci_V'=`dots_V'
+		      }
+		   }
+		   
+		   capture confirm matrix `ci_b' `ci_V' `xmean' 
+		   if (_rc!=0) {
+			    binslogit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                    p(`ci_p') s(`ci_s') type(ci) `vce' ///
+			            xcat(`xcat') kmat(`kmat') dotsmean(`cingrid_mean') /// 
+			            xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						`sorted' `usegtools' logitopt(`logitopt')
+				 
+		        mat `ci_b'=e(bmat)
+		        mat `ci_V'=e(Vmat)
+		        mat `xmean'=e(xmat)
+		   }
+		   
+		   * prediction
+		   if (`cingrid_mean'==0) {
+		      mata: `plotmatby'[|1,`ci_start' \ `ci_nr',`ci_end'|] = ///
+			            binslogit_plotmat("`ci_b'", "`ci_V'", ///
+						      `=invnormal(`alpha')', "`kmat'", ///
+		                      `nbins', `ci_p', `ci_s', `deriv', "ci", ///
+							  `cingrid', "`wval'", `nwvar', "`transform'", "`asyvar'")
+		   }
+		   else {
+		      mata: `plotmatby'[|1,`ci_start' \ `ci_nr',`ci_end'|] = ///
+			            binslogit_plotmat("`ci_b'", "`ci_V'", ///
+						   `=invnormal(`alpha')', "`kmat'", ///
+		                   `nbins', `ci_p', `ci_s', `deriv', "ci", ///
+						   `cingrid', "`wval'", `nwvar', ///
+						   "`transform'", "`asyvar'", "`xmean'")
+		   }
+		   
+		   * ci
+		   local plotnum=`plotnum'+1
+		   local col: word `counter_by' of `bycolors'
+		   local lty: word `counter_by' of `bylpatterns'
+	       local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+	             local plotcond `plotcond' CI_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &CI_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' CI_l>=`min_yr'
+				 else                    local plotcond `plotcond' &CI_l>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &CI_r<=`max_yr' 
+		      }
+		   }
+
+		   local plotcmdby `plotcmdby' (rcap CI_l CI_r CI_x ///
+		                   `plotcond' in `ci_first'/`ci_last', ///
+						   sort lcolor(`col') lpattern(`lty') `ciplotopt')
+
+	    }
+	 
+	    *******************************
+	    ***** Confidence Band *********
+	    *******************************
+	    tempname cval
+	    scalar `cval'=.
+	    if ("`cbON'"=="T") {
+		   if (`nsims'<2000|`simsgrid'<50) {
+	         di as text "Note: A larger number random draws/evaluation points is recommended to obtain the final results."
+	       }
+		   * Prepare grid for plotting
+	       local cb_first=`byfirst'
+		   local cb_last=`byfirst'-1+`cb_nr'
+		
+		   * fitting
+		   tempname cb_b cb_V
+		   capture confirm matrix `ci_b' `ci_V'
+		   if ("`cb_p'"=="`ci_p'"& "`cb_s'"=="`ci_s'" & _rc==0) {
+		      matrix `cb_b'=`ci_b'
+		      matrix `cb_V'=`ci_V'
+		   } 
+		   else {
+		      capture confirm matrix `line_b' `line_V'
+		      if ("`cb_p'"=="`line_p'"& "`cb_s'"=="`line_s'" & _rc==0) {
+		         matrix `cb_b'=`line_b'
+		         matrix `cb_V'=`line_V'
+		      }
+			  else {
+			     capture confirm matrix `dots_b' `dots_V'
+			     if ("`cb_p'"=="`dots_p'"& "`cb_s'"=="`dots_s'" & _rc==0) {
+		            matrix `cb_b'=`dots_b'
+		            matrix `cb_V'=`dots_V'
+		         }
+				 else {
+				    binslogit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                    p(`cb_p') s(`cb_s') type(cb) `vce' ///
+			            xcat(`xcat') kmat(`kmat') dotsmean(0) /// 
+			            xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						`sorted' `usegtools' logitopt(`logitopt')
+					mat `cb_b'=e(bmat)
+		            mat `cb_V'=e(Vmat)
+				 }
+			  }
+		   }
+		
+		   * Compute critical values
+		   * Prepare grid for simulation
+		   local uni_last=`simsngrid'*`nbins'+`nbins'-1
+		   local nseries=(`cb_p'-`cb_s'+1)*(`nbins'-1)+`cb_p'+1
+	       
+		   tempname cb_basis
+		   mata: `cb_basis'=binsreg_grids("`kmat'", `simsngrid'); ///
+		         `cb_basis'=binsreg_spdes(`cb_basis'[,1], "`kmat'", `cb_basis'[,3], `cb_p', `deriv', `cb_s'); ///
+		         `Xm'=binsreg_pred(`cb_basis', st_matrix("`cb_b'")[|1 \ `nseries'|]', ///
+			                       st_matrix("`cb_V'")[|1,1 \ `nseries',`nseries'|], "all"); ///
+			      binsreg_pval(`cb_basis', `Xm'[,2], "`cb_V'", ".", `nsims', `nseries', "two", `=`level'/100', ".", "`cval'", "inf")		  
+		   mata: mata drop `cb_basis' `Xm'
+	          
+	       * prediction
+		   mata: `plotmatby'[|1,`cb_start' \ `cb_nr',`cb_end'|] =   ///
+			                binslogit_plotmat("`cb_b'", "`cb_V'",      ///
+						                      `=`cval'', "`kmat'",       ///
+		                                      `nbins', `cb_p', `cb_s', `deriv', ///
+							                  "cb", `cbngrid', "`wval'", `nwvar', ///
+											  "`transform'", "`asyvar'")	  
+							  
+		   * cb
+		   local plotnum=`plotnum'+1
+		   local col: word `counter_by' of `bycolors'
+	       local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+	             local plotcond `plotcond' CB_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &CB_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' CB_l>=`min_yr'
+				 else                    local plotcond `plotcond' &CB_l>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &(CB_r<=`max_yr'|CB_r==.) 
+		      }
+		   }
+
+		   local plotcmdby (rarea CB_l CB_r CB_x ///
+		                   `plotcond' in `cb_first'/`cb_last', sort cmissing(n) ///
+		                   lcolor(none%0) fcolor(`col'%50) fintensity(50) `cbplotopt') `plotcmdby'
+	    }
+		mat `cvallist'=(nullmat(`cvallist') \ `cval')
+		
+		local plotcmd `plotcmd' `plotcmdby'
+		mata: `plotmat'=(`plotmat' \ `plotmatby')
+		
+		*********************************
+	    **** display ********************
+	    *********************************	 
+	    di ""
+	    * Plotting
+	    if ("`plot'"=="") {
+		   if (`counter_by'==1) {
+		      di in smcl in gr "Binscatter plot, logit model"
+	          di in smcl in gr "Bin selection method: `binselectmethod'"
+	          di in smcl in gr "Placement: `placement'"
+	          di in smcl in gr "Derivative: `deriv'"
+		      if (`"`savedata'"'!=`""') {
+		         di in smcl in gr `"Output file: `savedata'.dta"'
+		      }
+		   }
+		   di ""
+		   if ("`by'"!="") {
+		      di in smcl in gr "Group: `byvarname' = " in yellow "`byvalname'"
+		   }
+	       di in smcl in gr "{hline 30}{c TT}{hline 15}"
+	       di in smcl in gr "{lalign 1:# of observations}"      _col(30) " {c |} " _col(32) as result %7.0f `N'
+	       di in smcl in gr "{lalign 1:# of distinct values}"   _col(30) " {c |} " _col(32) as result %7.0f `Ndist'
+	       di in smcl in gr "{lalign 1:# of clusters}"          _col(30) " {c |} " _col(32) as result %7.0f `Nclust'	 
+	       di in smcl in gr "{hline 30}{c +}{hline 15}"
+	       di in smcl in gr "{lalign 1:Bin/Degree selection:}"                   _col(30) " {c |} "
+		   if ("`selection'"=="P") {
+		   di in smcl in gr "{ralign 29:Degree of polynomial}"         _col(30) " {c |} " _col(32) as result %7.0f `binsp'
+	       di in smcl in gr "{ralign 29:# of smoothness constraints}"  _col(30) " {c |} " _col(32) as result %7.0f `binss'
+		   }
+		   else {
+	       di in smcl in gr "{ralign 29:Degree of polynomial}"         _col(30) " {c |} " _col(32) as result %7.0f `dots_p'
+	       di in smcl in gr "{ralign 29:# of smoothness constraints}"  _col(30) " {c |} " _col(32) as result %7.0f `dots_s'
+		   }
+
+		   di in smcl in gr "{ralign 29:# of bins}"                       _col(30) " {c |} " _col(32) as result %7.0f `nbins'
+	       if ("`binselectmethod'"!="User-specified") {
+		      if ("`binsmethod'"=="ROT") {
+		         di in smcl in gr "{ralign 29:imse, bias^2}"                 _col(30) " {c |} " _col(32) as result %7.3f `=`mat_imse_bsq_rot'[`counter_by',1]'
+	             di in smcl in gr "{ralign 29:imse, var.}"                   _col(30) " {c |} " _col(32) as result %7.3f `=`mat_imse_var_rot'[`counter_by',1]'
+			  }
+			  else if ("`binsmethod'"=="DPI") {
+			     di in smcl in gr "{ralign 29:imse, bias^2}"                 _col(30) " {c |} " _col(32) as result %7.3f `=`mat_imse_bsq_dpi'[`counter_by',1]'
+	             di in smcl in gr "{ralign 29:imse, var.}"                   _col(30) " {c |} " _col(32) as result %7.3f `=`mat_imse_var_dpi'[`counter_by',1]'
+			  }
+		   }
+		   di in smcl in gr "{hline 30}{c BT}{hline 15}"
+		   di ""
+		   di in smcl in gr "{hline 9}{c TT}{hline 30}"
+		   di in smcl _col(10) "{c |}" in gr _col(17) "p" _col(25) "s" _col(33) "df"
+		   di in smcl in gr "{hline 9}{c +}{hline 30}"
+		   if (`dotsntot'!=0) {
+		      local dots_df=(`dots_p'-`dots_s'+1)*(`nbins'-1)+`dots_p'+1
+		      di in smcl in gr "{lalign 1: dots}"  _col(10) "{c |}" in gr _col(17) "`dots_p'" _col(25) "`dots_s'" _col(33) "`dots_df'"
+		   }
+		   if ("`lineON'"=="T") {
+		      local line_df=(`line_p'-`line_s'+1)*(`nbins'-1)+`line_p'+1
+		      di in smcl in gr "{lalign 1: line}"  _col(10) "{c |}" in gr _col(17) "`line_p'" _col(25) "`line_s'" _col(33) "`line_df'"
+		   }
+		   if (`cintot'!=0) {
+		      local ci_df=(`ci_p'-`ci_s'+1)*(`nbins'-1)+`ci_p'+1
+		      di in smcl in gr "{lalign 1: CI}"  _col(10) "{c |}" in gr _col(17) "`ci_p'" _col(25) "`ci_s'" _col(33) "`ci_df'"
+		   }
+		   if ("`cbON'"=="T") {
+		      local cb_df=(`cb_p'-`cb_s'+1)*(`nbins'-1)+`cb_p'+1
+		      di in smcl in gr "{lalign 1: CB}"  _col(10) "{c |}" in gr _col(17) "`cb_p'" _col(25) "`cb_s'" _col(33) "`cb_df'"
+		   }
+		   if ("`polyON'"=="T") {
+		      local poly_df=`polyreg'+1
+		      di in smcl in gr "{lalign 1: polyreg}"  _col(10) "{c |}" in gr _col(17) "`polyreg'" _col(25) "NA" _col(33) "`poly_df'"
+		   }
+		   di in smcl in gr "{hline 9}{c BT}{hline 30}"
+	    }
+		
+		
+		mata: mata drop `plotmatby'
+		local ++counter_by
+	 }
+	 mata: mata drop `xsub' `ysub' `binedges'
+	 if (`bynum'>1) mata: mata drop `byindex'
+	 capture mata: mata drop `xcatsub'
+	 ****************** END loop ****************************************
+	 ********************************************************************
+	 
+
+	 
+	 *******************************************
+	 *************** Plotting ******************
+	 *******************************************
+	 clear
+	 if ("`plotcmd'"!="") {
+	    * put data back to STATA
+		mata: st_local("nr", strofreal(rows(`plotmat'))) 
+		qui set obs `nr'
+		
+		* MAKE SURE the orderings match
+		qui gen group=. in 1
+		if (`dotsntot'!=0) {
+		   qui gen dots_x=. in 1
+		   qui gen dots_isknot=. in 1
+		   qui gen dots_binid=. in 1 
+		   qui gen dots_fit=. in 1
+		}
+	    if (`linengrid'!=0&"`fullfewobs'"=="") {
+		   qui gen line_x=. in 1
+		   qui gen line_isknot=. in 1
+		   qui gen line_binid=. in 1 
+		   qui gen line_fit=. in 1
+		}
+        if (`polyregngrid'!=0) {
+		   qui gen poly_x=. in 1
+		   qui gen poly_isknot=. in 1
+		   qui gen poly_binid=. in 1
+		   qui gen poly_fit=. in 1
+		   if (`polyregcingrid'!=0) {
+		      qui gen polyCI_x=. in 1
+			  qui gen polyCI_isknot=. in 1
+			  qui gen polyCI_binid=. in 1
+			  qui gen polyCI_l=. in 1
+			  qui gen polyCI_r=. in 1
+		   }
+		}
+		if (`cintot'!=0) {
+           qui gen CI_x=. in 1
+		   qui gen CI_isknot=. in 1
+		   qui gen CI_binid=. in 1
+		   qui gen CI_l=. in 1
+		   qui gen CI_r=. in 1 
+		}
+		if (`cbngrid'!=0&"`fullfewobs'"=="") {
+           qui gen CB_x=. in 1
+		   qui gen CB_isknot=. in 1
+		   qui gen CB_binid=. in 1
+		   qui gen CB_l=. in 1
+		   qui gen CB_r=. in 1
+		}
+			
+		mata: st_store(.,.,`plotmat')
+		
+		* Legend
+		local plot_legend legend(order(
+	    if ("`by'"!=""&`dotsntot'!=0) {
+		  forval i=1/`bynum' {
+			 local byvalname: word `i' of `byvalnamelist'
+	         local plot_legend `plot_legend' `: word `i' of `legendnum'' "`byvarname'=`byvalname'"		  
+	      }
+		  local plot_legend `plot_legend' ))
+	    }
+		else {
+		   local plot_legend legend(off)
+		}
+		
+		* Plot it
+	    local graphcmd twoway `plotcmd', xtitle(`x_varname') ytitle(`y_varname') xscale(range(`xsc')) `plot_legend' `options' 
+	    `graphcmd'
+	 }
+	 mata: mata drop `plotmat' `xvec' `yvec' `byvec' `cluvec'
+	 
+	 
+	 * Save graph data ?
+	 * In the normal case
+     if (`"`savedata'"'!=`""'&`"`plotcmd'"'!=`""') {		
+		* Add labels
+		if ("`by'"!="") {
+		    if ("`bystring'"=="T") {
+			   label val group `bylabel'
+			   decode group, gen(`byvarname')
+			}
+		    else {
+			   qui gen `byvarname'=group
+			   if ("`bylabel'"!="") label val `byvarname' `bylabel'
+			}
+			label var `byvarname' "Group"
+			qui drop group
+			order `byvarname'
+		}
+		else qui drop group
+		
+		capture confirm variable dots_x dots_binid dots_isknot dots_fit
+		if (_rc==0) {
+			label var dots_x "Dots: grid"
+			label var dots_binid "Dots: indicator of bins"
+			label var dots_isknot "Dots: indicator of inner knot"
+			label var dots_fit "Dots: fitted values"
+		}
+		capture confirm variable line_x line_binid line_isknot line_fit
+		if (_rc==0) {
+			label var line_x "Line: grid"
+			label var line_binid "Line: indicator of bins"
+			label var line_isknot "Line: indicator of inner knot"
+			label var line_fit "Line: fitted values"
+		}
+		capture confirm variable poly_x poly_binid poly_isknot poly_fit
+		if (_rc==0) {
+			label var poly_x "Poly: grid"
+			label var poly_binid "Poly: indicator of bins"
+			label var poly_isknot "Poly: indicator of inner knot"
+			label var poly_fit "Poly: fitted values"
+		}
+		capture confirm variable polyCI_x polyCI_binid polyCI_isknot polyCI_l polyCI_r
+		if (_rc==0) {
+			label var polyCI_x "Poly confidence interval: grid"
+			label var polyCI_binid "Poly confidence interval: indicator of bins"
+			label var polyCI_isknot "Poly confidence interval: indicator of inner knot"
+			label var polyCI_l "Poly confidence interval: left boundary"
+			label var polyCI_r "Poly confidence interval: right boundary"
+		}
+		capture confirm variable CI_x CI_binid CI_isknot CI_l CI_r
+		if (_rc==0) {
+			label var CI_x "Confidence interval: grid"
+			label var CI_binid "Confidence interval: indicator of bins"
+			label var CI_isknot "Confidence interval: indicator of inner knot"
+			label var CI_l "Confidence interval: left boundary"
+			label var CI_r "Confidence interval: right boundary"
+		}
+		capture confirm variable CB_x CB_binid CB_isknot CB_l CB_r
+		if (_rc==0) {
+			label var CB_x "Confidence band: grid"			
+		    label var CB_binid "Confidence band: indicator of bins"
+		    label var CB_isknot "Confidence band: indicator of inner knot"
+			label var CB_l "Confidence band: left boundary"
+			label var CB_r "Confidence band: right boundary"
+		}
+	    qui save `"`savedata'"', `replace'
+	 }
+	 ***************************************************************************
+	 	 
+	 *********************************
+	 ********** Return ***************
+	 *********************************
+	 ereturn clear
+	 * # of observations
+	 ereturn scalar N=`Ntotal'
+	 * Options
+	 ereturn scalar level=`level'
+	 ereturn scalar dots_p=`dots_p'
+	 ereturn scalar dots_s=`dots_s'
+	 ereturn scalar line_p=`line_p'
+	 ereturn scalar line_s=`line_s'
+	 ereturn scalar ci_p=`ci_p'
+	 ereturn scalar ci_s=`ci_s'
+	 ereturn scalar cb_p=`cb_p'
+	 ereturn scalar cb_s=`cb_s'
+	 * by group:
+	 *ereturn matrix knot=`kmat'
+	 ereturn matrix cval_by=`cvallist'
+	 ereturn matrix nbins_by=`nbinslist'
+	 ereturn matrix Nclust_by=`Nclustlist'
+	 ereturn matrix Ndist_by=`Ndistlist'
+	 ereturn matrix N_by=`Nlist'
+
+	 ereturn matrix imse_var_rot=`mat_imse_var_rot'
+	 ereturn matrix imse_bsq_rot=`mat_imse_bsq_rot'
+	 ereturn matrix	imse_var_dpi=`mat_imse_var_dpi'
+	 ereturn matrix imse_bsq_dpi=`mat_imse_bsq_dpi'
+end
+
+* Helper commands
+* Estimation
+program define binslogit_fit, eclass
+     version 13
+     syntax varlist(min=2 numeric ts fv) [if] [in] [fw aw pw] [, deriv(integer 0) ///
+	        p(integer 0) s(integer 0) type(string) vce(passthru)  ///
+			xcat(varname numeric) kmat(name) dotsmean(integer 0) ///        /* xmean: report x-mean? */
+			xname(name) yname(name) catname(name) edge(name) ///
+			usereg sorted usegtools logitopt(string asis)]                  /* usereg: force the command to use reg; sored: sorted data? */
+	 
+	 preserve
+	 marksample touse
+	 qui keep if `touse'
+	 
+	 if ("`weight'"!="") local wt [`weight'`exp']
+	 
+	 tokenize `varlist'
+	 local y_var `1'
+	 local x_var `2'
+	 macro shift 2
+	 local w_var "`*'"
+	 local nbins=rowsof(`kmat')-1
+	 
+	 tempname matxmean temp_b temp_V
+	 mat `matxmean'=.
+	 mat `temp_b'=.
+	 mat `temp_V'=.
+	 
+	 if (`dotsmean'!=0) {
+	    if ("`sorted'"==""|"`weight'"!=""|"`usegtools'"!="") {
+	       if ("`usegtools'"=="") {
+		      tempfile tmpfile
+			  qui save `tmpfile', replace
+			  
+		      collapse (mean) `x_var' `wt', by(`xcat') fast
+		      mkmat `xcat' `x_var', matrix(`matxmean')
+			  
+			  use `tmpfile', clear
+		   }
+		   else {
+		      tempname obj
+		      qui gstats tabstat `x_var' `wt', stats(mean) by(`xcat') matasave("`obj'")
+			  mata: st_matrix("`matxmean'", (`obj'.getnum(.,1), `obj'.getOutputVar("`x_var'")))	
+		      mata: mata drop `obj'
+		   }
+		}
+		else {
+		   tempname output
+		   mata: `output'=binsreg_stat(`xname', `catname', `nbins', `edge', "mean", -1); ///
+				 st_matrix("`matxmean'", `output')
+		   mata: mata drop `output'
+		}
+	 }
+	 
+	 * Regression?
+	 if (`p'==0) {
+		 capture logit `y_var' ibn.`xcat' `w_var' `wt', nocon `vce' `logitopt'
+		 if (_rc==0) {
+		    matrix `temp_b'=e(b)
+		    matrix `temp_V'=e(V)
+		 }
+		 else {
+		    error _rc
+			exit _rc
+		 }
+	 }
+	 else {
+	     local nseries=(`p'-`s'+1)*(`nbins'-1)+`p'+1
+	     local series ""
+	     forvalues i=1/`nseries' {
+	        tempvar sp`i'
+	        local series `series' `sp`i''
+		    qui gen `sp`i''=. in 1
+	     }
+	
+		 mata: binsreg_st_spdes(`xname', "`series'", "`kmat'", `catname', `p', 0, `s')
+		 
+		 capture logit `y_var' `series' `w_var' `wt', nocon `vce' `logitopt'
+	     * store results
+	     if (_rc==0) {
+		    matrix `temp_b'=e(b)
+		    matrix `temp_V'=e(V)
+			mata: binsreg_checkdrop("`temp_b'", "`temp_V'", `nseries')
+	     }
+	     else {
+	        error  _rc
+	   	    exit _rc
+         }
+	 }
+	 
+	 
+	 ereturn clear
+	 ereturn matrix bmat=`temp_b'
+	 ereturn matrix Vmat=`temp_V'
+	 ereturn matrix xmat=`matxmean'         /* xcat, xbar */
+end
+
+mata:
+
+  // Prediction for plotting
+  real matrix binslogit_plotmat(string scalar eb, string scalar eV, real scalar cval, ///
+                                string scalar knotname, real scalar J, ///
+                                real scalar p, real scalar s, real scalar deriv, ///
+                                string scalar type, real scalar ngrid, string scalar muwmat, ///
+							    real scalar nw, string scalar transform, string scalar avar, | string scalar muxmat) 
+  {
+    real matrix coef, bmat, rmat, vmat, knot, xmean, wval, eval, out, fit, fit0, se, semat, Xm, Xm0, result
+	real scalar nseries
+	
+	nseries=(p-s+1)*(J-1)+p+1
+	coef=st_matrix(eb)'
+	bmat=coef[|1\nseries|]
+	if (nw>0) rmat=coef[|(nseries+1)\rows(coef)|]
+	
+	if (type=="ci"|type=="cb") {
+	   vfull=st_matrix(eV)
+	   vmat=vfull[|1,1\nseries,nseries|]
+	}
+    
+    // Prepare evaluation points
+    eval=J(0,3,.)
+    if (args()==15) {
+	   xmean=st_matrix(muxmat)
+       eval=(eval \ (xmean[,2], J(J, 1, 0), xmean[,1])) 
+    }
+    if (ngrid!=0) {
+	   eval=(eval \ binsreg_grids(knotname, ngrid))
+    }
+	
+	// adjust w variables
+	if (nw>0) {
+	   wvec=st_matrix(muwmat)
+       wval=wvec*rmat
+	}
+	else wval=0
+
+	fit=J(0,1,.)
+	se=J(0,1,.)
+	if (p==0) {
+	   if (args()==15) fit=(fit \ bmat)
+	   if (ngrid!=0) {
+	     fit=(fit \ (bmat#(J(ngrid,1,1)\.)))
+		 fit=fit[|1 \ (rows(fit)-1)|]
+	   }
+	   if (type=="ci"|type=="cb") {
+	      if (avar=="on") semat=sqrt(diagonal(vmat))
+		  else {
+		     if (nw>0) {
+			    Xm=(I(nseries), J(nseries,1,1)#wvec)
+				semat=sqrt(rowsum((Xm*vfull):*Xm))
+			 }
+			 else semat=sqrt(diagonal(vmat))
+		  }
+		  if (args()==15) se=(se \ semat)
+		  if (ngrid!=0) {
+		     se=(se \ (semat#(J(ngrid,1,1)\.)))
+		     se=se[|1 \ (rows(se)-1)|]
+		  }
+	   }
+	   if (type=="dots"|type=="line") {
+	      if (transform=="T") out=(eval, logistic(fit:+wval))
+		  else                out=(eval, fit:+wval)
+	   }
+	   else {
+	      if (transform=="T") out=(eval, logistic(fit:+wval)-(logisticden(fit:+wval):*se)*cval, ///
+		                                 logistic(fit:+wval)+(logisticden(fit:+wval):*se)*cval)
+		  else                out=(eval, (fit:+wval)-se*cval, (fit:+wval)+se*cval)
+	   }
+	}
+	else {
+	   Xm=binsreg_spdes(eval[,1], knotname, eval[,3], p, deriv, s)
+	   if (type=="dots"|type=="line") {
+	      if (transform=="T") {
+		     fit=binsreg_pred(Xm, bmat, ., "xb")[,1]
+		     if (deriv==0) {
+			    fit=logistic(fit:+wval)
+			 }
+			 if (deriv==1) {
+			    Xm0=binsreg_spdes(eval[,1], knotname, eval[,3], p, 0, s)
+			    fit0=binsreg_pred(Xm0, bmat, ., "xb")[,1]
+			    fit=logisticden(fit0:+wval):*fit
+			 }
+			 out=(eval, fit)
+		  }
+		  else {
+	         fit=binsreg_pred(Xm, bmat, ., "xb")[,1]
+			 if (deriv==0) out=(eval, fit:+wval)
+			 else          out=(eval, fit)
+		  }
+	   }
+	   else {
+	      if (avar=="on") {
+	   	     result=binsreg_pred(Xm, bmat, vmat, "all")
+	         if (transform=="T") {
+		  	    Xm0=binsreg_spdes(eval[,1], knotname, eval[,3], p, 0, s)
+			    fit0=binsreg_pred(Xm0, bmat, ., "xb")[,1]
+		        result[,2]=logisticden(fit0:+wval):*result[,2]
+			 
+		        if (deriv==0) {
+			       result[,1]=logistic(result[,1]:+wval)
+			    }
+			    else if (deriv==1) {
+			       result[,1]=logisticden(fit0:+wval):*result[,1]
+			    }
+			 
+			    out=(eval, result[,1]-cval*result[,2], result[,1]+cval*result[,2])
+		     }
+		     else {
+		        if (deriv==0) out=(eval, (result[,1]:+wval)-cval*result[,2], (result[,1]:+wval)+cval*result[,2])
+			    else          out=(eval, result[,1]-cval*result[,2], result[,1]+cval*result[,2])
+	         }
+		  }
+		  else {
+		     result=binsreg_pred(Xm, bmat, vmat, "all")
+		     if (transform=="T") {				
+				if (deriv==0) {
+				   if (nw>0) Xm=(Xm, J(rows(Xm),1,1)#wvec)
+				   result[,2]=logisticden(result[,1]:+wval):*sqrt(rowsum((Xm*vfull):*Xm))
+				   result[,1]=logistic(result[,1]:+wval)
+				}
+				if (deriv==1) {
+				   Xm0=binsreg_spdes(eval[,1], knotname, eval[,3], p, 0, s)
+				   if (nw>0) {
+				      Xm0=(Xm0, J(rows(Xm0),1,1)#wvec)
+					  Xm=(Xm, J(rows(Xm),nw,0))
+				   }
+			       fit0=binsreg_pred(Xm0, coef, ., "xb")[,1]
+				   Xm=logisticden(fit0):*(1:-2*logistic(fit0)):*result[,1]:*Xm0 + ///
+				      logisticden(fit0):*Xm
+				   result[,2]=sqrt(rowsum((Xm*vfull):*Xm))
+				   result[,1]=logisticden(fit0):*result[,1]
+				}
+				out=(eval, result[,1]-cval*result[,2], result[,1]+cval*result[,2])
+			 }
+			 else {
+			    if (nw>0) {
+				   if (deriv==0) Xm=(Xm, J(rows(Xm),1,1)#wvec)
+				   else          Xm=(Xm, J(rows(Xm),nw,0))
+				}
+				result=binsreg_pred(Xm, coef, vfull, "all")
+				out=(eval, result[,1]-cval*result[,2], result[,1]+cval*result[,2])
+			 }
+		  }
+	   }
+	}
+
+	if (type=="dots"|(type=="line"&(s==0|s-deriv<=0))) {
+	   out[selectindex(out[,2]:==1),4]=J(sum(out[,2]),1,.)
+	}
+	if (type=="ci"|(type=="cb"&(s==0|s-deriv<=0))) {
+	   out[selectindex(out[,2]:==1),4..5]=J(sum(out[,2]),2,.)
+	}
+	
+	return(out)
+  }
+
+  
+end
+

110/replication_package/replication/ado/plus/b/binslogit.sthlp

@@ -0,0 +1,427 @@
+{smcl}
+{* *! version 1.2 09-OCT-2022}{...}
+{viewerjumpto "Syntax" "binslogit##syntax"}{...}
+{viewerjumpto "Description" "binslogit##description"}{...}
+{viewerjumpto "Options" "binslogit##options"}{...}
+{viewerjumpto "Examples" "binslogit##examples"}{...}
+{viewerjumpto "Stored results" "binslogit##stored_results"}{...}
+{viewerjumpto "References" "binslogit##references"}{...}
+{viewerjumpto "Authors" "binslogit##authors"}{...}
+{cmd:help binslogit}
+{hline}
+
+{title:Title}
+
+{p 4 8}{hi:binslogit} {hline 2} Data-Driven Binscatter Logit Estimation with Robust Inference Procedures and Plots.{p_end}
+
+
+{marker syntax}{...}
+{title:Syntax}
+
+{p 4 14} {cmdab:binslogit} {depvar} {it:indvar} [{it:othercovs}] {ifin} {weight} [ {cmd:,} {opt deriv(v)} {opt at(position)} {opt nolink}{p_end}
+{p 14 14} {opt dots(dotsopt)} {opt dotsgrid(dotsgridoption)} {opt dotsplotopt(dotsoption)}{p_end}
+{p 14 14} {opt line(lineopt)} {opt linegrid(#)} {opt lineplotopt(lineoption)}{p_end}
+{p 14 14} {opt ci(ciopt)} {opt cigrid(cigridoption)} {opt ciplotopt(rcapoption)}{p_end}
+{p 14 14} {opt cb(cbopt)} {opt cbgrid(#)} {opt cbplotopt(rareaoption)}{p_end}
+{p 14 14} {opt polyreg(p)} {opt polyreggrid(#)} {opt polyregcigrid(#)} {opt polyregplotopt(lineoption)}{p_end}
+{p 14 14} {opth by(varname)} {cmd:bycolors(}{it:{help colorstyle}list}{cmd:)} {cmd:bysymbols(}{it:{help symbolstyle}list}{cmd:)} {cmd:bylpatterns(}{it:{help linepatternstyle}list}{cmd:)}{p_end}
+{p 14 14} {opt nbins(nbinsopt)} {opt binspos(position)} {opt binsmethod(method)} {opt nbinsrot(#)} {opt samebinsby} {opt randcut(#)}{p_end}
+{p 14 14} {cmd:pselect(}{it:{help numlist}}{cmd:)} {cmd:sselect(}{it:{help numlist}}{cmd:)}{p_end}
+{p 14 14} {opt nsims(#)} {opt simsgrid(#)} {opt simsseed(seed)}{p_end}
+{p 14 14} {opt dfcheck(n1 n2)} {opt masspoints(masspointsoption)}{p_end}
+{p 14 14} {cmd:vce(}{it:{help vcetype}}{cmd:)} {opt asyvar(on/off)}{p_end}
+{p 14 14} {opt level(level)} {opt logitopt(logit_option)} {opt usegtools(on/off)} {opt noplot} {opt savedata(filename)} {opt replace}{p_end}
+{p 14 14} {opt plotxrange(min max)} {opt plotyrange(min max)} {it:{help twoway_options}} ]{p_end}
+
+{p 4 8} where {depvar} is the dependent variable, {it:indvar} is the independent variable for binning, and {it:othercovs} are other covariates to be controlled for.{p_end}
+
+{p 4 8} The degree of the piecewise polynomial p, the number of smoothness constraints s, and the derivative order v are integers 
+satisfying 0 <= s,v <= p, which can take different values in each case.{p_end}
+
+{p 4 8} {opt fweight}s and {opt pweight}s are allowed; see {help weight}.{p_end}
+
+{marker description}{...}
+{title:Description}
+
+{p 4 8} {cmd:binslogit} implements binscatter logit estimation with robust inference procedures and plots, following the results in
+{browse "https://nppackages.github.io/references/Cattaneo-Crump-Farrell-Feng_2022_Binscatter.pdf":Cattaneo, Crump, Farrell and Feng (2022a)}.
+Binscatter provides a flexible way of describing the mean relationship between two variables, after possibly adjusting for other covariates, based on partitioning/binning of the independent variable of interest.
+The main purpose of this command is to generate binned scatter plots with curve estimation with robust pointwise confidence intervals and uniform confidence band.
+If the binning scheme is not set by the user, the companion command {help binsregselect:binsregselect} is used to implement binscatter
+in a data-driven way.
+Hypothesis testing for parametric specifications of and shape restrictions on the regression function can be conducted via the
+companion command {help binstest:binstest}. Hypothesis testing for pairwise group comparisons can be conducted via the
+companion command {help binspwc: binspwc}. Binscatter estimation based on the least squares method can be conducted via the command {help binsreg: binsreg}.
+{p_end}
+
+{p 4 8} A detailed introduction to this command is given in
+{browse "https://nppackages.github.io/references/Cattaneo-Crump-Farrell-Feng_2022_Stata.pdf":Cattaneo, Crump, Farrell and Feng (2022b)}.
+Companion R and Python packages with the same capabilities are available (see website below).
+{p_end}
+
+{p 4 8} Companion commands: {help binstest:binstest} for hypothesis testing of parametric specifications and shape restrictions,
+{help binspwc:binspwc} for hypothesis testing for pairwise group comparisons,
+and {help binsregselect:binsregselect} for data-driven binning selection.
+{p_end}
+
+{p 4 8} Related Stata, R and Python packages are available in the following website:{p_end}
+
+{p 8 8} {browse "https://nppackages.github.io/":https://nppackages.github.io/}{p_end}
+
+
+{marker options}{...}
+{title:Options}
+
+{dlgtab:Estimand}
+
+{p 4 8} {opt deriv(v)} specifies the derivative order of the regression function for estimation and plotting.
+The default is {cmd:deriv(0)}, which corresponds to the function itself.
+{p_end}
+
+{p 4 8} {opt at(position)} specifies the values of {it:othercovs} at which the estimated function is evaluated for plotting.
+The default is {cmd:at(mean)}, which corresponds to the mean of {it:othercovs}. Other options are: {cmd:at(median)} for the median of {it:othercovs},
+{cmd:at(0)} for zeros, and {cmd:at(filename)} for particular values of {it:othercovs} saved in another file.
+{p_end}
+
+{p 4 8} Note: When {cmd:at(mean)} or {cmd:at(median)} is specified, all factor variables in {it:othercovs} (if specified) are excluded from the evaluation (set as zero).
+{p_end}
+
+{p 4 8}{opt nolink} specifies that the function within the inverse link (logistic) function be reported instead of the conditional probability function.
+{p_end}
+
+{dlgtab:Dots}
+
+{p 4 8} {opt dots(dotsopt)} sets the degree of polynomial and the number of smoothness for point estimation and plotting as "dots".
+If {cmd:dots(p s)} is specified, a piecewise polynomial of degree {it:p} with {it:s} smoothness constraints is used.  
+The default is {cmd:dots(0 0)}, which corresponds to piecewise constant (canonical binscatter). 
+If {cmd:dots(T)} is specified, the default {cmd:dots(0 0)} is used unless the degree {it:p} and smoothness {it:s} selection
+is requested via the option {cmd:pselect()} (see more details in the explanation of {cmd:pselect()}).  
+If {cmd:dots(F)} is specified, the dots are not included in the plot.
+{p_end}
+
+{p 4 8} {opt dotsgrid(dotsgridoption)} specifies the number and location of dots within each bin to be plotted.
+Two options are available: {it:mean} and a {it:numeric} non-negative integer.
+The option {opt dotsgrid(mean)} adds the sample average of {it:indvar} within each bin to the grid of evaluation points.
+The option {opt dotsgrid(#)} adds {it:#} number of evenly-spaced points to the grid of evaluation points for each bin.
+Both options can be used simultaneously: for example, {opt dotsgrid(mean 5)} generates six evaluation points
+within each bin containing the sample mean of {it:indvar} within each bin and five evenly-spaced points.
+Given this choice, the dots are point estimates evaluated over the selected grid within each bin.
+The default is {opt dotsgrid(mean)}, which corresponds to one dot per bin evaluated at the sample average of {it:indvar} within each bin (canonical binscatter).
+{p_end}
+
+{p 4 8} {opt dotsplotopt(dotsoption)} standard graphs options to be passed on to the {help twoway:twoway} command to modify the appearance of the plotted dots.
+{p_end}
+
+{dlgtab:Line}
+
+{p 4 8} {opt line(lineopt)} sets the degree of polynomial and the number of smoothness constraints 
+for plotting as a "line". If {cmd:line(p s)} is specified, a piecewise polynomial of 
+degree {it:p} with {it:s} smoothness constraints is used.  
+If {cmd:line(T)} is specified, {cmd:line(0 0)} is used unless the degree {it:p} and smoothness {it:s} selection
+is requested via the option {cmd:pselect()} (see more details in the explanation of {cmd:pselect()}). 
+If {cmd:line(F)} or {cmd:line()} is specified, the line is not included in the plot.
+The default is {cmd:line()}.
+{p_end}
+
+{p 4 8} {opt linegrid(#)} specifies the number of evaluation points of an evenly-spaced grid within
+each bin used for evaluation of the point estimate set by the {cmd:line(p s)} option.
+The default is {cmd:linegrid(20)}, which corresponds to 20 evenly-spaced evaluation points within each bin for fitting/plotting the line.
+{p_end}
+
+{p 4 8} {opt lineplotopt(lineoption)} standard graphs options to be passed on to
+the {help twoway:twoway} command to modify the appearance of the plotted line.
+{p_end}
+
+{dlgtab:Confidence Intervals}
+
+{p 4 8} {opt ci(ciopt)} specifies the degree of polynomial and the number of smoothness constraints
+for constructing confidence intervals. If {cmd:ci(p s)} is specified, a piecewise polynomial of 
+degree {it:p} with {it:s} smoothness constraints is used.  
+If {cmd:ci(T)} is specified, {cmd:ci(1 1)} is used unless the degree {it:p} and smoothness {it:s} selection
+is requested via the option {cmd:pselect()} (see more details in the explanation of {cmd:pselect()}). 
+If {cmd:ci(F)} or {cmd:ci()} is specified, the confidence intervals are not included in the plot. 
+The default is {cmd:ci()}.
+{p_end}
+
+{p 4 8} {opt cigrid(cigridoption)} specifies the number and location of evaluation points in the grid
+used to construct the confidence intervals set by the {opt ci(p s)} option.
+Two options are available: {it:mean} and a {it:numeric} non-negative integer.
+The option {opt cigrid(mean)} adds the sample average of {it:indvar} within each bin to the grid of evaluation points.
+The option {opt cigrid(#)} adds {it:#} number of evenly-spaced points to the grid of evaluation points for each bin.
+Both options can be used simultaneously: for example, {opt cigrid(mean 5)} generates six evaluation points within each bin containing the sample mean of {it:indvar} within each bin and five evenly-spaced points.
+The default is {opt cigrid(mean)}, which corresponds to one evaluation point set at the sample average of {it:indvar} within each bin for confidence interval construction.
+{p_end}
+
+{p 4 8} {opt ciplotopt(rcapoption)} standard graphs options to be passed on to the {help twoway:twoway} command to modify the appearance of the confidence intervals.
+{p_end}
+
+{dlgtab:Confidence Band}
+
+{p 4 8} {opt cb(cbopt)} specifies the degree of polynomial and the number of smoothness constraints
+for constructing the confidence band. If {cmd:cb(p s)} is specified, a piecewise polynomial of 
+degree {it:p} with {it:s} smoothness constraints is used. 
+If the option {cmd:cb(T)} is specified, {cmd:cb(1 1)} is used unless the degree {it:p} and smoothness {it:s} selection
+is requested via the option {cmd:pselect()} (see more details in the explanation of {cmd:pselect()}). 
+If {cmd:cb(F)} or {cmd:cb()} is specified, the confidence band is not included in the plot.
+The default is {cmd:cb()}.
+{p_end}
+
+{p 4 8} {opt cbgrid(#)} specifies the number of evaluation points of an evenly-spaced grid within each bin
+used for evaluation of the point estimate set by the {cmd:cb(p s)} option.
+The default is {cmd:cbgrid(20)}, which corresponds to 20 evenly-spaced evaluation points within each bin for confidence band construction.
+{p_end}
+
+{p 4 8} {opt cbplotopt(rareaoption)} standard graphs options to be passed on to
+the {help twoway:twoway} command to modify the appearance of the confidence band.
+{p_end}
+
+{dlgtab:Global Polynomial Regression}
+
+{p 4 8} {opt polyreg(p)} sets the degree {it:p} of a global polynomial regression model for plotting.
+By default, this fit is not included in the plot unless explicitly specified.
+Recommended specification is {cmd:polyreg(3)}, which adds a cubic polynomial fit of the regression function of interest to the binned scatter plot. 
+{p_end}
+
+{p 4 8} {opt polyreggrid(#)} specifies the number of evaluation points of an evenly-spaced grid
+within each bin used for evaluation of the point estimate set by the {cmd:polyreg(p)} option.
+The default is {cmd:polyreggrid(20)}, which corresponds to 20 evenly-spaced evaluation points within each bin for confidence interval construction.
+{p_end}
+
+{p 4 8} {opt polyregcigrid(#)} specifies the number of evaluation points of an evenly-spaced grid within each bin used for constructing confidence intervals based on polynomial regression set by the {cmd:polyreg(p)} option.
+The default is {cmd:polyregcigrid(0)}, which corresponds to not plotting confidence intervals for the global polynomial regression approximation.
+{p_end}
+
+{p 4 8} {opt polyregplotopt(lineoption)} standard graphs options to be passed on to the {help twoway:twoway} command to modify the appearance of the global polynomial regression fit.
+{p_end}
+
+{dlgtab:Subgroup Analysis}
+
+{p 4 8} {opt by(varname)} specifies the variable containing the group indicator to perform subgroup analysis;
+both numeric and string variables are supported.
+When {opt by(varname)} is specified, {cmdab:binslogit} implements estimation and inference for each subgroup separately,
+but produces a common binned scatter plot.
+By default, the binning structure is selected for each subgroup separately,
+but see the option {cmd:samebinsby} below for imposing a common binning structure across subgroups.
+{p_end}
+
+{p 4 8} {cmd:bycolors(}{it:{help colorstyle}list}{cmd:)} specifies an ordered list of colors
+for plotting each subgroup series defined by the option {opt by()}.
+{p_end}
+
+{p 4 8} {cmd:bysymbols(}{it:{help symbolstyle}list}{cmd:)} specifies an ordered list of symbols
+for plotting each subgroup series defined by the option {opt by()}.
+{p_end}
+
+{p 4 8} {cmd:bylpatterns(}{it:{help linepatternstyle}list}{cmd:)} specifies an ordered list of line patterns
+for plotting each subgroup series defined by the option {opt by()}.
+{p_end}
+
+{dlgtab:Binning/Degree/Smoothness Selection}
+
+{p 4 8} {opt nbins(nbinsopt)} sets the number of bins for partitioning/binning of {it:indvar}. 
+If {cmd:nbins(T)} or {cmd:nbins()} (default) is specified, the number of bins is selected via the companion command {help binsregselect:binsregselect} 
+in a data-driven, optimal way whenever possible. If a {help numlist:numlist} with more than one number is specified, 
+the number of bins is selected within this list via the companion command {help binsregselect:binsregselect}.
+{p_end}
+
+{p 4 8} {opt binspos(position)} specifies the position of binning knots.
+The default is {cmd:binspos(qs)}, which corresponds to quantile-spaced binning (canonical binscatter).
+Other options are: {cmd:es} for evenly-spaced binning, or a {help numlist} for manual specification of
+the positions of inner knots (which must be within the range of {it:indvar}).
+{p_end}
+
+{p 4 8} {opt binsmethod(method)} specifies the method for data-driven selection of the number of bins via the companion command {help binsregselect:binsregselect}.
+The default is {cmd:binsmethod(dpi)}, which corresponds to the IMSE-optimal direct plug-in rule.
+The other option is: {cmd:rot} for rule of thumb implementation.
+{p_end}
+
+{p 4 8} {opt nbinsrot(#)} specifies an initial number of bins value used to construct the DPI number of bins selector.
+If not specified, the data-driven ROT selector is used instead.
+{p_end}
+
+{p 4 8} {opt samebinsby} forces a common partitioning/binning structure across all subgroups specified by the option {cmd:by()}.
+The knots positions are selected according to the option {cmd:binspos()} and using the full sample.
+If {cmd:nbins()} is not specified, then the number of bins is selected via the companion command
+{help binsregselect:binsregselect} and using the full sample.
+{p_end}
+
+{p 4 8} {opt randcut(#)} specifies the upper bound on a uniformly distributed variable used to draw a subsample 
+for bins/degree/smoothness selection.
+Observations for which {cmd:runiform()<=#} are used. # must be between 0 and 1. 
+By default, max(5,000, 0.01n) observations are used if the samples size n>5,000.
+{p_end}
+
+{p 4 8} {opt pselect(numlist)} specifies a list of numbers within which the degree of polynomial {it:p} for 
+point estimation is selected. Piecewise polynomials of the selected optimal degree {it:p} 
+are used to construct dots or line if {cmd:dots(T)} or {cmd:line(T)} is specified, 
+whereas piecewise polynomials of degree {it:p+1} are used to construct confidence intervals
+or confidence band if {cmd:ci(T)} or {cmd:cb(T)} is specified.
+{p_end}
+
+{p 4 8} {opt sselect(numlist)} specifies a list of numbers within which 
+the number of smoothness constraints {it:s}
+for point estimation.  Piecewise polynomials with the selected optimal 
+{it:s} smoothness constraints are used to construct dots or line 
+if {cmd:dots(T)} or {cmd:line(T)} is specified, 
+whereas piecewise polynomials with {it:s+1} constraints are used to construct 
+confidence intervals or confidence band if {cmd:ci(T)} or {cmd:cb(T)} is specified. 
+If not specified, for each value {it:p} supplied in the 
+option {cmd:pselect()}, only the piecewise polynomial with the maximum smoothness is considered, i.e., {it:s=p}. 
+{p_end}
+
+{p 4 8} Note: To implement the degree or smoothness selection, in addition to {cmd:pselect()} 
+or {cmd:sselect()}, {cmd:nbins(#)} must be specified.
+{p_end}
+
+{dlgtab:Simulation}
+
+{p 4 8} {opt nsims(#)} specifies the number of random draws for constructing confidence bands.
+The default is {cmd:nsims(500)}, which corresponds to 500 draws from a standard Gaussian random vector of size [(p+1)*J - (J-1)*s].
+A large number of random draws is recommended to obtain the final results.
+{p_end}
+
+{p 4 8} {opt simsgrid(#)} specifies the number of evaluation points of an evenly-spaced grid
+within each bin used for evaluation of the supremum operation needed to construct confidence bands.
+The default is {cmd:simsgrid(20)}, which corresponds to 20 evenly-spaced evaluation points within each bin 
+for approximating the supremum operator.
+A large number of evaluation points is recommended to obtain the final results.
+{p_end}
+
+{p 4 8} {opt simsseed(#)} sets the seed for simulations.
+{p_end}
+
+{dlgtab:Mass Points and Degrees of Freedom}
+
+{p 4 8} {opt dfcheck(n1 n2)} sets cutoff values for minimum effective sample size checks,
+which take into account the number of unique values of {it:indvar} (i.e., adjusting for the number of mass points),
+number of clusters, and degrees of freedom of the different statistical models considered.
+The default is {cmd:dfcheck(20 30)}. See Cattaneo, Crump, Farrell and Feng (2022b) for more details.
+{p_end}
+
+{p 4 8} {opt masspoints(masspointsoption)} specifies how mass points in {it:indvar} are handled.
+By default, all mass point and degrees of freedom checks are implemented.
+Available options:
+{p_end}
+{p 8 8} {opt masspoints(noadjust)} omits mass point checks and the corresponding effective sample size adjustments.{p_end}
+{p 8 8} {opt masspoints(nolocalcheck)} omits within-bin mass point and degrees of freedom checks.{p_end}
+{p 8 8} {opt masspoints(off)} sets {opt masspoints(noadjust)} and {opt masspoints(nolocalcheck)} simultaneously.{p_end}
+{p 8 8} {opt masspoints(veryfew)} forces the command to proceed as if {it:indvar} has only a few number of mass points (i.e., distinct values).
+In other words, forces the command to proceed as if the mass point and degrees of freedom checks were failed.{p_end}
+
+{dlgtab:Standard Error}
+
+{p 4 8} {cmd:vce(}{it:{help vcetype}}{cmd:)} specifies the {it:vcetype} for variance estimation used by
+the command {help logit##options:logit}.
+The default is {cmd:vce(robust)}.
+{p_end}
+
+{p 4 8} {opt asyvar(on/off)} specifies the method used to compute standard errors.
+If {cmd:asyvar(on)} is specified, the standard error of the nonparametric component is used and the uncertainty related to other control variables {it:othercovs} is omitted.
+Default is {cmd:asyvar(off)}, that is, the uncertainty related to {it:othercovs} is taken into account.
+{p_end}
+
+{dlgtab:Other Options}
+
+{p 4 8} {opt level(#)} sets the nominal confidence level for confidence interval and confidence band estimation. Default is {cmd:level(95)}.
+{p_end}
+
+{p 4 8} {opt logitopt(logit_option)} options to be passed on to the command {help logit##options:logit}. 
+For example, options that control for the optimization process can be added here.
+{p_end}
+
+{p 4 8}{opt usegtools(on/off)} forces the use of several commands in the community-distributed Stata package {cmd:gtools} to speed the computation up, if {it:on} is specified.
+Default is {cmd:usegtools(off)}.
+{p_end}
+
+{p 4 8} For more information about the package {cmd:gtools}, please see {browse "https://gtools.readthedocs.io/en/latest/index.html":https://gtools.readthedocs.io/en/latest/index.html}.
+{p_end}
+
+{p 4 8} {opt noplot} omits binscatter plotting.
+{p_end}
+
+{p 4 8} {opt savedata(filename)} specifies a filename for saving all data underlying the binscatter plot (and more).
+{p_end}
+
+{p 4 8} {opt replace} overwrites the existing file when saving the graph data.
+{p_end}
+
+{p 4 8} {opt plotxrange(min max)} specifies the range of the x-axis for plotting. Observations outside the range are dropped in the plot.{p_end}
+
+{p 4 8} {opt plotyrange(min max)} specifies the range of the y-axis for plotting. Observations outside the range are dropped in the plot.{p_end}
+
+{p 4 8} {it:{help twoway_options}} any unrecognized options are appended to the end of the twoway command generating the binned scatter plot.
+{p_end}
+
+
+{marker examples}{...}
+{title:Examples}
+
+{p 4 8}  Setup{p_end}
+{p 8 8} . {stata sysuse auto}{p_end}
+
+{p 4 8} Run a binscatter logit regression and report the plot{p_end}
+{p 8 8} . {stata binslogit foreign weight mpg}{p_end}
+
+{p 4 8} Add confidence intervals and confidence band{p_end}
+{p 8 8} . {stata binslogit foreign weight mpg, ci(1 1) nbins(5)}{p_end}
+
+
+{marker stored_results}{...}
+{title:Stored results}
+
+{synoptset 17 tabbed}{...}
+{p2col 5 17 21 2: Scalars}{p_end}
+{synopt:{cmd:e(N)}}number of observations{p_end}
+{synopt:{cmd:e(level)}}confidence level{p_end}
+{synopt:{cmd:e(dots_p)}}degree of polynomial for dots{p_end}
+{synopt:{cmd:e(dots_s)}}smoothness of polynomial for dots{p_end}
+{synopt:{cmd:e(line_p)}}degree of polynomial for line{p_end}
+{synopt:{cmd:e(line_s)}}smoothness of polynomial for line{p_end}
+{synopt:{cmd:e(ci_p)}}degree of polynomial for confidence interval{p_end}
+{synopt:{cmd:e(ci_s)}}smoothness of polynomial for confidence interval{p_end}
+{synopt:{cmd:e(cb_p)}}degree of polynomial for confidence band{p_end}
+{synopt:{cmd:e(cb_s)}}smoothness of polynomial for confidence band{p_end}
+{p2col 5 17 21 2: Matrices}{p_end}
+{synopt:{cmd:e(N_by)}}number of observations for each group{p_end}
+{synopt:{cmd:e(Ndist_by)}}number of distinct values for each group{p_end}
+{synopt:{cmd:e(Nclust_by)}}number of clusters for each group{p_end}
+{synopt:{cmd:e(nbins_by)}}number of bins for each group{p_end}
+{synopt:{cmd:e(cval_by)}}critical value for each group, used for confidence bands{p_end}
+{synopt:{cmd:e(imse_var_rot)}}variance constant in IMSE, ROT selection{p_end}
+{synopt:{cmd:e(imse_bsq_rot)}}bias constant in IMSE, ROT selection{p_end}
+{synopt:{cmd:e(imse_var_dpi)}}variance constant in IMSE, DPI selection{p_end}
+{synopt:{cmd:e(imse_bsq_dpi)}}bias constant in IMSE, DPI selection{p_end}
+
+{marker references}{...}
+{title:References}
+
+{p 4 8} Cattaneo, M. D., R. K. Crump, M. H. Farrell, and Y. Feng. 2022a.
+{browse "https://nppackages.github.io/references/Cattaneo-Crump-Farrell-Feng_2022_Binscatter.pdf":On Binscatter}.
+{it:arXiv:1902.09608}.
+{p_end}
+
+{p 4 8} Cattaneo, M. D., R. K. Crump, M. H. Farrell, and Y. Feng. 2022b.
+{browse "https://nppackages.github.io/references/Cattaneo-Crump-Farrell-Feng_2022_Stata.pdf":Binscatter Regressions}.
+{it:arXiv:1902.09615}.
+{p_end}
+
+
+{marker authors}{...}
+{title:Authors}
+
+{p 4 8} Matias D. Cattaneo, Princeton University, Princeton, NJ.
+{browse "mailto:[email protected]":[email protected]}.
+{p_end}
+
+{p 4 8} Richard K. Crump, Federal Reserve Band of New York, New York, NY.
+{browse "mailto:[email protected]":[email protected]}.
+{p_end}
+
+{p 4 8} Max H. Farrell, University of Chicago, Chicago, IL.
+{browse "mailto:[email protected]":[email protected]}.
+{p_end}
+
+{p 4 8} Yingjie Feng, Tsinghua University, Beijing, China.
+{browse "mailto:[email protected]":[email protected]}.
+{p_end}
+

110/replication_package/replication/ado/plus/b/binsprobit.ado

@@ -0,0 +1,2390 @@
+*! version 1.2 09-Oct-2022  
+
+capture program drop binsprobit
+program define binsprobit, eclass
+     version 13
+	 
+	 syntax varlist(min=2 numeric fv ts) [if] [in] [fw pw] [, deriv(integer 0) at(string asis) nolink ///
+	        probitopt(string asis) ///
+	        dots(string) dotsgrid(string) dotsplotopt(string asis) ///
+			line(string) linegrid(integer 20) lineplotopt(string asis) ///
+			ci(string) cigrid(string) ciplotopt(string asis) /// 
+			cb(string) cbgrid(integer 20) cbplotopt(string asis) ///
+			polyreg(string) polyreggrid(integer 20) polyregcigrid(integer 0) polyregplotopt(string asis) ///
+			by(varname) bycolors(string asis) bysymbols(string asis) bylpatterns(string asis) ///
+			nbins(string) binspos(string) binsmethod(string) nbinsrot(string) ///
+			pselect(numlist integer >=0) sselect(numlist integer >=0) ///
+			samebinsby randcut(numlist max=1 >=0 <=1) ///
+			nsims(integer 500) simsgrid(integer 20) simsseed(numlist integer max=1 >=0) ///
+			dfcheck(numlist integer max=2 >=0) masspoints(string) usegtools(string) ///
+			vce(passthru) level(real 95) asyvar(string) ///
+			noplot savedata(string asis) replace ///
+			plotxrange(numlist asc max=2) plotyrange(numlist asc max=2) *]
+	 
+	 *********************************************
+	 * Regularization constant (for checking only)
+	 local qrot=2
+	 
+	 **************************************
+	 * Create weight local
+     if ("`weight'"!="") {
+	    local wt [`weight'`exp']
+		local wtype=substr("`weight'",1,1)
+	 }
+	 
+	 **********************
+	 ** Extract options ***
+	 **********************
+	 * report the results for the cond. mean model?
+	 if ("`link'"!="") local transform "F"
+	 else              local transform "T"
+	 
+	 * default vce, clustered?
+	 if ("`vce'"=="") local vce "vce(robust)"
+	 local vcetemp: subinstr local vce "vce(" "", all
+     local vcetemp: subinstr local vcetemp ")" "", all
+	 tokenize "`vcetemp'"
+	 if ("`1'"=="cl"|"`1'"=="clu"|"`1'"=="clus"|"`1'"=="clust"| /// 
+		 "`1'"=="cluste"|"`1'"=="cluster") {
+		local clusterON "T"           /* Mark cluster is specified */
+		local clustervar `2'
+	 }
+	 if ("`vce'"=="vce(oim)"|"`vce'"=="vce(opg)") local vce_select "vce(ols)"
+	 else                                         local vce_select "`vce'"
+	 
+	 if ("`asyvar'"=="") local asyvar "off"
+	 
+	 if ("`binsmethod'"=="rot") local binsmethod "ROT"
+	 if ("`binsmethod'"=="dpi") local binsmethod "DPI"
+	 if ("`binsmethod'"=="")    local binsmethod "DPI"
+	 if ("`binspos'"=="es") local binspos "ES"
+	 if ("`binspos'"=="qs") local binspos "QS"
+	 if ("`binspos'"=="")   local binspos "QS"
+
+	 
+	 * analyze options related to degrees *************
+	 if ("`dots'"!="T"&"`dots'"!="F"&"`dots'"!="") {
+	    numlist "`dots'", integer max(2) range(>=0)
+		local dots=r(numlist)
+	 }
+	 if ("`line'"!="T"&"`line'"!="F"&"`line'"!="") {
+	    numlist "`line'", integer max(2) range(>=0)
+		local line=r(numlist)
+	 }
+	 if ("`ci'"!="T"&"`ci'"!="F"&"`ci'"!="") {
+	    numlist "`ci'", integer max(2) range(>=0)
+		local ci=r(numlist)
+	 }
+	 if ("`cb'"!="T"&"`cb'"!="F"&"`cb'"!="") {
+	    numlist "`cb'", integer max(2) range(>=0)
+		local cb=r(numlist)
+	 }
+	 
+	 
+	 if ("`dots'"=="F") {                   /* shut down dots */
+	    local dots ""
+	    local dotsgrid 0
+	 }
+	 if ("`line'"=="F") local line ""
+	 if ("`ci'"=="F")   local ci ""
+	 if ("`cb'"=="F")   local cb ""
+	 
+	 ***************************************************************
+	 * 4 cases: select J, select p, user specified both, and error
+	 local selection ""
+	 
+	 * analyze nbins
+	 if ("`nbins'"=="T") local nbins=0
+	 local len_nbins=0
+	 if ("`nbins'"!=""&"`nbins'"!="F") {
+	    numlist "`nbins'", integer sort
+	    local nbins=r(numlist)
+	    local len_nbins: word count `nbins'
+	 }
+	 
+	 * analyze numlist in pselect and sselect
+	 local len_p=0
+	 local len_s=0
+	 
+	 if ("`pselect'"!="") {
+	    numlist "`pselect'", integer range(>=`deriv') sort
+		local plist=r(numlist)
+	 }
+	 
+	 if ("`sselect'"!="") {
+	    numlist "`sselect'", integer range(>=0) sort
+		local slist=r(numlist)
+	 }
+	 	 	 
+	 local len_p: word count `plist'
+	 local len_s: word count `slist'
+	 
+	 if (`len_p'==1&`len_s'==0) {
+	    local slist `plist'
+		local len_s=1
+	 }
+	 if (`len_p'==0&`len_s'==1) {
+	    local plist `slist'
+		local len_p=1
+     }
+	 
+	 if ("`binspos'"!="ES"&"`binspos'"!="QS") {
+		if ("`nbins'"!=""|"`pselect'"!=""|"`sselect'"!="") {
+		   di as error "nbins(), pselect() or sselect() incorrectly specified."
+		   exit
+		}
+	 }
+	 
+	 * 1st case: select J
+	 if (("`nbins'"=="0"|`len_nbins'>1|"`nbins'"=="")&("`binspos'"=="ES"|"`binspos'"=="QS")) local selection "J"
+	 if ("`selection'"=="J") {
+	 	if (`len_p'>1|`len_s'>1) {
+		   if ("`nbins'"=="") {
+		      di as error "nbins() must be specified for degree/smoothness selection."
+			  exit
+		   }
+		   else {
+			  di as error "Only one p and one s are allowed to select # of bins."
+			  exit
+		   }
+		}
+	 	if ("`plist'"=="") local plist=`deriv'
+		if ("`slist'"=="") local slist=`plist'
+		if ("`dots'"!=""&"`dots'"!="T"&"`dots'"!="F") {                         /* respect user-specified dots */
+		   local plist: word 1 of `dots'
+		   local slist: word 2 of `dots'
+		   if ("`slist'"=="") local slist `plist'
+		}
+		if ("`dots'"==""|"`dots'"=="T") local dots `plist' `slist'              /* selection is based on dots */
+		if ("`line'"=="T") local line `plist' `slist'
+		if ("`ci'"=="T") local ci `=`plist'+1' `=`slist'+1'
+		if ("`cb'"=="T") local cb `=`plist'+1' `=`slist'+1'
+		local len_p=1
+	    local len_s=1
+     }                                                                          /* e.g., binsreg y x, nbins(a b) or nbins(T) or pselect(a) nbins(T) */
+	 
+	 
+	 * 2nd case: select P (at least for one object) 
+	 if ("`selection'"!="J" & ("`dots'"==""|"`dots'"=="T"|"`line'"=="T"|"`ci'"=="T"|"`cb'"=="T")) {
+	    local pselectOK "T"                                                     /* p selection CAN be turned on as long as one of the four is T */     
+	 }
+
+	 if ("`pselectOK'"=="T" & `len_nbins'==1 & (`len_p'>1|`len_s'>1)) {
+	    local selection "P"
+	 }                                                                         /* e.g., binsreg y x, pselect(a b) or pselect() dots(T) */
+	 
+	 * 3rd case: completely user-specified J and p
+	 if ((`len_p'<=1&`len_s'<=1) & "`selection'"!="J") {
+		local selection "NA"
+		if ("`dots'"==""|"`dots'"=="T") {
+		   if (`len_p'==1&`len_s'==1) local dots `plist' `slist'
+	       else                       local dots `deriv' `deriv'                            /* e.g., binsreg y x or , dots(0 0) nbins(20) */
+		}
+		tokenize `dots'
+		if ("`2'"=="") local 2 `1'
+	    if ("`line'"=="T") {
+		   if (`len_p'==1&`len_s'==1) local line `plist' `slist'
+	       else                       local line `dots'                            
+		}
+	    if ("`ci'"=="T") {
+		   if (`len_p'==1&`len_s'==1) local ci `=`plist'+1' `=`slist'+1'
+	       else                       local ci `=`1'+1' `=`2'+1'                            
+		}
+	    if ("`cb'"=="T") {
+		   if (`len_p'==1&`len_s'==1) local cb `=`plist'+1' `=`slist'+1'
+	       else                       local cb `=`1'+1' `=`2'+1'                            
+		}
+	 }
+	 	 
+	 * exclude all other cases
+	 if ("`selection'"=="") {
+	    di as error "Degree, smoothness, or # of bins are not correctly specified."
+        exit
+	 }
+	 	 
+	 ****** Now, extract from dots, line, etc. ************ 
+	 * dots
+	 tokenize `dots'
+	 local dots_p "`1'"
+	 local dots_s "`2'"
+	 if ("`dots_p'"==""|"`dots_p'"=="T") local dots_p=.
+	 if ("`dots_s'"=="") local dots_s `dots_p'
+	 
+	 if ("`dotsgrid'"=="") local dotsgrid "mean"
+	 local dotsngrid_mean=0
+	 if (strpos("`dotsgrid'","mean")!=0) {
+	    local dotsngrid_mean=1
+		local dotsgrid: subinstr local dotsgrid "mean" "", all
+	 }
+	 if (wordcount("`dotsgrid'")==0) local dotsngrid=0
+	 else {
+	    confirm integer n `dotsgrid'
+	    local dotsngrid `dotsgrid'
+     }
+	 local dotsntot=`dotsngrid_mean'+`dotsngrid'
+	 
+	 
+	 * line
+	 tokenize `line'
+	 local line_p "`1'"
+	 local line_s "`2'"
+	 local linengrid `linegrid'
+	 if ("`line'"=="") local linengrid=0
+	 if ("`line_p'"==""|"`line_p'"=="T") local line_p=.
+	 if ("`line_s'"=="") local line_s `line_p'
+	 	 
+	 * ci
+	 if ("`cigrid'"=="") local cigrid "mean"
+	 local cingrid_mean=0
+	 if (strpos("`cigrid'","mean")!=0) {
+	    local cingrid_mean=1
+		local cigrid: subinstr local cigrid "mean" "", all
+	 }
+	 if (wordcount("`cigrid'")==0) local cingrid=0
+	 else {
+	    confirm integer n `cigrid'
+	    local cingrid `cigrid'
+	 }
+	 local cintot=`cingrid_mean'+`cingrid'
+	 
+	 tokenize `ci'
+	 local ci_p "`1'"
+	 local ci_s "`2'"
+	 if ("`ci'"=="") local cintot=0
+	 if ("`ci_p'"==""|"`ci_p'"=="T") local ci_p=.
+	 if ("`ci_s'"=="") local ci_s `ci_p'
+	 
+	 * cb
+	 tokenize `cb'
+	 local cb_p "`1'"
+	 local cb_s "`2'"
+	 local cbngrid `cbgrid'
+	 if ("`cb'"=="") local cbngrid=0
+	 if ("`cb_p'"==""|"`cb_p'"=="T") local cb_p=.
+	 if ("`cb_s'"=="") local cb_s `cb_p'
+	 
+	 * Add warnings about degrees for estimation and inference
+	 if ("`selection'"=="J") {
+	    if ("`ci_p'"!=".") {
+		   if (`ci_p'<=`dots_p') {
+		      local ci_p=`dots_p'+1
+			  local ci_s=`ci_p'
+			  di as text "Warning: Degree for ci() has been changed. It must be greater than the degree for dots()."
+		   }
+		}
+	    if ("`cb_p'"!=".") {
+		   if (`cb_p'<=`dots_p') {
+		      local cb_p=`dots_p'+1
+			  local cb_s=`cb_p'
+			  di as text "Warning: Degree for cb() has been changed. It must be greater than the degree for dots()."
+		   }
+		}
+	 }
+	 if ("`selection'"=="NA") {
+	    if ("`ci'"!=""|"`cb'"!="") {
+		   di as text "Warning: Confidence intervals/bands are valid when nbins() is much larger than IMSE-optimal choice."
+	    }
+	 }
+	 * if selection==P, compare ci_p/cb_p with P_opt later
+	 
+	 * poly fit
+	 local polyregngrid `polyreggrid'
+	 local polyregcingrid `polyregcigrid'
+	 if ("`polyreg'"!="") {
+	    confirm integer n `polyreg'
+	 }
+	 else {
+	    local polyregngrid=0
+	 }
+	 
+	 * range of x axis and y axis?
+	 tokenize `plotxrange'
+     local min_xr "`1'"
+	 local max_xr "`2'"
+	 tokenize `plotyrange'
+     local min_yr "`1'"
+	 local max_yr "`2'"
+
+	 
+	 * Simuls
+	 local simsngrid=`simsgrid'
+	 	 
+	 * Record if nbins specified by users, set default
+	 local nbins_full `nbins'              /* local save common nbins */
+	 if ("`selection'"=="NA")   local binselectmethod "User-specified"
+     else {
+	    if ("`binsmethod'"=="DPI")  local binselectmethod "IMSE-optimal plug-in choice"
+        if ("`binsmethod'"=="ROT")  local binselectmethod "IMSE-optimal rule-of-thumb choice"
+		if ("`selection'"=="J") local binselectmethod "`binselectmethod' (select # of bins)"
+		if ("`selection'"=="P") local binselectmethod "`binselectmethod' (select degree and smoothness)"		
+	 }
+	 
+	 * Mass point check?
+	 if ("`masspoints'"=="") {
+	    local massadj "T"
+		local localcheck "T"	    
+	 }
+	 else if ("`masspoints'"=="off") {
+	    local massadj "F"
+		local localcheck "F"
+	 }
+	 else if ("`masspoints'"=="noadjust") {
+	    local massadj "F"
+		local localcheck "T"
+	 }
+	 else if ("`masspoints'"=="nolocalcheck") {
+	 	local massadj "T"
+		local localcheck "F"
+     }
+	 else if ("`masspoints'"=="veryfew") {
+	    local fewmasspoints "T"    /* count mass point, but turn off checks */
+	 }
+	 
+	 * extract dfcheck
+	 if ("`dfcheck'"=="") local dfcheck 20 30
+	 tokenize `dfcheck'
+	 local dfcheck_n1 "`1'"
+	 local dfcheck_n2 "`2'"
+	 
+	 * evaluate at w from another dataset?
+	 if (`"`at'"'!=`""'&`"`at'"'!=`"mean"'&`"`at'"'!=`"median"'&`"`at'"'!=`"0"') local atwout "user"
+	 
+	 * use gtools commands instead?
+	 if ("`usegtools'"=="off") local usegtools ""
+	 if ("`usegtools'"=="on")  local usegtools usegtools
+	 if ("`usegtools'"!="") {
+	    capture which gtools
+		if (_rc) {
+		   di as error "Gtools package not installed."
+		   exit
+		}
+		local localcheck "F"
+		local sel_gtools "on"
+	    * use gstats tab instead of tabstat/collapse
+		* use gquantiles instead of _pctile
+		* use gunique instead of binsreg_uniq
+		* use fasterxtile instead of irecode (within binsreg_irecode)
+		* shut down local checks & do not sort
+	 }
+	 
+	 *************************
+	 **** error checks *******
+	 *************************
+	 if (`deriv'<0) {
+	    di as error "Derivative incorrectly specified."
+		exit
+	 }
+	 if (`deriv'>1&"`transform'"=="T") {
+	    di as error "deriv cannot be greater than 1 if the conditional probability is requested." 
+		exit
+	 }
+	 if (`dotsngrid'<0|`linengrid'<0|`cingrid'<0|`cbngrid'<0|`simsngrid'<0) {
+	    di as error "Number of evaluation points incorrectly specified."
+		exit
+	 }
+	 if (`level'>100|`level'<0) {
+	     di as error "Confidence level incorrectly specified."
+		 exit
+	 }
+	 if ("`dots_p'"!=".") {
+		 if (`dots_p'<`dots_s') {
+			 di as error "p cannot be smaller than s."
+			 exit
+		 }
+		 if (`dots_p'<`deriv') {
+			 di as error "p for dots cannot be less than deriv."
+			 exit
+		 }
+	 }
+	 if ("`line_p'"!=".") {
+	    if (`line_p'<`line_s') {
+		   di as error "p cannot be smaller than s."
+		   exit
+		}
+		if (`line_p'<`deriv') {
+		   di as error "p for line cannot be less than deriv."
+		   exit
+		}
+	 }
+	 if ("`ci_p'"!=".") {
+	    if (`ci_p'<`ci_s') {
+		   di as error "p cannot be smaller than s."
+		   exit
+		}
+		if (`ci_p'<`deriv') {
+		   di as error "p for CI cannot be less than deriv."
+		   exit
+		}
+	 }
+	 if ("`cb_p'"!=".") {
+	    if (`cb_p'<`cb_s') {
+		   di as error "p cannot be smaller than s."
+		   exit
+		}
+		if (`cb_p'<`deriv') {
+		   di as error "p for CB cannot be less than deriv."
+		   exit
+		}
+	 }
+	 if ("`polyreg'"!="") {
+	    if (`polyreg'<`deriv') {
+		   di as error "polyreg() cannot be less than deriv()."
+		   exit
+		}
+	 }
+     
+	 if (`"`savedata'"'!=`""') {
+	    if ("`replace'"=="") {
+		   confirm new file `"`savedata'.dta"'
+		}
+		if ("`plot'"!="") {
+		    di as error "plot cannot be turned off if graph data are requested."
+			exit
+		}
+	 }
+	 if (`polyregcingrid'!=0&"`polyreg'"=="") {
+	    di as error "polyreg() is missing."
+		exit
+	 }
+	 if ("`binsmethod'"!="DPI"&"`binsmethod'"!="ROT") {
+	    di as error "binsmethod incorrectly specified."
+		exit
+	 }
+	 ******** END error checking ***************************
+
+	 * Mark sample
+	 preserve
+	 
+	 * Parse varlist into y_var, x_var and w_var
+	 tokenize `varlist'
+	 fvrevar `1', tsonly
+	 local y_var "`r(varlist)'"
+	 local y_varname "`1'"
+	 fvrevar `2', tsonly
+	 local x_var "`r(varlist)'"
+	 local x_varname "`2'"
+	 
+	 macro shift 2
+	 local w_var "`*'"
+	 * read eval point for w from another file
+	 if ("`atwout'"=="user") {
+	    append using `at'
+	 }
+	 
+	 fvrevar `w_var', tsonly
+	 local w_var "`r(varlist)'"
+	 local nwvar: word count `w_var'
+	 
+	 * Save the last obs in a vector and then drop it
+	 tempname wuser                  /* a vector used to keep eval for w */
+	 if ("`atwout'"=="user") {
+	    mata: st_matrix("`wuser'", st_data(`=_N', "`w_var'")) 
+	    qui drop in `=_N'
+	 }
+	 
+	 * Get positions of factor vars
+     local indexlist ""
+     local i = 1
+     foreach v in `w_var' {
+        if strpos("`v'", ".") == 0 {
+           local indexlist  `indexlist' `i'
+        }
+        local ++i
+     }
+	 
+	 * add a default for at
+	 if (`"`at'"'==""&`nwvar'>0) {
+	    local at "mean"
+	 }
+
+	 marksample touse
+	 markout `touse' `by', strok	 
+	 qui keep if `touse'
+	 local nsize=_N             /* # of rows in the original dataset */
+	 
+	 if ("`usegtools'"==""&("`masspoints'"!="off"|"`binspos'"=="QS")) {
+	    if ("`:sortedby'"!="`x_var'") {
+		  di as text in gr "Sorting dataset on `x_varname'..."
+		  di as text in gr "Note: This step is omitted if dataset already sorted by `x_varname'."
+		  sort `x_var', stable
+		}
+		local sorted "sorted"
+	 }
+	 
+	 if ("`wtype'"=="f") qui sum `x_var' `wt', meanonly
+	 else 	             qui sum `x_var', meanonly
+
+	 local xmin=r(min)
+	 local xmax=r(max)
+	 local Ntotal=r(N)  /* total sample size, with wt */
+	 * define the support of plot
+	 if ("`plotxrange'"!="") {
+	    local xsc `plotxrange'
+		if (wordcount("`xsc'")==1) local xsc `xsc' `xmax'
+	 }
+	 else local xsc `xmin' `xmax'
+	 
+	 * Effective sample size
+	 local eN=`nsize'
+	 * DO NOT check mass points and clusters outside loop unless needed
+	 
+	 * Check number of unique byvals & create local storing byvals
+	 local byvarname `by'
+     if "`by'"!="" {        
+        capture confirm numeric variable `by'
+        if _rc {
+		  local bystring "T"
+        * generate a numeric version
+          tempvar by
+          tempname bylabel
+          qui egen `by'=group(`byvarname'), lname(`bylabel')
+        }
+                
+        local bylabel `:value label `by'' /* catch value labels for numeric by-vars too */ 
+                
+        tempname byvalmatrix
+        qui tab `by', nofreq matrow(`byvalmatrix')
+                
+        local bynum=r(r)
+        forvalues i=1/`bynum' {
+           local byvals `byvals' `=`byvalmatrix'[`i',1]'
+        }
+     }
+     else local bynum=1
+	 
+	 * Default colors, symbols, linepatterns
+     if (`"`bycolors'"'==`""') local bycolors ///
+                navy maroon forest_green dkorange teal cranberry lavender ///
+                khaki sienna emidblue emerald brown erose gold bluishgray
+	 if (`"`bysymbols'"'==`""') local bysymbols ///
+	            O D T S + X A a | V o d s t x
+	 if (`"`bylpatterns'"'==`""') {
+	    forval i=1/`bynum' {
+		   local bylpatterns `bylpatterns' solid 
+		}
+	 }        
+
+	 * Temp name in MATA
+	 tempname xvec yvec byvec cluvec binedges
+	 mata: `xvec'=st_data(., "`x_var'"); `yvec'=st_data(.,"`y_var'"); `byvec'=.; `cluvec'=.
+	 
+	 *******************************************************
+	 *** Mass point counting *******************************
+	 tempname Ndistlist Nclustlist mat_imse_var_rot mat_imse_bsq_rot mat_imse_var_dpi mat_imse_bsq_dpi
+	 mat `Ndistlist'=J(`bynum',1,.)
+	 mat `Nclustlist'=J(`bynum',1,.)
+	 * Matrices saving imse
+	 mat `mat_imse_var_rot'=J(`bynum',1,.)
+	 mat `mat_imse_bsq_rot'=J(`bynum',1,.)
+	 mat `mat_imse_var_dpi'=J(`bynum',1,.)
+	 mat `mat_imse_bsq_dpi'=J(`bynum',1,.)
+
+	 if (`bynum'>1) mata: `byvec'=st_data(.,"`by'")
+	 if ("`clusterON'"=="T") mata: `cluvec'=st_data(.,"`clustervar'")
+	 
+	 ********************************************************
+	 ********** Bins, based on FULL sample ******************
+	 ********************************************************
+	 * knotlist: inner knot seq; knotlistON: local, knot available before loop
+	 
+	 tempname fullkmat   /* matrix name for saving knots based on the full sample */
+	 
+	 * Extract user-specified knot list
+	 if ("`binspos'"!="ES"&"`binspos'"!="QS") {
+		capture numlist "`binspos'", ascending
+		if (_rc==0) {
+		   local knotlistON "T"
+		   local knotlist `binspos'
+		   local nbins: word count `knotlist'
+		   local first: word 1 of `knotlist'
+		   local last: word `nbins' of `knotlist'
+		   if (`first'<=`xmin'|`last'>=`xmax') {
+			  di as error "Inner knots specified out of allowed range."
+			  exit
+		   }
+		   else {
+		      local nbins=`nbins'+1
+			  local nbins_full `nbins'
+              local pos "user"
+				   
+			  foreach el of local knotlist {
+		         mat `fullkmat'=(nullmat(`fullkmat') \ `el')
+		      }
+              mat `fullkmat'=(`xmin' \ `fullkmat' \ `xmax')
+		   }
+	    }
+	    else {
+		   di as error "numeric list incorrectly specified in binspos()."
+		   exit
+		}
+	 }
+	 
+	 * Discrete x?
+	 if ("`fewmasspoints'"!="") local fullfewobs "T"
+	 
+	 * Bin selection using the whole sample if
+	 if ("`fullfewobs'"==""&"`selection'"!="NA"&(("`by'"=="")|(("`by'"!="")&("`samebinsby'"!="")))) {
+	    local selectfullON "T"
+	 }
+	 
+	 if ("`selectfullON'"=="T") {
+	    local Ndist=.
+	    if ("`massadj'"=="T") {
+	       if ("`usegtools'"=="") {
+	          mata: `binedges'=binsreg_uniq(`xvec', ., 1, "Ndist")
+		      mata: mata drop `binedges'
+		   }
+		   else {
+		      qui gunique `x_var'
+			  local Ndist=r(unique)
+		   }
+	       local eN=min(`eN', `Ndist')
+	    }
+	    * # of clusters
+	    local Nclust=.
+	    if ("`clusterON'"=="T") {
+		   if ("`usegtools'"=="") {
+		      mata: st_local("Nclust", strofreal(rows(uniqrows(`cluvec'))))
+		   }
+		   else {
+		      qui gunique `clustervar'
+			  local Nclust=r(unique)
+		   }
+		   local eN=min(`eN', `Nclust')   /* effective sample size */
+	    }
+	 
+
+		* Check effective sample size
+		if ("`dots_p'"==".") local dotspcheck=6
+		else                 local dotspcheck=`dots_p'
+		* Check effective sample size
+		if ("`nbinsrot'"==""&(`eN'<=`dfcheck_n1'+`dotspcheck'+1+`qrot')) {
+		    di as text in gr "Warning: Too small effective sample size for bin selection." ///
+			                 _newline _skip(9) "# of mass points or clusters used and by() option ignored."
+	        local by ""                 
+			local byvals ""
+			local fullfewobs "T"
+			local binspos "QS"                /* forced to be QS */
+	    }
+		else {
+		   local randcut1k `randcut'
+		   if ("`randcut'"=="" & `Ntotal'>5000) {
+	           local randcut1k=max(5000/`Ntotal', 0.01)
+		       di as text in gr "Warning: To speed up computation, bin/degree selection uses a subsample of roughly max(5,000, 0.01n) observations if the sample size n>5000. To use the full sample, set randcut(1)."
+	       }
+		   if ("`selection'"=="J") {
+		      qui binsregselect `y_var' `x_var' `w_var' `wt', deriv(`deriv') bins(`dots_p' `dots_s') nbins(`nbins_full') ///
+				   			    absorb(`absorb') reghdfeopt(`reghdfeopt') ///
+								binsmethod(`binsmethod') binspos(`binspos') nbinsrot(`nbinsrot') ///
+								`vce' masspoints(`masspoints') dfcheck(`dfcheck_n1' `dfcheck_n2') ///
+								numdist(`Ndist') numclust(`Nclust') randcut(`randcut1k') usegtools(`sel_gtools')
+			  if (e(nbinsrot_regul)==.) {
+			      di as error "Bin selection fails."
+				  exit
+			  }
+			  if ("`binsmethod'"=="ROT") {
+				  local nbins=e(nbinsrot_regul)
+				  mat `mat_imse_var_rot'=J(`bynum',1,e(imse_var_rot))
+	              mat `mat_imse_bsq_rot'=J(`bynum',1,e(imse_bsq_rot))
+			  }
+			  else if ("`binsmethod'"=="DPI") {
+				 local nbins=e(nbinsdpi)
+				 mat `mat_imse_var_dpi'=J(`bynum',1,e(imse_var_dpi))
+	             mat `mat_imse_bsq_dpi'=J(`bynum',1,e(imse_bsq_dpi))
+				 if (`nbins'==.) {
+				    local nbins=e(nbinsrot_regul)
+ 				    mat `mat_imse_var_rot'=J(`bynum',1,e(imse_var_rot))
+	                mat `mat_imse_bsq_rot'=J(`bynum',1,e(imse_bsq_rot))
+					di as text in gr "Warning: DPI selection fails. ROT choice used."
+				 }
+			  }
+		   }
+		   else if ("`selection'"=="P") {
+		   	  qui binsregselect `y_var' `x_var' `w_var' `wt', deriv(`deriv') nbins(`nbins_full') ///
+				   			    absorb(`absorb') reghdfeopt(`reghdfeopt') ///
+								pselect(`plist') sselect(`slist') ///
+								binsmethod(`binsmethod') binspos(`binspos') nbinsrot(`nbinsrot') ///
+								`vce' masspoints(`masspoints') dfcheck(`dfcheck_n1' `dfcheck_n2') ///
+								numdist(`Ndist') numclust(`Nclust') randcut(`randcut1k') usegtools(`sel_gtools')
+			  if (e(prot_regul)==.) {
+			      di as error "Bin selection fails."
+				  exit
+			  }
+			  if ("`binsmethod'"=="ROT") {
+			      local binsp=e(prot_regul)
+				  local binss=e(srot_regul)
+				  mat `mat_imse_var_rot'=J(`bynum',1,e(imse_var_rot))
+	              mat `mat_imse_bsq_rot'=J(`bynum',1,e(imse_bsq_rot))
+			  }
+			  else if ("`binsmethod'"=="DPI") {
+				 local binsp=e(pdpi)
+				 local binss=e(sdpi)
+				 mat `mat_imse_var_dpi'=J(`bynum',1,e(imse_var_dpi))
+	             mat `mat_imse_bsq_dpi'=J(`bynum',1,e(imse_bsq_dpi))
+				 if (`binsp'==.) {
+				    local binsp=e(prot_regul)
+					local binss=e(srot_regul)
+				    mat `mat_imse_var_rot'=J(`bynum',1,e(imse_var_rot))
+	                mat `mat_imse_bsq_rot'=J(`bynum',1,e(imse_bsq_rot))
+					di as text in gr "Warning: DPI selection fails. ROT choice used."
+				 }
+			  }
+			  if ("`dots'"=="T"|"`dots'"=="") {
+				 local dots_p=`binsp'
+				 local dots_s=`binss'
+			  }
+			  if ("`line'"=="T") {
+			     local line_p=`binsp'
+				 local line_s=`binss'
+			  }
+			  if ("`ci'"!="T"&"`ci'"!="") {
+			     if (`ci_p'<=`binsp') {
+				   local ci_p=`binsp'+1
+				   local ci_s=`ci_p'
+				   di as text "Warning: Degree for ci() has been changed. It must be greater than the IMSE-optimal degree."
+				 }
+			  }
+			  if ("`ci'"=="T") {
+			     local ci_p=`binsp'+1
+				 local ci_s=`binss'+1
+			  }
+			  if ("`cb'"!="T"&"`cb'"!="") {
+			     if (`cb_p'<=`binsp') {
+				   local cb_p=`binsp'+1
+				   local cb_s=`cb_p'
+				   di as text "Warning: Degree for cb() has been changed. It must be greater than the IMSE-optimal degree."
+				 }
+			  }
+			  if ("`cb'"=="T") {
+			     local cb_p=`binsp'+1
+				 local cb_s=`binss'+1
+			  }
+		   }
+		}
+	 }
+	 
+	 if (("`selectfullON'"=="T"|("`selection'"=="NA"&"`samebinsby'"!=""))&"`fullfewobs'"=="") {
+		 * Save in a knot list
+         local knotlistON "T"
+		 local nbins_full=`nbins'
+		 if ("`binspos'"=="ES") {
+	        local stepsize=(`xmax'-`xmin')/`nbins'
+	        forvalues i=1/`=`nbins'+1' {
+		       mat `fullkmat'=(nullmat(`fullkmat') \ `=`xmin'+`stepsize'*(`i'-1)')
+		    }
+	     }
+	     else if ("`binspos'"=="QS") {
+			 if (`nbins'==1)  mat `fullkmat'=(`xmin' \ `xmax')
+		     else {		
+	           binsreg_pctile `x_var' `wt', nq(`nbins') `usegtools'
+		       mat `fullkmat'=(`xmin' \ r(Q) \ `xmax')
+		     }
+	     }
+	 }
+	 
+	 *** Placement name, for display ************
+	 if ("`pos'"=="user") {
+	     local binselectmethod "User-specified"
+		 local placement "User-specified"
+	 }
+	 else if ("`binspos'"=="ES") {
+	     local placement "Evenly-spaced"
+	 }
+	 else if ("`binspos'"=="QS") {
+	     local placement "Quantile-spaced"
+	 }
+	 
+	 * NOTE: ALL checkings are put within the loop
+	 
+	 * Set seed
+	 if ("`simsseed'"!="") set seed `simsseed'
+	 
+	 * alpha quantile (for two-sided CI)
+	 local alpha=(100-(100-`level')/2)/100
+	 	 
+	 ***************************************************************************
+	 *************** Preparation before loop************************************
+	 ***************************************************************************
+	 
+	 ********** Prepare vars for plotting ********************
+	 * names for mata objects storing graph data
+	 * plotmat: final output (defined outside); 
+	 * plotmatby: output for each group
+	 tempname plotmat plotmatby xsub ysub byindex xcatsub
+	 tempname Xm Xm0 mata_fit mata_se          /* temp name for mata obj */
+	 
+	 * count the number of requested columns, record the positions
+	 local ncolplot=1                /* 1st col reserved for group */
+	 if ("`plot'"=="") {
+	    if (`dotsntot'!=0) {
+		   local dots_start=`ncolplot'+1
+		   local dots_end=`ncolplot'+4
+		   local ncolplot=`ncolplot'+4
+		}
+	    if (`linengrid'!=0&"`fullfewobs'"=="") {
+		   local line_start=`ncolplot'+1
+		   local line_end=`ncolplot'+4
+		   local ncolplot=`ncolplot'+4
+		}
+        if (`polyregngrid'!=0) {
+		   local poly_start=`ncolplot'+1
+		   local poly_end=`ncolplot'+4
+		   local ncolplot=`ncolplot'+4
+		   if (`polyregcingrid'!=0) {
+		      local polyci_start=`ncolplot'+1
+		      local polyci_end=`ncolplot'+5
+		      local ncolplot=`ncolplot'+5
+		   }
+		}
+		if (`cintot'!=0) {
+		   local ci_start=`ncolplot'+1
+		   local ci_end=`ncolplot'+5
+		   local ncolplot=`ncolplot'+5
+		}
+		if (`cbngrid'!=0&"`fullfewobs'"=="") {
+		   local cb_start=`ncolplot'+1
+		   local cb_end=`ncolplot'+5
+		   local ncolplot=`ncolplot'+5
+		}
+	 }
+	 mata: `plotmat'=J(0,`ncolplot',.)
+	 
+	 * mark the (varying) last row (for plotting)
+	 local bylast=0               
+     *******************************************************************	 
+	 * temp var: bin id
+	 tempvar xcat
+	 qui gen `xcat'=. in 1
+	 
+	 * matrix names, for returns
+	 tempname Nlist nbinslist cvallist
+	 
+	 * local vars, for plotting
+	 local counter_by=1
+	 local plotnum=0                     /* count the number of series, for legend */
+     if ("`by'"=="") local noby="noby"
+	 local byvalnamelist ""              /* save group name (value) */
+	 local plotcmd ""                    /* plotting cmd */
+	 
+	 ***************************************************************************
+	 ******************* Now, enter the loop ***********************************
+	 ***************************************************************************
+	 foreach byval in `byvals' `noby' {
+	    local conds ""
+		if ("`by'"!="") {
+		    local conds "if `by'==`byval'"     /* with "if" */
+	        if ("`bylabel'"=="") local byvalname=`byval'
+		    else {
+			   local byvalname `: label `bylabel' `byval''
+			}
+			local byvalnamelist `" `byvalnamelist' `"`byvalname'"' "'
+		}
+		if (`bynum'>1) {
+		   mata: `byindex'=`byvec':==`byval'
+		   mata: `xsub'=select(`xvec',`byindex'); `ysub'=select(`yvec', `byindex')
+		}
+		else {
+		   mata: `xsub'=`xvec'; `ysub'=`yvec'
+		}
+		
+		* Subsample size
+		if ("`wtype'"=="f") sum `x_var' `conds' `wt', meanonly
+		else                sum `x_var' `conds', meanonly
+		
+		local xmin=r(min)
+	    local xmax=r(max)
+	    local N=r(N)
+		mat `Nlist'=(nullmat(`Nlist') \ `N')
+		
+	    * Effective sample size
+		if (`bynum'==1) local eN=`nsize'
+		else {
+		   if ("`wtype'"!="f") local eN=r(N)
+		   else {
+		      qui count `conds'
+	          local eN=r(N)
+		   }
+		}
+	    
+	    local Ndist=.
+	    if ("`massadj'"=="T") {
+		   if ("`usegtools'"=="") {
+		      mata: `binedges'=binsreg_uniq(`xsub', ., 1, "Ndist")
+		      mata: mata drop `binedges'
+		   }
+		   else {
+		      qui gunique `x_var' `conds'
+			  local Ndist=r(unique)
+		   }
+		   local eN=min(`eN', `Ndist')
+		   mat `Ndistlist'[`counter_by',1]=`Ndist'
+	    }
+		
+	    * # of clusters
+	    local Nclust=.
+	    if ("`clusterON'"=="T") {
+		   if (`bynum'==1) {
+		   	  if ("`usegtools'"=="") {
+			     mata: st_local("Nclust", strofreal(rows(uniqrows(`cluvec'))))
+		      }
+			  else {
+			     qui gunique `clustervar'
+				 local Nclust=r(unique)
+			  }
+		   }
+		   else {
+		      if ("`usegtools'"=="") {
+		         mata: st_local("Nclust", strofreal(rows(uniqrows(select(`cluvec', `byindex')))))
+		      }
+			  else {
+			     qui gunique `clustervar' `conds'
+				 local Nclust=r(unique)
+			  }
+		   }
+		   local eN=min(`eN', `Nclust')   /* effective SUBsample size */
+		   mat `Nclustlist'[`counter_by',1]=`Nclust'
+	    }
+	    
+		*********************************************************
+		************** Prepare bins, within loop ****************
+		*********************************************************
+		if ("`pos'"!="user") local pos `binspos'              /* initialize pos */
+		* Selection?
+	    if ("`selection'"!="NA"&"`knotlistON'"!="T"&"`fullfewobs'"=="") {
+		   * Check effective sample size
+		   if ("`dots_p'"==".") local dotspcheck=6
+		   else                 local dotspcheck=`dots_p'
+		   if ("`nbinsrot'"==""&(`eN'<=`dfcheck_n1'+`dotspcheck'+1+`qrot')) {
+		      di as text in gr "Warning: Too small effective sample size for bin selection." ///
+			                   _newline _skip(9) "# of mass points or clusters used."
+	          local fewobs "T"
+			  local nbins=`eN'
+			  local pos "QS"                /* forced to be QS */
+	       }
+		   else {
+		   	  local randcut1k `randcut'
+		      if ("`randcut'"=="" & `N'>5000) {
+			     local randcut1k=max(5000/`N', 0.01)
+				 di as text in gr "Warning: To speed up computation, bin/degree selection uses a subsample of roughly max(5,000, 0.01n) observations if the sample size n>5,000. To use the full sample, set randcut(1)."
+		      }
+		      if ("`selection'"=="J") {
+			     qui binsregselect `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+				                   bins(`dots_p' `dots_s') nbins(`nbins_full') ///
+		                           absorb(`absorb') reghdfeopt(`reghdfeopt') /// 
+					   			   binsmethod(`binsmethod') binspos(`pos') nbinsrot(`nbinsrot') ///
+							       `vce' masspoints(`masspoints') dfcheck(`dfcheck_n1' `dfcheck_n2') ///
+							       numdist(`Ndist') numclust(`Nclust') randcut(`randcut1k') usegtools(`sel_gtools')
+			     if (e(nbinsrot_regul)==.) {
+			        di as error "bin selection fails."
+			        exit
+			     }
+			     if ("`binsmethod'"=="ROT") {
+		            local nbins=e(nbinsrot_regul)
+				    mat `mat_imse_bsq_rot'[`counter_by',1]=e(imse_bsq_rot)
+				    mat `mat_imse_var_rot'[`counter_by',1]=e(imse_var_rot)
+		         }
+		         else if ("`binsmethod'"=="DPI") {
+			        local nbins=e(nbinsdpi)
+					mat `mat_imse_bsq_dpi'[`counter_by',1]=e(imse_bsq_dpi)
+				    mat `mat_imse_var_dpi'[`counter_by',1]=e(imse_var_dpi)
+			        if (`nbins'==.) {
+			           local nbins=e(nbinsrot_regul)
+					   mat `mat_imse_bsq_rot'[`counter_by',1]=e(imse_bsq_rot)
+				       mat `mat_imse_var_rot'[`counter_by',1]=e(imse_var_rot)
+			           di as text in gr "Warning: DPI selection fails. ROT choice used."
+			        }
+		         }
+			  }
+		      else if ("`selection'"=="P") {
+		   	     qui binsregselect `y_var' `x_var' `w_var' `wt', deriv(`deriv') nbins(`nbins_full') ///
+				     			    absorb(`absorb') reghdfeopt(`reghdfeopt') ///
+					  			    pselect(`plist') sselect(`slist') ///
+								    binsmethod(`binsmethod') binspos(`binspos') nbinsrot(`nbinsrot') ///
+								    `vce' masspoints(`masspoints') dfcheck(`dfcheck_n1' `dfcheck_n2') ///
+								    numdist(`Ndist') numclust(`Nclust') randcut(`randcut1k') usegtools(`sel_gtools')
+			     if (e(prot_regul)==.) {
+			        di as error "bin selection fails."
+				    exit
+			     }
+			     if ("`binsmethod'"=="ROT") {
+				    local binsp=e(prot_regul)
+				    local binss=e(srot_regul)
+					mat `mat_imse_bsq_rot'[`counter_by',1]=e(imse_bsq_rot)
+				    mat `mat_imse_var_rot'[`counter_by',1]=e(imse_var_rot)
+			     }
+			     else if ("`binsmethod'"=="DPI") {
+				    local binsp=e(pdpi)
+				    local binss=e(sdpi)
+					mat `mat_imse_bsq_dpi'[`counter_by',1]=e(imse_bsq_dpi)
+				    mat `mat_imse_var_dpi'[`counter_by',1]=e(imse_var_dpi)
+				    if (`binsp'==.) {
+				       local binsp=e(prot_regul)
+					   local binss=e(srot_regul)
+					   mat `mat_imse_bsq_rot'[`counter_by',1]=e(imse_bsq_rot)
+				       mat `mat_imse_var_rot'[`counter_by',1]=e(imse_var_rot)
+					   di as text in gr "Warning: DPI selection fails. ROT choice used."
+				    }
+			     }
+				 if ("`dots'"=="T"|"`dots'"=="") {
+				    local dots_p=`binsp'
+					local dots_s=`binss'
+				 }
+				 if ("`line'"=="T") {
+				    local line_p=`binsp'
+					local line_s=`binss'
+				 }
+				 if ("`ci'"!="T"&"`ci'"!="") {
+					if (`ci_p'<=`binsp') {
+					   local ci_p=`binsp'+1
+					   local ci_s=`ci_p'
+				       di as text "Warning: Degree for ci() has been changed. It must be greater than the IMSE-optimal degree."
+				    }
+			     }
+				 if ("`ci'"=="T") {
+					local ci_p=`binsp'+1
+					local ci_s=`binss'+1
+				 }
+				 if ("`cb'"!="T"&"`cb'"!="") {
+			        if (`cb_p'<=`binsp') {
+				      local cb_p=`binsp'+1
+					  local cb_s=`cb_p'
+				      di as text "Warning: Degree for cb() has been changed. It must be greater than the IMSE-optimal degree."
+				    }
+			     }
+				 if ("`cb'"=="T") {
+				    local cb_p=`binsp'+1
+					local cb_s=`binss'+1
+				 }
+		      }		   
+		   }
+	    }
+		
+		if ("`selection'"=="NA"|"`knotlistON'"=="T") local nbins=`nbins_full'    /* add the universal nbins */
+		*if ("`knotlistON'"=="T") local nbins=`nbins_full'
+		if ("`fullfewobs'"!="") {
+		   local fewobs "T"
+		   local nbins=`eN'
+		}
+		
+	    ******************************************************
+	    * Check effective sample size for each case **********
+		******************************************************
+	    if ("`fewobs'"!="T") {
+		   if ((`nbins'-1)*(`dots_p'-`dots_s'+1)+`dots_p'+1+`dfcheck_n2'>=`eN') {
+		      local fewobs "T"           /* even though ROT available, treat it as few obs case */
+		      local nbins=`eN'
+		      local pos "QS"
+		      di as text in gr "Warning: Too small effective sample size for dots. # of mass points or clusters used."
+	       }
+		   if ("`line_p'"!=".") {
+	          if ((`nbins'-1)*(`line_p'-`line_s'+1)+`line_p'+1+`dfcheck_n2'>=`eN') {
+	             local line_fewobs "T"
+		         di as text in gr "Warning: Too small effective sample size for line."
+	          }
+		   }
+		   if ("`ci_p'"!=".") {
+	          if ((`nbins'-1)*(`ci_p'-`ci_s'+1)+`ci_p'+1+`dfcheck_n2'>=`eN') {
+	             local ci_fewobs "T"
+		         di as text in gr "Warning: Too small effective sample size for CI."
+	          }
+		   }
+		   if ("`cb_p'"!=".") {
+	          if ((`nbins'-1)*(`cb_p'-`cb_s'+1)+`cb_p'+1+`dfcheck_n2'>=`eN') {
+	             local cb_fewobs "T"
+		         di as text in gr "Warning: Too small effective sample size for CB."
+	          }
+		   }
+	    }
+		
+	    if ("`polyreg'"!="") {
+	       if (`polyreg'+1>=`eN') {
+	          local polyreg_fewobs "T"
+		      di as text in gr "Warning: Too small effective sample size for polynomial fit."
+	       }
+	    }
+ 
+	    * Generate category variable for data and save knot in matrix
+		tempname kmat
+	    
+		if ("`knotlistON'"=="T") {
+		   mat `kmat'=`fullkmat'
+		   if ("`fewobs'"=="T"&"`eN'"!="`Ndist'") {
+		      if (`nbins'==1)  mat `kmat'=(`xmin' \ `xmax')
+		      else {		
+	            binsreg_pctile `x_var' `conds' `wt', nq(`nbins') `usegtools'
+		        mat `kmat'=(`xmin' \ r(Q) \ `xmax')
+		      }
+		   }
+		}
+		else {
+		   if ("`fewmasspoints'"==""&("`fewobs'"!="T"|"`eN'"!="`Ndist'")) {
+             if ("`pos'"=="ES") {
+	            local stepsize=(`xmax'-`xmin')/`nbins'
+	            forvalues i=1/`=`nbins'+1' {
+		           mat `kmat'=(nullmat(`kmat') \ `=`xmin'+`stepsize'*(`i'-1)')
+		        }
+		     }
+	         else {		
+		        if (`nbins'==1)  mat `kmat'=(`xmin' \ `xmax')
+		        else {		
+	              binsreg_pctile `x_var' `conds' `wt', nq(`nbins') `usegtools'
+		          mat `kmat'=(`xmin' \ r(Q) \ `xmax')
+		        }
+		     }
+		   }
+		}
+	
+		* Renew knot list if few mass points
+		if (("`fewobs'"=="T"&"`eN'"=="`Ndist'")|"`fewmasspoints'"!="") {
+		   qui tab `x_var' `conds', matrow(`kmat')
+		   if ("`fewmasspoints'"!="") {
+		      local nbins=rowsof(`kmat')
+			  local Ndist=`nbins'
+			  local eN=`Ndist'
+		   }
+		}
+		else {
+		   mata: st_matrix("`kmat'", (`xmin' \ uniqrows(st_matrix("`kmat'")[|2 \ `=`nbins'+1'|])))
+	       if (`nbins'!=rowsof(`kmat')-1) {
+	          di as text in gr "Warning: Repeated knots. Some bins dropped."
+		      local nbins=rowsof(`kmat')-1
+	       }
+		   
+		   binsreg_irecode `x_var' `conds', knotmat(`kmat') bin(`xcat') ///
+		                                   `usegtools' nbins(`nbins') pos(`pos') knotliston(`knotlistON')
+		   
+		   mata: `xcatsub'=st_data(., "`xcat'")
+		   if (`bynum'>1) {
+		      mata: `xcatsub'=select(`xcatsub', `byindex')
+		   }
+        }
+
+	    *************************************************
+	    **** Check for empty bins ***********************
+		*************************************************
+		mata: `binedges'=.               /* initialize */
+		if ("`fewobs'"!="T"&"`localcheck'"=="T") {
+		   mata: st_local("Ncat", strofreal(rows(uniqrows(`xcatsub'))))
+		   if (`nbins'==`Ncat') {
+		      mata: `binedges'=binsreg_uniq(`xsub', `xcatsub', `nbins', "uniqmin")
+		   }
+		   else {
+		      local uniqmin=0
+			  di as text in gr "Warning: There are empty bins. Specify a smaller number in nbins()."
+		   }
+		   
+		   if ("`dots_p'"!=".") {
+		      if (`uniqmin'<`dots_p'+1) {
+		         local dots_fewobs "T"
+		         di as text in gr "Warning: Some bins have too few distinct x-values for dots."
+		      }
+	       }
+	       if ("`line_p'"!=".") {
+		      if (`uniqmin'<`line_p'+1) {
+		         local line_fewobs "T"
+		         di as text in gr "Warning: Some bins have too few distinct x-values for line."
+		      }
+	       }
+	       if ("`ci_p'"!=".") {
+		      if (`uniqmin'<`ci_p'+1) {
+		         local ci_fewobs "T"
+		         di as text in gr "Warning: Some bins have too few distinct x-values for CI."
+		      }
+	       }
+	       if ("`cb_p'"!=".") {
+		      if (`uniqmin'<`cb_p'+1) {
+		         local cb_fewobs "T"
+		         di as text in gr "Warning: Some bins have too few distinct x-values for CB."
+		      }
+	       }
+		}
+		
+		* Now, save nbins in a list !!!
+		mat `nbinslist'=(nullmat(`nbinslist') \ `nbins')
+		
+		**********************************************************
+	    **** Count the number of rows needed (within loop!) ******
+		**********************************************************
+		local byfirst=`bylast'+1
+		local byrange=0
+		if ("`fewobs'"!="T") {
+		   local dots_nr=`dotsngrid_mean'*`nbins'
+		   if (`dotsngrid'!=0) local dots_nr=`dots_nr'+`dotsngrid'*`nbins'+`nbins'-1
+		   local ci_nr=`cingrid_mean'*`nbins'
+		   if (`cingrid'!=0)   local ci_nr=`ci_nr'+`cingrid'*`nbins'+`nbins'-1
+		   if (`linengrid'!=0) local line_nr=`linengrid'*`nbins'+`nbins'-1
+		   if (`cbngrid'!=0)   local cb_nr=`cbngrid'*`nbins'+`nbins'-1
+		   if (`polyregngrid'!=0) {
+		      local poly_nr=`polyregngrid'*`nbins'+`nbins'-1
+		      if (`polyregcingrid'!=0) local polyci_nr=`polyregcingrid'*`nbins'+`nbins'-1
+		   }	   
+		   local byrange=max(`dots_nr'+0,`line_nr'+0,`ci_nr'+0,`cb_nr'+0, `poly_nr'+0, `polyci_nr'+0)
+		}
+		else {
+		   if ("`eN'"=="`Ndist'") {
+		      if (`polyregngrid'!=0) {
+			     local poly_nr=`polyregngrid'*(`nbins'-1)+`nbins'-1-1
+				 if (`polyregcingrid'!=0) local polyci_nr=`polyregcingrid'*(`nbins'-1)+`nbins'-1-1
+			  }
+		   }
+		   else {
+		      if (`polyregngrid'!=0) {
+		         local poly_nr=`polyregngrid'*`nbins'+`nbins'-1
+			     if (`polyregcingrid'!=0) local polyci_nr=`polyregcingrid'*`nbins'+`nbins'-1
+			  }
+		   }
+		   local byrange=max(`nbins', `poly_nr'+0, `polyci_nr'+0)
+		}
+		local bylast=`bylast'+`byrange'
+		mata: `plotmatby'=J(`byrange',`ncolplot',.)
+		if ("`byval'"!="noby") {
+		   mata: `plotmatby'[.,1]=J(`byrange',1,`byval')
+		}
+ 
+		************************************************
+	    **** START: prepare data for plotting***********
+	    ************************************************
+		local plotcmdby ""
+		
+		********************************
+		* adjust w vars
+		tempname wval
+		if (`nwvar'>0) {
+		   if (`"`at'"'==`"mean"'|`"`at'"'==`"median"') {
+		     matrix `wval'=J(1, `nwvar', 0)
+			 tempname wvaltemp mataobj
+			 mata: `mataobj'=.
+			 foreach wpos in `indexlist' {
+			    local wname: word `wpos' of `w_var'
+		        if ("`usegtools'"=="") {
+		           if ("`wtype'"!="") qui tabstat `wname' `conds' [aw`exp'], stat(`at') save
+			       else               qui tabstat `wname' `conds', stat(`at') save
+				   mat `wvaltemp'=r(StatTotal)
+				}
+				else {
+				   qui gstats tabstat `wname' `conds' `wt', stat(`at') matasave("`mataobj'")
+				   mata: st_matrix("`wvaltemp'", `mataobj'.getOutputCol(1))
+				}
+				mat `wval'[1,`wpos']=`wvaltemp'[1,1]
+		     }
+			 mata: mata drop `mataobj'
+		   }
+		   else if (`"`at'"'==`"0"') {
+   		     matrix `wval'=J(1,`nwvar',0)
+		   }
+		   else if ("`atwout'"=="user") {
+		     matrix `wval'=`wuser'
+		   }
+		}
+
+		
+		*************************************************
+	    ********** dots and ci for few obs. case ********
+	    *************************************************
+	    if (`dotsntot'!=0&"`plot'"==""&"`fewobs'"=="T") {
+		   di as text in gr "Warning: dots(0 0) is used."
+		   if (`deriv'>0) di as text in gr "Warning: deriv(0 0) is used."
+		   
+		   local dots_first=`byfirst'
+		   local dots_last=`byfirst'-1+`nbins'
+	       
+		   mata: `plotmatby'[|1,`dots_start'+2 \ `nbins',`dots_start'+2|]=range(1,`nbins',1)
+		
+		   if ("`eN'"=="`Ndist'") {
+		      mata: `plotmatby'[|1,`dots_start' \ `nbins',`dots_start'|]=st_matrix("`kmat'"); ///
+			        `plotmatby'[|1,`dots_start'+1 \ `nbins',`dots_start'+1|]=J(`nbins',1,1)
+			  
+			  * Renew knot commalist, each value forms a group
+		      local xknot ""
+		      forvalues i=1/`nbins' {
+		         local xknot `xknot' `kmat'[`i',1]
+		      }
+		      local xknotcommalist : subinstr local xknot " " ",", all
+		      qui replace `xcat'=1+irecode(`x_var',`xknotcommalist') `conds'
+		   }
+		   else {
+		      tempname grid
+		      mat `grid'=(`kmat'[1..`nbins',1]+`kmat'[2..`nbins'+1,1])/2
+		      mata: `plotmatby'[|1,`dots_start' \ `nbins',`dots_start'|]=st_matrix("`grid'"); ///
+			        `plotmatby'[|1,`dots_start'+1 \ `nbins',`dots_start'+1|]=J(`nbins',1,0)
+		   }
+		   
+	       local nseries=`nbins'
+	       capture probit `y_var' ibn.`xcat' `w_var' `conds' `wt', nocon `vce' `probitopt'
+		   tempname fewobs_b fewobs_V
+		   if (_rc==0) {
+		      mat `fewobs_b'=e(b)
+		      mat `fewobs_V'=e(V)
+		      mata: binsreg_checkdrop("`fewobs_b'", "`fewobs_V'", `nseries')
+			  if (`nwvar'>0) {
+			     mat `fewobs_b'=`fewobs_b'[1,1..`nseries']+(`fewobs_b'[1,`=`nseries'+1'..`=`nseries'+`nwvar'']*`wval'')*J(1,`nseries',1)
+		      }
+			  else {
+			     mat `fewobs_b'=`fewobs_b'[1,1..`nseries']
+		      }
+		   }
+		   else {
+		      error _rc
+		      exit _rc
+		   }
+		
+		   if ("`transform'"=="T") {
+		      mata: `plotmatby'[|1,`dots_start'+3 \ `nbins',`dots_start'+3|]=normal(st_matrix("`fewobs_b'"))'
+           }
+		   else {
+		      mata: `plotmatby'[|1,`dots_start'+3 \ `nbins',`dots_start'+3|]=st_matrix("`fewobs_b'")'
+		   }
+		   
+		   local plotnum=`plotnum'+1
+		   local legendnum `legendnum' `plotnum' 
+		   local col: word `counter_by' of `bycolors'
+		   local sym: word `counter_by' of `bysymbols'
+		   local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond `plotcond' if 
+			  if ("`plotxrange'"!="") {
+		         local plotcond `plotcond' dots_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &dots_x<=`max_xr' 
+		      }
+		      if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' dots_fit>=`min_yr'
+				 else                    local plotcond `plotcond' &dots_fit>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &dots_fit<=`max_yr' 
+		      }
+		   }
+
+		   local plotcmdby `plotcmdby' (scatter dots_fit dots_x ///
+		                   `plotcond' in `dots_first'/`dots_last', ///
+						   mcolor(`col') msymbol(`sym') `dotsplotopt')
+		   
+		   if (`cintot'!=0) {
+		      di as text in gr "Warning: ci(0 0) is used."
+		   
+		   	  if (`nwvar'>0) {
+			     mata: `mata_se'=(I(`nseries'), J(`nseries',1,1)#st_matrix("`wval'"))
+			  }
+			  else {
+			     mata: `mata_se'=I(`nseries')
+			  }
+
+		      mata: `plotmatby'[|1,`ci_start'+1 \ `nbins',`ci_start'+2|]=`plotmatby'[|1,`dots_start'+1 \ `nbins',`dots_start'+2|]; ///
+			        `mata_se'=sqrt(rowsum((`mata_se'*st_matrix("`fewobs_V'")):*`mata_se'))
+			  if ("`transform'"=="T") {
+			     mata: `mata_se'=`mata_se':*(normalden(st_matrix("`fewobs_b'"))')
+			  }
+			  mata: `plotmatby'[|1,`ci_start'+3 \ `nbins',`ci_start'+3|]=`plotmatby'[|1,`dots_start'+3 \ `nbins',`dots_start'+3|]-`mata_se'*invnormal(`alpha'); ///
+			        `plotmatby'[|1,`ci_start'+4 \ `nbins',`ci_start'+4|]=`plotmatby'[|1,`dots_start'+3 \ `nbins',`dots_start'+3|]+`mata_se'*invnormal(`alpha')
+			  mata: mata drop `mata_se'
+			  
+			  local plotnum=`plotnum'+1
+			  local lty: word `counter_by' of `bylpatterns'
+		      local plotcmdby `plotcmdby' (rcap CI_l CI_r dots_x ///
+			                  `plotcond' in `dots_first'/`dots_last', ///
+							  sort lcolor(`col') lpattern(`lty') `ciplotopt')
+		   }
+	    } 
+	 
+	    *********************************************
+	    **** The following handles the usual case ***
+	    *********************************************
+		* Turn on or off?
+		local dotsON ""
+		local lineON ""
+		local polyON ""
+		local ciON   ""
+		local cbON   ""
+	    if (`dotsntot'!=0&"`plot'"==""&"`fewobs'"!="T"&"`dots_fewobs'"!="T") {
+	       local dotsON "T"
+	    }	    
+		if (`linengrid'!=0&"`plot'"==""&"`line_fewobs'"!="T"&"`fewobs'"!="T") {
+	       local lineON "T"
+	    }
+	    if (`polyregngrid'!=0&"`plot'"==""&"`polyreg_fewobs'"!="T") {
+	       local polyON "T"
+	    }
+	    if (`cintot'!=0&"`plot'"==""&"`ci_fewobs'"!="T"&"`fewobs'"!="T") {
+	       local ciON "T"
+	    }
+		if (`cbngrid'!=0&"`plot'"==""&"`cb_fewobs'"!="T"&"`fewobs'"!="T") {
+	       local cbON "T"
+	    }
+				
+		
+	    ************************
+	    ****** Dots ************
+	    ************************
+		tempname xmean
+
+	    if ("`dotsON'"=="T") {
+		   local dots_first=`byfirst'
+		   local dots_last=`byfirst'+`dots_nr'-1
+		   
+		   * fitting
+		   tempname dots_b dots_V
+		   if (("`dots_p'"=="`ci_p'"&"`dots_s'"=="`ci_s'"&"`ciON'"=="T")| ///
+		       ("`dots_p'"=="`cb_p'"&"`dots_s'"=="`cb_s'"&"`cbON'"=="T")) {
+			  binsprobit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                    p(`dots_p') s(`dots_s') type(dots) `vce' ///
+			            xcat(`xcat') kmat(`kmat') dotsmean(`dotsngrid_mean') /// 
+			            xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						usereg `sorted' `usegtools' probitopt(`probitopt')
+		   }
+		   else {
+		      binsprobit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                    p(`dots_p') s(`dots_s') type(dots) `vce' ///
+			            xcat(`xcat') kmat(`kmat') dotsmean(`dotsngrid_mean') /// 
+			            xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						`sorted' `usegtools' probitopt(`probitopt')
+		   }
+		   
+		   mat `dots_b'=e(bmat)
+		   mat `dots_V'=e(Vmat)
+		   if (`dotsngrid_mean'!=0) mat `xmean'=e(xmat)
+		   
+		   * prediction
+		   if (`dotsngrid_mean'==0) {
+		      mata: `plotmatby'[|1,`dots_start' \ `dots_nr',`dots_end'|] = ///
+			                  binsprobit_plotmat("`dots_b'", "`dots_V'", ., "`kmat'", ///
+		                                       `nbins', `dots_p', `dots_s', `deriv', ///
+							                   "dots", `dotsngrid', "`wval'", `nwvar', ///
+											   "`transform'", "`asyvar'")
+		   }
+		   else {
+		      mata: `plotmatby'[|1,`dots_start' \ `dots_nr',`dots_end'|] = ///
+			                  binsprobit_plotmat("`dots_b'", "`dots_V'", ., "`kmat'", ///
+		                                        `nbins', `dots_p', `dots_s', `deriv', ///
+							                    "dots", `dotsngrid', "`wval'", `nwvar', ///
+												"`transform'", "`asyvar'", "`xmean'")
+		   }		  
+		  
+		   * dots
+		   local plotnum=`plotnum'+1
+		   if ("`cbON'"=="T") local legendnum `legendnum' `=`plotnum'+1'
+		   else {
+		      local legendnum `legendnum' `plotnum'
+		   }
+		   local col: word `counter_by' of `bycolors'
+		   local sym: word `counter_by' of `bysymbols'
+		   local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+		         local plotcond `plotcond' dots_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &dots_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' dots_fit>=`min_yr'
+				 else                    local plotcond `plotcond' &dots_fit>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &dots_fit<=`max_yr' 
+		      }
+		   }
+		   
+	       local plotcmdby `plotcmdby' (scatter dots_fit dots_x ///
+		                   `plotcond' in `dots_first'/`dots_last', ///
+						   mcolor(`col') msymbol(`sym') `dotsplotopt')
+	    }
+
+	    **********************************************
+	    ********************* Line *******************
+	    **********************************************
+	    if ("`lineON'"=="T") {
+		   local line_first=`byfirst'
+		   local line_last=`byfirst'-1+`line_nr'
+
+		   * fitting
+		   tempname line_b line_V
+		   capture confirm matrix `dots_b' `dots_V'
+		   if ("`line_p'"=="`dots_p'"& "`line_s'"=="`dots_s'" & _rc==0) {
+		      matrix `line_b'=`dots_b'
+		      matrix `line_V'=`dots_V'
+		   }
+		   else {
+		      if (("`line_p'"=="`ci_p'"&"`line_s'"=="`ci_s'"&"`ciON'"=="T")| ///
+		          ("`line_p'"=="`cb_p'"&"`line_s'"=="`cb_s'"&"`cbON'"=="T")) {
+				 binsprobit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                      p(`line_p') s(`line_s') type(line) `vce' ///
+			              xcat(`xcat') kmat(`kmat') dotsmean(0) /// 
+			              xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						  usereg `sorted' `usegtools' probitopt(`probitopt')
+			  }
+			  else {
+		         binsprobit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                      p(`line_p') s(`line_s') type(line) `vce' ///
+			              xcat(`xcat') kmat(`kmat') dotsmean(0) /// 
+			              xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') /// 
+						  `sorted' `usegtools' probitopt(`probitopt')
+			  }
+		      mat `line_b'=e(bmat)
+		      mat `line_V'=e(Vmat)
+		   }
+
+		   * prediction
+		   mata: `plotmatby'[|1,`line_start' \ `line_nr',`line_end'|] = ///
+			              binsprobit_plotmat("`line_b'", "`line_V'", ., "`kmat'", ///
+		                      `nbins', `line_p', `line_s', `deriv', ///
+							  "line", `linengrid', "`wval'", `nwvar', "`transform'", "`asyvar'")
+		   
+		   * line
+		   local plotnum=`plotnum'+1
+		   local col: word `counter_by' of `bycolors'
+		   local lty: word `counter_by' of `bylpatterns'
+		   local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+		         local plotcond `plotcond' line_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &line_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' line_fit>=`min_yr'
+				 else                    local plotcond `plotcond' &line_fit>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &(line_fit<=`max_yr'|line_fit==.) 
+		      }
+		   }
+		   
+	       local plotcmdby `plotcmdby' (line line_fit line_x ///
+		                   `plotcond' in `line_first'/`line_last', sort cmissing(n) ///
+						   lcolor(`col') lpattern(`lty') `lineplotopt')
+	
+	    }
+	 
+	    ***********************************
+	    ******* Polynomial fit ************
+	    ***********************************
+	    if ("`polyON'"=="T") {
+		   if (`nwvar'>0) {
+		      di as text "Note: When additional covariates w are included, the polynomial fit may not always be close to the binscatter fit."
+		   }
+
+	       local poly_first=`byfirst'
+		   local poly_last=`byfirst'-1+`poly_nr'
+
+	       mata:`plotmatby'[|1,`poly_start' \ `poly_nr',`poly_start'+2|]=binsreg_grids("`kmat'",`polyregngrid')
+		   
+	       local poly_series ""
+	       forval i=0/`polyreg' {
+		      tempvar x_var_`i'
+			  qui gen `x_var_`i''=`x_var'^`i' `conds'
+	          local poly_series `poly_series' `x_var_`i''
+		   }
+		 
+		   capture probit `y_var' `poly_series' `w_var' `conds' `wt', nocon `vce' `probitopt'
+		   * store results
+		   tempname poly_b poly_V poly_adjw
+	       if (_rc==0) {
+	 	      matrix `poly_b'=e(b)
+			  matrix `poly_V'=e(V)
+	       }
+	       else {
+	          error  _rc
+	   	      exit _rc
+           }
+		 
+		   * Data for derivative
+		   mata: `Xm'=J(`poly_nr',0,.); `Xm0'=J(`poly_nr',0,.)   
+	       forval i=`deriv'/`polyreg' {
+		      mata: `Xm'=(`Xm', ///
+				      `plotmatby'[|1,`poly_start' \ `poly_nr',`poly_start'|]:^(`i'-`deriv')* ///
+					  factorial(`i')/factorial(`i'-`deriv'))	
+	       }
+		   mata: `Xm'=(J(`poly_nr', `deriv',0), `Xm')
+		   if (`nwvar'>0) {
+		      if (`deriv'==0) mata: `Xm'=(`Xm', J(`poly_nr',1,1)#st_matrix("`wval'"))
+			  else            mata: `Xm'=(`Xm', J(`poly_nr',`nwvar',0))
+		   }
+		   
+		   if ("`transform'"=="T") {
+		      if (`deriv'==0) {
+			     mata:`plotmatby'[|1,`poly_start'+3 \ `poly_nr',`poly_start'+3|]=normal(`Xm'*st_matrix("`poly_b'")')
+			  }
+			  else if (`deriv'==1) {
+			     forval i=0/`polyreg' {
+		            mata: `Xm0'=(`Xm0', `plotmatby'[|1,`poly_start' \ `poly_nr',`poly_start'|]:^`i')	
+	             }
+				 if (`nwvar'>0) mata: `Xm0'=(`Xm0', J(`poly_nr',1,1)#st_matrix("`wval'"))
+			     mata:`plotmatby'[|1,`poly_start'+3 \ `poly_nr',`poly_start'+3|]=normalden(`Xm0'*st_matrix("`poly_b'")'):* ///
+				                                                                 (`Xm'*st_matrix("`poly_b'")')
+			  }
+		   }
+		   else {
+		      mata:`plotmatby'[|1,`poly_start'+3 \ `poly_nr',`poly_start'+3|]=`Xm'*st_matrix("`poly_b'")'
+		   }
+		   
+		   mata: mata drop `Xm' `Xm0'
+		   
+		   local plotnum=`plotnum'+1
+		   local col: word `counter_by' of `bycolors'
+		   local lty: word `counter_by' of `bylpatterns'
+		   local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+		         local plotcond `plotcond' poly_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &poly_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' poly_fit>=`min_yr'
+				 else                    local plotcond `plotcond' &poly_fit>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &poly_fit<=`max_yr' 
+		      }
+		   }
+
+		   local plotcmdby `plotcmdby' (line poly_fit poly_x ///
+		                   `plotcond' in `poly_first'/`poly_last', ///
+						   sort lcolor(`col') lpattern(`lty') `polyregplotopt')
+		
+		   * add CI for global poly?
+		   if (`polyregcingrid'!=0) {
+	          local polyci_first=`byfirst'
+			  local polyci_last=`byfirst'-1+`polyci_nr'
+	          
+	          mata: `plotmatby'[|1,`polyci_start' \ `polyci_nr',`polyci_start'+2|]=binsreg_grids("`kmat'", `polyregcingrid')
+		   
+		      mata: `Xm'=J(`polyci_nr',0,.); `Xm0'=J(`polyci_nr',0,.)
+	          forval i=`deriv'/`polyreg' {
+		         mata:`Xm'=(`Xm', ///
+				      `plotmatby'[|1,`polyci_start' \ `polyci_nr',`polyci_start'|]:^(`i'-`deriv')* ///
+					  factorial(`i')/factorial(`i'-`deriv'))	
+	          }
+ 		      mata: `Xm'=(J(`polyci_nr', `deriv',0), `Xm')
+		      if (`nwvar'>0) {
+		         if (`deriv'==0) mata: `Xm'=(`Xm', J(`polyci_nr',1,1)#st_matrix("`wval'"))
+			     else            mata: `Xm'=(`Xm', J(`polyci_nr',`nwvar',0))
+		      }
+			  
+			  if ("`transform'"=="T") {
+		         if (`deriv'==0) {
+				    mata: `mata_fit'=normal(`Xm'*st_matrix("`poly_b'")')
+					mata: `mata_se'=normalden(`Xm'*st_matrix("`poly_b'")'):* ///
+					                sqrt(rowsum((`Xm'*st_matrix("`poly_V'")):*`Xm'))
+				 }
+				 else if (`deriv'==1) {
+				    forval i=0/`polyreg' {
+		               mata: `Xm0'=(`Xm0', `plotmatby'[|1,`polyci_start' \ `polyci_nr',`polyci_start'|]:^`i')	
+	                }
+					if (`nwvar'>0) mata: `Xm0'=(`Xm0', J(`polyci_nr',1,1)#st_matrix("`wval'"))
+			        mata:`mata_fit'=normalden(`Xm0'*st_matrix("`poly_b'")'):* ///
+				                    (`Xm'*st_matrix("`poly_b'")')
+									
+					tempname tempobj
+					mata: `tempobj'=`Xm0'*st_matrix("`poly_b'")'; ///
+					      `tempobj'=(-`tempobj'):*normalden(`tempobj'):*(`Xm'*st_matrix("`poly_b'")'):*`Xm0' + ///
+					                normalden(`tempobj'):*`Xm'; ///
+						  `mata_se'=sqrt(rowsum((`tempobj'*st_matrix("`poly_V'")):*`tempobj'))
+					mata: mata drop `tempobj'
+				 }
+			  }
+			  else {
+		         mata: `mata_fit'=`Xm'*st_matrix("`poly_b'")';	///			 
+			           `mata_se'=sqrt(rowsum((`Xm'*st_matrix("`poly_V'")):*`Xm')) 
+			  }
+
+			  mata:`plotmatby'[|1,`polyci_start'+3 \ `polyci_nr',`polyci_start'+3|]=`mata_fit'-`mata_se'*invnormal(`alpha'); ///
+				   `plotmatby'[|1,`polyci_start'+4 \ `polyci_nr',`polyci_start'+4|]=`mata_fit'+`mata_se'*invnormal(`alpha'); ///
+				   `plotmatby'[selectindex(`plotmatby'[,`=`polyci_start'+1']:==1),(`=`polyci_start'+3',`=`polyci_start'+4')]=J(`=`nbins'-1',2,.)
+		      
+		      mata: mata drop `Xm' `Xm0' `mata_fit' `mata_se'
+		
+		      * poly ci
+			  local plotnum=`plotnum'+1
+			  local plotcond ""
+		      if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		         local plotcond if
+		         if ("`plotxrange'"!="") {
+		            local plotcond `plotcond' polyCI_x>=`min_xr'
+			        if ("`max_xr'"!="") local plotcond `plotcond' &polyCI_x<=`max_xr' 
+		         }
+			     if ("`plotyrange'"!="") {
+		            if ("`plotxrange'"=="") local plotcond `plotcond' polyCI_l>=`min_yr'
+				    else                    local plotcond `plotcond' &polyCI_l>=`min_yr'
+			        if ("`max_yr'"!="") local plotcond `plotcond' &polyCI_r<=`max_yr' 
+		         }
+		      }
+
+	          local plotcmdby `plotcmdby' (rcap polyCI_l polyCI_r polyCI_x ///
+			                  `plotcond' in `polyci_first'/`polyci_last', ///
+							  sort lcolor(`col') lpattern(`lty') `ciplotopt')
+		   }
+	    }
+	  
+	 
+	    **********************************
+	    ******* Confidence Interval ******
+	    **********************************
+	    if ("`ciON'"=="T") {
+	       local ci_first=`byfirst'
+		   local ci_last=`byfirst'-1+`ci_nr'
+		   
+		   * fitting
+		   tempname ci_b ci_V
+		   capture confirm matrix `line_b' `line_V'
+		   if ("`ci_p'"=="`line_p'"& "`ci_s'"=="`line_s'" & _rc==0) {
+		         matrix `ci_b'=`line_b'
+		         matrix `ci_V'=`line_V'
+		   }
+		   else {
+		      capture confirm matrix `dots_b' `dots_V'
+		      if ("`ci_p'"=="`dots_p'"& "`ci_s'"=="`dots_s'" & _rc==0) {
+		         matrix `ci_b'=`dots_b'
+		         matrix `ci_V'=`dots_V'
+		      }
+		   }
+		   
+		   capture confirm matrix `ci_b' `ci_V' `xmean' 
+		   if (_rc!=0) {
+			    binsprobit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                    p(`ci_p') s(`ci_s') type(ci) `vce' ///
+			            xcat(`xcat') kmat(`kmat') dotsmean(`cingrid_mean') /// 
+			            xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						`sorted' `usegtools' probitopt(`probitopt')
+				 
+		        mat `ci_b'=e(bmat)
+		        mat `ci_V'=e(Vmat)
+		        mat `xmean'=e(xmat)
+		   }
+		   
+		   * prediction
+		   if (`cingrid_mean'==0) {
+		      mata: `plotmatby'[|1,`ci_start' \ `ci_nr',`ci_end'|] = ///
+			            binsprobit_plotmat("`ci_b'", "`ci_V'", ///
+						      `=invnormal(`alpha')', "`kmat'", ///
+		                      `nbins', `ci_p', `ci_s', `deriv', "ci", ///
+							  `cingrid', "`wval'", `nwvar', "`transform'", "`asyvar'")
+		   }
+		   else {
+		      mata: `plotmatby'[|1,`ci_start' \ `ci_nr',`ci_end'|] = ///
+			            binsprobit_plotmat("`ci_b'", "`ci_V'", ///
+						   `=invnormal(`alpha')', "`kmat'", ///
+		                   `nbins', `ci_p', `ci_s', `deriv', "ci", ///
+						   `cingrid', "`wval'", `nwvar', ///
+						   "`transform'", "`asyvar'", "`xmean'")
+		   }
+		   
+		   * ci
+		   local plotnum=`plotnum'+1
+		   local col: word `counter_by' of `bycolors'
+		   local lty: word `counter_by' of `bylpatterns'
+	       local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+	             local plotcond `plotcond' CI_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &CI_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' CI_l>=`min_yr'
+				 else                    local plotcond `plotcond' &CI_l>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &CI_r<=`max_yr' 
+		      }
+		   }
+
+		   local plotcmdby `plotcmdby' (rcap CI_l CI_r CI_x ///
+		                   `plotcond' in `ci_first'/`ci_last', ///
+						   sort lcolor(`col') lpattern(`lty') `ciplotopt')
+
+	    }
+	 
+	    *******************************
+	    ***** Confidence Band *********
+	    *******************************
+	    tempname cval
+	    scalar `cval'=.
+	    if ("`cbON'"=="T") {
+		   if (`nsims'<2000|`simsgrid'<50) {
+	         di as text "Note: A larger number random draws/evaluation points is recommended to obtain the final results."
+	       }
+		   * Prepare grid for plotting
+	       local cb_first=`byfirst'
+		   local cb_last=`byfirst'-1+`cb_nr'
+		
+		   * fitting
+		   tempname cb_b cb_V
+		   capture confirm matrix `ci_b' `ci_V'
+		   if ("`cb_p'"=="`ci_p'"& "`cb_s'"=="`ci_s'" & _rc==0) {
+		      matrix `cb_b'=`ci_b'
+		      matrix `cb_V'=`ci_V'
+		   } 
+		   else {
+		      capture confirm matrix `line_b' `line_V'
+		      if ("`cb_p'"=="`line_p'"& "`cb_s'"=="`line_s'" & _rc==0) {
+		         matrix `cb_b'=`line_b'
+		         matrix `cb_V'=`line_V'
+		      }
+			  else {
+			     capture confirm matrix `dots_b' `dots_V'
+			     if ("`cb_p'"=="`dots_p'"& "`cb_s'"=="`dots_s'" & _rc==0) {
+		            matrix `cb_b'=`dots_b'
+		            matrix `cb_V'=`dots_V'
+		         }
+				 else {
+				    binsprobit_fit `y_var' `x_var' `w_var' `conds' `wt', deriv(`deriv') ///
+	                    p(`cb_p') s(`cb_s') type(cb) `vce' ///
+			            xcat(`xcat') kmat(`kmat') dotsmean(0) /// 
+			            xname(`xsub') yname(`ysub') catname(`xcatsub') edge(`binedges') ///
+						`sorted' `usegtools' probitopt(`probitopt')
+					mat `cb_b'=e(bmat)
+		            mat `cb_V'=e(Vmat)
+				 }
+			  }
+		   }
+		
+		   * Compute critical values
+		   * Prepare grid for simulation
+		   local uni_last=`simsngrid'*`nbins'+`nbins'-1
+		   local nseries=(`cb_p'-`cb_s'+1)*(`nbins'-1)+`cb_p'+1
+	       
+		   tempname cb_basis
+		   mata: `cb_basis'=binsreg_grids("`kmat'", `simsngrid'); ///
+		         `cb_basis'=binsreg_spdes(`cb_basis'[,1], "`kmat'", `cb_basis'[,3], `cb_p', `deriv', `cb_s'); ///
+		         `Xm'=binsreg_pred(`cb_basis', st_matrix("`cb_b'")[|1 \ `nseries'|]', ///
+			                       st_matrix("`cb_V'")[|1,1 \ `nseries',`nseries'|], "all"); ///
+			      binsreg_pval(`cb_basis', `Xm'[,2], "`cb_V'", ".", `nsims', `nseries', "two", `=`level'/100', ".", "`cval'", "inf")		  
+		   mata: mata drop `cb_basis' `Xm'
+	          
+	       * prediction
+		   mata: `plotmatby'[|1,`cb_start' \ `cb_nr',`cb_end'|] =   ///
+			                binsprobit_plotmat("`cb_b'", "`cb_V'",      ///
+						                      `=`cval'', "`kmat'",       ///
+		                                      `nbins', `cb_p', `cb_s', `deriv', ///
+							                  "cb", `cbngrid', "`wval'", `nwvar', ///
+											  "`transform'", "`asyvar'")	  
+							  
+		   * cb
+		   local plotnum=`plotnum'+1
+		   local col: word `counter_by' of `bycolors'
+	       local plotcond ""
+		   if ("`plotxrange'"!=""|"`plotyrange'"!="") {
+		      local plotcond if
+		      if ("`plotxrange'"!="") {
+	             local plotcond `plotcond' CB_x>=`min_xr'
+			     if ("`max_xr'"!="") local plotcond `plotcond' &CB_x<=`max_xr' 
+		      }
+			  if ("`plotyrange'"!="") {
+		         if ("`plotxrange'"=="") local plotcond `plotcond' CB_l>=`min_yr'
+				 else                    local plotcond `plotcond' &CB_l>=`min_yr'
+			     if ("`max_yr'"!="") local plotcond `plotcond' &(CB_r<=`max_yr'|CB_r==.) 
+		      }
+		   }
+
+		   local plotcmdby (rarea CB_l CB_r CB_x ///
+		                   `plotcond' in `cb_first'/`cb_last', sort cmissing(n) ///
+		                   lcolor(none%0) fcolor(`col'%50) fintensity(50) `cbplotopt') `plotcmdby'
+	    }
+		mat `cvallist'=(nullmat(`cvallist') \ `cval')
+		
+		local plotcmd `plotcmd' `plotcmdby'
+		mata: `plotmat'=(`plotmat' \ `plotmatby')
+		
+		*********************************
+	    **** display ********************
+	    *********************************	 
+	    di ""
+	    * Plotting
+	    if ("`plot'"=="") {
+		   if (`counter_by'==1) {
+		      di in smcl in gr "Binscatter plot, probit model"
+	          di in smcl in gr "Bin selection method: `binselectmethod'"
+	          di in smcl in gr "Placement: `placement'"
+	          di in smcl in gr "Derivative: `deriv'"
+		      if (`"`savedata'"'!=`""') {
+		         di in smcl in gr `"Output file: `savedata'.dta"'
+		      }
+		   }
+		   di ""
+		   if ("`by'"!="") {
+		      di in smcl in gr "Group: `byvarname' = " in yellow "`byvalname'"
+		   }
+	       di in smcl in gr "{hline 30}{c TT}{hline 15}"
+	       di in smcl in gr "{lalign 1:# of observations}"      _col(30) " {c |} " _col(32) as result %7.0f `N'
+	       di in smcl in gr "{lalign 1:# of distinct values}"   _col(30) " {c |} " _col(32) as result %7.0f `Ndist'
+	       di in smcl in gr "{lalign 1:# of clusters}"          _col(30) " {c |} " _col(32) as result %7.0f `Nclust'	 
+	       di in smcl in gr "{hline 30}{c +}{hline 15}"
+	       di in smcl in gr "{lalign 1:Bin/Degree selection:}"                   _col(30) " {c |} "
+		   if ("`selection'"=="P") {
+		   di in smcl in gr "{ralign 29:Degree of polynomial}"         _col(30) " {c |} " _col(32) as result %7.0f `binsp'
+	       di in smcl in gr "{ralign 29:# of smoothness constraints}"  _col(30) " {c |} " _col(32) as result %7.0f `binss'
+		   }
+		   else {
+	       di in smcl in gr "{ralign 29:Degree of polynomial}"         _col(30) " {c |} " _col(32) as result %7.0f `dots_p'
+	       di in smcl in gr "{ralign 29:# of smoothness constraints}"  _col(30) " {c |} " _col(32) as result %7.0f `dots_s'
+		   }
+		   di in smcl in gr "{ralign 29:# of bins}"                       _col(30) " {c |} " _col(32) as result %7.0f `nbins'
+	       if ("`binselectmethod'"!="User-specified") {
+		      if ("`binsmethod'"=="ROT") {
+		         di in smcl in gr "{ralign 29:imse, bias^2}"                 _col(30) " {c |} " _col(32) as result %7.3f `=`mat_imse_bsq_rot'[`counter_by',1]'
+	             di in smcl in gr "{ralign 29:imse, var.}"                   _col(30) " {c |} " _col(32) as result %7.3f `=`mat_imse_var_rot'[`counter_by',1]'
+			  }
+			  else if ("`binsmethod'"=="DPI") {
+			     di in smcl in gr "{ralign 29:imse, bias^2}"                 _col(30) " {c |} " _col(32) as result %7.3f `=`mat_imse_bsq_dpi'[`counter_by',1]'
+	             di in smcl in gr "{ralign 29:imse, var.}"                   _col(30) " {c |} " _col(32) as result %7.3f `=`mat_imse_var_dpi'[`counter_by',1]'
+			  }
+		   }	       
+		   di in smcl in gr "{hline 30}{c BT}{hline 15}"
+		   di ""
+		   di in smcl in gr "{hline 9}{c TT}{hline 30}"
+		   di in smcl _col(10) "{c |}" in gr _col(17) "p" _col(25) "s" _col(33) "df"
+		   di in smcl in gr "{hline 9}{c +}{hline 30}"
+		   if (`dotsntot'!=0) {
+		      local dots_df=(`dots_p'-`dots_s'+1)*(`nbins'-1)+`dots_p'+1
+		      di in smcl in gr "{lalign 1: dots}"  _col(10) "{c |}" in gr _col(17) "`dots_p'" _col(25) "`dots_s'" _col(33) "`dots_df'"
+		   }
+		   if ("`lineON'"=="T") {
+		      local line_df=(`line_p'-`line_s'+1)*(`nbins'-1)+`line_p'+1
+		      di in smcl in gr "{lalign 1: line}"  _col(10) "{c |}" in gr _col(17) "`line_p'" _col(25) "`line_s'" _col(33) "`line_df'"
+		   }
+		   if (`cintot'!=0) {
+		      local ci_df=(`ci_p'-`ci_s'+1)*(`nbins'-1)+`ci_p'+1
+		      di in smcl in gr "{lalign 1: CI}"  _col(10) "{c |}" in gr _col(17) "`ci_p'" _col(25) "`ci_s'" _col(33) "`ci_df'"
+		   }
+		   if ("`cbON'"=="T") {
+		      local cb_df=(`cb_p'-`cb_s'+1)*(`nbins'-1)+`cb_p'+1
+		      di in smcl in gr "{lalign 1: CB}"  _col(10) "{c |}" in gr _col(17) "`cb_p'" _col(25) "`cb_s'" _col(33) "`cb_df'"
+		   }
+		   if ("`polyON'"=="T") {
+		      local poly_df=`polyreg'+1
+		      di in smcl in gr "{lalign 1: polyreg}"  _col(10) "{c |}" in gr _col(17) "`polyreg'" _col(25) "NA" _col(33) "`poly_df'"
+		   }
+		   di in smcl in gr "{hline 9}{c BT}{hline 30}"
+	    }
+		
+		
+		mata: mata drop `plotmatby'
+		local ++counter_by
+	 }
+	 mata: mata drop `xsub' `ysub' `binedges'
+	 if (`bynum'>1) mata: mata drop `byindex'
+	 capture mata: mata drop `xcatsub'
+	 ****************** END loop ****************************************
+	 ********************************************************************
+	 
+
+	 
+	 *******************************************
+	 *************** Plotting ******************
+	 *******************************************
+	 clear
+	 if ("`plotcmd'"!="") {
+	    * put data back to STATA
+		mata: st_local("nr", strofreal(rows(`plotmat'))) 
+		qui set obs `nr'
+		
+		* MAKE SURE the orderings match
+		qui gen group=. in 1
+		if (`dotsntot'!=0) {
+		   qui gen dots_x=. in 1
+		   qui gen dots_isknot=. in 1
+		   qui gen dots_binid=. in 1 
+		   qui gen dots_fit=. in 1
+		}
+	    if (`linengrid'!=0&"`fullfewobs'"=="") {
+		   qui gen line_x=. in 1
+		   qui gen line_isknot=. in 1
+		   qui gen line_binid=. in 1 
+		   qui gen line_fit=. in 1
+		}
+        if (`polyregngrid'!=0) {
+		   qui gen poly_x=. in 1
+		   qui gen poly_isknot=. in 1
+		   qui gen poly_binid=. in 1
+		   qui gen poly_fit=. in 1
+		   if (`polyregcingrid'!=0) {
+		      qui gen polyCI_x=. in 1
+			  qui gen polyCI_isknot=. in 1
+			  qui gen polyCI_binid=. in 1
+			  qui gen polyCI_l=. in 1
+			  qui gen polyCI_r=. in 1
+		   }
+		}
+		if (`cintot'!=0) {
+           qui gen CI_x=. in 1
+		   qui gen CI_isknot=. in 1
+		   qui gen CI_binid=. in 1
+		   qui gen CI_l=. in 1
+		   qui gen CI_r=. in 1 
+		}
+		if (`cbngrid'!=0&"`fullfewobs'"=="") {
+           qui gen CB_x=. in 1
+		   qui gen CB_isknot=. in 1
+		   qui gen CB_binid=. in 1
+		   qui gen CB_l=. in 1
+		   qui gen CB_r=. in 1
+		}
+			
+		mata: st_store(.,.,`plotmat')
+		
+		* Legend
+		local plot_legend legend(order(
+	    if ("`by'"!=""&`dotsntot'!=0) {
+		  forval i=1/`bynum' {
+			 local byvalname: word `i' of `byvalnamelist'
+	         local plot_legend `plot_legend' `: word `i' of `legendnum'' "`byvarname'=`byvalname'"		  
+	      }
+		  local plot_legend `plot_legend' ))
+	    }
+		else {
+		   local plot_legend legend(off)
+		}
+		
+		* Plot it
+	    local graphcmd twoway `plotcmd', xtitle(`x_varname') ytitle(`y_varname') xscale(range(`xsc')) `plot_legend' `options' 
+	    `graphcmd'
+	 }
+	 mata: mata drop `plotmat' `xvec' `yvec' `byvec' `cluvec'
+	 
+	 
+	 * Save graph data ?
+	 * In the normal case
+     if (`"`savedata'"'!=`""'&`"`plotcmd'"'!=`""') {		
+		* Add labels
+		if ("`by'"!="") {
+		    if ("`bystring'"=="T") {
+			   label val group `bylabel'
+			   decode group, gen(`byvarname')
+			}
+		    else {
+			   qui gen `byvarname'=group
+			   if ("`bylabel'"!="") label val `byvarname' `bylabel'
+			}
+			label var `byvarname' "Group"
+			qui drop group
+			order `byvarname'
+		}
+		else qui drop group
+		
+		capture confirm variable dots_x dots_binid dots_isknot dots_fit
+		if (_rc==0) {
+			label var dots_x "Dots: grid"
+			label var dots_binid "Dots: indicator of bins"
+			label var dots_isknot "Dots: indicator of inner knot"
+			label var dots_fit "Dots: fitted values"
+		}
+		capture confirm variable line_x line_binid line_isknot line_fit
+		if (_rc==0) {
+			label var line_x "Line: grid"
+			label var line_binid "Line: indicator of bins"
+			label var line_isknot "Line: indicator of inner knot"
+			label var line_fit "Line: fitted values"
+		}
+		capture confirm variable poly_x poly_binid poly_isknot poly_fit
+		if (_rc==0) {
+			label var poly_x "Poly: grid"
+			label var poly_binid "Poly: indicator of bins"
+			label var poly_isknot "Poly: indicator of inner knot"
+			label var poly_fit "Poly: fitted values"
+		}
+		capture confirm variable polyCI_x polyCI_binid polyCI_isknot polyCI_l polyCI_r
+		if (_rc==0) {
+			label var polyCI_x "Poly confidence interval: grid"
+			label var polyCI_binid "Poly confidence interval: indicator of bins"
+			label var polyCI_isknot "Poly confidence interval: indicator of inner knot"
+			label var polyCI_l "Poly confidence interval: left boundary"
+			label var polyCI_r "Poly confidence interval: right boundary"
+		}
+		capture confirm variable CI_x CI_binid CI_isknot CI_l CI_r
+		if (_rc==0) {
+			label var CI_x "Confidence interval: grid"
+			label var CI_binid "Confidence interval: indicator of bins"
+			label var CI_isknot "Confidence interval: indicator of inner knot"
+			label var CI_l "Confidence interval: left boundary"
+			label var CI_r "Confidence interval: right boundary"
+		}
+		capture confirm variable CB_x CB_binid CB_isknot CB_l CB_r
+		if (_rc==0) {
+			label var CB_x "Confidence band: grid"			
+		    label var CB_binid "Confidence band: indicator of bins"
+		    label var CB_isknot "Confidence band: indicator of inner knot"
+			label var CB_l "Confidence band: left boundary"
+			label var CB_r "Confidence band: right boundary"
+		}
+	    qui save `"`savedata'"', `replace'
+	 }
+	 ***************************************************************************
+	 	 
+	 *********************************
+	 ********** Return ***************
+	 *********************************
+	 ereturn clear
+	 * # of observations
+	 ereturn scalar N=`Ntotal'
+	 * Options
+	 ereturn scalar level=`level'
+	 ereturn scalar dots_p=`dots_p'
+	 ereturn scalar dots_s=`dots_s'
+	 ereturn scalar line_p=`line_p'
+	 ereturn scalar line_s=`line_s'
+	 ereturn scalar ci_p=`ci_p'
+	 ereturn scalar ci_s=`ci_s'
+	 ereturn scalar cb_p=`cb_p'
+	 ereturn scalar cb_s=`cb_s'
+	 * by group:
+	 *ereturn matrix knot=`kmat'
+	 ereturn matrix cval_by=`cvallist'
+	 ereturn matrix nbins_by=`nbinslist'
+     ereturn matrix Nclust_by=`Nclustlist'
+	 ereturn matrix Ndist_by=`Ndistlist'
+	 ereturn matrix N_by=`Nlist'
+
+	 ereturn matrix imse_var_rot=`mat_imse_var_rot'
+	 ereturn matrix imse_bsq_rot=`mat_imse_bsq_rot'
+	 ereturn matrix	imse_var_dpi=`mat_imse_var_dpi'
+	 ereturn matrix imse_bsq_dpi=`mat_imse_bsq_dpi'
+end
+
+* Helper commands
+* Estimation
+program define binsprobit_fit, eclass
+     version 13
+     syntax varlist(min=2 numeric ts fv) [if] [in] [fw aw pw] [, deriv(integer 0) ///
+	        p(integer 0) s(integer 0) type(string) vce(passthru)  ///
+			xcat(varname numeric) kmat(name) dotsmean(integer 0) ///        /* xmean: report x-mean? */
+			xname(name) yname(name) catname(name) edge(name) ///
+			usereg sorted usegtools probitopt(string asis)]                                                 /* usereg: force the command to use reg; sored: sorted data? */
+	 
+	 preserve
+	 marksample touse
+	 qui keep if `touse'
+	 
+	 if ("`weight'"!="") local wt [`weight'`exp']
+	 
+	 tokenize `varlist'
+	 local y_var `1'
+	 local x_var `2'
+	 macro shift 2
+	 local w_var "`*'"
+	 local nbins=rowsof(`kmat')-1
+	 
+	 tempname matxmean temp_b temp_V
+	 mat `matxmean'=.
+	 mat `temp_b'=.
+	 mat `temp_V'=.
+	 
+	 if (`dotsmean'!=0) {
+	    if ("`sorted'"==""|"`weight'"!=""|"`usegtools'"!="") {
+	       if ("`usegtools'"=="") {
+		      tempfile tmpfile
+			  qui save `tmpfile', replace
+			  
+		      collapse (mean) `x_var' `wt', by(`xcat') fast
+		      mkmat `xcat' `x_var', matrix(`matxmean')
+			  
+			  use `tmpfile', clear
+		   }
+		   else {
+		      tempname obj
+		      qui gstats tabstat `x_var' `wt', stats(mean) by(`xcat') matasave("`obj'")
+			  mata: st_matrix("`matxmean'", (`obj'.getnum(.,1), `obj'.getOutputVar("`x_var'")))	
+		      mata: mata drop `obj'
+		   }
+		}
+		else {
+		   tempname output
+		   mata: `output'=binsreg_stat(`xname', `catname', `nbins', `edge', "mean", -1); ///
+				 st_matrix("`matxmean'", `output')
+		   mata: mata drop `output'
+		}
+	 }
+	 
+	 * Regression?
+	 if (`p'==0) {
+		 capture probit `y_var' ibn.`xcat' `w_var' `wt', nocon `vce' `probitopt'
+		 if (_rc==0) {
+		    matrix `temp_b'=e(b)
+		    matrix `temp_V'=e(V)
+		 }
+		 else {
+		    error _rc
+			exit _rc
+		 }
+	 }
+	 else {
+	     local nseries=(`p'-`s'+1)*(`nbins'-1)+`p'+1
+	     local series ""
+	     forvalues i=1/`nseries' {
+	        tempvar sp`i'
+	        local series `series' `sp`i''
+		    qui gen `sp`i''=. in 1
+	     }
+	
+		 mata: binsreg_st_spdes(`xname', "`series'", "`kmat'", `catname', `p', 0, `s')
+	     
+		 capture probit `y_var' `series' `w_var' `wt', nocon `vce' `probitopt'
+	     * store results
+	     if (_rc==0) {
+		    matrix `temp_b'=e(b)
+		    matrix `temp_V'=e(V)
+			mata: binsreg_checkdrop("`temp_b'", "`temp_V'", `nseries')
+	     }
+	     else {
+	        error  _rc
+	   	    exit _rc
+         }
+	 }
+	 
+	 
+	 ereturn clear
+	 ereturn matrix bmat=`temp_b'
+	 ereturn matrix Vmat=`temp_V'
+	 ereturn matrix xmat=`matxmean'         /* xcat, xbar */
+end
+
+mata:
+
+  // Prediction for plotting
+  real matrix binsprobit_plotmat(string scalar eb, string scalar eV, real scalar cval, ///
+                                string scalar knotname, real scalar J, ///
+                                real scalar p, real scalar s, real scalar deriv, ///
+                                string scalar type, real scalar ngrid, string scalar muwmat, ///
+							    real scalar nw, string scalar transform, string scalar avar, | string scalar muxmat) 
+  {
+    real matrix coef, bmat, rmat, vmat, knot, xmean, wval, eval, out, fit, fit0, se, semat, Xm, Xm0, result
+	real scalar nseries
+	
+	nseries=(p-s+1)*(J-1)+p+1
+	coef=st_matrix(eb)'
+	bmat=coef[|1\nseries|]
+	if (nw>0) rmat=coef[|(nseries+1)\rows(coef)|]
+	
+	if (type=="ci"|type=="cb") {
+	   vfull=st_matrix(eV)
+	   vmat=vfull[|1,1\nseries,nseries|]
+	}
+    
+    // Prepare evaluation points
+    eval=J(0,3,.)
+    if (args()==15) {
+	   xmean=st_matrix(muxmat)
+       eval=(eval \ (xmean[,2], J(J, 1, 0), xmean[,1])) 
+    }
+    if (ngrid!=0) eval=(eval \ binsreg_grids(knotname, ngrid))
+	
+	// adjust w variables
+	if (nw>0) {
+	   wvec=st_matrix(muwmat)
+       wval=wvec*rmat
+	}
+	else wval=0
+	
+	fit=J(0,1,.)
+	se=J(0,1,.)
+	if (p==0) {
+	   if (args()==15) fit=(fit \ bmat)
+	   if (ngrid!=0) {
+	     fit=(fit \ (bmat#(J(ngrid,1,1)\.)))
+		 fit=fit[|1 \ (rows(fit)-1)|]
+	   }
+	   if (type=="ci"|type=="cb") {
+	      if (avar=="on") semat=sqrt(diagonal(vmat))
+		  else {
+		     if (nw>0) {
+			    Xm=(I(nseries), J(nseries,1,1)#wvec)
+				semat=sqrt(rowsum((Xm*vfull):*Xm))
+			 }
+			 else semat=sqrt(diagonal(vmat))
+		  }
+		  if (args()==15) se=(se \ semat)
+		  if (ngrid!=0) {
+		     se=(se \ (semat#(J(ngrid,1,1)\.)))
+		     se=se[|1 \ (rows(se)-1)|]
+		  }
+	   }
+	   if (type=="dots"|type=="line") {
+	      if (transform=="T") out=(eval, normal(fit:+wval))
+		  else                out=(eval, fit:+wval)
+	   }
+	   else {
+	      if (transform=="T") out=(eval, normal(fit:+wval)-(normalden(fit:+wval):*se)*cval, ///
+		                                 normal(fit:+wval)+(normalden(fit:+wval):*se)*cval)
+		  else                out=(eval, (fit:+wval)-se*cval, (fit:+wval)+se*cval)
+	   }
+	}
+	else {
+	   Xm=binsreg_spdes(eval[,1], knotname, eval[,3], p, deriv, s)
+	   if (type=="dots"|type=="line") {
+	      if (transform=="T") {
+		     fit=binsreg_pred(Xm, bmat, ., "xb")[,1]
+		     if (deriv==0) {
+			    fit=normal(fit:+wval)
+			 }
+			 if (deriv==1) {
+			    Xm0=binsreg_spdes(eval[,1], knotname, eval[,3], p, 0, s)
+			    fit0=binsreg_pred(Xm0, bmat, ., "xb")[,1]
+			    fit=normalden(fit0:+wval):*fit
+			 }
+			 
+			 out=(eval, fit)
+		  }
+		  else {
+	         fit=binsreg_pred(Xm, bmat, ., "xb")[,1]
+			 if (deriv==0) out=(eval, fit:+wval)
+			 else          out=(eval, fit)
+		  }
+	   }
+	   else {
+	      if (avar=="on") {
+	   	     result=binsreg_pred(Xm, bmat, vmat, "all")
+	         if (transform=="T") {
+		  	    Xm0=binsreg_spdes(eval[,1], knotname, eval[,3], p, 0, s)
+			    fit0=binsreg_pred(Xm0, bmat, ., "xb")[,1]
+		        result[,2]=normalden(fit0:+wval):*result[,2]
+			 
+		        if (deriv==0) {
+			       result[,1]=normal(result[,1]:+wval)
+			    }
+			    if (deriv==1) {
+			       result[,1]=normalden(fit0:+wval):*result[,1]
+			    }
+			 
+			    out=(eval, result[,1]-cval*result[,2], result[,1]+cval*result[,2])
+		     }
+		     else {
+		        if (deriv==0) out=(eval, (result[,1]:+wval)-cval*result[,2], (result[,1]:+wval)+cval*result[,2])
+			    else          out=(eval, result[,1]-cval*result[,2], result[,1]+cval*result[,2])
+	         }
+		  }
+		  else {
+		     result=binsreg_pred(Xm, bmat, vmat, "all")
+		     if (transform=="T") {				
+				if (deriv==0) {
+				   if (nw>0) Xm=(Xm, J(rows(Xm),1,1)#wvec)
+				   result[,2]=normalden(result[,1]:+wval):*sqrt(rowsum((Xm*vfull):*Xm))
+				   result[,1]=normal(result[,1]:+wval)
+				}
+				if (deriv==1) {
+				   Xm0=binsreg_spdes(eval[,1], knotname, eval[,3], p, 0, s)
+				   if (nw>0) {
+				      Xm0=(Xm0, J(rows(Xm0),1,1)#wvec)
+					  Xm=(Xm, J(rows(Xm),nw,0))
+				   }
+			       fit0=binsreg_pred(Xm0, coef, ., "xb")[,1]
+				   Xm=(-fit0):*normalden(fit0):*result[,1]:*Xm0 + ///
+				      normalden(fit0):*Xm
+				   result[,2]=sqrt(rowsum((Xm*vfull):*Xm))
+				   result[,1]=normalden(fit0):*result[,1]
+				}
+				out=(eval, result[,1]-cval*result[,2], result[,1]+cval*result[,2])
+			 }
+			 else {
+			    if (nw>0) {
+				   if (deriv==0) Xm=(Xm, J(rows(Xm),1,1)#wvec)
+				   else          Xm=(Xm, J(rows(Xm),nw,0))
+				}
+				result=binsreg_pred(Xm, coef, vfull, "all")
+				out=(eval, result[,1]-cval*result[,2], result[,1]+cval*result[,2])
+			 }
+		  }
+	   }
+	}
+
+	if (type=="dots"|(type=="line"&(s==0|s-deriv<=0))) {
+	   out[selectindex(out[,2]:==1),4]=J(sum(out[,2]),1,.)
+	}
+	if (type=="ci"|(type=="cb"&(s==0|s-deriv<=0))) {
+	   out[selectindex(out[,2]:==1),4..5]=J(sum(out[,2]),2,.)
+	}
+	
+	return(out)
+  }
+
+  
+end
+

110/replication_package/replication/ado/plus/b/binsprobit.sthlp

@@ -0,0 +1,428 @@
+{smcl}
+{* *! version 1.2 09-OCT-2022}{...}
+{viewerjumpto "Syntax" "binsprobit##syntax"}{...}
+{viewerjumpto "Description" "binsprobit##description"}{...}
+{viewerjumpto "Options" "binsprobit##options"}{...}
+{viewerjumpto "Examples" "binsprobit##examples"}{...}
+{viewerjumpto "Stored results" "binsprobit##stored_results"}{...}
+{viewerjumpto "References" "binsprobit##references"}{...}
+{viewerjumpto "Authors" "binsprobit##authors"}{...}
+{cmd:help binsprobit}
+{hline}
+
+{title:Title}
+
+{p 4 8}{hi:binsprobit} {hline 2} Data-Driven Binscatter Probit Estimation with Robust Inference Procedures and Plots.{p_end}
+
+
+{marker syntax}{...}
+{title:Syntax}
+
+{p 4 15} {cmdab:binsprobit} {depvar} {it:indvar} [{it:othercovs}] {ifin} {weight} [ {cmd:,} {opt deriv(v)} {opt at(position)} {opt nolink}{p_end}
+{p 15 15} {opt dots(dotsopt)} {opt dotsgrid(dotsgridoption)} {opt dotsplotopt(dotsoption)}{p_end}
+{p 15 15} {opt line(lineopt)} {opt linegrid(#)} {opt lineplotopt(lineoption)}{p_end}
+{p 15 15} {opt ci(ciopt)} {opt cigrid(cigridoption)} {opt ciplotopt(rcapoption)}{p_end}
+{p 15 15} {opt cb(cbopt)} {opt cbgrid(#)} {opt cbplotopt(rareaoption)}{p_end}
+{p 15 15} {opt polyreg(p)} {opt polyreggrid(#)} {opt polyregcigrid(#)} {opt polyregplotopt(lineoption)}{p_end}
+{p 15 15} {opth by(varname)} {cmd:bycolors(}{it:{help colorstyle}list}{cmd:)} {cmd:bysymbols(}{it:{help symbolstyle}list}{cmd:)} {cmd:bylpatterns(}{it:{help linepatternstyle}list}{cmd:)}{p_end}
+{p 15 15} {opt nbins(nbinsopt)} {opt binspos(position)} {opt binsmethod(method)} {opt nbinsrot(#)} {opt samebinsby} {opt randcut(#)}{p_end}
+{p 15 15} {cmd:pselect(}{it:{help numlist}}{cmd:)} {cmd:sselect(}{it:{help numlist}}{cmd:)}{p_end}
+{p 15 15} {opt nsims(#)} {opt simsgrid(#)} {opt simsseed(seed)}{p_end}
+{p 15 15} {opt dfcheck(n1 n2)} {opt masspoints(masspointsoption)}{p_end}
+{p 15 15} {cmd:vce(}{it:{help vcetype}}{cmd:)} {opt asyvar(on/off)}{p_end}
+{p 15 15} {opt level(level)} {opt probitopt(probit_option)} {opt usegtools(on/off)} {opt noplot} {opt savedata(filename)} {opt replace}{p_end}
+{p 15 15} {opt plotxrange(min max)} {opt plotyrange(min max)} {it:{help twoway_options}} ]{p_end}
+
+{p 4 8} where {depvar} is the dependent variable, {it:indvar} is the independent variable for binning, and {it:othercovs} are other covariates to be controlled for.{p_end}
+
+{p 4 8} The degree of the piecewise polynomial p, the number of smoothness constraints s, and the derivative order v are integers 
+satisfying 0 <= s,v <= p, which can take different values in each case.{p_end}
+
+{p 4 8} {opt fweight}s and {opt pweight}s are allowed; see {help weight}.{p_end}
+
+{marker description}{...}
+{title:Description}
+
+{p 4 8} {cmd:binsprobit} implements binscatter probit estimation with robust inference procedures and plots, following the results in
+{browse "https://nppackages.github.io/references/Cattaneo-Crump-Farrell-Feng_2022_Binscatter.pdf":Cattaneo, Crump, Farrell and Feng (2022a)}.
+Binscatter provides a flexible way to describe the mean relationship between two variables, after possibly adjusting for other covariates,
+based on partitioning/binning of the independent variable of interest.
+The main purpose of this command is to generate binned scatter plots with curve estimation with robust pointwise confidence intervals and uniform confidence band.
+If the binning scheme is not set by the user, the companion command {help binsregselect:binsregselect} is used to implement binscatter in a data-driven way.
+Hypothesis testing for parametric specifications of and shape restrictions on the regression function can be conducted via the
+companion command {help binstest:binstest}. Hypothesis testing for pairwise group comparisons can be conducted via the
+companion command {help binspwc: binspwc}. Binscatter estimation based on the least squares method can be conducted via the command {help binsreg: binsreg}.
+{p_end}
+
+{p 4 8} A detailed introduction to this command is given in
+{browse "https://nppackages.github.io/references/Cattaneo-Crump-Farrell-Feng_2022_Stata.pdf":Cattaneo, Crump, Farrell and Feng (2022b)}.
+Companion R and Python packages with the same capabilities are available (see website below).
+{p_end}
+
+{p 4 8} Companion commands: {help binstest:binstest} for hypothesis testing of parametric specifications and shape restrictions,
+{help binspwc:binspwc} for hypothesis testing for pairwise group comparisons, and
+{help binsregselect:binsregselect} for data-driven binning selection.{p_end}
+
+{p 4 8} Related Stata, R and Python packages are available in the following website:{p_end}
+
+{p 8 8} {browse "https://nppackages.github.io/":https://nppackages.github.io/}{p_end}
+
+
+{marker options}{...}
+{title:Options}
+
+{dlgtab:Estimand}
+
+{p 4 8} {opt deriv(v)} specifies the derivative order of the regression function for estimation and plotting.
+The default is {cmd:deriv(0)}, which corresponds to the function itself.
+{p_end}
+
+{p 4 8} {opt at(position)} specifies the values of {it:othercovs} at which the estimated function is evaluated for plotting.
+The default is {cmd:at(mean)}, which corresponds to the mean of {it:othercovs}. Other options are: {cmd:at(median)} for the median of {it:othercovs},
+{cmd:at(0)} for zeros, and {cmd:at(filename)} for particular values of {it:othercovs} saved in another file.
+{p_end}
+
+{p 4 8} Note: When {cmd:at(mean)} or {cmd:at(median)} is specified, all factor variables in {it:othercovs} (if specified) are excluded from the evaluation (set as zero).
+{p_end}
+
+{p 4 8}{opt nolink} specifies that the function within the inverse link (logistic) function be reported instead of the conditional probability function.
+{p_end}
+
+{dlgtab:Dots}
+
+{p 4 8} {opt dots(dotsopt)} sets the degree of polynomial and the number of smoothness for point estimation and plotting as "dots".
+If {cmd:dots(p s)} is specified, a piecewise polynomial of degree {it:p} with {it:s} smoothness constraints is used.  
+The default is {cmd:dots(0 0)}, which corresponds to piecewise constant (canonical binscatter). 
+If {cmd:dots(T)} is specified, the default {cmd:dots(0 0)} is used unless the degree {it:p} and smoothness {it:s} selection
+is requested via the option {cmd:pselect()} (see more details in the explanation of {cmd:pselect()}).  
+If {cmd:dots(F)} is specified, the dots are not included in the plot.
+{p_end}
+
+{p 4 8} {opt dotsgrid(dotsgridoption)} specifies the number and location of dots within each bin to be plotted.
+Two options are available: {it:mean} and a {it:numeric} non-negative integer.
+The option {opt dotsgrid(mean)} adds the sample average of {it:indvar} within each bin to the grid of evaluation points.
+The option {opt dotsgrid(#)} adds {it:#} number of evenly-spaced points to the grid of evaluation points for each bin.
+Both options can be used simultaneously: for example, {opt dotsgrid(mean 5)} generates six evaluation points within each bin
+containing the sample mean of {it:indvar} within each bin and five evenly-spaced points.
+Given this choice, the dots are point estimates evaluated over the selected grid within each bin.
+The default is {opt dotsgrid(mean)}, which corresponds to one dot per bin evaluated at
+the sample average of {it:indvar} within each bin (canonical binscatter).
+{p_end}
+
+{p 4 8} {opt dotsplotopt(dotsoption)} standard graphs options to be passed on to the {help twoway:twoway} command to modify the appearance of the plotted dots.
+{p_end}
+
+{dlgtab:Line}
+
+{p 4 8} {opt line(lineopt)} sets the degree of polynomial and the number of smoothness constraints 
+for plotting as a "line". If {cmd:line(p s)} is specified, a piecewise polynomial of 
+degree {it:p} with {it:s} smoothness constraints is used.  
+If {cmd:line(T)} is specified, {cmd:line(0 0)} is used unless the degree {it:p} and smoothness {it:s} selection
+is requested via the option {cmd:pselect()} (see more details in the explanation of {cmd:pselect()}). 
+If {cmd:line(F)} or {cmd:line()} is specified, the line is not included in the plot.
+The default is {cmd:line()}.
+{p_end}
+
+{p 4 8} {opt linegrid(#)} specifies the number of evaluation points of an evenly-spaced grid within each bin used for evaluation of the point estimate set by the {cmd:line(p s)} option.
+The default is {cmd:linegrid(20)}, which corresponds to 20 evenly-spaced evaluation points within each bin for fitting/plotting the line.
+{p_end}
+
+{p 4 8} {opt lineplotopt(lineoption)} standard graphs options to be passed on to the {help twoway:twoway} command to modify the appearance of the plotted line.
+{p_end}
+
+{dlgtab:Confidence Intervals}
+
+{p 4 8} {opt ci(ciopt)} specifies the degree of polynomial and the number of smoothness constraints
+for constructing confidence intervals. If {cmd:ci(p s)} is specified, a piecewise polynomial of 
+degree {it:p} with {it:s} smoothness constraints is used.  
+If {cmd:ci(T)} is specified, {cmd:ci(1 1)} is used unless the degree {it:p} and smoothness {it:s} selection
+is requested via the option {cmd:pselect()} (see more details in the explanation of {cmd:pselect()}). 
+If {cmd:ci(F)} or {cmd:ci()} is specified, the confidence intervals are not included in the plot. 
+The default is {cmd:ci()}.
+{p_end}
+
+{p 4 8} {opt cigrid(cigridoption)} specifies the number and location of evaluation points in the grid
+used to construct the confidence intervals set by the {opt ci(p s)} option.
+Two options are available: {it:mean} and a {it:numeric} non-negative integer.
+The option {opt cigrid(mean)} adds the sample average of {it:indvar} within each bin to the grid of evaluation points.
+The option {opt cigrid(#)} adds {it:#} number of evenly-spaced points to the grid of evaluation points for each bin.
+Both options can be used simultaneously: for example, {opt cigrid(mean 5)} generates six evaluation points within each bin
+containing the sample mean of {it:indvar} within each bin and five evenly-spaced points.
+The default is {opt cigrid(mean)}, which corresponds to one evaluation point set at
+the sample average of {it:indvar} within each bin for confidence interval construction.
+{p_end}
+
+{p 4 8} {opt ciplotopt(rcapoption)} standard graphs options to be passed on to the
+{help twoway:twoway} command to modify the appearance of the confidence intervals.
+{p_end}
+
+{dlgtab:Confidence Band}
+
+{p 4 8} {opt cb(cbopt)} specifies the degree of polynomial and the number of smoothness constraints
+for constructing the confidence band. If {cmd:cb(p s)} is specified, a piecewise polynomial of 
+degree {it:p} with {it:s} smoothness constraints is used. 
+If the option {cmd:cb(T)} is specified, {cmd:cb(1 1)} is used unless the degree {it:p} and smoothness {it:s} selection
+is requested via the option {cmd:pselect()} (see more details in the explanation of {cmd:pselect()}). 
+If {cmd:cb(F)} or {cmd:cb()} is specified, the confidence band is not included in the plot.
+The default is {cmd:cb()}.
+{p_end}
+
+{p 4 8} {opt cbgrid(#)} specifies the number of evaluation points of an evenly-spaced grid within each bin used for evaluation of the point estimate set by the {cmd:cb(p s)} option.
+The default is {cmd:cbgrid(20)}, which corresponds to 20 evenly-spaced evaluation points within each bin for confidence band construction.
+{p_end}
+
+{p 4 8} {opt cbplotopt(rareaoption)} standard graphs options to be passed on to the {help twoway:twoway} command to modify the appearance of the confidence band.
+{p_end}
+
+{dlgtab:Global Polynomial Regression}
+
+{p 4 8} {opt polyreg(p)} sets the degree {it:p} of a global polynomial regression model for plotting.
+By default, this fit is not included in the plot unless explicitly specified.
+Recommended specification is {cmd:polyreg(3)}, which adds a cubic polynomial fit of the regression function of interest to the binned scatter plot. 
+{p_end}
+
+{p 4 8} {opt polyreggrid(#)} specifies the number of evaluation points of an evenly-spaced grid within each bin
+used for evaluation of the point estimate set by the {cmd:polyreg(p)} option.
+The default is {cmd:polyreggrid(20)}, which corresponds to 20 evenly-spaced evaluation points within each bin for confidence interval construction.
+{p_end}
+
+{p 4 8} {opt polyregcigrid(#)} specifies the number of evaluation points of an evenly-spaced grid within each bin used for
+constructing confidence intervals based on polynomial regression set by the {cmd:polyreg(p)} option.
+The default is {cmd:polyregcigrid(0)}, which corresponds to not plotting confidence intervals for the global polynomial regression approximation.
+{p_end}
+
+{p 4 8} {opt polyregplotopt(lineoption)} standard graphs options to be passed on to the {help twoway:twoway} command to modify the appearance of the global polynomial regression fit.
+{p_end}
+
+{dlgtab:Subgroup Analysis}
+
+{p 4 8} {opt by(varname)} specifies the variable containing the group indicator to perform subgroup analysis;
+both numeric and string variables are supported.
+When {opt by(varname)} is specified, {cmdab:binsprobit} implements estimation and inference for each subgroup separately,
+but produces a common binned scatter plot.
+By default, the binning structure is selected for each subgroup separately,
+but see the option {cmd:samebinsby} below for imposing a common binning structure across subgroups.
+{p_end}
+
+{p 4 8} {cmd:bycolors(}{it:{help colorstyle}list}{cmd:)} specifies an ordered list of colors for plotting each subgroup series defined by the option {opt by()}.
+{p_end}
+
+{p 4 8} {cmd:bysymbols(}{it:{help symbolstyle}list}{cmd:)} specifies an ordered list of symbols for plotting each subgroup series defined by the option {opt by()}.
+{p_end}
+
+{p 4 8} {cmd:bylpatterns(}{it:{help linepatternstyle}list}{cmd:)} specifies an ordered list of line patterns for plotting each subgroup series defined by the option {opt by()}.
+{p_end}
+
+{dlgtab:Binning/Degree/Smoothness Selection}
+
+{p 4 8} {opt nbins(nbinsopt)} sets the number of bins for partitioning/binning of {it:indvar}. 
+If {cmd:nbins(T)} or {cmd:nbins()} (default) is specified, the number of bins is selected via the companion command {help binsregselect:binsregselect} 
+in a data-driven, optimal way whenever possible. If a {help numlist:numlist} with more than one number is specified, 
+the number of bins is selected within this list via the companion command {help binsregselect:binsregselect}.
+{p_end}
+
+{p 4 8} {opt binspos(position)} specifies the position of binning knots.
+The default is {cmd:binspos(qs)}, which corresponds to quantile-spaced binning (canonical binscatter).
+Other options are: {cmd:es} for evenly-spaced binning, or a {help numlist} for manual specification of
+the positions of inner knots (which must be within the range of {it:indvar}).
+{p_end}
+
+{p 4 8} {opt binsmethod(method)} specifies the method for data-driven selection of the number of bins via
+the companion command {help binsregselect:binsregselect}.
+The default is {cmd:binsmethod(dpi)}, which corresponds to the IMSE-optimal direct plug-in rule.
+The other option is: {cmd:rot} for rule of thumb implementation.
+{p_end}
+
+{p 4 8} {opt nbinsrot(#)} specifies an initial number of bins value used to construct the DPI number of bins selector.
+If not specified, the data-driven ROT selector is used instead.
+{p_end}
+
+{p 4 8} {opt samebinsby} forces a common partitioning/binning structure across all subgroups specified by the option {cmd:by()}.
+The knots positions are selected according to the option {cmd:binspos()} and using the full sample.
+If {cmd:nbins()} is not specified, then the number of bins is selected via the companion command
+{help binsregselect:binsregselect} and using the full sample.
+{p_end}
+
+{p 4 8} {opt randcut(#)} specifies the upper bound on a uniformly distributed variable used to draw a subsample 
+for bins/degree/smoothness selection.
+Observations for which {cmd:runiform()<=#} are used. # must be between 0 and 1. 
+By default, max(5,000, 0.01n) observations are used if the samples size n>5,000.
+{p_end}
+
+{p 4 8} {opt pselect(numlist)} specifies a list of numbers within which the degree of polynomial {it:p} for 
+point estimation is selected. Piecewise polynomials of the selected optimal degree {it:p} 
+are used to construct dots or line if {cmd:dots(T)} or {cmd:line(T)} is specified, 
+whereas piecewise polynomials of degree {it:p+1} are used to construct confidence intervals
+or confidence band if {cmd:ci(T)} or {cmd:cb(T)} is specified.
+{p_end}
+
+{p 4 8} {opt sselect(numlist)} specifies a list of numbers within which 
+the number of smoothness constraints {it:s}
+for point estimation.  Piecewise polynomials with the selected optimal 
+{it:s} smoothness constraints are used to construct dots or line 
+if {cmd:dots(T)} or {cmd:line(T)} is specified, 
+whereas piecewise polynomials with {it:s+1} constraints are used to construct 
+confidence intervals or confidence band if {cmd:ci(T)} or {cmd:cb(T)} is specified. 
+If not specified, for each value {it:p} supplied in the 
+option {cmd:pselect()}, only the piecewise polynomial with the maximum smoothness is considered, i.e., {it:s=p}. 
+{p_end}
+
+{p 4 8} Note: To implement the degree or smoothness selection, in addition to {cmd:pselect()} 
+or {cmd:sselect()}, {cmd:nbins(#)} must be specified.
+{p_end}
+
+{dlgtab:Simulation}
+
+{p 4 8} {opt nsims(#)} specifies the number of random draws for constructing confidence bands.
+The default is {cmd:nsims(500)}, which corresponds to 500 draws from a standard Gaussian random vector of size [(p+1)*J - (J-1)*s].
+A large number of random draws is recommended to obtain the final results.
+{p_end}
+
+{p 4 8} {opt simsgrid(#)} specifies the number of evaluation points of an evenly-spaced grid
+within each bin used for evaluation of the supremum operation needed to construct confidence bands.
+The default is {cmd:simsgrid(20)}, which corresponds to 20 evenly-spaced evaluation points
+within each bin for approximating the supremum operator.
+A large number of evaluation points is recommended to obtain the final results.
+{p_end}
+
+{p 4 8} {opt simsseed(#)} sets the seed for simulations.
+{p_end}
+
+{dlgtab:Mass Points and Degrees of Freedom}
+
+{p 4 8} {opt dfcheck(n1 n2)} sets cutoff values for minimum effective sample size checks,
+which take into account the number of unique values of {it:indvar} (i.e., adjusting for the number of mass points),
+number of clusters, and degrees of freedom of the different statistical models considered.
+The default is {cmd:dfcheck(20 30)}. See Cattaneo, Crump, Farrell and Feng (2022b) for more details.
+{p_end}
+
+{p 4 8} {opt masspoints(masspointsoption)} specifies how mass points in {it:indvar} are handled.
+By default, all mass point and degrees of freedom checks are implemented.
+Available options:
+{p_end}
+{p 8 8} {opt masspoints(noadjust)} omits mass point checks and the corresponding effective sample size adjustments.{p_end}
+{p 8 8} {opt masspoints(nolocalcheck)} omits within-bin mass point and degrees of freedom checks.{p_end}
+{p 8 8} {opt masspoints(off)} sets {opt masspoints(noadjust)} and {opt masspoints(nolocalcheck)} simultaneously.{p_end}
+{p 8 8} {opt masspoints(veryfew)} forces the command to proceed as if {it:indvar} has only a few number of mass points (i.e., distinct values).
+In other words, forces the command to proceed as if the mass point and degrees of freedom checks were failed.{p_end}
+
+{dlgtab:Standard Error}
+
+{p 4 8} {cmd:vce(}{it:{help vcetype}}{cmd:)} specifies the {it:vcetype} for variance estimation used by the command {help probit##options:probit}.
+The default is {cmd:vce(robust)}.
+{p_end}
+
+{p 4 8} {opt asyvar(on/off)} specifies the method used to compute standard errors.
+If {cmd:asyvar(on)} is specified, the standard error of the nonparametric component is used
+and the uncertainty related to other control variables {it:othercovs} is omitted.
+Default is {cmd:asyvar(off)}, that is, the uncertainty related to {it:othercovs} is taken into account.
+{p_end}
+
+{dlgtab:Other Options}
+
+{p 4 8} {opt level(#)} sets the nominal confidence level for confidence interval and confidence band estimation. 
+Default is {cmd:level(95)}.
+{p_end}
+
+{p 4 8} {opt probitopt(probit_option)} options to be passed on to the command {help probit##options:probit}. 
+For example, options that control for the optimization process can be added here.
+{p_end}
+
+{p 4 8}{opt usegtools(on/off)} forces the use of several commands in the community-distributed Stata package {cmd:gtools} to speed the computation up, if {it:on} is specified.
+Default is {cmd:usegtools(off)}.
+{p_end}
+
+{p 4 8} For more information about the package {cmd:gtools}, please see {browse "https://gtools.readthedocs.io/en/latest/index.html":https://gtools.readthedocs.io/en/latest/index.html}.
+{p_end}
+
+{p 4 8} {opt noplot} omits binscatter plotting.
+{p_end}
+
+{p 4 8} {opt savedata(filename)} specifies a filename for saving all data underlying the binscatter plot (and more).
+{p_end}
+
+{p 4 8} {opt replace} overwrites the existing file when saving the graph data.
+{p_end}
+
+{p 4 8} {opt plotxrange(min max)} specifies the range of the x-axis for plotting. Observations outside the range are dropped in the plot.
+{p_end}
+
+{p 4 8} {opt plotyrange(min max)} specifies the range of the y-axis for plotting. Observations outside the range are dropped in the plot.
+{p_end}
+
+{p 4 8} {it:{help twoway_options}} any unrecognized options are appended to the end of the twoway command generating the binned scatter plot.
+{p_end}
+
+
+{marker examples}{...}
+{title:Examples}
+
+{p 4 8}  Setup{p_end}
+{p 8 8} . {stata sysuse auto}{p_end}
+
+{p 4 8} Run a binscatter probit regression and report the plot{p_end}
+{p 8 8} . {stata binsprobit foreign weight mpg}{p_end}
+
+{p 4 8} Add confidence intervals and confidence band{p_end}
+{p 8 8} . {stata binsprobit foreign weight mpg, ci(1 1) nbins(5)}{p_end}
+
+
+{marker stored_results}{...}
+{title:Stored results}
+
+{synoptset 17 tabbed}{...}
+{p2col 5 17 21 2: Scalars}{p_end}
+{synopt:{cmd:e(N)}}number of observations{p_end}
+{synopt:{cmd:e(level)}}confidence level{p_end}
+{synopt:{cmd:e(dots_p)}}degree of polynomial for dots{p_end}
+{synopt:{cmd:e(dots_s)}}smoothness of polynomial for dots{p_end}
+{synopt:{cmd:e(line_p)}}degree of polynomial for line{p_end}
+{synopt:{cmd:e(line_s)}}smoothness of polynomial for line{p_end}
+{synopt:{cmd:e(ci_p)}}degree of polynomial for confidence interval{p_end}
+{synopt:{cmd:e(ci_s)}}smoothness of polynomial for confidence interval{p_end}
+{synopt:{cmd:e(cb_p)}}degree of polynomial for confidence band{p_end}
+{synopt:{cmd:e(cb_s)}}smoothness of polynomial for confidence band{p_end}
+{p2col 5 17 21 2: Matrices}{p_end}
+{synopt:{cmd:e(N_by)}}number of observations for each group{p_end}
+{synopt:{cmd:e(Ndist_by)}}number of distinct values for each group{p_end}
+{synopt:{cmd:e(Nclust_by)}}number of clusters for each group{p_end}
+{synopt:{cmd:e(nbins_by)}}number of bins for each group{p_end}
+{synopt:{cmd:e(cval_by)}}critical value for each group, used for confidence bands{p_end}
+{synopt:{cmd:e(imse_var_rot)}}variance constant in IMSE, ROT selection{p_end}
+{synopt:{cmd:e(imse_bsq_rot)}}bias constant in IMSE, ROT selection{p_end}
+{synopt:{cmd:e(imse_var_dpi)}}variance constant in IMSE, DPI selection{p_end}
+{synopt:{cmd:e(imse_bsq_dpi)}}bias constant in IMSE, DPI selection{p_end}
+
+{marker references}{...}
+{title:References}
+
+{p 4 8} Cattaneo, M. D., R. K. Crump, M. H. Farrell, and Y. Feng. 2022a.
+{browse "https://nppackages.github.io/references/Cattaneo-Crump-Farrell-Feng_2022_Binscatter.pdf":On Binscatter}.
+{it:arXiv:1902.09608}.
+{p_end}
+
+{p 4 8} Cattaneo, M. D., R. K. Crump, M. H. Farrell, and Y. Feng. 2022b.
+{browse "https://nppackages.github.io/references/Cattaneo-Crump-Farrell-Feng_2022_Stata.pdf":Binscatter Regressions}.
+{it:arXiv:1902.09615}.
+{p_end}
+
+
+{marker authors}{...}
+{title:Authors}
+
+{p 4 8} Matias D. Cattaneo, Princeton University, Princeton, NJ.
+{browse "mailto:[email protected]":[email protected]}.
+{p_end}
+
+{p 4 8} Richard K. Crump, Federal Reserve Band of New York, New York, NY.
+{browse "mailto:[email protected]":[email protected]}.
+{p_end}
+
+{p 4 8} Max H. Farrell, University of Chicago, Chicago, IL.
+{browse "mailto:[email protected]":[email protected]}.
+{p_end}
+
+{p 4 8} Yingjie Feng, Tsinghua University, Beijing, China.
+{browse "mailto:[email protected]":[email protected]}.
+{p_end}
+